NullReference अपवाद - विज़ुअल बेसिक
NullReference Exceptionके लिए दृश्य मूल में एक से अलग नहीं है सी # । आखिरकार, वे दोनों .NET फ्रेमवर्क में परिभाषित एक ही अपवाद को रिपोर्ट कर रहे हैं जो वे दोनों का उपयोग करते हैं। Visual Basic के लिए अद्वितीय कारण दुर्लभ हैं (शायद केवल एक)।
यह उत्तर विज़ुअल बेसिक शब्दों, सिंटैक्स और संदर्भ का उपयोग करेगा। उपयोग किए जाने वाले उदाहरण ढेर सारे स्टैक ओवरफ्लो प्रश्नों से आते हैं। यह अक्सर पोस्ट में देखी जाने वाली स्थितियों के प्रकार का उपयोग करके प्रासंगिकता को अधिकतम करना है । उन लोगों के लिए थोड़ा और स्पष्टीकरण भी प्रदान किया जाता है जिन्हें इसकी आवश्यकता हो सकती है। आपके जैसा एक उदाहरण यहाँ बहुत संभावना है।
ध्यान दें:
- यह अवधारणा-आधारित है: आपके पास अपनी परियोजना में पेस्ट करने के लिए कोई कोड नहीं है। इसका उद्देश्य आपको यह समझने में मदद करना है कि क्या कारण है
NullReferenceException(एनआरई), इसे कैसे खोजना है, इसे कैसे ठीक करना है और कैसे इससे बचना है। एक एनआरई कई तरीकों से हो सकता है इसलिए यह आपके एकमात्र मुठभेड़ होने की संभावना नहीं है।
- उदाहरण (स्टैक ओवरफ्लो पोस्ट से) हमेशा पहली जगह में कुछ करने का सबसे अच्छा तरीका नहीं दिखाते हैं।
- आमतौर पर, सबसे सरल उपाय का उपयोग किया जाता है।
मूल अर्थ
संदेश "ऑब्जेक्ट ऑब्जेक्ट के एक उदाहरण के लिए सेट नहीं है" का अर्थ है कि आप उस ऑब्जेक्ट का उपयोग करने की कोशिश कर रहे हैं जिसे प्रारंभ नहीं किया गया है। यह इनमें से एक को उबालता है:
- आपके कोड ने एक वस्तु चर घोषित किया , लेकिन उसने इसे इनिशियलाइज़ नहीं किया (एक उदाहरण बनाएं या इसे ' तत्काल ' बनाएं )
- कुछ ऐसा है जो आपके कोड ने मान लिया कि किसी ऑब्जेक्ट को इनिशियलाइज़ करेगा, नहीं
- संभवतः, अन्य कोड ने समय से पहले एक वस्तु को अवैध रूप से अमान्य कर दिया है
कारण ढूँढना
चूंकि समस्या एक वस्तु संदर्भ है Nothing, जो है , इसका उत्तर यह है कि उन्हें यह पता लगाने के लिए कि कौन सा है। फिर निर्धारित करें कि यह क्यों प्रारंभिक नहीं है। विभिन्न चर पर माउस को पकड़ें और विजुअल स्टूडियो (वीएस) अपने मूल्यों को दिखाएगा - अपराधी होगा Nothing।
आपको संबंधित कोड से किसी भी कोशिश / कैच ब्लॉक को भी हटा देना चाहिए, खासकर उन लोगों को जहां कैच ब्लॉक में कुछ भी नहीं है। जब यह किसी ऑब्जेक्ट का उपयोग करने का प्रयास करता है तो यह आपके कोड को क्रैश कर देगा Nothing। यह वही है जो आप चाहते हैं क्योंकि यह समस्या के सटीक स्थान की पहचान करेगा , और आपको इसके कारण होने वाली वस्तु की पहचान करने की अनुमति देगा।
MsgBoxपकड़ में A जो प्रदर्शित करता है उससे Error while...बहुत कम मदद मिलेगी। यह विधि बहुत खराब स्टैक ओवरफ्लो प्रश्नों की ओर भी ले जाती है , क्योंकि आप वास्तविक अपवाद, शामिल वस्तु या यहां तक कि कोड की पंक्ति का वर्णन नहीं कर सकते हैं जहां यह होता है।
आप अपनी वस्तुओं की जांच करने के लिए Locals Window( डिबग -> विंडोज -> स्थानीय लोगों ) का भी उपयोग कर सकते हैं।
एक बार जब आप जानते हैं कि समस्या क्या है और कहां है, तो आमतौर पर एक नया प्रश्न पोस्ट करने की तुलना में इसे ठीक करना और तेज करना काफी आसान है।
यह सभी देखें:
उदाहरण और उपाय
कक्षा वस्तुओं / एक उदाहरण बनाना
Dim reg As CashRegister
...
TextBox1.Text = reg.Amount ' NRE
समस्या यह है कि Dimएक CashRegister ऑब्जेक्ट नहीं बनाता है ; यह केवल regउस प्रकार के नाम से एक चर घोषित करता है । ऑब्जेक्ट चर की घोषणा करना और एक उदाहरण बनाना दो अलग-अलग चीजें हैं।
उपाय
Newऑपरेटर अक्सर जब आप इसे घोषित उदाहरण बनाने के लिए इस्तेमाल किया जा सकता है:
Dim reg As New CashRegister ' [New] creates instance, invokes the constructor
' Longer, more explicit form:
Dim reg As CashRegister = New CashRegister
जब बाद में उदाहरण बनाना ही उचित हो:
Private reg As CashRegister ' Declare
...
reg = New CashRegister() ' Create instance
नोट: निर्माणकर्ता ( ) सहित एक प्रक्रिया में फिर से उपयोग न करें :DimSub New
Private reg As CashRegister
'...
Public Sub New()
'...
Dim reg As New CashRegister
End Sub
यह एक स्थानीय चर बनाएगा reg, जो केवल उस संदर्भ (उप) में मौजूद है। regमॉड्यूल स्तर के साथ चर Scopeजो आप अन्य सभी स्थानों अवशेष का उपयोग करेगा Nothing।
Newऑपरेटर को मिस करनाNullReference Exceptions स्टैक ओवरफ्लो प्रश्नों की समीक्षा में देखा गया # 1 कारण है ।
Visual Basic का उपयोग करके प्रक्रिया को बार-बार स्पष्ट करने की कोशिश करता है New: Newऑपरेटर का उपयोग करना एक बनाता है नई वस्तु बनती है और कॉल होती है Sub New- निर्माणकर्ता - जहाँ आपकी वस्तु किसी अन्य इनिशियलाइज़ेशन को कर सकती है।
स्पष्ट होने के लिए, Dim(या Private) केवल एक चर और इसकी घोषणा करता है Type। चर का दायरा - चाहे वह पूरे मॉड्यूल / वर्ग के लिए मौजूद हो या प्रक्रिया के लिए स्थानीय हो - द्वारा निर्धारित किया जाता है कि यह कहां घोषित किया गया है। Private | Friend | Publicपहुँच स्तर को परिभाषित करता है, स्कोप को नहीं ।
अधिक जानकारी के लिए देखें:
Arrays
Arrays को भी तत्काल किया जाना चाहिए:
Private arr as String()
यह सरणी केवल घोषित की गई है, बनाई नहीं गई है। किसी सरणी को आरम्भ करने के कई तरीके हैं:
Private arr as String() = New String(10){}
' or
Private arr() As String = New String(10){}
' For a local array (in a procedure) and using 'Option Infer':
Dim arr = New String(10) {}
नोट: वीएस 2010 के साथ शुरुआत, जब एक स्थानीय सरणी को शाब्दिक और तत्वों का उपयोग करके आरम्भ किया जाता है Option Infer, As <Type>और Newतत्व वैकल्पिक हैं:
Dim myDbl As Double() = {1.5, 2, 9.9, 18, 3.14}
Dim myDbl = New Double() {1.5, 2, 9.9, 18, 3.14}
Dim myDbl() = {1.5, 2, 9.9, 18, 3.14}
डेटा प्रकार और सरणी आकार असाइन किए जा रहे डेटा से अनुमानित हैं। कक्षा / मॉड्यूल स्तर की घोषणाओं की अभी भी आवश्यकता As <Type>है Option Strict:
Private myDoubles As Double() = {1.5, 2, 9.9, 18, 3.14}
उदाहरण: वर्ग की वस्तुओं की सरणी
Dim arrFoo(5) As Foo
For i As Integer = 0 To arrFoo.Count - 1
arrFoo(i).Bar = i * 10 ' Exception
Next
सरणी बनाई गई है, लेकिन इसमें Fooऑब्जेक्ट नहीं हैं।
उपाय
For i As Integer = 0 To arrFoo.Count - 1
arrFoo(i) = New Foo() ' Create Foo instance
arrFoo(i).Bar = i * 10
Next
एक का उपयोग करना एक List(Of T)वैध वस्तु के बिना एक तत्व रखना काफी मुश्किल होगा:
Dim FooList As New List(Of Foo) ' List created, but it is empty
Dim f As Foo ' Temporary variable for the loop
For i As Integer = 0 To 5
f = New Foo() ' Foo instance created
f.Bar = i * 10
FooList.Add(f) ' Foo object added to list
Next
अधिक जानकारी के लिए देखें:
सूचियाँ और संग्रह
.NET संग्रह (जिनमें से कई किस्में हैं - सूची, शब्दकोश, आदि) को भी तत्काल या बनाया जाना चाहिए।
Private myList As List(Of String)
..
myList.Add("ziggy") ' NullReference
आपको एक ही कारण के लिए एक ही अपवाद मिलता है - myListकेवल घोषित किया गया था, लेकिन कोई उदाहरण नहीं बनाया गया। उपाय एक ही है:
myList = New List(Of String)
' Or create an instance when declared:
Private myList As New List(Of String)
एक सामान्य निरीक्षण एक वर्ग है जो एक संग्रह का उपयोग करता है Type:
Public Class Foo
Private barList As List(Of Bar)
Friend Function BarCount As Integer
Return barList.Count
End Function
Friend Sub AddItem(newBar As Bar)
If barList.Contains(newBar) = False Then
barList.Add(newBar)
End If
End Function
या तो प्रक्रिया एक एनआरई में परिणाम करेगी, क्योंकि barListकेवल घोषित की जाती है, तात्कालिक नहीं। का एक उदाहरण Fooबनाने से भी आंतरिक का एक उदाहरण नहीं होगा barList। कंस्ट्रक्टर में ऐसा करने का इरादा हो सकता है:
Public Sub New ' Constructor
' Stuff to do when a new Foo is created...
barList = New List(Of Bar)
End Sub
पहले की तरह, यह गलत है:
Public Sub New()
' Creates another barList local to this procedure
Dim barList As New List(Of Bar)
End Sub
अधिक जानकारी के लिए, List(Of T)क्लास देखें ।
डेटा प्रदाता ऑब्जेक्ट
डेटाबेस प्रस्तुत के साथ एक NullReference के लिए कई अवसर कार्य क्योंकि वहाँ कई वस्तुओं (हो सकता है Command, Connection, Transaction, Dataset, DataTable, DataRowsएक ही बार में ....) उपयोग में। नोट: यह कोई फर्क नहीं पड़ता कि आप किस डेटा प्रदाता का उपयोग कर रहे हैं - MySQL, SQL सर्वर, OleDB, आदि - अवधारणाएं समान हैं।
उदाहरण 1
Dim da As OleDbDataAdapter
Dim ds As DataSet
Dim MaxRows As Integer
con.Open()
Dim sql = "SELECT * FROM tblfoobar_List"
da = New OleDbDataAdapter(sql, con)
da.Fill(ds, "foobar")
con.Close()
MaxRows = ds.Tables("foobar").Rows.Count ' Error
पहले की तरह, dsडेटासेट ऑब्जेक्ट घोषित किया गया था, लेकिन एक उदाहरण कभी नहीं बनाया गया था। DataAdapterएक मौजूदा भर जाएगा DataSet, नहीं एक बनाएँ। इस मामले में, चूंकि dsएक स्थानीय चर है, आईडीई आपको चेतावनी देता है कि ऐसा हो सकता है:
जब मॉड्यूल / वर्ग स्तर के चर के रूप में घोषित किया जाता है, जैसा कि मामला प्रतीत होता है con, तो कंपाइलर को पता नहीं चल सकता है कि ऑब्जेक्ट अपस्ट्रीम प्रक्रिया द्वारा बनाया गया था या नहीं। चेतावनियों को नजरअंदाज न करें।
उपाय
Dim ds As New DataSet
उदाहरण 2
ds = New DataSet
da = New OleDBDataAdapter(sql, con)
da.Fill(ds, "Employees")
txtID.Text = ds.Tables("Employee").Rows(0).Item(1)
txtID.Name = ds.Tables("Employee").Rows(0).Item(2)
एक टाइपो यहाँ एक समस्या है: Employeesबनाम Employee। कोई DataTable"कर्मचारी" नहीं बनाया गया था, इसलिए NullReferenceExceptionइसके उपयोग की कोशिश करने वाले परिणाम। एक अन्य संभावित समस्या यह मानकर चल रही है कि Itemsऐसा तब नहीं होगा जब SQL में WHERE क्लॉज शामिल हो।
उपाय
चूंकि यह एक तालिका का उपयोग करता है, इसलिए Tables(0)स्पेलिंग त्रुटियों से बचना होगा। जांच से Rows.Countभी मदद मिल सकती है:
If ds.Tables(0).Rows.Count > 0 Then
txtID.Text = ds.Tables(0).Rows(0).Item(1)
txtID.Name = ds.Tables(0).Rows(0).Item(2)
End If
Fillएक ऐसा कार्य है Rowsजो प्रभावितों की संख्या को लौटाता है जिसे परीक्षण भी किया जा सकता है:
If da.Fill(ds, "Employees") > 0 Then...
उदाहरण 3
Dim da As New OleDb.OleDbDataAdapter("SELECT TICKET.TICKET_NO,
TICKET.CUSTOMER_ID, ... FROM TICKET_RESERVATION AS TICKET INNER JOIN
FLIGHT_DETAILS AS FLIGHT ... WHERE [TICKET.TICKET_NO]= ...", con)
Dim ds As New DataSet
da.Fill(ds)
If ds.Tables("TICKET_RESERVATION").Rows.Count > 0 Then
DataAdapterप्रदान करेगा TableNamesजैसा कि पिछले उदाहरण में दिखाया गया है, लेकिन यह एसक्यूएल या डेटाबेस तालिका से नहीं है पार्स नाम। नतीजतन,ds.Tables("TICKET_RESERVATION") एक गैर-मौजूद तालिका का संदर्भ देता है।
उपचार ही है, सूचकांक द्वारा तालिका को देख:
If ds.Tables(0).Rows.Count > 0 Then
डेटाटेबल क्लास भी देखें ।
ऑब्जेक्ट पथ / नेस्टेड
If myFoo.Bar.Items IsNot Nothing Then
...
कोड केवल परीक्षण कर रहा है Itemsजबकि दोनों myFooऔर Barकुछ भी नहीं हो सकता है। उपाय एक बार में पूरी श्रृंखला या वस्तुओं में से एक का पथ का परीक्षण करने के लिए है:
If (myFoo IsNot Nothing) AndAlso
(myFoo.Bar IsNot Nothing) AndAlso
(myFoo.Bar.Items IsNot Nothing) Then
....
AndAlsoमहत्वपूर्ण है। पहली Falseस्थिति सामने आने के बाद बाद के परीक्षण नहीं किए जाएंगे । यह कोड को एक बार में ऑब्जेक्ट (ओं) में सुरक्षित रूप से 'ड्रिल' करने की अनुमति देता है, myFoo.Barकेवल (और अगर) के मूल्यांकन के बाद ही myFooमान्य होता है। जटिल ऑब्जेक्ट्स को कोड करते समय ऑब्जेक्ट चेन या पाथ काफी लंबा मिल सकता है:
myBase.myNodes(3).Layer.SubLayer.Foo.Files.Add("somefilename")
किसी nullवस्तु के 'डाउनस्ट्रीम' को संदर्भित करना संभव नहीं है । यह नियंत्रणों पर भी लागू होता है:
myWebBrowser.Document.GetElementById("formfld1").InnerText = "some value"
यहाँ, myWebBrowserया Documentकुछ भी नहीं हो सकता है या formfld1तत्व मौजूद नहीं हो सकता है।
यूआई नियंत्रण
Dim cmd5 As New SqlCommand("select Cartons, Pieces, Foobar " _
& "FROM Invoice where invoice_no = '" & _
Me.ComboBox5.SelectedItem.ToString.Trim & "' And category = '" & _
Me.ListBox1.SelectedItem.ToString.Trim & "' And item_name = '" & _
Me.ComboBox2.SelectedValue.ToString.Trim & "' And expiry_date = '" & _
Me.expiry.Text & "'", con)
अन्य बातों के अलावा, यह कोड यह अनुमान नहीं लगाता है कि उपयोगकर्ता ने एक या अधिक यूआई नियंत्रण में कुछ का चयन नहीं किया होगा। ListBox1.SelectedItemअच्छी तरह से हो सकता है Nothing, इसलिए ListBox1.SelectedItem.ToStringएक एनआरई में परिणाम होगा।
उपाय
उपयोग करने से पहले डेटा को मान्य करें (उपयोग Option Strictऔर SQL पैरामीटर भी):
Dim expiry As DateTime ' for text date validation
If (ComboBox5.SelectedItems.Count > 0) AndAlso
(ListBox1.SelectedItems.Count > 0) AndAlso
(ComboBox2.SelectedItems.Count > 0) AndAlso
(DateTime.TryParse(expiry.Text, expiry) Then
'... do stuff
Else
MessageBox.Show(...error message...)
End If
वैकल्पिक रूप से, आप उपयोग कर सकते हैं (ComboBox5.SelectedItem IsNot Nothing) AndAlso...
विजुअल बेसिक फॉर्म
Public Class Form1
Private NameBoxes = New TextBox(5) {Controls("TextBox1"), _
Controls("TextBox2"), Controls("TextBox3"), _
Controls("TextBox4"), Controls("TextBox5"), _
Controls("TextBox6")}
' same thing in a different format:
Private boxList As New List(Of TextBox) From {TextBox1, TextBox2, TextBox3 ...}
' Immediate NRE:
Private somevar As String = Me.Controls("TextBox1").Text
यह एनआरई पाने का एक काफी सामान्य तरीका है। C # में, यह कैसे कोडित है, इसके आधार पर, IDE रिपोर्ट करेगा Controlsजो वर्तमान संदर्भ में मौजूद नहीं है, या "गैर-स्थिर सदस्य का संदर्भ नहीं दे सकता है"। तो, कुछ हद तक, यह एक VB- केवल स्थिति है। यह भी जटिल है क्योंकि यह एक विफलता कैस्केड के परिणामस्वरूप हो सकता है।
सरणियों और संग्रह को इस तरह से आरंभ नहीं किया जा सकता है। यह इनिशियलाइज़ेशन कोड कंस्ट्रक्टर या बनाने से पहले चलेगा । नतीजतन:FormControls
- सूची और संग्रह बस खाली हो जाएगा
- ऐरे में नथिंग के पांच तत्व होंगे
somevarकाम एक तत्काल एनआरई में परिणाम होगा क्योंकि कुछ भी नहीं है एक भी नहीं है .Textसंपत्ति
बाद में सरणी तत्वों को संदर्भित करने से NRE हो जाएगा। यदि आप ऐसा करते हैं Form_Load, तो एक विषम बग के कारण, IDE अपवाद तब नहीं हो सकता जब यह होता है। जब आपका कोड सरणी का उपयोग करने का प्रयास करता है तो अपवाद बाद में पॉप जाएगा । यह "मूक अपवाद" इस पोस्ट में विस्तृत है । हमारे उद्देश्यों के लिए, कुंजी यह है कि जब एक फॉर्म ( Sub Newया Form Loadईवेंट) बनाते समय कुछ भयावह होता है , तो अपवाद अप्रमाणित हो सकते हैं, कोड प्रक्रिया से बाहर निकलता है और बस फॉर्म प्रदर्शित करता है।
चूंकि एनआरई के बाद आपके Sub Newया Form Loadईवेंट में कोई अन्य कोड नहीं चलेगा, इसलिए बहुत सी अन्य चीजों को अनइंस्टॉल किया जा सकता है।
Sub Form_Load(..._
'...
Dim name As String = NameBoxes(2).Text ' NRE
' ...
' More code (which will likely not be executed)
' ...
End Sub
ध्यान दें कि यह किसी भी और सभी नियंत्रण और घटक संदर्भों पर लागू होता है, जहां ये अवैध हैं:
Public Class Form1
Private myFiles() As String = Me.OpenFileDialog1.FileName & ...
Private dbcon As String = OpenFileDialog1.FileName & ";Jet Oledb..."
Private studentName As String = TextBox13.Text
आंशिक उपाय
यह उत्सुक है कि वीबी एक चेतावनी प्रदान नहीं करता है, लेकिन उपाय कंटेनरों को फॉर्म स्तर पर घोषित करना है, लेकिन नियंत्रण के मौजूद होने पर उन्हें लोड लोड ईवेंट हैंडलर में आरंभ करना है। यह तब तक किया जा सकता है Sub Newजब तक आपका कोड InitializeComponentकॉल के बाद है :
' Module level declaration
Private NameBoxes as TextBox()
Private studentName As String
' Form Load, Form Shown or Sub New:
'
' Using the OP's approach (illegal using OPTION STRICT)
NameBoxes = New TextBox() {Me.Controls("TextBox1"), Me.Controls("TestBox2"), ...)
studentName = TextBox32.Text ' For simple control references
सरणी कोड अभी तक जंगल से बाहर नहीं हो सकता है। कोई भी नियंत्रण जो कंटेनर नियंत्रण में है (जैसे GroupBoxया Panel) में नहीं मिलेगा Me.Controls; वे उस पैनल या GroupBox के नियंत्रण संग्रह में होंगे। जब नियंत्रण नाम गलत वर्तनी ( "TeStBox2") है, तो कोई नियंत्रण वापस नहीं किया जाएगा । ऐसे मामलों में, Nothingफिर से उन सरणी तत्वों में संग्रहीत किया जाएगा और जब आप इसे संदर्भित करने का प्रयास करेंगे तो एक एनआरई परिणाम देगा।
इन्हें ढूंढना आसान होना चाहिए ताकि आप जान सकें कि आप क्या देख रहे हैं:
"Button2" एक पर रहता है Panel
उपाय
प्रपत्र के Controlsसंग्रह का उपयोग करके नाम के अप्रत्यक्ष संदर्भों के बजाय , नियंत्रण संदर्भ का उपयोग करें:
' Declaration
Private NameBoxes As TextBox()
' Initialization - simple and easy to read, hard to botch:
NameBoxes = New TextBox() {TextBox1, TextBox2, ...)
' Initialize a List
NamesList = New List(Of TextBox)({TextBox1, TextBox2, TextBox3...})
' or
NamesList = New List(Of TextBox)
NamesList.AddRange({TextBox1, TextBox2, TextBox3...})
फंक्शन रिटर्निंग नथिंग
Private bars As New List(Of Bars) ' Declared and created
Public Function BarList() As List(Of Bars)
bars.Clear
If someCondition Then
For n As Integer = 0 to someValue
bars.Add(GetBar(n))
Next n
Else
Exit Function
End If
Return bars
End Function
यह एक ऐसा मामला है जहां आईडीई आपको चेतावनी देगा कि ' सभी रास्तों का एक मूल्य और एक NullReferenceExceptionपरिणाम नहीं हो सकता है '। आप चेतावनी को दबा सकते हैं, के Exit Functionसाथ प्रतिस्थापित करके Return Nothing, लेकिन यह समस्या का समाधान नहीं करता है। कुछ भी जो someCondition = Falseएनआरई में परिणाम देगा जब वापसी का उपयोग करने की कोशिश करता है :
bList = myFoo.BarList()
For Each b As Bar in bList ' EXCEPTION
...
उपाय
के Exit Functionसाथ फ़ंक्शन में बदलें Return bList। खाली लौटना Listवैसा ही नहीं है जैसा लौटना Nothing। यदि एक मौका है कि एक लौटी हुई वस्तु हो सकती है Nothing, तो उपयोग करने से पहले परीक्षण करें:
bList = myFoo.BarList()
If bList IsNot Nothing Then...
खराब रूप से लागू किया गया प्रयास / कैच
एक बुरी तरह से कार्यान्वित किया गया प्रयास / कैच छिपा सकता है जहां समस्या है और नए परिणाम हैं:
Dim dr As SqlDataReader
Try
Dim lnk As LinkButton = TryCast(sender, LinkButton)
Dim gr As GridViewRow = DirectCast(lnk.NamingContainer, GridViewRow)
Dim eid As String = GridView1.DataKeys(gr.RowIndex).Value.ToString()
ViewState("username") = eid
sqlQry = "select FirstName, Surname, DepartmentName, ExtensionName, jobTitle,
Pager, mailaddress, from employees1 where username='" & eid & "'"
If connection.State <> ConnectionState.Open Then
connection.Open()
End If
command = New SqlCommand(sqlQry, connection)
'More code fooing and barring
dr = command.ExecuteReader()
If dr.Read() Then
lblFirstName.Text = Convert.ToString(dr("FirstName"))
...
End If
mpe.Show()
Catch
Finally
command.Dispose()
dr.Close() ' <-- NRE
connection.Close()
End Try
यह एक ऐसी वस्तु का मामला है जिसे अपेक्षित रूप से नहीं बनाया जा रहा है, लेकिन यह खाली की काउंटर उपयोगिता को भी प्रदर्शित करता है Catch।
SQL में एक अतिरिक्त अल्पविराम है ('mailaddress' के बाद) जिसके परिणामस्वरूप इसका अपवाद है .ExecuteReader। बाद Catchकुछ नहीं करता, Finallyस्वच्छ ऊपर प्रदर्शन करने की कोशिश करता है, लेकिन जब से तुम नहीं कर सकते हैं Closeएक अशक्त DataReaderवस्तु, एक नया NullReferenceExceptionपरिणाम नहीं।
एक खाली Catchब्लॉक शैतान का खेल का मैदान है। इस ओपी को चकित किया गया कि वह Finallyब्लॉक में एनआरई क्यों बन रहा है । अन्य स्थितियों में, एक खाली Catchचीज के परिणामस्वरूप कुछ और बहाव हो सकता है और आप समस्या के लिए गलत जगह पर गलत चीजों को देखने में समय व्यतीत कर सकते हैं। (ऊपर वर्णित "मूक अपवाद" वही मनोरंजन मूल्य प्रदान करता है।)
उपाय
खाली का उपयोग न करें कोशिश करें / पकड़ ब्लॉक - कोड को क्रैश होने दें ताकि आप ए) कारण की पहचान कर सकें बी) स्थान की पहचान करें और सी) एक उचित उपाय लागू करें। डेवलपर को पकड़ने के लिए प्रयास / कैच ब्लॉक का उद्देश्य विशिष्ट रूप से योग्य व्यक्ति से अपवादों को छिपाना नहीं है।
DBNull कुछ भी नहीं के समान नहीं है
For Each row As DataGridViewRow In dgvPlanning.Rows
If Not IsDBNull(row.Cells(0).Value) Then
...
IsDBNullसमारोह परीक्षण करने के लिए इस्तेमाल करता है, तो एक है मूल्य के बराबर होती है System.DBNull: MSDN से:
System.DBNull मान इंगित करता है कि ऑब्जेक्ट गुम या गैर-मौजूद डेटा का प्रतिनिधित्व करता है। DBNull कुछ भी नहीं के समान नहीं है, जो इंगित करता है कि एक चर अभी तक आरंभ नहीं किया गया है।
उपाय
If row.Cells(0) IsNot Nothing Then ...
पहले की तरह, आप कुछ भी नहीं के लिए परीक्षण कर सकते हैं, फिर एक विशिष्ट मूल्य के लिए:
If (row.Cells(0) IsNot Nothing) AndAlso (IsDBNull(row.Cells(0).Value) = False) Then
उदाहरण 2
Dim getFoo = (From f In dbContext.FooBars
Where f.something = something
Select f).FirstOrDefault
If Not IsDBNull(getFoo) Then
If IsDBNull(getFoo.user_id) Then
txtFirst.Text = getFoo.first_name
Else
...
FirstOrDefaultपहला आइटम या डिफ़ॉल्ट मान लौटाता है, जो Nothingसंदर्भ प्रकारों के लिए है और कभी नहीं DBNull:
If getFoo IsNot Nothing Then...
नियंत्रण
Dim chk As CheckBox
chk = CType(Me.Controls(chkName), CheckBox)
If chk.Checked Then
Return chk
End If
एक तो CheckBoxसाथ chkNameनहीं पाया जा सकता है (या एक में मौजूद है GroupBox), तो chkकुछ भी नहीं किया जाएगा और किसी भी संपत्ति एक अपवाद में परिणाम होगा संदर्भित करने के लिए कोशिश कर रहे होंगे।
उपाय
If (chk IsNot Nothing) AndAlso (chk.Checked) Then ...
DataGridView
डीजीवी में समय-समय पर कुछ क्विर्क देखे जाते हैं:
dgvBooks.DataSource = loan.Books
dgvBooks.Columns("ISBN").Visible = True ' NullReferenceException
dgvBooks.Columns("Title").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Author").DefaultCellStyle.Format = "C"
dgvBooks.Columns("Price").DefaultCellStyle.Format = "C"
यदि dgvBooksहै AutoGenerateColumns = True, तो यह कॉलम बनाएगा, लेकिन यह उन्हें नाम नहीं देता है, इसलिए जब यह उन्हें नाम से संदर्भित करता है तो उपरोक्त कोड विफल हो जाता है।
उपाय
स्तंभों को मैन्युअल रूप से नाम दें, या इंडेक्स द्वारा संदर्भ:
dgvBooks.Columns(0).Visible = True
उदाहरण 2 - NewRow से सावधान रहें
xlWorkSheet = xlWorkBook.Sheets("sheet1")
For i = 0 To myDGV.RowCount - 1
For j = 0 To myDGV.ColumnCount - 1
For k As Integer = 1 To myDGV.Columns.Count
xlWorkSheet.Cells(1, k) = myDGV.Columns(k - 1).HeaderText
xlWorkSheet.Cells(i + 2, j + 1) = myDGV(j, i).Value.ToString()
Next
Next
Next
अपने जब DataGridViewहै AllowUserToAddRowsके रूप में True(डिफ़ॉल्ट), Cellsखाली में / तल पर नई पंक्ति में शामिल होंगे सभी Nothing। सामग्री (उदाहरण के लिए ToString) का उपयोग करने के अधिकांश प्रयासों का परिणाम एक एनआरई होगा।
उपाय
एक For/Eachलूप का उपयोग करें और IsNewRowयह निर्धारित करने के लिए संपत्ति का परीक्षण करें कि क्या यह अंतिम पंक्ति है। यह काम करता AllowUserToAddRowsहै या नहीं यह सच है:
For Each r As DataGridViewRow in myDGV.Rows
If r.IsNewRow = False Then
' ok to use this row
यदि आप For nलूप का उपयोग करते हैं , तो पंक्ति गणना को संशोधित करें या सही Exit Forहोने पर उपयोग करें IsNewRow।
My.Settings (StringCollection)
कुछ परिस्थितियों में, उस आइटम का उपयोग करने की कोशिश करना My.Settingsजिससे कोई StringCollectionपरिणाम हो सकता है कि आप इसका उपयोग करने वाले पहली बार NullReference में परिणाम कर सकते हैं। समाधान समान है, लेकिन स्पष्ट नहीं है। विचार करें:
My.Settings.FooBars.Add("ziggy") ' foobars is a string collection
चूँकि VB आपके लिए सेटिंग्स का प्रबंधन कर रहा है, इसलिए संग्रह को शुरू करने की अपेक्षा करना उचित है। यह होगा, लेकिन केवल अगर आपने पहले संग्रह में एक प्रारंभिक प्रविष्टि (सेटिंग्स संपादक में) जोड़ दी है। चूँकि जब आइटम जोड़ा जाता है तो संग्रह (जाहिरा तौर पर) इनिशियलाइज़ होता है, यह Nothingतब रहता है जब सेटिंग्स एडिटर में कोई आइटम जोड़ने के लिए नहीं होते हैं।
उपाय
प्रपत्र के Loadइवेंट हैंडलर में सेटिंग्स संग्रह को आरम्भ करें, यदि / जब जरूरत हो:
If My.Settings.FooBars Is Nothing Then
My.Settings.FooBars = New System.Collections.Specialized.StringCollection
End If
आमतौर पर, Settingsसंग्रह को केवल पहली बार शुरू करने की आवश्यकता होगी जब आवेदन चलता है। एक वैकल्पिक उपाय परियोजना में अपने संग्रह के लिए एक प्रारंभिक मूल्य जोड़ना है -> सेटिंग्स | FooBars , प्रोजेक्ट सहेजें, फिर नकली मान निकालें।
प्रमुख बिंदु
आप शायद Newऑपरेटर को भूल गए ।
या
आपके द्वारा ग्रहण की गई किसी वस्तु को आपके कोड के लिए एक इनिशियलाइज़्ड ऑब्जेक्ट वापस करने के लिए निर्दोष प्रदर्शन करेगा।
संकलक चेतावनी (कभी) और उपयोग Option Strict On(हमेशा) को अनदेखा न करें ।
MSDN NullReference अपवाद