N दिनों से अधिक पुरानी फ़ाइलों को हटाने के लिए बैच फ़ाइल

677

मैं एक बैच फ़ाइल में 7 दिनों से अधिक पुरानी सभी फ़ाइलों को हटाने का एक तरीका ढूंढ रहा हूं। मैंने वेब के चारों ओर खोज की है, और कोड की सैकड़ों लाइनों के साथ कुछ उदाहरण पाए हैं, और अन्य जो कार्य को पूरा करने के लिए अतिरिक्त कमांड लाइन उपयोगिताओं को स्थापित करने की आवश्यकता है।

कोड की सिर्फ दो पंक्तियों में BASH में इसी तरह की चीजें की जा सकती हैं । ऐसा लगता है कि कम से कम दूरस्थ रूप से विंडोज में बैच फ़ाइलों के लिए कुछ किया जा सकता है। मैं एक ऐसे समाधान की तलाश में हूं जो बिना किसी अतिरिक्त उपयोगिताओं के मानक विंडोज कमांड प्रॉम्प्ट में काम करता हो। कृपया कोई PowerShell या Cygwin नहीं है।

windows  date  batch-file  file-io  cmd 
— Kibbee
स्रोत
8
जेफ एटवुड ने सर्वरफॉल्ट पर इसका उत्तर दिया जो मुझे लगता है कि यहां दस्तावेज होना चाहिए। serverfault.com/questions/49614/delete-files-older-than-x-days
— डस्टी
एक .BAT फ़ाइल पर आधारित एक नई विधि जो आंतरिक CMD.EXE कमांड का उपयोग करती है, केवल यहां पोस्ट की गई है: stackoverflow.com/questions/9746778/…
— Aacini
1
gehrcke.de/timegaps को इस उद्देश्य के लिए डिज़ाइन किया गया है। यह और भी अधिक परिष्कृत विलोपन योजना के लिए अनुमति देता है: पिछले 7 दिनों की फाइलों को रखने के अलावा, यह भी पिछले 8 सप्ताह, 12, महीनों, 2 वर्षों में से प्रत्येक के लिए एक फ़ाइल रखने की अनुमति देता है।
— डॉ। जन-फिलिप गेर्के

जवाबों:

1071

का आनंद लें:

forfiles -p "C:\what\ever" -s -m *.* -d <number of days> -c "cmd /c del @path"

अधिक विवरण के लिए forfilesप्रलेखन देखें ।

अधिक अच्छाइयों के लिए, Windows XP कमांड लाइन के एक AZ इंडेक्स का संदर्भ लें ।

यदि आपने forfilesअपनी मशीन पर स्थापित नहीं किया है, तो इसे किसी भी विंडोज सर्वर 2003 से अपने विंडोज एक्सपी मशीन पर कॉपी करें %WinDir%\system32\। यह संभव है क्योंकि EXE विंडोज सर्वर 2003 और विंडोज एक्सपी के बीच पूरी तरह से संगत है।

विंडोज और विंडोज सर्वर के बाद के संस्करणों ने इसे डिफ़ॉल्ट रूप से स्थापित किया है।

विंडोज 7 और नए (विंडोज 10 सहित) के लिए:

वाक्य-विन्यास थोड़ा बदल गया है। इसलिए अद्यतन कमांड है:

forfiles /p "C:\what\ever" /s /m *.* /D -<number of days> /C "cmd /c del @path"
— अकु
स्रोत
12
डेल @ शरम होनी चाहिए, मामला यह भी है कि मैं परीक्षण के लिए ग / इको @ शख्स का उपयोग करने का सुझाव देता हूं
— रसेल स्टीन
40
@Russell: @PATH नाम सहित पूरा रास्ता है। @ शख्स केवल नाम है, इसलिए यदि आप सबफ़ोल्डर के साथ काम कर रहे हैं, तो यह काम नहीं करेगा।
— ग्रैग्मैक
86
ध्यान दें कि यदि आप 10 दिनों से अधिक पुरानी फ़ाइलें चाहते हैं, तो आपको "-10" निर्दिष्ट करना होगा। -ve का अर्थ है "पुराने से", + का अर्थ है "से नया"। आप DDMMYY या -DDMMYY प्रारूप को -d के पैरामीटर के रूप में निर्दिष्ट कर सकते हैं।
— ग्रिग्मैक
42
मैंने इस सिंटैक्स का उपयोग Win Server 2008: forfiles / P "C: \ Mysql_backup" / \ / M * .sql / D -30 / C "cmd / c del @PATH" पर किया
— jman
9
यह उत्तर तब काम करता है जब "7 दिनों से अधिक पुराने" को "7 दिनों से अधिक पहले बनाया गया" के बजाय "7 दिनों से अधिक पहले बनाया गया" के रूप में परिभाषित किया जाता है। बाद को कैसे प्राप्त किया जा सकता है?
— टिम्स
76

निम्न आदेश चलाएँ :

ROBOCOPY C:\source C:\destination /mov /minage:7
del C:\destination /q

सभी फ़ाइलों को स्थानांतरित करें (जो कि / मूव का उपयोग करता है, जो फ़ाइलों को स्थानांतरित करता है और फिर उन्हें / विरोध के रूप में हटा देता है / ले जाता है जो पूरे फ़िलेट्रेस को हटा देता है जो फिर हटा दिया जाता है) रोबोकॉपी के माध्यम से किसी अन्य स्थान पर, और फिर उस पथ पर एक डिलीट कमांड निष्पादित करें और आप सभी अच्छा।

इसके अलावा अगर आपके पास बहुत सारे डेटा के साथ एक निर्देशिका है तो आप /mirस्विच का उपयोग कर सकते हैं

— ईमान
स्रोत
5
अधिकांश भाग के लिए, यह एक काफी अव्यवहारिक उत्तर है। यदि मेरे पास बहुत सारे डेटा के साथ एक निर्देशिका है, तो अच्छी तरह से काम नहीं करेगा। मैं एक उत्तर के साथ जाऊंगा जो इसे "जगह पर" करता है
— adamb0mb
5
@ adamb0mb यह किसी भी तरह से अव्यावहारिक नहीं है - अगर "गंतव्य" "स्रोत" के समान फाइल सिस्टम पर है , तो चालन ऑपरेशन काफी हल्का है। जैसा कि रोबोकॉपी वास्तव में मजबूत है, यह वास्तव में किसी भी निर्देशिका आकार, अस्पष्ट फ़ाइल नामों के लिए काम करेगा, मूल रूप से पथ की लंबाई और यदि आवश्यक हो तो निर्देशिकाओं को शामिल करें - ऐसा कुछ जो निश्चित रूप से कई अन्य विंडोज उपयोगिताओं के बारे में नहीं कहा जा सकता है। यदि आप फ़ाइल नामों से परेशानी की उम्मीद करते हैं तो मैं निर्देशिका को खाली rd /s /q c:\destinationकरने के लिए delकमांड के बजाय उपयोग करूंगा या किसी अन्य robocopy /mir c:\emptydir c:\destinationरन का उपयोग करूंगा ।
— पर्यायवाची- dj
12
इसके अलावा, रोबोकॉपी यूएनसी रास्तों का समर्थन करता है - जो forfilesस्वीकृत उत्तर से नहीं करेगा।
— पर्यायवाची- dj
3
मेरे विचार लाइनों के साथ अधिक थे: "मेरी फाइलें पहले से ही हैं जहां मैं उन्हें चाहता हूं। मुझे उन्हें स्थानांतरित करने की आवश्यकता नहीं है।" "फ़ाइलों को हटाना तार्किक रूप से आप क्या कर रहे हैं, इसलिए ऐसा करें।
— रोबोकॉपी
3
मैं C:\test7 दिनों से अधिक पुरानी सभी फ़ाइलों को देखने के लिए इस एक-लाइनर की सलाह देता हूं । फ़ाइलों को हटाने के लिए बदलने echoके लिए del:forfiles /p "C:\test" /m "*.*" /c "cmd /c echo @file" /D -7
— पावर-
25

ओके थोड़ा ऊब गया था और इस के साथ आया था, जिसमें एक गरीब आदमी के लिनक्स युग के प्रतिस्थापन का मेरा दैनिक उपयोग (सीमित समय प्रतिधारण) के लिए सीमित है:

7daysclean.cmd

@echo off
setlocal ENABLEDELAYEDEXPANSION
set day=86400
set /a year=day*365
set /a strip=day*7
set dSource=C:\temp

call :epoch %date%
set /a slice=epoch-strip

for /f "delims=" %%f in ('dir /a-d-h-s /b /s %dSource%') do (
    call :epoch %%~tf
    if !epoch! LEQ %slice% (echo DELETE %%f ^(%%~tf^)) ELSE echo keep %%f ^(%%~tf^)
)
exit /b 0

rem Args[1]: Year-Month-Day
:epoch
    setlocal ENABLEDELAYEDEXPANSION
    for /f "tokens=1,2,3 delims=-" %%d in ('echo %1') do set Years=%%d& set Months=%%e& set Days=%%f
    if "!Months:~0,1!"=="0" set Months=!Months:~1,1!
    if "!Days:~0,1!"=="0" set Days=!Days:~1,1!
    set /a Days=Days*day
    set /a _months=0
    set i=1&& for %%m in (31 28 31 30 31 30 31 31 30 31 30 31) do if !i! LSS !Months! (set /a _months=!_months! + %%m*day&& set /a i+=1)
    set /a Months=!_months!
    set /a Years=(Years-1970)*year
    set /a Epoch=Years+Months+Days
    endlocal& set Epoch=%Epoch%
    exit /b 0

उपयोग

set /a strip=day*7: रखने के लिए दिनों की संख्या के लिए 7 बदलें ।

set dSource=C:\temp : यह फ़ाइलों के लिए जाँच करने के लिए प्रारंभिक निर्देशिका है।

टिप्पणियाँ

यह गैर-विनाशकारी कोड है, यह प्रदर्शित करेगा कि क्या हुआ होगा।

परिवर्तन :

if !epoch! LEQ %slice% (echo DELETE %%f ^(%%~tf^)) ELSE echo keep %%f ^(%%~tf^)

कुछ इस तरह से:

if !epoch! LEQ %slice% del /f %%f

इसलिए फ़ाइलें वास्तव में हटा दी जाती हैं

फरवरी : 28 दिनों के लिए हार्ड-कोडेड है। Bissextile साल जोड़ने के लिए एक नरक है, वास्तव में। अगर किसी को यह विचार है कि कोड की 10 पंक्तियों को नहीं जोड़ा जाएगा, तो आगे बढ़ें और पोस्ट करें ताकि मैं इसे अपने कोड में जोड़ दूं।

युग : मैंने इस बात पर ध्यान नहीं दिया, क्योंकि एक निश्चित तिथि से अधिक पुरानी फाइलों को हटाने की आवश्यकता है, घंटे / मिनट लेने से एक दिन से फाइलें नष्ट हो जाती हैं जो कि रखने के लिए थी।

परिसीमन

युग आपके लघु दिनांक प्रारूप के लिए लेता है YYYY-MM-DD है। इसे अन्य सेटिंग्स या रन-टाइम मूल्यांकन के लिए अनुकूलित करने की आवश्यकता होगी (पढ़ें sShortTime, उपयोगकर्ता-बाउंड कॉन्फ़िगरेशन, एक फ़िल्टर में उचित फ़ील्ड ऑर्डर कॉन्फ़िगर करें और तर्क से सही डेटा निकालने के लिए फ़िल्टर का उपयोग करें)।

क्या मैंने उल्लेख किया कि मुझे इस संपादक के ऑटो-फॉर्मेट से नफरत है? यह रिक्त लाइनों को हटा देता है और कॉपी-पेस्ट एक नरक है।

आशा है कि ये आपकी मदद करेगा।

— नीलकंठ
स्रोत
4
गैर-विनाशकारी कोड के लिए +1, मैं कोशिश करूंगा और जब मैं खुद कोड उदाहरण प्रदान करूं तो इसे ध्यान में रखूंगा।
— हॉगोल्ट
5
रास्ता देर से और पूरी तरह से असंबंधित, लेकिन 7daysclean.cmdएक सिंथ-पंक बैंड के लिए एक भयानक नाम की तरह लगता है।
— फ्लोंक
21 
forfiles /p "v:" /s /m *.* /d -3 /c "cmd /c del @path"

आपको करना चाहिए /d -3(3 दिन पहले) यह मेरे लिए ठीक काम करता है। तो सभी जटिल बैच कचरा बिन में हो सकते हैं। इसके अलावा forfilesUNC रास्तों का समर्थन न करें, इसलिए एक विशिष्ट ड्राइव के लिए नेटवर्क कनेक्शन बनाएं।

— अरनो जानसेन
स्रोत
3
अन्य उत्तरों की तरह ही त्रुटि (स्वीकृत एक सहित)। निर्दिष्ट करने की यह अजीब आदत कहाँ *.*से आई? वाइल्डकार्ड *.*विंडोज में सभी फाइलों से मेल नहीं खाता है। यह केवल .उनके नाम की फाइलों से मेल खाता है । ओपी ने कभी भी .फ़ाइल नाम की आवश्यकता के बारे में कुछ नहीं कहा । उचित पैरामीटर है /M *, लेकिन यह वैसे भी डिफ़ॉल्ट है। इसकी कोई आवश्यकता नहीं है /M।
— चींटी
@AnT: क्या आपको यकीन है? मुझे लगता है कि *.*बिल्कुल *विंडोज की तरह व्यवहार करता है । वास्तव में, मैंने इसे केवल अपने कंप्यूटर पर आज़माया, और dir *.*वास्तव में सूचीबद्ध किया test file, जिसमें कोई एक्सटेंशन नहीं है।
— एंड्रियास रिबब्रांड
1
@ एन्द्रियास रिबब्रांड: मुझे यह आश्चर्यजनक लगता है, लेकिन उपचार के *.*बीच असंगत है, कहते हैं, dirऔर -mविकल्प forfiles। -m *.*मुखौटा वास्तव में, extensionless फ़ाइल नाम को छोड़ के रूप में मैं ऊपर मेरी टिप्पणी (यह अपने आप कोशिश) में कहा गया है जाएगा। यहाँ मज़ेदार हिस्सा यह है कि MS प्रलेखन स्पष्ट रूप से बताता है कि -m *.*डिफ़ॉल्ट है। हालाँकि, यदि आप इसे वास्तविक जीवन में आज़माते हैं, तो आप देखेंगे कि डिफ़ॉल्ट वास्तव में है -m *- सभी फाइलें पुनरावृत्त हैं।
— चींटी
1
यह MS प्रलेखन पृष्ठ - Technet.microsoft.com/en-us/library/cc753551(v=ws.11).aspx - में बड़ी संख्या में त्रुटियां हैं (उदाहरणों में उदाहरण के लिए) क्योंकि डॉक्टर के लेखक ने गलत तरीके से माना कि *.*मास्क लागू किया गया था सभी फ़ाइलों के लिए। "इस अजीब आदत" के बारे में मेरा पुनर्विचार प्रश्न वास्तव में इलाज के बाद से *.*और इसके *समकक्ष एक लंबे समय तक चलने वाला विंडोज हस्तक्षेप है, जिसके लिए इसे बंद कर दिया गया था । हालांकि, /mविकल्प forfilesकिसी कारण से उस सम्मेलन का उल्लंघन करने के लिए होता है।
— टीटी
1
विंडोज में 5 वाइल्डकार्ड्स पर पृष्ठभूमि : blogs.msdn.microsoft.com/jeremykuhne/2017/06/04/…
— MSalters
18

एक समान प्रश्न के मेरे उत्तर पर एक नज़र डालें :

REM del_old.bat
REM usage: del_old MM-DD-YYY
for /f "tokens=*" %%a IN ('xcopy *.* /d:%1 /L /I null') do if exist %%~nxa echo %%~nxa >> FILES_TO_KEEP.TXT
for /f "tokens=*" %%a IN ('xcopy *.* /L /I /EXCLUDE:FILES_TO_KEEP.TXT null') do if exist "%%~nxa" del "%%~nxa"

यह दी गई तारीख से अधिक पुरानी फ़ाइलों को हटा देता है। मुझे यकीन है कि वर्तमान तिथि से सात दिन पीछे जाने के लिए इसे संशोधित किया जा सकता है।

अद्यतन: मुझे लगता है कि HerbCSO उपरोक्त स्क्रिप्ट पर सुधार हुआ है। मैं इसके बजाय उसके संस्करण का उपयोग करने की सलाह देता हूं ।

— e.James
स्रोत
12

मेरी आज्ञा है

forfiles -p "d:\logs" -s -m*.log -d-15 -c"cmd /c del @PATH\@FILE"

@PATH - मेरे मामले में सिर्फ रास्ता है, इसलिए मुझे इसका इस्तेमाल करना था @PATH\@FILE

forfiles /?मेरे लिए भी काम नहीं कर रहा है, लेकिन forfiles("के बिना?") ठीक काम किया।

और एकमात्र प्रश्न जो मेरे पास है: कई मास्क कैसे जोड़ें (उदाहरण के लिए " .log | .bak")?

यह सब forfiles.exe के बारे में है जो मैंने यहां डाउनलोड किया (जीत XP पर)

लेकिन अगर आप Windows सर्वर का उपयोग कर रहे हैं forfiles.exe पहले से ही होना चाहिए और यह ftp संस्करण से अलग है। इसलिए मुझे कमांड को संशोधित करना चाहिए।

Windows Server 2003 के लिए मैं इस कमांड का उपयोग कर रहा हूं:

forfiles -p "d:\Backup" -s -m *.log -d -15 -c "cmd /c del @PATH"
— segero
स्रोत
9

बैच फ़ाइल के साथ हल करने के लिए बहुत बार रिश्तेदार दिनांक / समय संबंधित प्रश्न हैं। लेकिन कमांड लाइन दुभाषिया cmd.exe तारीख / समय की गणना के लिए कोई फ़ंक्शन नहीं है। स्टैक ओवरफ्लो के अन्य पृष्ठों पर और अन्य वेबसाइटों पर, अतिरिक्त कंसोल एप्लिकेशन या स्क्रिप्ट का उपयोग करके बहुत सारे काम करने वाले समाधान पहले से ही यहां पोस्ट किए गए हैं।

तारीख / समय के आधार पर संचालन के लिए सामान्य एक निर्धारित दिन के बाद से तारीख / समय स्ट्रिंग को सेकंड में बदलने की आवश्यकता है। बहुत आम है 1970-01-01 00:00:00 UTC। लेकिन किसी विशेष कार्य के लिए आवश्यक तिथि सीमा के आधार पर किसी भी बाद के दिन का उपयोग किया जा सकता है।

जे ने 7daysclean.cmd को कमांड लाइन दुभाषिया cmd.exe के लिए एक तेज "सेकंड से सेकंड" समाधान युक्त पोस्ट किया । लेकिन यह लीप वर्ष को ध्यान में नहीं रखता है। जेआर ने चालू वर्ष में खाते में छलांग लगाने के लिए एक ऐड-ऑन पोस्ट किया , लेकिन आधार वर्ष के बाद से 1970 के बाद से अन्य छलांग वर्षों की अनदेखी कर रहा है।

मैं सी / सी ++ में लिखे गए मेरे अनुप्रयोगों में दिनांक / समय रूपांतरण कार्यों में 1970-01-01 से लीप दिनों सहित कई दिनों की संख्या प्राप्त करने के लिए एक छोटे सी फ़ंक्शन के साथ एक बार बनाए गए 20 साल के स्थिर तालिकाओं (सरणियों) का उपयोग करता हूं।

यह बहुत तेज़ तालिका विधि का उपयोग बैच कोड में कमांड के लिए भी किया जा सकता है । इसलिए मैंने बैच सबरूटीन को कोड करने का निर्णय लिया, GetSecondsजो इस दिनचर्या को पारित दिनांक / समय स्ट्रिंग के लिए 1970-01-01 00:00:00 UTC के बाद से सेकंड की संख्या की गणना करता है।

ध्यान दें: लीप सेकंड को ध्यान में नहीं रखा जाता है क्योंकि विंडोज फाइल सिस्टम भी लीप सेकंड का समर्थन नहीं करता है।

सबसे पहले, टेबल:

  1. लीप दिनों सहित प्रत्येक वर्ष के लिए 1970-01-01 00:00:00 UTC के बाद के दिन।

    1970 - 1979:     0   365   730  1096  1461  1826  2191  2557  2922  3287
1980 - 1989:  3652  4018  4383  4748  5113  5479  5844  6209  6574  6940
1990 - 1999:  7305  7670  8035  8401  8766  9131  9496  9862 10227 10592
2000 - 2009: 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245
2010 - 2019: 14610 14975 15340 15706 16071 16436 16801 17167 17532 17897
2020 - 2029: 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550
2030 - 2039: 21915 22280 22645 23011 23376 23741 24106 24472 24837 25202
2040 - 2049: 25567 25933 26298 26663 27028 27394 27759 28124 28489 28855
2050 - 2059: 29220 29585 29950 30316 30681 31046 31411 31777 32142 32507
2060 - 2069: 32872 33238 33603 33968 34333 34699 35064 35429 35794 36160
2070 - 2079: 36525 36890 37255 37621 37986 38351 38716 39082 39447 39812
2080 - 2089: 40177 40543 40908 41273 41638 42004 42369 42734 43099 43465
2090 - 2099: 43830 44195 44560 44926 45291 45656 46021 46387 46752 47117
2100 - 2106: 47482 47847 48212 48577 48942 49308 49673

    1970-01-01 की शुरुआत के साथ वर्ष 2039 से 2106 के लिए सेकंड की गणना केवल एक अहस्ताक्षरित 32-बिट चर, यानी अहस्ताक्षरित लंबे (या अहस्ताक्षरित int) का उपयोग C / C ++ में संभव है।

    लेकिन गणितीय अभिव्यक्तियों के लिए cmd.exe एक हस्ताक्षरित 32-बिट चर का उपयोग करता है। इसलिए अधिकतम मूल्य 2147483647 (0x7FFFFFFF) है जो 2038-01-19 03:14:07 है।

  2. वर्ष 1970 से 2106 तक लीप वर्ष की जानकारी (नहीं / हाँ)।

    1970 - 1989: N N Y N N N Y N N N Y N N N Y N N N Y N
1990 - 2009: N N Y N N N Y N N N Y N N N Y N N N Y N
2010 - 2029: N N Y N N N Y N N N Y N N N Y N N N Y N
2030 - 2049: N N Y N N N Y N N N Y N N N Y N N N Y N
2050 - 2069: N N Y N N N Y N N N Y N N N Y N N N Y N
2070 - 2089: N N Y N N N Y N N N Y N N N Y N N N Y N
2090 - 2106: N N Y N N N Y N N N N N N N Y N N
                                 ^ year 2100

  3. चालू वर्ष में प्रत्येक माह के पहले दिन के दिनों की संख्या।

                       Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
Year with 365 days:  0  31  59  90 120 151 181 212 243 273 304 334
Year with 366 days:  0  31  60  91 121 152 182 213 244 274 305 335

1970-01-01 से उन तारीखों की संख्या को परिवर्तित करना उन तालिकाओं का उपयोग करना काफी आसान है।

कृपया ध्यान दें!

दिनांक और समय स्ट्रिंग्स का प्रारूप विंडोज क्षेत्र और भाषा सेटिंग्स पर निर्भर करता है। सीमांकक और वातावरण चरों करने के लिए सौंपा टोकन के आदेश Day, Monthऔर Yearपहले में के लिए की पाश GetSecondsयदि आवश्यक हो तो स्थानीय दिनांक / समय प्रारूप के लिए अनुकूलित किया जाना चाहिए।

यह वातावरण चर की तारीख स्ट्रिंग अनुकूल करने के लिए करता है, तो वातावरण चर में दिनांक स्वरूप के लिए आवश्यक है , DATE कमांड द्वारा प्रयुक्त दिनांक स्वरूप के लिए अलग है के लिए पर %%~tF।

उदाहरण के लिए जब %DATE%करने के लिए फैलता है Sun 02/08/2015, जबकि %%~tFकरने के लिए फैलता है 02/08/2015 07:38 PMनीचे दिया गया कोड लाइन 4 को संशोधित करने के साथ प्रयोग किया जा सकता है:

call :GetSeconds "%DATE:~4% %TIME%"

यह सबरूटीन को पास करने में परिणाम देता है 02/08/2015- कार्यदिवस के संक्षिप्त नाम के 3 अक्षरों और अलग-अलग अंतरिक्ष चरित्र के बिना तारीख स्ट्रिंग।

वैकल्पिक रूप से निम्नलिखित का उपयोग सही प्रारूप में वर्तमान तिथि को पारित करने के लिए किया जा सकता है:

call :GetSeconds "%DATE:~-10% %TIME%"

अब दिनांक स्ट्रिंग से अंतिम 10 वर्णों को कार्य करने के लिए पारित किया जाता है GetSecondsऔर इसलिए यह कोई फर्क नहीं पड़ता है कि पर्यावरण चर DATE की तिथि स्ट्रिंग दिन के साथ या बिना दिन के रूप में है और जब तक दिन हमेशा और महीने हमेशा अपेक्षित क्रम में 2 अंकों के साथ होते हैं, अर्थात प्रारूप में dd/mm/yyyy या dd.mm.yyyy।

यहाँ टिप्पणी जो सिर्फ outputs जो फ़ाइल को हटाने और जो फाइल करने के लिए में रखने के लिए समझाने के साथ बैच कोड है C:\Tempफ़ोल्डर ट्री, पहले के कोड को देखने के लिए पाश।

@echo off
setlocal EnableExtensions EnableDelayedExpansion
rem Get seconds since 1970-01-01 for current date and time.
call :GetSeconds "%DATE% %TIME%"
rem Subtract seconds for 7 days from seconds value.
set /A "LastWeek=Seconds-7*86400"

rem For each file in each subdirectory of C:\Temp get last modification date
rem (without seconds -> append second 0) and determine the number of seconds
rem since 1970-01-01 for this date/time. The file can be deleted if seconds
rem value is lower than the value calculated above.

for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
    call :GetSeconds "%%~tF:0"
    rem if !Seconds! LSS %LastWeek% del /F "%%~fF"
    if !Seconds! LEQ %LastWeek% (
        echo Delete "%%~fF"
    ) else (
        echo Keep   "%%~fF"
    )
)
endlocal
goto :EOF


rem No validation is made for best performance. So make sure that date
rem and hour in string is in a format supported by the code below like
rem MM/DD/YYYY hh:mm:ss or M/D/YYYY h:m:s for English US date/time.

:GetSeconds

rem If there is " AM" or " PM" in time string because of using 12 hour
rem time format, remove those 2 strings and in case of " PM" remember
rem that 12 hours must be added to the hour depending on hour value.

set "DateTime=%~1"
set "Add12Hours=0"
if "%DateTime: AM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: AM=%"
) else if "%DateTime: PM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: PM=%"
    set "Add12Hours=1"
)

rem Get year, month, day, hour, minute and second from first parameter.

for /F "tokens=1-6 delims=,-./: " %%A in ("%DateTime%") do (
    rem For English US date MM/DD/YYYY or M/D/YYYY
    set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
    rem For German date DD.MM.YYYY or English UK date DD/MM/YYYY
    rem set "Day=%%A" & set "Month=%%B" & set "Year=%%C"
    set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
rem echo Date/time is: %Year%-%Month%-%Day% %Hour%:%Minute%:%Second%

rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )

rem Add 12 hours for time range 01:00:00 PM to 11:59:59 PM,
rem but keep the hour as is for 12:00:00 PM to 12:59:59 PM.
if "%Add12Hours%" == "1" (
    if %Hour% LSS 12 set /A Hour+=12
)
set "DateTime="
set "Add12Hours="

rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"

if %Index1% LEQ 30 (
    rem Get number of days to year for the years 1980 to 2009.
    for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
    for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
    rem Get number of days to year for the years 2010 to 2038.
    for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
    for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)

rem Add the days to month in year.
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)

rem Add the complete days in month of year.
set /A "Days+=Day-1"

rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"

rem Exit this subroutine
goto :EOF

इष्टतम प्रदर्शन के लिए यह सभी टिप्पणियों को हटाने के लिए सबसे अच्छा होगा, अर्थात 0-4 प्रमुख स्थानों के बाद रेम से शुरू होने वाली सभी लाइनें ।

और सरणियों को भी छोटा किया जा सकता है, अर्थात समय सीमा घटाकर 1980-01-01 00:00:00 से 2038-01-19 03:14:07 वर्तमान में उदाहरण के लिए 2015 बैच से ऊपर के बैच कोड द्वारा समर्थित है। -01 से 2019-12-31 नीचे दिए गए कोड के रूप में उपयोग करता है जो वास्तव में C:\Tempफ़ोल्डर ट्री में 7 दिनों से अधिक पुरानी फ़ाइलों को हटा देता है ।

इसके अलावा नीचे दिए गए बैच कोड को 24 घंटे के समय के प्रारूप के लिए अनुकूलित किया गया है।

@echo off
setlocal EnableDelayedExpansion
call :GetSeconds "%DATE:~-10% %TIME%"
set /A "LastWeek=Seconds-7*86400"

for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
    call :GetSeconds "%%~tF:0"
    if !Seconds! LSS %LastWeek% del /F "%%~fF"
)
endlocal
goto :EOF

:GetSeconds
for /F "tokens=1-6 delims=,-./: " %%A in ("%~1") do (
    set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
    set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
set /A "Index=Year-2014"
for /F "tokens=%Index% delims= " %%Y in ("16436 16801 17167 17532 17897") do set "Days=%%Y"
for /F "tokens=%Index% delims= " %%L in ("N Y N N N") do set "LeapYear=%%L"
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
set /A "Days+=Day-1"
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
goto :EOF

दिनांक और समय के प्रारूप और फ़ाइल समय की तुलना के बारे में अधिक जानकारी के लिए, विंडोज पर मेरे जवाब को देखें कि क्या फाइल समय के बारे में बहुत सारी अतिरिक्त जानकारी के साथ बैच फ़ाइल में 4 घंटे से अधिक पुराना है ।

— Mofi
स्रोत
9

इस कोड को कॉपी करें और इसे सेव करें DelOldFiles.vbs।

CMD में उपयोग करें: cscript //nologo DelOldFiles.vbs 15

15 का मतलब अतीत में 15 दिनों से पुरानी फाइलों को हटाना है।

  'copy from here
    Function DeleteOlderFiles(whichfolder)
       Dim fso, f, f1, fc, n, ThresholdDate
       Set fso = CreateObject("Scripting.FileSystemObject")
       Set f = fso.GetFolder(whichfolder)
       Set fc = f.Files
       Set objArgs = WScript.Arguments
       n = 0
       If objArgs.Count=0 Then
           howmuchdaysinpast = 0
       Else
           howmuchdaysinpast = -objArgs(0)
       End If
       ThresholdDate = DateAdd("d", howmuchdaysinpast, Date)   
       For Each f1 in fc
     If f1.DateLastModified<ThresholdDate Then
        Wscript.StdOut.WriteLine f1
        f1.Delete
        n = n + 1    
     End If
       Next
       Wscript.StdOut.WriteLine "Deleted " & n & " file(s)."
    End Function

    If Not WScript.FullName = WScript.Path & "\cscript.exe" Then
      WScript.Echo "USAGE ONLY IN COMMAND PROMPT: cscript DelOldFiles.vbs 15" & vbCrLf & "15 means to delete files older than 15 days in past."
      WScript.Quit 0   
    End If

    DeleteOlderFiles(".")
 'to here
— पेरिस
स्रोत
8

Windows Server 2008 R2 के लिए:

forfiles /P c:\sql_backups\ /S /M *.sql /D -90 /C "cmd /c del @PATH"

यह 90 दिनों से अधिक पुरानी सभी .sql फ़ाइलों को हटा देगा ।

— NotJustClarkKent
स्रोत
7

फोरफाइल्स का उपयोग करें।

अलग-अलग संस्करण हैं। शुरुआती लोग यूनिक्स शैली के मापदंडों का उपयोग करते हैं।

मेरा संस्करण (सर्वर 2000 के लिए - स्विच के बाद कोई स्थान न दें) - 

forfiles -p"C:\what\ever" -s -m*.* -d<number of days> -c"cmd /c del @path"

XP के लिए forfiles जोड़ने के लिए, से exe मिल ftp://ftp.microsoft.com/ResKit/y2kfix/x86/

और इसे C: \ WINDOWS \ system32 में जोड़ें

— ऐडन इवेन
स्रोत
11
@ रिबन यह एक ही जवाब नहीं है वाक्यविन्यास अलग है। यह मदद करने का एक जीनियस प्रयास था। विंडोज़ कमांड लाइन के बहुत कम हिस्से को जानते हुए, मैंने काम करने के लिए घंटों की हताशा का सामना किया। मेरे लिए जानकारी के प्रमुख बिट्स यह तथ्य थे कि अलग-अलग संस्करण (विभिन्न सिंटैक्स के साथ) हैं, और यह कि मुझे रिक्त स्थान निकालने की आवश्यकता है। इन बातों में से कोई भी मूल उत्तर में शामिल नहीं थे। (मैंने उत्तर पर टिप्पणी की होगी, लेकिन मेरे पास विशेषाधिकार नहीं हैं
— Aidan Ewen
अन्य उत्तरों की तरह ही त्रुटि (स्वीकृत एक सहित)। वाइल्डकार्ड *.*में forfilesमेल नहीं खाती सभी फ़ाइलें। यह केवल .उनके नाम (यानी एक्सटेंशन वाली फाइलें) के साथ फाइल से मेल खाता है । ओपी ने कभी भी .फ़ाइल नाम की आवश्यकता के बारे में कुछ नहीं कहा । उचित पैरामीटर है /M *, लेकिन यह वैसे भी डिफ़ॉल्ट है। इसकी कोई आवश्यकता नहीं है /M।
— टीटी
7

विंडोज़ 2012 R2 के लिए निम्नलिखित कार्य करेगा:

    forfiles /p "c:\FOLDERpath" /d -30 /c "cmd /c del @path"

जिन फ़ाइलों को हटा दिया जाएगा उन्हें यह देखने के लिए उपयोग करें

    forfiles /p "c:\FOLDERpath" /d -30 /c "cmd /c echo @path @fdate"
— विक्टर का
स्रोत
यह भी विंडोज सर्वर 2008 और इसके बाद के संस्करण में काम करता है और विंडोज 7.
— kwrl
6

IMO, जावास्क्रिप्ट धीरे-धीरे एक सार्वभौमिक स्क्रिप्टिंग मानक बन रहा है: यह संभवतः किसी भी अन्य स्क्रिप्टिंग भाषा (विंडोज में, यह विंडोज़ स्क्रिप्टिंग होस्ट का उपयोग करके उपलब्ध है) की तुलना में अधिक उत्पादों में उपलब्ध है। मुझे बहुत सारी फोल्डर में पुरानी फाइलों को साफ करना है, इसलिए यहां एक जावास्क्रिप्ट फंक्शन करना है:

// run from an administrator command prompt (or from task scheduler with full rights):  wscript jscript.js
// debug with:   wscript /d /x jscript.js

var fs = WScript.CreateObject("Scripting.FileSystemObject");

clearFolder('C:\\temp\\cleanup');

function clearFolder(folderPath)
{
    // calculate date 3 days ago
    var dateNow = new Date();
    var dateTest = new Date();
    dateTest.setDate(dateNow.getDate() - 3);

    var folder = fs.GetFolder(folderPath);
    var files = folder.Files;

    for( var it = new Enumerator(files); !it.atEnd(); it.moveNext() )
    {
        var file = it.item();

        if( file.DateLastModified < dateTest)
        {
            var filename = file.name;
            var ext = filename.split('.').pop().toLowerCase();

            if (ext != 'exe' && ext != 'dll')
            {
                file.Delete(true);
            }
        }
    }

    var subfolders = new Enumerator(folder.SubFolders);
    for (; !subfolders.atEnd(); subfolders.moveNext())
    {
        clearFolder(subfolders.item().Path);
    }
}

प्रत्येक फ़ोल्डर को साफ़ करने के लिए, बस ClearFolder () फ़ंक्शन में एक और कॉल जोड़ें। यह विशेष कोड exe और dll फ़ाइलों को भी संरक्षित करता है, और सबफ़ोल्डर्स को भी साफ करता है।

— ग्राहम लाईट
स्रोत
6

कैसे पर इस संशोधन के बारे में 7daysclean.cmd खाते में एक लीप वर्ष लेने के लिए?

यह कोडिंग की 10 से कम लाइनों में किया जा सकता है!

set /a Leap=0
if (Month GEQ 2 and ((Years%4 EQL 0 and Years%100 NEQ 0) or Years%400 EQL 0)) set /a Leap=day
set /a Months=!_months!+Leap

मोफी द्वारा संपादित:

जेआर द्वारा योगदान दी गई स्थिति अमान्य सिंटैक्स के कारण हमेशा झूठी का मूल्यांकन करती है ।

और Month GEQ 2यह भी गलत है क्योंकि एक और दिन के लिए 86400 सेकंड जोड़ना केवल मार्च से दिसंबर के महीनों के लिए एक लीप वर्ष में किया जाना चाहिए, लेकिन फरवरी के लिए नहीं।

खाते में लीप दिन लेने का एक कार्य कोड - चालू वर्ष में केवल - बैच फ़ाइल में 7daysclean.cmd जे द्वारा पोस्ट किया जाएगा:

set "LeapDaySecs=0"
if %Month% LEQ 2 goto CalcMonths
set /a "LeapRule=Years%%4"
if %LeapRule% NEQ 0 goto CalcMonths
rem The other 2 rules can be ignored up to year 2100.
set /A "LeapDaySecs=day"
:CalcMonths
set /a Months=!_months!+LeapDaySecs
— जे आर
स्रोत
5

हो सकता है कि मैं इसमें पहले ही मूल्यवान सूत्र में एक विनम्र योगदान जोड़ दूं। मुझे पता चल रहा है कि अन्य समाधान वास्तविक त्रुटि पाठ से छुटकारा पा सकते हैं लेकिन% ERRORLEVEL% की अनदेखी कर रहे हैं जो मेरे आवेदन में विफल होने का संकेत देता है। और मैं वैध रूप से% ERRORLEVEL% तब तक चाहता हूं जब तक कि यह "कोई फ़ाइल नहीं मिली" त्रुटि हो।

कुछ उदाहरण:

डीबग करना और विशेष रूप से त्रुटि को समाप्त करना: 

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&ECHO found error||echo found success

ERRORLEVEL सफलता या विफलता वापस करने के लिए एक oneliner का उपयोग करना:

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&EXIT /B 1||EXIT /B 0

अन्य कोड के बीच बैचफाइल के संदर्भ में सफलता के लिए ERRORLEVEL को शून्य पर रखने के लिए एक oneliner का उपयोग करना (ver> nul resets ERRORLEVEL):

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&ECHO found error||ver > nul

SQL सर्वर एजेंट CmdExec कार्य चरण के लिए मैं निम्न पर उतरा। मुझे नहीं पता कि यह एक बग है, लेकिन कदम के भीतर CmdExec केवल कोड की पहली पंक्ति को पहचानता है:

cmd /e:on /c "forfiles /p "C:\SQLADMIN\MAINTREPORTS\SQL2" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&EXIT 1||EXIT 0"&exit %errorlevel%
— डंक
स्रोत
5

गोश, पहले से ही बहुत सारे जवाब। मेरे द्वारा पाया गया एक सरल और सुविधाजनक मार्ग ROBOCOPY.EXE को एक ही विंडोज कमांड लाइन निर्देश से दो बार अनुक्रमिक क्रम में & पैरामीटर का उपयोग करके निष्पादित करना था ।

ROBOCOPY.EXE SOURCE-DIR TARGET-DIR *.* /MOV /MINAGE:30 & ROBOCOPY.EXE SOURCE-DIR TARGET-DIR *.* /MOV /MINAGE:30 /PURGE

इस उदाहरण में यह सभी फाइलों ( । ) को उठाकर काम करता है जो 30 दिनों से पुराने हैं और उन्हें लक्ष्य फ़ोल्डर में ले जा रहे हैं। दूसरा कमांड PURGE कमांड को जोड़ने के साथ फिर से वही करता है जिसका मतलब है कि टार्गेट फोल्डर में मौजूद फाइल्स को हटाना जो कि सोर्स फोल्डर में मौजूद नहीं है। इसलिए अनिवार्य रूप से, पहली कमांड MOVES फ़ाइलें और दूसरा DELETES क्योंकि वे अब दूसरी फ़ोल्डर को लागू करने पर स्रोत फ़ोल्डर में मौजूद नहीं हैं।

ROBOCOPY के प्रलेखन से परामर्श करें और परीक्षण करते समय / एल स्विच का उपयोग करें।

— GBGOLC
स्रोत
4

यदि आपके पास XP संसाधन किट है, तो आप सभी पुरानी निर्देशिकाओं को एक ही निर्देशिका में स्थानांतरित करने के लिए रोबोकॉपी का उपयोग कर सकते हैं, फिर rmdir का उपयोग केवल उस एक को हटाने के लिए करें:

mkdir c:\temp\OldDirectoriesGoHere
robocopy c:\logs\SoManyDirectoriesToDelete\ c:\temp\OldDirectoriesGoHere\ /move /minage:7
rmdir /s /q c:\temp\OldDirectoriesGoHere
— neuracnu
स्रोत
4

मुझे लगता है कि e.James का उत्तर अच्छा है क्योंकि यह विंडोज के अनमॉडिफाइड संस्करणों के साथ काम करता है, जो कि विंडोज 2000 SP4 (और संभवतः पहले) के रूप में शुरू होता है, लेकिन इसके लिए बाहरी फाइल को लिखना आवश्यक है। यहां एक संशोधित संस्करण है जो संगतता बनाए रखते हुए एक बाहरी पाठ फ़ाइल नहीं बनाता है:

REM del_old.cmd
REM usage: del_old MM-DD-YYYY
setlocal enabledelayedexpansion
for /f "tokens=*" %%a IN ('xcopy *.* /d:%1 /L /I null') do @if exist "%%~nxa" set "excludefiles=!excludefiles!;;%%~nxa;;"
for /f "tokens=*" %%a IN ('dir /b') do @(@echo "%excludefiles%"|FINDSTR /C:";;%%a;;">nul || if exist "%%~nxa" DEL /F /Q "%%a">nul 2>&1)

मूल प्रश्न के लिए सही होने के लिए, यहां एक स्क्रिप्ट है जो आपके लिए सभी गणित करता है यदि आप इसे पैरामीटर के रूप में दिनों की संख्या के साथ कहते हैं:

REM del_old_compute.cmd
REM usage: del_old_compute N
setlocal enabledelayedexpansion
set /a days=%1&set cur_y=%DATE:~10,4%&set cur_m=%DATE:~4,2%&set cur_d=%DATE:~7,2%
for /f "tokens=1 delims==" %%a in ('set cur_') do if "!%%a:~0,1!"=="0" set /a %%a=!%%a:~1,1!+0
set mo_2=28&set /a leapyear=cur_y*10/4
if %leapyear:~-1% equ 0 set mo_2=29
set mo_1=31&set mo_3=31&set mo_4=30&set mo_5=31
set mo_6=30&set mo_7=31&set mo_8=31&set mo_9=30
set mo_10=31&set mo_11=30&set mo_12=31
set /a past_y=(days/365)
set /a monthdays=days-((past_y*365)+((past_y/4)*1))&&set /a past_y=cur_y-past_y&set months=0
:setmonth
set /a minusmonth=(cur_m-1)-months
if %minusmonth% leq 0 set /a minusmonth+=12
set /a checkdays=(mo_%minusmonth%)
if %monthdays% geq %checkdays% set /a months+=1&set /a monthdays-=checkdays&goto :setmonth
set /a past_m=cur_m-months
set /a lastmonth=cur_m-1
if %lastmonth% leq 0 set /a lastmonth+=12
set /a lastmonth=mo_%lastmonth%
set /a past_d=cur_d-monthdays&set adddays=::
if %past_d% leq 0 (set /a past_m-=1&set adddays=)
if %past_m% leq 0 (set /a past_m+=12&set /a past_y-=1)
set mo_2=28&set /a leapyear=past_y*10/4
if %leapyear:~-1% equ 0 set mo_2=29
%adddays%set /a past_d+=mo_%past_m%
set d=%past_m%-%past_d%-%past_y%
for /f "tokens=*" %%a IN ('xcopy *.* /d:%d% /L /I null') do @if exist "%%~nxa" set "excludefiles=!excludefiles!;;%%~nxa;;"
for /f "tokens=*" %%a IN ('dir /b') do @(@echo "%excludefiles%"|FINDSTR /C:";;%%a;;">nul || if exist "%%~nxa" DEL /F /Q "%%a">nul 2>&1)

नोट: ऊपर दिए गए कोड को लीप वर्ष में, साथ ही साथ प्रत्येक महीने में सटीक संख्या में दिन लगते हैं। एकमात्र अधिकतम कुल दिनों की संख्या है, जो 0/0/0 के बाद से है (इसके बाद यह नकारात्मक वर्ष लौटाता है)।

नोट: गणित केवल एक ही रास्ता जाता है; यह नकारात्मक इनपुट से भविष्य की तारीखों को सही ढंग से प्राप्त नहीं कर सकता है (यह कोशिश करेगा, लेकिन संभवतः महीने के आखिरी दिन से आगे बढ़ जाएगा)।

— Lectrode
स्रोत
3

आप इसे खींचने में सक्षम हो सकते हैं। आप एक सरल उदाहरण के लिए, इस प्रश्न पर एक नज़र डाल सकते हैं । जटिलता तब आती है, जब आप तारीखों की तुलना करना शुरू करते हैं। यह बताना आसान हो सकता है कि तारीख अधिक है या नहीं, लेकिन विचार करने के लिए कई स्थितियां हैं कि क्या आपको वास्तव में दो तिथियों के बीच अंतर प्राप्त करने की आवश्यकता है।

दूसरे शब्दों में - जब तक आप वास्तव में तीसरे पक्ष के उपकरण का उपयोग नहीं कर सकते, तब तक इसे आविष्कार करने की कोशिश न करें।

— पौलिअस
स्रोत
3

यह कुछ भी आश्चर्यजनक नहीं है, लेकिन मुझे आज ऐसा कुछ करने और इसे निर्धारित कार्य आदि के रूप में चलाने की आवश्यकता है।

बैच फ़ाइल, DelFilesOlderThanNDays.bat नमूना निष्पादन w / params के साथ नीचे:

DelFilesOlderThanNDays.bat 7 C: \ dir1 \ dir2 \ dir3 \ लॉग * लॉग।

echo off
cls
Echo(
SET keepDD=%1
SET logPath=%2 :: example C:\dir1\dir2\dir3\logs
SET logFileExt=%3
SET check=0
IF [%3] EQU [] SET logFileExt=*.log & echo: file extention not specified (default set to "*.log")
IF [%2] EQU [] echo: file directory no specified (a required parameter), exiting! & EXIT /B 
IF [%1] EQU [] echo: number of days not specified? :)
echo(
echo: in path [ %logPath% ]
echo: finding all files like [ %logFileExt% ]
echo: older than [ %keepDD% ] days
echo(
::
::
:: LOG
echo:  >> c:\trimLogFiles\logBat\log.txt
echo: executed on %DATE% %TIME% >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt
echo: in path [ %logPath% ] >> c:\trimLogFiles\logBat\log.txt
echo: finding all files like [ %logFileExt% ] >> c:\trimLogFiles\logBat\log.txt
echo: older than [ %keepDD% ] days >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt
::
FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c echo @path" >> c:\trimLogFiles\logBat\log.txt 2<&1
IF %ERRORLEVEL% EQU 0 (
 FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c echo @path"
)
::
::
:: LOG
IF %ERRORLEVEL% EQU 0 (
 echo:  >> c:\trimLogFiles\logBat\log.txt
 echo: deleting files ... >> c:\trimLogFiles\logBat\log.txt
 echo:  >> c:\trimLogFiles\logBat\log.txt
 SET check=1
)
::
::
IF %check% EQU 1 (
 FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c del @path"
)
::
:: RETURN & LOG
::
IF %ERRORLEVEL% EQU 0 echo: deletion successfull! & echo: deletion successfull! >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt
— गोरान बी।
स्रोत
3

अकु के जवाब पर विस्तार करते हुए, मैंने देखा कि बहुत से लोग UNC रास्तों के बारे में पूछ रहे हैं। बस एक ड्राइव लेटर को अनफिट रास्ते को मैप करने से फोरफाइल्स खुश हो जाएगा। उदाहरण के लिए, ड्राइव और मैपिंग को एक बैच फ़ाइल में प्रोग्रामेटिक रूप से अनमैप किया जा सकता है।

net use Z: /delete
net use Z: \\unc\path\to\my\folder
forfiles /p Z: /s /m *.gz /D -7 /C "cmd /c del @path"

यह .gz एक्सटेंशन वाली सभी फ़ाइलों को हटा देगा जो 7 दिनों से अधिक पुरानी हैं। यदि आप यह सुनिश्चित करना चाहते हैं कि Z: इसका उपयोग करने से पहले किसी और चीज की मैपिंग नहीं की जाती है तो आप कुछ सरल कर सकते हैं

net use Z: \\unc\path\to\my\folder
if %errorlevel% equ 0 (
    forfiles /p Z: /s /m *.gz /D -7 /C "cmd /c del @path"
) else (
    echo "Z: is already in use, please use another drive letter!"
)
— टोबियास जेवेलवेल
स्रोत
3

ROBOCOPY मेरे लिए बहुत अच्छा काम करता है। मूल रूप से मेरे ईमान का सुझाव दिया। लेकिन फ़ाइलों / फ़ोल्डरों को अस्थायी निर्देशिका में ले जाने के बजाय फिर अस्थायी फ़ोल्डर की सामग्री को हटाकर, फ़ाइलों को ट्रैश में ले जाएं !!!

यह उदाहरण के लिए मेरे बैकअप बैच फ़ाइल की कुछ पंक्तियाँ है:

SET FilesToClean1=C:\Users\pauls12\Temp
SET FilesToClean2=C:\Users\pauls12\Desktop\1616 - Champlain\Engineering\CAD\Backups

SET RecycleBin=C:\$Recycle.Bin\S-1-5-21-1480896384-1411656790-2242726676-748474

robocopy "%FilesToClean1%" "%RecycleBin%" /mov /MINLAD:15 /XA:SH /NC /NDL /NJH /NS /NP /NJS
robocopy "%FilesToClean2%" "%RecycleBin%" /mov /MINLAD:30 /XA:SH /NC /NDL /NJH /NS /NP /NJS

यह मेरे 'टेंप' फोल्डर में से 15 दिनों से अधिक पुराने और मेरे ऑटोकैड बैकअप फोल्डर में किसी भी चीज के लिए 30 दिनों की सफाई करता है। मैं चर का उपयोग करता हूं क्योंकि लाइन काफी लंबी हो सकती है और मैं अन्य स्थानों के लिए उनका पुन: उपयोग कर सकता हूं। आपको बस अपने लॉगिन से जुड़े अपने रीसायकल बिन में डॉस का रास्ता खोजना होगा।

यह मेरे लिए एक कार्य कंप्यूटर पर है और यह काम करता है। मैं समझता हूं कि आप में से कुछ के पास अधिक प्रतिबंधात्मक अधिकार हो सकते हैं लेकिन इसे वैसे भी आज़माएं;) ROBOCOPY मापदंडों पर स्पष्टीकरण के लिए Google खोजें।

चीयर्स!

— शॉन पॉलिस्ज़िन
स्रोत
1
मौजूदा दूसरे सबसे अधिक उत्थान का जवाब भी रोबोकोपी को दिया गया है। दी, आप कुछ अलग विकल्पों का उपयोग करते हैं, लेकिन यह मौजूदा उत्तर के करीब है।
— जोनाथन लेफ़लर
2
इस पोस्ट में एक नई सामग्री है - फ़ाइलों को रीसायकल बिन में ले जाना। यह अभी तक रोबोकॉपी के साथ प्रस्तावित नहीं किया गया है और यह बिल्ट-इन सिंगल-लाइन कमांड का उपयोग करके मूल पोस्ट का पूरी तरह से उत्तर देता है। 'DEL' और 'RMDIR' कमांड के संयोजन से बेहतर काम करता है क्योंकि फ़ाइलों को रीसायकल बिन से पुनर्स्थापित किया जा सकता है। अरे मैं अभी भी यहाँ नया हूँ - मुझे एक विराम दे;)
— शॉन पॉलिसज़िन
2

एक विशिष्ट वर्ष से अधिक पुरानी फ़ाइलों को हटाने के लिए मेरी स्क्रिप्ट:

@REM _______ GENERATE A CMD TO DELETE FILES OLDER THAN A GIVEN YEAR
@REM _______ (given in _olderthanyear variable)
@REM _______ (you must LOCALIZE the script depending on the dir cmd console output)
@REM _______ (we assume here the following line's format "11/06/2017  15:04            58 389 SpeechToText.zip")

@set _targetdir=c:\temp
@set _olderthanyear=2017

@set _outfile1="%temp%\deleteoldfiles.1.tmp.txt"
@set _outfile2="%temp%\deleteoldfiles.2.tmp.txt"

  @if not exist "%_targetdir%" (call :process_error 1 DIR_NOT_FOUND "%_targetdir%") & (goto :end)

:main
  @dir /a-d-h-s /s /b %_targetdir%\*>%_outfile1%
  @for /F "tokens=*" %%F in ('type %_outfile1%') do @call :process_file_path "%%F" %_outfile2%
  @goto :end

:end
  @rem ___ cleanup and exit
  @if exist %_outfile1% del %_outfile1%
  @if exist %_outfile2% del %_outfile2%
  @goto :eof

:process_file_path %1 %2
  @rem ___ get date info of the %1 file path
  @dir %1 | find "/" | find ":" > %2
  @for /F "tokens=*" %%L in ('type %2') do @call :process_line "%%L" %1
  @goto :eof

:process_line %1 %2
  @rem ___ generate a del command for each file older than %_olderthanyear%
  @set _var=%1
  @rem  LOCALIZE HERE (char-offset,string-length)
  @set _fileyear=%_var:~0,4%
  @set _fileyear=%_var:~7,4%
  @set _filepath=%2
  @if %_fileyear% LSS %_olderthanyear% echo @REM %_fileyear%
  @if %_fileyear% LSS %_olderthanyear% echo @del %_filepath%
  @goto :eof

:process_error %1 %2
  @echo RC=%1 MSG=%2 %3
  @goto :eof
— efdummy
स्रोत
1

यह एक मेरे लिए किया था। यह एक तिथि के साथ काम करता है और आप समय में वापस जाने के लिए वर्षों में वांछित राशि को हटा सकते हैं:

@echo off

set m=%date:~-7,2%
set /A m
set dateYear=%date:~-4,4%
set /A dateYear -= 2
set DATE_DIR=%date:~-10,2%.%m%.%dateYear% 

forfiles /p "C:\your\path\here\" /s /m *.* /d -%DATE_DIR% /c "cmd /c del @path /F"

pause

/Fमें cmd /c del @path /Fबलों विशिष्ट फ़ाइल कुछ मामलों फ़ाइल केवल पढ़ने के लिए किया जा सकता है में हटाए जाने के लिए।

dateYearसाल परिवर्तनीय है और वहाँ आप अपनी जरूरतों को घटाना बदल सकते हैं

— Snickbrack
स्रोत
हमारी साइट का प्रयोग करके, आप स्वीकार करते हैं कि आपने हमारी Cookie Policy और निजता नीति को पढ़ और समझा लिया है।
Licensed under cc by-sa 3.0 with attribution required.