सबसे सरल लेकिन पूरा CMake उदाहरण

Question

किसी तरह सीएमके काम करने से मैं पूरी तरह से भ्रमित हूं। हर बार जब मुझे लगता है कि मैं यह समझने के लिए करीब आ रहा हूं कि सीएमके को कैसे लिखा जाना है, तो यह अगले उदाहरण में गायब हो जाता है जो मैंने पढ़ा। मैं यह जानना चाहता हूं कि मुझे अपनी परियोजना को किस तरह से तैयार करना चाहिए, ताकि मेरे सीएमके को भविष्य में कम से कम रखरखाव की आवश्यकता हो। उदाहरण के लिए, मैं अपने CMakeList.txt को अपडेट नहीं करना चाहता जब मैं अपने src ट्री में एक नया फ़ोल्डर जोड़ रहा हूं, जो अन्य सभी src फ़ोल्डरों की तरह ही काम करता है।

यह मैं अपनी परियोजना की संरचना की कल्पना करता हूं, लेकिन कृपया यह केवल एक उदाहरण है। यदि अनुशंसित तरीका अलग है, तो कृपया मुझे बताएं, और मुझे बताएं कि यह कैसे करना है।

myProject
    src/
        module1/
            module1.h
            module1.cpp
        module2/
            [...]
        main.cpp
    test/
        test1.cpp
    resources/
        file.png
    bin
        [execute cmake ..]

वैसे, यह महत्वपूर्ण है कि मेरा कार्यक्रम जानता है कि संसाधन कहां हैं। मैं संसाधनों के प्रबंधन के अनुशंसित तरीके को जानना चाहूंगा। मैं अपने संसाधनों को "../resource/file.png" के साथ एक्सेस नहीं करना चाहता

Comments

For example I don't want to update my CMakeList.txt when I am adding a new folder in my src treeक्या आप आईडीई का एक उदाहरण दे सकते हैं जो स्रोतों को स्वचालित रूप से एकत्र करता है?

कोई भी विचारधारा आम तौर पर स्रोतों को स्वचालित रूप से एकत्र नहीं करती है, क्योंकि उन्हें इसकी आवश्यकता नहीं होती है। जब मैं एक नई फ़ाइल या फ़ोल्डर जोड़ता हूं, तो मैं इसे ide के भीतर करता हूं, और प्रोजेक्ट अपडेट किया जाता है। दूसरी तरफ एक बिल्ड सिस्टम ध्यान नहीं देता है जब मैं कुछ फ़ाइलों को बदलता हूं, तो यह एक वांछित व्यवहार है कि यह सभी स्रोत फ़ाइलों को स्वचालित रूप से इकट्ठा करता है

— Arne

अगर मुझे वह लिंक दिखाई देता है, तो मुझे यह आभास होता है कि सीएमके उस सबसे महत्वपूर्ण कार्य में विफल हो गया जिसे हल करना चाहते थे: क्रॉस प्लेटफॉर्म बिल्ड सिस्टम को आसान बनाना।

— अर्ने

Answer 1

कुछ शोध के बाद अब मेरे पास सबसे सरल लेकिन पूर्ण cmake उदाहरण का अपना संस्करण है। यहां यह है, और यह संसाधनों और पैकेजिंग सहित अधिकांश मूल बातें कवर करने की कोशिश करता है।

एक चीज जो गैर-मानक है वह संसाधन हैंडलिंग है। डिफ़ॉल्ट रूप से cmake उन्हें / usr / शेयर /, / usr / लोकल / शेयर / और विंडो पर समतुल्य रखना चाहता है। मैं एक सरल ज़िप / टारगेट चाहता था जिसे आप कहीं भी निकाल सकते हैं और चला सकते हैं। इसलिए निष्पादन योग्य के सापेक्ष संसाधन लोड किए जाते हैं।

cmake कमांड्स को समझने के लिए मूल नियम निम्नलिखित सिंटैक्स है: <function-name>(<arg1> [<arg2> ...])कॉमा या अर्धविराम के बिना। प्रत्येक तर्क एक स्ट्रिंग है। foobar(3.0)और foobar("3.0")ऐसा ही है। आप के साथ सूची / चर सेट कर सकते हैं set(args arg1 arg2)। इस चर सेट के साथ foobar(${args}) और foobar(arg1 arg2)प्रभावी रूप से समान हैं। एक गैर-मौजूद चर एक खाली सूची के बराबर है। तत्वों को अलग करने के लिए एक सूची आंतरिक रूप से अर्धविराम के साथ एक स्ट्रिंग है। इसलिए केवल एक तत्व के साथ एक सूची परिभाषा के अनुसार उस तत्व की है, कोई मुक्केबाजी नहीं होती है। चर वैश्विक हैं। बिलिन फ़ंक्शंस कुछ इस तरह के नामित तर्कों की पेशकश करते हैं कि वे कुछ आईडी की उम्मीद करते हैं जैसे PUBLICयाDESTINATIONउनकी तर्क सूची में, तर्कों को समूहित करने के लिए। लेकिन यह एक भाषा की विशेषता नहीं है, उन आईडी भी सिर्फ तार हैं, और फ़ंक्शन कार्यान्वयन द्वारा पार्स किया गया है।

आप गितुब से सब कुछ क्लोन कर सकते हैं

cmake_minimum_required(VERSION 3.0)
project(example_project)

###############################################################################
## file globbing ##############################################################
###############################################################################

# these instructions search the directory tree when cmake is
# invoked and put all files that match the pattern in the variables 
# `sources` and `data`
file(GLOB_RECURSE sources      src/main/*.cpp src/main/*.h)
file(GLOB_RECURSE sources_test src/test/*.cpp)
file(GLOB_RECURSE data resources/*)
# you can use set(sources src/main.cpp) etc if you don't want to
# use globing to find files automatically

###############################################################################
## target definitions #########################################################
###############################################################################

# add the data to the target, so it becomes visible in some IDE
add_executable(example ${sources} ${data})

# just for example add some compiler flags
target_compile_options(example PUBLIC -std=c++1y -Wall -Wfloat-conversion)

# this lets me include files relative to the root src dir with a <> pair
target_include_directories(example PUBLIC src/main)

# this copies all resource files in the build directory
# we need this, because we want to work with paths relative to the executable
file(COPY ${data} DESTINATION resources)

###############################################################################
## dependencies ###############################################################
###############################################################################

# this defines the variables Boost_LIBRARIES that contain all library names
# that we need to link to
find_package(Boost 1.36.0 COMPONENTS filesystem system REQUIRED)

target_link_libraries(example PUBLIC
  ${Boost_LIBRARIES}
  # here you can add any library dependencies
)

###############################################################################
## testing ####################################################################
###############################################################################

# this is for our testing framework
# we don't add REQUIRED because it's just for testing
find_package(GTest)

if(GTEST_FOUND)
  add_executable(unit_tests ${sources_test} ${sources})

  # we add this define to prevent collision with the main
  # this might be better solved by not adding the source with the main to the
  # testing target
  target_compile_definitions(unit_tests PUBLIC UNIT_TESTS)

  # this allows us to use our executable as a link library
  # therefore we can inherit all compiler options and library dependencies
  set_target_properties(example PROPERTIES ENABLE_EXPORTS on)

  target_link_libraries(unit_tests PUBLIC
    ${GTEST_BOTH_LIBRARIES}
    example
  )

  target_include_directories(unit_tests PUBLIC
    ${GTEST_INCLUDE_DIRS} # doesn't do anything on Linux
  )
endif()

###############################################################################
## packaging ##################################################################
###############################################################################

# all install commands get the same destination. this allows us to use paths
# relative to the executable.
install(TARGETS example DESTINATION example_destination)
# this is basically a repeat of the file copy instruction that copies the
# resources in the build directory, but here we tell cmake that we want it
# in the package
install(DIRECTORY resources DESTINATION example_destination)

# now comes everything we need, to create a package
# there are a lot more variables you can set, and some
# you need to set for some package types, but we want to
# be minimal here
set(CPACK_PACKAGE_NAME "MyExample")
set(CPACK_PACKAGE_VERSION "1.0.0")

# we don't want to split our program up into several things
set(CPACK_MONOLITHIC_INSTALL 1)

# This must be last
include(CPack)

Comments

@SteveLorimer मैं सिर्फ असहमत हूं, वह फ़ाइल ग्लोबिंग एक खराब शैली है, मुझे लगता है कि मैन्युअल रूप से फाइल ट्री को CMakeLists.txt में कॉपी करना एक बुरा स्टाइल है क्योंकि यह बेमानी है। लेकिन मुझे पता है कि लोग इस विषय पर असहमत हैं, इसलिए मैंने कोड में एक टिप्पणी छोड़ दी, जहां आप ग्लोबिंग को एक सूची से बदल सकते हैं जिसमें सभी स्रोत फाइलें स्पष्ट रूप से होती हैं। के लिए खोजें set(sources src/main.cpp)।

— अर्ने

@SteveLorimer हाँ अक्सर मुझे cmake को फिर से आमंत्रित करना पड़ा। हर बार जब मैं डायरेक्टरी ट्री में कुछ जोड़ता हूं, तो मुझे मैन्युअल रूप से cmake को रिवाइव करने की जरूरत होती है, ताकि ग्लोबिंग को फिर से मिलाया जा सके। यदि आप फ़ाइलों को डालते हैं CMakeLists.txt, तो एक सामान्य मेक (या निन्जा) cmake के पुनर्निवेश को ट्रिगर करेगा, इसलिए आप इसे नहीं भूल सकते। यह थोड़ा टीम फ्रेंडली भी है, क्योंकि तब टीम के सदस्य भी cmake को अंजाम देना नहीं भूल सकते। लेकिन मुझे लगता है कि एक मेकफाइल को छूने की आवश्यकता नहीं होनी चाहिए, सिर्फ इसलिए कि किसी ने एक फ़ाइल को जोड़ा। इसे एक बार लिखें, और किसी को भी इसके बारे में फिर से सोचने की आवश्यकता नहीं होनी चाहिए।

— Arne

@SteveLorimer मैं भी परियोजनाओं के हर निर्देशिका में एक CMakeLists.txt लगाने के पैटर्न से असहमत हूं, यह सिर्फ परियोजना को हर जगह कॉन्फ़िगरेशन को डराता है, मुझे लगता है कि यह करने के लिए एक फाइल पर्याप्त होनी चाहिए, अन्यथा क्या, का सिंहावलोकन ढीला है वास्तव में निर्माण प्रक्रिया में किया जाता है। इसका मतलब यह नहीं है कि अपने स्वयं के CMakeLists.txt के साथ उपनिर्देशिकाएं नहीं हो सकती हैं, मुझे लगता है कि यह एक अपवाद होना चाहिए।

— Arne

"संस्करण नियंत्रण प्रणाली" के लिए "VCS" को छोटा मान लिया जाए , तो यह अप्रासंगिक है। मुद्दा यह नहीं है, कि कलाकृतियों को स्रोत नियंत्रण में जोड़ा नहीं जाएगा। मुद्दा यह है कि, सीएमके अतिरिक्त स्रोत फ़ाइलों का पुनर्मूल्यांकन करने में विफल रहेगा। यह बिल्ड सिस्टम इनपुट फ़ाइलों को फिर से जेनरेट नहीं करेगा। निर्माण प्रणाली खुशी से पुरानी इनपुट फ़ाइलों के साथ चिपकेगी, या तो त्रुटियों की ओर ले जाएगी (यदि आप भाग्यशाली हैं), या यदि आप भाग्य से बाहर निकलते हैं, तो किसी का ध्यान नहीं जाएगा। GLOBbing निर्भरता गणना श्रृंखला में एक अंतर पैदा करता है। यह है एक महत्वपूर्ण मुद्दा है, और एक टिप्पणी को उचित रूप से यह स्वीकार नहीं करता है।

— IInspectable

CMake और VCS पूर्ण अलगाव में काम करते हैं। वीसीएस सीएमके से अनजान है और सीएमके किसी भी वीसीएस से अनजान है। उनके बीच कोई संबंध नहीं है। जब तक आप यह सुझाव नहीं देते हैं कि डेवलपर्स को मैनुअल कदम उठाने चाहिए, वीसीएस से बाहर की जानकारी लेनी चाहिए, और कुछ हेयुरिस्टिक क्लीन एंड रेयर सीएमके पर आधारित होना चाहिए। यह स्पष्ट नहीं है, और मनुष्यों के लिए अजीब है। नहीं, क्षमा करें, आपने अब तक GLOBbing फ़ाइलों के लिए एक ठोस बिंदु नहीं बनाया है।

— IInspectable

Answer 2

सीएमके ट्यूटोरियल में सबसे बुनियादी लेकिन पूर्ण उदाहरण पाया जा सकता है :

cmake_minimum_required (VERSION 2.6)
project (Tutorial)
add_executable(Tutorial tutorial.cxx)

आपके प्रोजेक्ट उदाहरण के लिए आपके पास हो सकता है:

cmake_minimum_required (VERSION 2.6)
project (MyProject)
add_executable(myexec src/module1/module1.cpp src/module2/module2.cpp src/main.cpp)
add_executable(mytest test1.cpp)

आपके अतिरिक्त प्रश्न के लिए, जाने का एक तरीका फिर से ट्यूटोरियल में है: एक विन्यास योग्य हेडर फ़ाइल बनाएं जिसे आप अपने कोड में शामिल करते हैं। इसके लिए, configuration.h.inनिम्नलिखित सामग्री के साथ एक फ़ाइल बनाएं :

#define RESOURCES_PATH "@RESOURCES_PATH@"

फिर अपने CMakeLists.txtऐड में:

set(RESOURCES_PATH "${PROJECT_SOURCE_DIR}/resources/"
# configure a header file to pass some of the CMake settings
# to the source code
configure_file (
  "${PROJECT_SOURCE_DIR}/configuration.h.in"
  "${PROJECT_BINARY_DIR}/configuration.h"
)

# add the binary tree to the search path for include files
# so that we will find TutorialConfig.h
include_directories("${PROJECT_BINARY_DIR}")

अंत में, जहां आपको अपने कोड में पथ की आवश्यकता है, आप कर सकते हैं:

#include "configuration.h"

...

string resourcePath = string(RESOURCE_PATH) + "file.png";

Comments

बहुत बहुत धन्यवाद, विशेष रूप से RESOURCE_PATH के लिए, किसी तरह मुझे यह नहीं मिला कि config_file वह है जिसे मैं ढूंढ रहा था। लेकिन आपने प्रोजेक्ट से सभी फ़ाइलों को मैन्युअल रूप से जोड़ा है, क्या केवल एक पैटर्न को परिभाषित करने का एक बेहतर तरीका है जिसमें सभी फाइलें src ट्री से जोड़ी जाती हैं?

— अर्ने

डायटर का जवाब देखें, लेकिन मेरी टिप्पणियों पर भी कि आपको इसका उपयोग क्यों नहीं करना चाहिए। यदि आप वास्तव में इसे स्वचालित करना चाहते हैं, तो एक बेहतर दृष्टिकोण एक स्क्रिप्ट लिखने के लिए हो सकता है जिसे आप स्रोत फ़ाइलों की सूची को पुन: उत्पन्न करने के लिए चला सकते हैं (या आपके लिए ऐसा करने वाले cmake जागरूक IDE का उपयोग करें; मैं किसी से परिचित नहीं हूं)।

— sgvd

@sgvd string resourcePath = string(RESOURCE_PATH) + "file.png"IMHO स्रोत निर्देशिका के लिए पूर्ण पथ को हार्डकोड करना एक बुरा विचार है । यदि आपको अपनी परियोजना स्थापित करने की आवश्यकता हो तो क्या होगा?

मुझे पता है कि स्वचालित रूप से स्रोत इकट्ठा करना अच्छा लगता है, लेकिन यह सभी प्रकार की जटिलताओं को जन्म दे सकता है। संक्षिप्त चर्चा के लिए कुछ समय पहले इस प्रश्न को देखें: stackoverflow.com/q/10914607/1401351 ।

— पीटर

यदि आप cmake नहीं चलाते हैं तो आपको ठीक वही त्रुटि मिलती है; हाथ से फाइलें जोड़ने में एक सेकंड का समय लगता है, हर कंपाइल पर सीमेक चलाने में हर बार एक सेकंड लगता है; आप वास्तव में cmake की एक विशेषता को तोड़ते हैं; जो कोई भी एक ही परियोजना पर काम करता है और आपके बदलावों को खींचता है, वह करेगा: रन बनाना -> अपरिभाषित संदर्भ प्राप्त करना -> उम्मीद है कि रीमुन सीमेक को याद करें, या आपके साथ बग को फाइल करें -> रन सीमेक -> रन मेक सक्सेसफुल है, जबकि यदि आप फाइल को जोड़ते हैं हाथ से वह करता है: रन बनाने में सफल -> परिवार के साथ समय बिताता है। योग है कि, आलसी मत बनो, और भविष्य में अपने आप को और दूसरों को एक सिर दर्द छोड़ दो।

— svvd

Answer 3

यहाँ मैं सबसे सरल लेकिन पूर्ण CMakeLists.txt फाइल सैंपल लिखता हूँ।

सोर्स कोड

1. प्लेटफ़ॉर्म एंड्रॉइड / iOS / वेब / डेस्कटॉप को पार करने के लिए हैलो दुनिया से ट्यूटोरियल।
2. प्रत्येक प्लेटफ़ॉर्म मैंने एक नमूना एप्लिकेशन जारी किया।
3. 08-cross_platform फ़ाइल संरचना मेरे काम से सत्यापित है
4. यह मेरे लिए एक टीम के लिए सही लेकिन उपयोगी और सर्वोत्तम अभ्यास नहीं हो सकता है

उसके बाद, मैंने विवरण के लिए दस्तावेज़ पेश किया।

यदि आपके कोई प्रश्न हैं, तो आप मुझसे संपर्क कर सकते हैं और मैं इसे समझाना चाहूंगा।