परिवर्तनशील के रूप में तालिका का नाम

Question

मैं इस क्वेरी को निष्पादित करने का प्रयास कर रहा हूं:

declare @tablename varchar(50)
set @tablename = 'test'
select * from @tablename

यह निम्न त्रुटि उत्पन्न करता है:

Msg 1087, स्तर 16, राज्य 1, पंक्ति 5

टेबल चर "@tablename" घोषित करना चाहिए।

डायनामिक रूप से टेबल का नाम रखने का सही तरीका क्या है?

Answer 1

स्थिर प्रश्नों के लिए, जैसे आपके प्रश्न में, तालिका के नाम और स्तंभ नाम स्थिर होने चाहिए।

गतिशील प्रश्नों के लिए आपको गतिशील रूप से पूर्ण SQL उत्पन्न करना चाहिए, और इसे निष्पादित करने के लिए sp_executesql का उपयोग करना चाहिए।

विभिन्न डेटाबेस के समान तालिकाओं के बीच डेटा की तुलना करने के लिए उपयोग की जाने वाली स्क्रिप्ट का एक उदाहरण यहां दिया गया है:

स्थिर क्वेरी:

SELECT * FROM [DB_ONE].[dbo].[ACTY]
EXCEPT
SELECT * FROM [DB_TWO].[dbo].[ACTY]

चूंकि मैं आसानी से tha नाम बदलना चाहता हूं tableऔर schemaमैंने यह गतिशील क्वेरी बनाई है:

declare @schema varchar(50)
declare @table varchar(50)
declare @query nvarchar(500)

set @schema = 'dbo'
set @table = 'ACTY'

set @query = 'SELECT * FROM [DB_ONE].['+ @schema +'].[' + @table + '] EXCEPT SELECT * FROM [DB_TWO].['+ @schema +'].[' + @table + ']'

EXEC sp_executesql @query

चूंकि डायनामिक क्वेरी में कई विवरण होते हैं, जिन पर विचार करने की आवश्यकता होती है और वे कठिन होते हैं, मैं आपको सलाह देता हूं कि आप पढ़ें: गतिशील एसक्यूएल का अभिशाप और आशीर्वाद

Answer 2

अपना अंतिम विवरण इसमें बदलें:

EXEC('SELECT * FROM ' + @tablename)

इस तरह से मैं एक संग्रहीत प्रक्रिया में अपना काम करता हूं। पहला ब्लॉक चर घोषित करेगा, और इस वर्ष TEST_2012OCTOBER में वर्तमान वर्ष और महीने के नाम के आधार पर तालिका नाम सेट करेगा। मैं तब जांचता हूं कि क्या यह पहले से ही डीबी में मौजूद है, और यदि ऐसा है तो हटा दें। फिर अगला ब्लॉक टेबल बनाने के लिए एक SELECT INTO स्टेटमेंट का उपयोग करेगा और इसे दूसरे टेबल से रिकॉर्ड के साथ पॉप्युलेट करेगा।

--DECLARE TABLE NAME VARIABLE DYNAMICALLY
DECLARE @table_name varchar(max)
SET @table_name = 
    (SELECT 'TEST_'
            + DATENAME(YEAR,GETDATE())
            + UPPER(DATENAME(MONTH,GETDATE())) )

--DROP THE TABLE IF IT ALREADY EXISTS
IF EXISTS(SELECT name 
          FROM sysobjects 
          WHERE name = @table_name AND xtype = 'U')

BEGIN
    EXEC('drop table ' +  @table_name)
END

--CREATES TABLE FROM DYNAMIC VARIABLE AND INSERTS ROWS FROM ANOTHER TABLE
EXEC('SELECT * INTO ' + @table_name + ' FROM dbo.MASTER WHERE STATUS_CD = ''A''')

Comments

यह सबसे अच्छा जवाब है।

— कॉलिनमैक

यह सबसे अच्छा जवाब है क्योंकि यह ओपी के मौजूदा कोड पर सबसे सीधे लागू होता है।

— BH

Answer 3

जवाब के लिए थोड़ा देर से लेकिन किसी और की मदद करना चाहिए:

CREATE PROCEDURE [dbo].[GetByName]
    @TableName NVARCHAR(100)
    AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;
    DECLARE @sSQL nvarchar(500);

    SELECT @sSQL = N'SELECT * FROM' + QUOTENAME(@TableName);

    EXEC sp_executesql @sSQL



END

Comments

QUOTENAME सुरक्षा के लिए महत्वपूर्ण है। धन्यवाद।

— सिहान याकर

लेकिन ऐसी क्वेरी से मान कैसे लौटाएं? जैसे COUNT(*)?

— सनकैचर

Answer 4

आप एक चर के लिए एक तालिका नाम का उपयोग नहीं कर सकते हैं, आपको इसके बजाय ऐसा करना होगा:

DECLARE @sqlCommand varchar(1000)
SET @sqlCommand = 'SELECT * from yourtable'
EXEC (@sqlCommand)

Answer 5

आपको गतिशील रूप से sql उत्पन्न करना होगा:

declare @tablename varchar(50) 

set @tablename = 'test' 

declare @sql varchar(500)

set @sql = 'select * from ' + @tablename 

exec (@sql)

Answer 6

sp_executesqlकिसी भी SQL, उदाहरण के लिए निष्पादित करने के लिए उपयोग करें

DECLARE @tbl    sysname,
        @sql    nvarchar(4000),
        @params nvarchar(4000),
        @count  int

DECLARE tblcur CURSOR STATIC LOCAL FOR
   SELECT object_name(id) FROM syscolumns WHERE name = 'LastUpdated'
   ORDER  BY 1
OPEN tblcur

WHILE 1 = 1
BEGIN
   FETCH tblcur INTO @tbl
   IF @@fetch_status <> 0
      BREAK

   SELECT @sql =
   N' SELECT @cnt = COUNT(*) FROM dbo.' + quotename(@tbl) +
   N' WHERE LastUpdated BETWEEN @fromdate AND ' +
   N'                           coalesce(@todate, ''99991231'')'
   SELECT @params = N'@fromdate datetime, ' +
                    N'@todate   datetime = NULL, ' +
                    N'@cnt      int      OUTPUT'
   EXEC sp_executesql @sql, @params, '20060101', @cnt = @count OUTPUT

   PRINT @tbl + ': ' + convert(varchar(10), @count) + ' modified rows.'
END

DEALLOCATE tblcur

Comments

यह उदाहरण बहुत उपयोगी है।

— डाउनहिल्स्की

Answer 7

इसके अलावा, आप इस का उपयोग कर सकते हैं ...

DECLARE @SeqID varchar(150);
DECLARE @TableName varchar(150);  
SET @TableName = (Select TableName from Table);
SET @SeqID = 'SELECT NEXT VALUE FOR '+ @TableName + '_Data'
exec (@SeqID)

Answer 8

Declare  @tablename varchar(50) 
set @tablename = 'Your table Name' 
EXEC('select * from ' + @tablename)

Comments

ढेर अतिप्रवाह में आपका स्वागत है! हालांकि यह कोड प्रश्न को हल कर सकता है, जिसमें यह भी बताया गया है कि यह समस्या कैसे और क्यों हल करती है, इससे वास्तव में आपके पोस्ट की गुणवत्ता को बेहतर बनाने में मदद मिलेगी, और संभवत: अधिक वोट मिले। याद रखें कि आप भविष्य में पाठकों के लिए सवाल का जवाब दे रहे हैं, न कि केवल उस व्यक्ति से जो अब पूछ रहा है। कृपया स्पष्टीकरण जोड़ने के लिए अपने उत्तर को संपादित करें और संकेत दें कि क्या सीमाएँ और मान्यताएँ लागू होती हैं। समीक्षा से

— डबल-बीप

Answer 9

आपको SQL सर्वर डायनेमिक SQL का उपयोग करने की आवश्यकता है

DECLARE @table     NVARCHAR(128),
        @sql       NVARCHAR(MAX);

SET @table = N'tableName';

SET @sql = N'SELECT * FROM ' + @table;

किसी भी SQL को निष्पादित करने के लिए EXEC का उपयोग करें

EXEC (@sql)

किसी भी SQL को निष्पादित करने के लिए EXEC sp_executesql का उपयोग करें

EXEC sp_executesql @sql;

किसी भी SQL को निष्पादित करने के लिए EXECUTE sp_executesql का उपयोग करें

EXECUTE sp_executesql @sql

Answer 10

Declare @fs_e int, @C_Tables CURSOR, @Table varchar(50)

SET @C_Tables = CURSOR FOR
        select name from sysobjects where OBJECTPROPERTY(id, N'IsUserTable') = 1 AND name like 'TR_%'
OPEN @C_Tables
FETCH @C_Tables INTO @Table
    SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'

WHILE ( @fs_e <> -1)
    BEGIN
        exec('Select * from '+ @Table)
        FETCH @C_Tables INTO @Table
        SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'
    END