स्प्लिट बफ़र्स को साइड-बाय-साइड में Emacs सेट करना

Question

बहुत सारे Emacs फ़ंक्शंस स्क्रीन को स्वचालित रूप से विभाजित करते हैं। हालांकि, वे सभी ऐसा करते हैं कि खिड़कियां एक के ऊपर एक हैं। क्या उन्हें विभाजित करने का कोई तरीका है कि वे डिफ़ॉल्ट रूप से इसके बजाय साइड-बाय-साइड हों?

Comments

मैं इस प्रश्न में क्षैतिज और ऊर्ध्वाधर का उपयोग स्वैप करूंगा - मैं कहूंगा कि डिफ़ॉल्ट व्यवहार क्षैतिज रूप से विभाजित करने के लिए है (विभाजन स्क्रीन के पार एक क्षैतिज रेखा है)।

— स्किलड्रिक

Cx 3 कमांड स्प्लिट-विंडो-क्षैतिज रूप से चलाता है, कमांड के लिए जो साइड-बाय-साइड विंडो देता है, इसलिए मैं उसी का उपयोग कर रहा हूं।

— निक्विन

@Skilldrick "वर्टिकल" और "हॉरिज़ॉन्टल" अस्पष्ट हैं और अलग-अलग व्याख्या की जा सकती है; वे वर्णन कर सकते हैं कि विभक्त कैसे उन्मुख है या विभाजन कैसे उन्मुख हैं। मेरा सामान्य झुकाव मूल प्रश्न के शब्दों के साथ सहमत होना है (अर्थात, मैं "ऊर्ध्वाधर रूप से विभाजित" "खड़ी जगह" के रूप में "विभाजित रूप से व्याख्या" करूंगा)।

— jamesdlin

Answer 1

(setq split-height-threshold nil)
(setq split-width-threshold 0)

GNU Emacs Lisp संदर्भ मैनुअल: विंडो विकल्प चुनना

Comments

ध्यान दें कि ये कार्य विभाजित-विंडो-पसंदीदा-फ़ंक्शन और स्प्लिट-विंडो-सेंसिटिव फ़ंक्शन को प्रभावित करने के कारण कैसे सेट होते हैं - यदि आप उसके लिए डॉक्स पढ़ते हैं, तो आप यह पता लगा सकते हैं कि सेट किए जा रहे ये चर चीजों को कैसे प्रभावित करते हैं। हममें से जो डिफ़ॉल्ट रूप से ऊर्ध्वाधर विभाजन को पसंद करते हैं, हम बस (सेट-स्प्लिट-चौड़ाई-थ्रेशोल्ड नील) का उपयोग कर सकते हैं जो सिस्टम को क्षैतिज रूप से खिड़कियों को विभाजित करने की अनुमति नहीं देता है।

— केंडल हेल्मसटेटर गेलनर

डॉक्स को पढ़ने और एक बिट के आसपास खेलने के बाद, मैंने एनआईएल के लिए विभाजन-ऊंचाई-दहलीज और विभाजन-चौड़ाई-दहलीज को 80 पर सेट किया है ताकि यह पहले यह देख सके कि यह क्षैतिज रूप से विभाजित हो सकता है और केवल तभी लंबवत प्रयास करें। यह केवल ऊर्ध्वाधर रूप से विभाजित होने से अक्सर बदसूरत हो जाता है क्योंकि खिड़कियां संकीर्ण हो जाती हैं।

— 20

यह बहुत प्रशंसनीय लगता है। हालाँकि, यह GDB / GUD एकीकरण के लिए emacs में काम नहीं कर रहा है। अगर मेरे पास एक सिंगल विंडो है तो डिबगर शुरू करें, इमैक हमेशा लंबवत रूप से विभाजित होता है। क्या उसके लिए कोई GUD / GDB- विशिष्ट सेटिंग है?

— mefiX

@ निक्विन: मेरे मामले में, यह समाधान "Cx 4 b" को दो 80 स्तंभों की खिड़कियों के किनारे-किनारे करता है (मेरी वर्तमान स्क्रीन अचल संपत्ति केवल इतना ही फिट हो सकती है)। दूसरी बार "Cx 4 b" को शामिल करने से एक नई वर्टिकली स्प्लिट "अन्य" विंडो नहीं खुलती है। इसके बजाय, यह वर्तमान में उपलब्ध "अन्य" विंडो पर बफर को खोलता है। जैसा कि आपने वर्णन किया है, मैं इसे कैसे व्यवहार कर सकता हूं (क्षैतिज रूप से लंबवत कोशिश करें)?

— एवेन्यू

यह परिचित Cx कुछ प्रारूप में नहीं है जिसके बारे में मुझे पता है। मैं इन आदेशों को कैसे निष्पादित करूं?

— 23:15 बजे user1552512

Answer 2

यहाँ दो समाधान, किसी एक का उपयोग करें जिसे आप पसंद करते हैं:

ए: डिफ़ॉल्ट रूप से (बाएं / दाएं):

(setq split-height-threshold nil)
(setq split-width-threshold 0)

बी: स्वचालित रूप से खिड़की खड़ी (बाएं / दाएं) विभाजित करें यदि वर्तमान खिड़की पर्याप्त चौड़ी है

(defun display-new-buffer (buffer force-other-window)
  "If BUFFER is visible, select it.
If it's not visible and there's only one window, split the
current window and select BUFFER in the new window. If the
current window (before the split) is more than 100 columns wide,
split horizontally(left/right), else split vertically(up/down).
If the current buffer contains more than one window, select
BUFFER in the least recently used window.
This function returns the window which holds BUFFER.
FORCE-OTHER-WINDOW is ignored."
  (or (get-buffer-window buffer)
    (if (one-window-p)
        (let ((new-win
               (if (> (window-width) 100)
                   (split-window-horizontally)
                 (split-window-vertically))))
          (set-window-buffer new-win buffer)
          new-win)
      (let ((new-win (get-lru-window)))
        (set-window-buffer new-win buffer)
        new-win))))
;; use display-buffer-alist instead of display-buffer-function if the following line won't work
(setq display-buffer-function 'display-new-buffer)

आप किसी भी एक को .emacs/init.elफाइल में रखें । आप अपनी पसंद के अनुसार "100" को अपने स्क्रीन के आधार पर बदल सकते हैं।

यदि आपको एक फ्रेम में दो खिड़कियां मिली हैं, और आप लेआउट को ऊर्ध्वाधर से क्षैतिज या इसके विपरीत में बदलना चाहते हैं, तो यहां एक समाधान है:

(defun toggle-window-split ()
  (interactive)
    (if (= (count-windows) 2)
      (let* ((this-win-buffer (window-buffer))
            (next-win-buffer (window-buffer (next-window)))
            (this-win-edges (window-edges (selected-window)))
            (next-win-edges (window-edges (next-window)))
            (this-win-2nd
             (not (and (<= (car this-win-edges)
                        (car next-win-edges))
                    (<= (cadr this-win-edges)
                        (cadr next-win-edges)))))
         (splitter
          (if (= (car this-win-edges)
                 (car (window-edges (next-window))))
              'split-window-horizontally
            'split-window-vertically)))
    (delete-other-windows)
    (let ((first-win (selected-window)))
      (funcall splitter)
      (if this-win-2nd (other-window 1))
      (set-window-buffer (selected-window) this-win-buffer)
      (set-window-buffer (next-window) next-win-buffer)
      (select-window first-win)
      (if this-win-2nd (other-window 1))))))
;; C-x 4 t 'toggle-window-split
(define-key ctl-x-4-map "t" 'toggle-window-split)

इसे अपनी .emacs/init.elफ़ाइल में रखें , C-x 4 tअपनी खिड़कियों के लेआउट को टॉगल करने के लिए उपयोग करें ।

Comments

समाधान दृश्य जब मैं उपयोग कर रहा था पर undo-treeदबाने qबफर Cluse नहीं है

— alper

Answer 3

(setq split-height-threshold 0) (setq split-width-threshold 0)

वह है जो मुझे वांछित व्यवहार (कोई क्षैतिज विभाजन नहीं) प्राप्त करने के लिए उपयोग करना था

Answer 4

कभी-कभी हमें वर्तमान प्रदर्शन और हमारी आवश्यकता (अधिक लाइनें या अधिक कॉलम) के अनुसार क्षैतिज और ऊर्ध्वाधर के बीच परिवर्तन की आवश्यकता होती है।

मैं महान ToggleWindowSplit की सिफारिश करता हूं , और मैं "Cc y" की कुंजी बांधता हूं

http://www.emacswiki.org/emacs/ToggleWindowSplit

Comments

या ट्रांसपोज़-फ्रेम , जो अधिक सुरुचिपूर्ण है।

— xuhdev

Answer 5

2 चर को शून्य और 0 में सेट करने का सरल उत्तर मेरे लिए काम नहीं करता था, इसलिए मैंने 2 सरल कार्य लिखे: एक बस एनएक्स ऊर्ध्वाधर बफ़र्स में विंडो को विभाजित करता है और नाम वाली फ़ाइलों को खोलता है (उदाहरण के लिए) file.1 file.2 ।। फ़ाइल। प्रत्येक में एक और एक दूसरे को एक ही लगता है, सिवाय यह 2 डी में है (फाइल खोलने के लिए NX कॉलम द्वारा एन पंक्तियों f.1 f.2 ... f। [एनएक्स * एनवाई])। स्थापित करने के लिए, इस कोड को .emacs में जोड़ें:

    (defun grid-files-h (nx wx pfx)
  "Using dotimes, split the window into NX side-by-side buffers of width WX and load files starting with prefix PFX and ending in numbers 1 through NX"
  (let (ox fn k)  ; ox is not used, but fn is used to store the filename, and k to store the index string
    (dotimes (x (- nx 1) ox) ; go through buffers, x goes from 0 to nx-2 and ox is not used here
;     (print x)
      (setq k (number-to-string (+ x 1) ) )  ; k is a string that goes from "1" to "nx-1"
;     (print k)
      (setq fn (concat pfx k) ) ; fn is filename - concatenate prefix with k
;     (print fn)
      (find-file fn) ; open the filename in current buffer
      (split-window-horizontally wx) ; split window (current buffer gets wx-columns)
      (other-window 1) ; switch to the next (right) buffer
      )
    (setq k (number-to-string nx )) ; last (rightmost) buffer gets the "nx" file
    (setq fn (concat pfx k) ) ; fn = "pfx"+"nx"
    (find-file fn ) ; open fn
    (other-window 1) ; go back to the first buffer
    )  
  )

   (defun grid-files-sq (ny wy nx wx pfx)
      "Using dotimes, split the window into NX columns of width WX and NY rows of height WY and load files starting with prefix PFX and ending in numbers 1 through NX*NY"
      (let (oy ox fn k)  
        (dotimes (y ny oy) ; go through rows, y goes from 0 to ny-1 and oy is not used here
          (split-window-vertically wy) ; create this row
          (dotimes (x (- nx 1) ox) ; go through columns, x goes from 0 to nx-2 and ox is not used here
        (setq k (number-to-string (+ 1 (+ x (* y nx) ) ) ) ) ; k must convert 2 indecies (x,y) into one linear one (like sub2ind in matlab)
        (setq fn (concat pfx k) ) ; filename
        (find-file fn ) ; open
        (split-window-horizontally wx) ; create this column in this row (this "cell")
        (other-window 1) ; go to the next buffer on the right 
        )
          (setq k (number-to-string (+ nx (* y nx) ) ) ) ; rightmost buffer in this row needs a file too
          (setq fn (concat pfx k) ) ; filename
          (find-file fn ) ; open
          (other-window 1) ; go to next row (one buffer down)
          )
        )
      )

और फिर खड़ी एक का उपयोग करने, मैं * खरोंच करने के लिए जाना * ( C-x b *scratch* RET, C-x 1), में टाइप (grid-files-h 3 20 "file.")तो C-x C-e, या आप वर्ग qrid एक बाहर का परीक्षण करने के चाहते हैं C-x 1प्रकार में, (grid-files-sq 2 15 3 20 "f.")और उसके बाद C-x C-eआप की तरह कुछ देखना चाहिए और

यह शायद बेहतर / अधिक कुशलता से किया जा सकता है, लेकिन यह एक शुरुआत है और यह वही करता है जो मुझे करने की आवश्यकता है (क्रमिक रूप से नामित छोटी फ़ाइलों का एक गुच्छा प्रदर्शित करें)। सुधार या पुन: उपयोग करने के लिए स्वतंत्र महसूस करें।

Answer 6

मैं नियमित रूप से विभिन्न परियोजनाओं के लिए emacs में कई फ्रेम (OSX विंडोज़) का उपयोग करता हूं। यहां बताया गया है कि मैं शुरू में कुछ फ्रेम सेटअप करके बाईं और दाईं विंडो में विभाजित हो गया।

  (defun make-maximized-split-frame (name)
    (let (( f (make-frame (list (cons 'name  name))) ))
      (maximize-frame f)
      (split-window (frame-root-window f) nil t)
      ))

  (make-maximized-split-frame "DocRaptor")
  (make-maximized-split-frame "Gauges")
  (make-maximized-split-frame "Instrumental")