हास्केल में व्युत्पन्न कैसे काम करता है?

Question

बीजीय डेटा प्रकार हास्केल में (ADTS) स्वचालित रूप से कुछ के उदाहरण बन सकता है typeclasse रों (जैसेShow,Eqद्वारा) पाने उन लोगों से।

data  Maybe a  =  Nothing | Just a
  deriving (Eq, Ord)

मेरा सवाल है, यह derivingकाम कैसे करता है , यानी हास्केल को कैसे पता है कि व्युत्पन्न एडीटी के लिए व्युत्पन्न टाइपेकेल के कार्यों को कैसे लागू किया जाए?

इसके अलावा, derivingकेवल कुछ टाइपकॉल तक ही सीमित क्यों है ? मैं अपना खुद का टाइपकास्ट क्यों नहीं लिख सकता जो व्युत्पन्न हो सकता है?

Answer 1

संक्षिप्त उत्तर है, जादू :-)। यह कहना है कि स्वचालित व्युत्पन्न हास्केल कल्पना में बेक किया गया है, और हर कंपाइलर इसे अपने तरीके से लागू करने का विकल्प चुन सकता है। हालांकि यह कैसे एक्स्टेंसिबल बनाने के लिए बहुत सारे काम है।

डेरिव हास्केल के लिए एक उपकरण है जो आपको अपने स्वयं के व्युत्पन्न तंत्र को लिखने देता है।

जीएचसी जेनेरिक क्लासेस नामक एक व्युत्पन्न प्रकार वर्ग विस्तार प्रदान करता था, लेकिन इसका उपयोग शायद ही कभी किया जाता था, क्योंकि यह कुछ हद तक कमजोर था। अब इसे निकाल लिया गया है, और इस पत्र में वर्णित एक नए सामान्य व्युत्पन्न तंत्र को एकीकृत करने के लिए काम जारी है: http://www.dreixel.net/research/pdf/gdmh.pdf

इस पर अधिक जानकारी के लिए देखें:

• GHC विकि: http://hackage.haskell.org/trac/ghc/wiki/Commentary/Compiler/GenericDeriving
• हास्केल विकी: http://www.haskell.org/haskellwiki/Generics
• हैकेज: http://hackage.haskell.org/package/generic-deriving

Comments

Ghc मैनुअल और haskellwikiStandaloneDeriving में भी देखें

— एंड्रयूसी

बस आपकी जानकारी के लिए, जादू स्पष्ट रूप से haskell.org/onlinereport/haskell2010/haskellar11.html पर निर्दिष्ट है ।

— वोंग जिया हौ

Answer 2

हास्केल 98 रिपोर्ट से:

प्रील्यूड में केवल वे वर्ग हैं जिनके लिए व्युत्पन्न उदाहरणों की अनुमति है, ईक, ऑर्ड, एनम, बाउंडेड, शो, और रीड ...

यहाँ इन प्रकार की कक्षाओं को प्राप्त करने का विवरण दिया गया है: http://www.haskell.org/onlinereport/derived.html#derived-appitix

Answer 3

व्युत्पन्न-खंडों के समान तरीके से उदाहरण घोषणाओं को उत्पन्न करने के लिए टेम्पलेट हास्केल का उपयोग करना संभव है ।

निम्नलिखित उदाहरण बेशर्मी विकी से चुराया गया है :

इस उदाहरण में हम निम्नलिखित हास्केल कोड का उपयोग करते हैं

$(gen_render ''Body)

निम्नलिखित उदाहरण का उत्पादन करने के लिए:

instance TH_Render Body where
  render (NormalB exp) = build 'normalB exp
  render (GuardedB guards) = build 'guardedB  guards

gen_renderऊपर दिए गए फ़ंक्शन को निम्नानुसार परिभाषित किया गया है। (ध्यान दें कि यह कोड उपरोक्त उपयोग से अलग मॉड्यूल में होना चाहिए)।

-- Generate an intance of the class TH_Render for the type typName
gen_render :: Name -> Q [Dec]
gen_render typName =
  do (TyConI d) <- reify typName -- Get all the information on the type
     (type_name,_,_,constructors) <- typeInfo (return d) -- extract name and constructors                  
     i_dec <- gen_instance (mkName "TH_Render") (conT type_name) constructors
                      -- generation function for method "render"
                      [(mkName "render", gen_render)]
     return [i_dec]  -- return the instance declaration
             -- function to generation the function body for a particular function
             -- and constructor
       where gen_render (conName, components) vars 
                 -- function name is based on constructor name  
               = let funcName = makeName $ unCapalize $ nameBase conName 
                 -- choose the correct builder function
                     headFunc = case vars of
                                     [] -> "func_out"
                                     otherwise -> "build" 
                      -- build 'funcName parm1 parm2 parm3 ...
                   in appsE $ (varE $ mkName headFunc):funcName:vars -- put it all together
             -- equivalent to 'funcStr where funcStr CONTAINS the name to be returned
             makeName funcStr = (appE (varE (mkName "mkName")) (litE $ StringL funcStr))

जो निम्नलिखित कार्यों और प्रकारों का उपयोग करता है।

कोड को अधिक पठनीय बनाने के लिए पहले कुछ प्रकार के समानार्थक शब्द।

type Constructor = (Name, [(Maybe Name, Type)]) -- the list of constructors
type Cons_vars = [ExpQ] -- A list of variables that bind in the constructor
type Function_body = ExpQ 
type Gen_func = Constructor -> Cons_vars -> Function_body
type Func_name = Name   -- The name of the instance function we will be creating
-- For each function in the instance we provide a generator function
-- to generate the function body (the body is generated for each constructor)
type Funcs = [(Func_name, Gen_func)]

मुख्य पुन: प्रयोज्य कार्य। हम इसे उदाहरणों के कार्यों को उत्पन्न करने के लिए कार्यों की सूची से गुजरते हैं।

-- construct an instance of class class_name for type for_type
-- funcs is a list of instance method names with a corresponding
-- function to build the method body
gen_instance :: Name -> TypeQ -> [Constructor] -> Funcs -> DecQ
gen_instance class_name for_type constructors funcs = 
  instanceD (cxt [])
    (appT (conT class_name) for_type)
    (map func_def funcs) 
      where func_def (func_name, gen_func) 
                = funD func_name -- method name
                  -- generate function body for each constructor
                  (map (gen_clause gen_func) constructors)

उपरोक्त का एक सहायक कार्य।

-- Generate the pattern match and function body for a given method and
-- a given constructor. func_body is a function that generations the
-- function body
gen_clause :: (Constructor -> [ExpQ] -> ExpQ) -> Constructor -> ClauseQ
gen_clause func_body data_con@(con_name, components) = 
      -- create a parameter for each component of the constructor
   do vars <- mapM var components
      -- function (unnamed) that pattern matches the constructor 
      -- mapping each component to a value.
      (clause [(conP con_name (map varP vars))]
            (normalB (func_body data_con (map varE vars))) [])
       -- create a unique name for each component. 
       where var (_, typ) 
                 = newName 
                   $ case typ of 
                     (ConT name) -> toL $ nameBase name
                     otherwise   -> "parm"
               where toL (x:y) = (toLower x):y

unCapalize :: [Char] -> [Char]
unCapalize (x:y) = (toLower x):y

और Syb III / प्रतिकृति 0.2 से लिया गया कुछ उधार सहायक कोड।

typeInfo :: DecQ -> Q (Name, [Name], [(Name, Int)], [(Name, [(Maybe Name, Type)])])
typeInfo m =
     do d <- m
        case d of
           d@(DataD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           d@(NewtypeD _ _ _ _ _) ->
            return $ (simpleName $ name d, paramsA d, consA d, termsA d)
           _ -> error ("derive: not a data type declaration: " ++ show d)

     where
        consA (DataD _ _ _ cs _)    = map conA cs
        consA (NewtypeD _ _ _ c _)  = [ conA c ]

        {- This part no longer works on 7.6.3
        paramsA (DataD _ _ ps _ _) = ps
        paramsA (NewtypeD _ _ ps _ _) = ps
        -}

        -- Use this on more recent GHC rather than the above
        paramsA (DataD _ _ ps _ _) = map nameFromTyVar ps
        paramsA (NewtypeD _ _ ps _ _) = map nameFromTyVar ps

        nameFromTyVar (PlainTV a) = a
        nameFromTyVar (KindedTV a _) = a


        termsA (DataD _ _ _ cs _) = map termA cs
        termsA (NewtypeD _ _ _ c _) = [ termA c ]

        termA (NormalC c xs)        = (c, map (\x -> (Nothing, snd x)) xs)
        termA (RecC c xs)           = (c, map (\(n, _, t) -> (Just $ simpleName n, t)) xs)
        termA (InfixC t1 c t2)      = (c, [(Nothing, snd t1), (Nothing, snd t2)])

        conA (NormalC c xs)         = (simpleName c, length xs)
        conA (RecC c xs)            = (simpleName c, length xs)
        conA (InfixC _ c _)         = (simpleName c, 2)

        name (DataD _ n _ _ _)      = n
        name (NewtypeD _ n _ _ _)   = n
        name d                      = error $ show d

simpleName :: Name -> Name
simpleName nm =
   let s = nameBase nm
   in case dropWhile (/=':') s of
        []          -> mkName s
        _:[]        -> mkName s
        _:t         -> mkName t