Windows बैच स्क्रिप्ट में पारित तर्कों की सूची प्राप्त करें (.bat)

405

मैं बैश के लिए एक विंडोज बैच समकक्ष खोजना चाहता हूं जो $@स्क्रिप्ट में पारित सभी तर्कों की एक सूची रखता है।

या मुझे परेशान करना है shift?

windows  batch-file 
— wheleph
स्रोत

जवाबों:

622

dancavallaro के पास यह अधिकार है, %*सभी कमांड लाइन मापदंडों (स्क्रिप्ट नाम को छोड़कर) के लिए। आपको ये उपयोगी भी लग सकते हैं:

%0- बैच फ़ाइल बुलाते थे कमांड (हो सकता है foo, ..\foo, c:\bats\foo.bat, आदि)
%1पहले कमांड लाइन पैरामीटर, है
%2दूसरा कमांड लाइन पैरामीटर है,
और इतने पर जब तक %9(और SHIFT9 वीं के बाद उन लोगों के लिए इस्तेमाल किया जा सकता है)।

%~nx0- बैच फ़ाइल का वास्तविक नाम, कॉलिंग मेथड (कुछ-बैच.बैट) की परवाह किए बिना
%~dp0- स्क्रिप्ट के लिए ड्राइव और पथ (d: \ script)
%~dpnx0- स्क्रिप्ट का पूरी तरह से योग्य पथ नाम है (d: \ script \ a) -batch.bat)

Https://www.ss64.com/nt/syntax-args.html और https://www.robvanderwoude.com/.com/ametamet.html पर अधिक जानकारी के उदाहरण

— मैट विल्की
स्रोत
11
ध्यान दें, कि SHIFT% * को प्रभावित नहीं करता है, इस प्रकार यह असंभव है कि SHIFT [/ n] का उपयोग करना कुछ हद तक सहज है जैसे कि n-th पैरामीटर से शुरू होने वाली संपूर्ण कमांड लाइन तक पहुंचना।
— वैन जौन
4
मुझे कुछ और पता चला है कि %~dpn0स्क्रिप्ट और बैच फ़ाइल के नाम के साथ ड्राइव और पथ वापस आ जाएगा, लेकिन विस्तार नहीं। बैच स्क्रिप्ट्स बनाते समय मुझे यह विशेष रूप से उपयोगी लगा जो एक .ps1फ़ाइल को उसी नाम से बुलाते हैं । अनिवार्य रूप से, dड्राइव को pसंदर्भित करता है, पथ को nसंदर्भित करता है, फ़ाइल के नाम को xसंदर्भित करता है , और एक्सटेंशन को संदर्भित करता है। उस जानकारी के साथ, आप काफी कुछ कर सकते हैं।
— डैन एटकिंसन
जिज्ञासा से बाहर, मुझे लगता है कि मैं ECHO का उपयोग फ़ाइल के पथ को प्रिंट करने के लिए करना चाहता हूं, लेकिन इसके विस्तार की जगह, यह कैसे होगा?
— मैथ्यूस रोचा
2
@ मैथ्यूस्रोचा@echo %~n0.my_ext
— मैट
@mattwilkie धन्यवाद, मैंने यह पता लगाने के लिए ईसीएचओ का उपयोग किया कि यह परिणाम के रूप में क्या छपेगा।
— मैथ्यूस रोचा
149

%* लगता है कि स्क्रिप्ट के लिए पारित सभी तर्क।

— dancavallaro
स्रोत
किसी भी विचार क्यों यह इस तरह के रूप में कुछ पात्रों को संभाल नहीं करता है &? जब मैं कई चयनित फ़ाइलों के पथ को पुनः प्राप्त करने का प्रयास करता हूं (सेंड टू मेन्यू और "% *" जो एक .py तक आर्ग को पास करता है) तो यह & caracters पर लिस्टिंग को रोक देता है। उदाहरण के लिए यदि दूसरी फ़ाइल &में उसका नाम, &इच्छा के बाद नाम का भाग , और फ़ाइल भी रहती है।)
— जिन्सव
1
@ जीनसॉन &एक विशेष चरित्र है जिसका अर्थ है stop this command and start another one। एक फ़ाइल नाम से युक्त होना & चाहिए ।
— जेसी चिशोल्म
65

%1... %nऔर %*तर्क रखते हैं, लेकिन उन्हें एक्सेस करना मुश्किल हो सकता है, क्योंकि सामग्री की व्याख्या की जाएगी।
इसलिए सामान्य बयानों के साथ कुछ इस तरह से संभालना असंभव है

myBatch.bat "&"^&

प्रत्येक पंक्ति विफल रहती है, क्योंकि cmd.exe एम्परसेंड्स में से किसी एक को निष्पादित करने का प्रयास करता है (% 1 की सामग्री "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

लेकिन अस्थायी फ़ाइल के साथ वर्कअराउंड मौजूद है

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

चाल एक बयान echo onके %1बाद सक्षम करने और विस्तारित करने के लिए है rem(% 2 ..% * के साथ भी काम करता है)।
लेकिन आउटपुट को पुनर्निर्देशित करने में सक्षम होने के लिए echo on, आपको दो फॉर-एलओपीएस की आवश्यकता है।

अतिरिक्त वर्णों * #का उपयोग सामग्री की तरह सुरक्षित होने के लिए किया जाता है /?(REM के लिए मदद दिखाएगा)।
या लाइन के अंत में एक कैरेट ^ एक बहु-चरित्र के रूप में काम कर सकता है।

FOR / F को विलंबित विस्तार के साथ काम करना चाहिए, बाकी सामग्री "!" नष्ट हो जाएगा।
अतिरिक्त वर्णों को निकालने के बाद param1और आपको मिल गया।

और param1सुरक्षित तरीके से उपयोग करने के लिए, विलंबित विस्तार को सक्षम करें।

संपादित करें:% 0 पर एक टिप्पणी

%0इसमें बैच को कॉल करने के लिए उपयोग की जाने वाली कमांड शामिल है, FoO.BaT
लेकिन किसी फ़ंक्शन को कॉल करने के बाद भी मामले को संरक्षित करना %0और %~0फ़ंक्शन नाम (या फ़ंक्शन को कॉल करने के लिए उपयोग किए जाने वाले स्ट्रिंग) को बेहतर बनाने में भी शामिल है।
लेकिन %~f0आप के साथ अभी भी फ़ाइल नाम याद कर सकते हैं।

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

उत्पादन

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat
— जेब
स्रोत
6
+++ 1 ओएमजी - %~f0चाल पूरी तरह से अप्रत्याशित है, जिस तरह से शांत है, और संभावित रूप से बहुत उपयोगी है :-) आश्चर्य की बात नहीं, अन्य संशोधक उसी तरह से काम करते हैं, हमेशा पेरेंट बैच फ़ाइल पर काम करते हैं, यहां तक ​​कि जब एक तथाकथित सबरूटीन में। यह अपने स्वयं के क्यू एंड ए के योग्य लगता है - "जब एक उप-उपपट्टी में चल रहे बैच के नाम का उपयोग कैसे किया जाए?"
— dbenham
अगर मुझे सही से याद है, तो आप तर्कों के साथ कॉल का उपयोग कर सकते हैं, और जिन्हें% 1,% 2, ...% n में संग्रहीत किया जाएगा, जब आप कोई स्क्रिप्ट चलाते हैं।
— नूलानो
49

मैंने पाया कि अगली बार जब आपको इन सूचनाओं को देखने की आवश्यकता होगी। एक ब्राउज़र खोलने और इसे गूगल करने के बजाय, आप बस call /?अपने cmd में टाइप कर सकते हैं और आपको यह मिल जाएगा:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*
— KFL
स्रोत
20

स्क्रिप्ट के सभी आर्ग्स को पुनः प्राप्त करने का तरीका यहाँ है:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause
— djangofan
स्रोत
2
वास्तव में नहीं, %%Iव्याख्या हो सकती है और आपकी स्क्रिप्ट को तोड़ सकती है।
— बोरिस ब्रोडस्की
5

यहाँ args पाने के लिए और उन्हें env vars के रूप में सेट करने का एक सरल तरीका है। इस उदाहरण में मैं उन्हें केवल कुंजी और मान के रूप में संदर्भित करूंगा।

निम्न कोड उदाहरण को "args.bat" के रूप में सहेजें। फिर जिस बैच फाइल को आपने कमांड लाइन से बचाया है, उसे कॉल करें। उदाहरण: arg.bat --x 90 --y 120

मैंने आपको प्रक्रिया के माध्यम से कदम बढ़ाने के लिए कुछ इको कमांड प्रदान किए हैं। लेकिन अंतिम परिणाम यह है कि --x का मान 90 होगा और - आपके पास 120 का मान होगा (यदि आप ऊपर दिए गए उदाहरण के रूप में चलाते हैं ;-))।

फिर आप अपने कोड ब्लॉक को चलाने के लिए यह निर्धारित करने के लिए 'यदि परिभाषित' सशर्त विवरण का उपयोग कर सकते हैं। तो चलिए बताते हैं: "arg.bat --x hello-world" मैं तब कथन "IF DEFINED --x echo% - x%" का उपयोग कर सकता था और परिणाम "hello-world" होगा। यदि आप बैच चलाते हैं तो यह अधिक समझ में आता है।

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done
यह बहुत उपयोगी है!
— बागे ro००
3

यहां छवि विवरण दर्ज करें

सभी तर्क और शुद्ध बैच पाने के लिए लूपिंग का उपयोग करने के लिए:

अवलोकन: बिना उपयोग के लिए:?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof

आपका कोड तर्क संख्या के साथ कुछ करने के लिए तैयार है जहाँ उसे ज़रूरत है, जैसे ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt
— यह मुझे नहीं था
स्रोत
2

निम्न कोड एक सरणी (' params') का अनुकरण करता है - स्क्रिप्ट द्वारा प्राप्त मापदंडों को लेता है और उन्हें चर में संग्रहीत करता है params_1.. params_n, जहां n= params_0= सरणी के तत्वों की संख्या:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof
1

यदि आपके पास रिक्त स्थान वाले उद्धरणों में पैरामीटर हैं, तो %*सही तरीके से काम नहीं करेगा। सबसे अच्छा समाधान मैंने पाया कि एक लूप है जो सभी तर्कों से जुड़ता है: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)
— Speedstone
स्रोत
1

आप उपयोग कर सकते हैं ForArg की सूची प्राप्त करने के लिए Commad का ।

मदद : For /? सहायता:Setlocal /?

यहाँ मेरा तरीका है =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

शिफ्ट कमांड की जरूरत नहीं है।

— scientist_7
स्रोत
0 
@ तो बंद
:शुरू

:: यहां अपना कोड डालें
इको। %% 1 अब है:% ~ 1
:: अंत में यहां अपना कोड डालें

यदि "% ~ 2" NEQ "" (
    खिसक जाना
    गोटो: शुरू करो
)
— user298107
स्रोत
0

ऊपर दी गई जानकारी के कारण मुझे और शोध करने का मौका मिला और आखिरकार मेरा जवाब था कि मैं योगदान देना चाहता था, जो मैं उम्मीद में करता हूं कि यह किसी और की मदद करता है:

  • मैं एक बैच फ़ाइल में विभिन्न प्रकार के चर भी पास करना चाहता था ताकि उन्हें फ़ाइल के भीतर संसाधित किया जा सके।

  • मैं उद्धरण चिह्नों का उपयोग करके उन्हें बैच फ़ाइल में भेजने के साथ ठीक था

  • मैं उन्हें नीचे के समान संसाधित करना चाहता हूं - लेकिन मैन्युअल रूप से लिखने के बजाय एक लूप का उपयोग करना:

इसलिए मैं इस पर अमल करना चाहता था:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

और छोरों के जादू के माध्यम से बैच फ़ाइल के भीतर ऐसा करते हैं:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

समस्या यह है कि लूप का उपयोग करने के मेरे सभी प्रयास काम नहीं कर रहे थे। नीचे का उदाहरण:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

बस करेंगे:

set "_appPath=C:\Services\Logs\PCAP"

और नहीं:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

सेटिंग के बाद भी 

SETLOCAL EnableDelayedExpansion

कारण यह था कि लूप के लिए पूरी लाइन पढ़ी और लूप के पहले पुनरावृत्ति के दौरान %% B को मेरा दूसरा पैरामीटर सौंपा। चूँकि% * सभी तर्कों का प्रतिनिधित्व करता है, प्रक्रिया करने के लिए केवल एक ही रेखा है - लूप के लिए केवल एक पास होता है। यह डिजाइन द्वारा यह पता चला है, और मेरा तर्क गलत था।

इसलिए मैंने लूप के लिए उपयोग करने की कोशिश करना बंद कर दिया और सरलीकृत कर दिया कि मैं क्या करने की कोशिश कर रहा था अगर, शिफ्ट और एक गोटो स्टेटमेंट का उपयोग करके। इसके एक हैक के लिए सहमत हैं, लेकिन यह मेरी जरूरतों के लिए अधिक अनुकूल है। मैं सभी तर्कों के माध्यम से लूप कर सकता हूं और फिर उन सभी को संसाधित करने के बाद लूप को छोड़ने के लिए एक स्टेटमेंट का उपयोग कर सकता हूं।

जो मैं पूरा करने की कोशिश कर रहा था, उसके लिए विजयी वक्तव्य:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

अद्यतन - मुझे इसके बजाय नीचे संशोधित करना था, मैं% 1 को संदर्भित करने और इस तरीके से बदलाव का उपयोग करते समय सभी पर्यावरण चर को उजागर कर रहा था:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)
— जॉन अहर्न
स्रोत
मैं गलत हूं, कुछ और जांच की गई और 3 पुनरावृत्ति के बाद मेरी शिफ्ट कमांड सभी पर्यावरण चर को उजागर करती है, जो उपरोक्त को तोड़ती है। मैं अभी भी देख रहा हूं कि क्या इसके आसपास कोई रास्ता है।
— जॉन अहर्ने
% 1 का उपयोग करने के बजाय, मुझे एक संशोधन करना था, मुझे शुरू में एक बार शिफ्ट करना था और% 0 का उपयोग करना था या फिर मैं एक अजीब समस्या में भाग गया, जहां अंततः% 1 में वर्तमान पर्यावरण चर के सभी शामिल थे।
— जॉन अहर्न
0

कभी-कभी मुझे कई कमांड लाइन मापदंडों को निकालने की आवश्यकता होती है, लेकिन उनमें से सभी नहीं और पहले से नहीं। चलो निम्नलिखित कॉल मान लेते हैं:

Test.bat uno dos tres cuatro cinco seis siete

बेशक, एक्सटेंशन ".bat" की आवश्यकता नहीं है कम से कम आपके पास एक ही फ़ोल्डर में test.exe है। हम जो चाहते हैं वह आउटपुट "ट्रेस क्यूट्रो सिनको" प्राप्त करना है (कोई बात नहीं अगर एक पंक्ति या तीन)। लक्ष्य यह है कि केवल मुझे तीन मापदंडों की आवश्यकता है और तीसरे एक में शुरू करना है। एक सरल उदाहरण के लिए हर एक के लिए कार्रवाई सिर्फ "प्रतिध्वनि" है, लेकिन आप चयनित मापदंडों पर कुछ और अधिक जटिल कार्रवाई में सोच सकते हैं।

मैंने कुछ उदाहरण प्रस्तुत किए हैं, (विकल्प) आप देख सकते हैं कि आप किसके लिए बेहतर मानते हैं। दुर्भाग्य से, वहाँ "%% i में (% 3, 1,% 5)" जैसी श्रेणी के लिए लूप के आधार पर एक अच्छा (या मुझे नहीं पता) तरीका है।

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

संभवतः आप अधिक विकल्प पा सकते हैं या कई लोगों को जोड़ सकते हैं। उनका लुत्फ उठाएं।

— Fortu
स्रोत
-1

विंडोज संस्करण (हालांकि सोसाइटी की जरूरत है)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

इसे स्थापित करना:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd
— Jabo
स्रोत
हमारी साइट का प्रयोग करके, आप स्वीकार करते हैं कि आपने हमारी Cookie Policy और निजता नीति को पढ़ और समझा लिया है।
Licensed under cc by-sa 3.0 with attribution required.