217

मुझे पता है कि color bfकमांड पूरी कमांड लाइन विंडो के रंग सेट करता है लेकिन मैं एक सिंगल लाइन को एक अलग रंग में प्रिंट करना चाहता था।

— रुई
स्रोत

1

ऐसा लगता है कि मैं विंडोज कमांड लाइन में बच रंग कोड जोड़ने का कोई सरल तरीका नहीं है। :(

— रुई

रुई, अगर Win10 एक स्वीकार्य OS संस्करण है, तो जेन्स के उत्तर की जांच करें - यह ठीक वही होना चाहिए जिसकी आपको आवश्यकता है, क्योंकि इस प्रश्न को सात साल पहले कभी भी स्वीकार नहीं किया गया था: stackoverflow.com/a/38617204/3543437

— kkleeFrye_onDeck

1

विंडोज बैच फ़ाइल में कई रंगों

— मीका विडेनमैन

284

मैं एक ही लाइन को अलग रंग में प्रिंट करना चाहता था।

ANSI एस्केप अनुक्रम का उपयोग करें।

10 से पहले विंडोज - कंसोल पर एएनएसआई रंगों के लिए कोई देशी समर्थन नहीं

10 से नीचे के विंडोज संस्करण के लिए, विंडोज कमांड कंसोल डिफ़ॉल्ट रूप से आउटपुट कलरिंग का समर्थन नहीं करता है। आप अपने विंडोज कमांड कंसोल में कलरिंग सपोर्ट को जोड़ने के लिए Cmder , ConEmu , ANSICON या मिंट्टी (GitBash और Cygwin में डिफ़ॉल्ट रूप से उपयोग) स्थापित कर सकते हैं।

विंडोज 10 - कमांड लाइन रंग

विंडोज 10 से शुरू होकर विंडोज कंसोल एएनएसआई एस्केप सीक्वेंस और कुछ रंगों को डिफ़ॉल्ट रूप से सपोर्ट करता है। फ़ीचर को थ्रेसहोल्ड 2 अपडेट के साथ नवंबर 2015 में भेज दिया गया।

MSDN प्रलेखन

अद्यतन (05-2019): ColorTool आपको कंसोल की रंग योजना को बदलने में सक्षम बनाता है। यह Microsoft टर्मिनल प्रोजेक्ट का हिस्सा है ।

डेमो

बैच कमान

win10colors.cmdद्वारा लिखा गया था मिशेल Locati :

@echo off
cls
echo [101;93m STYLES [0m
echo ^<ESC^>[0m [0mReset[0m
echo ^<ESC^>[1m [1mBold[0m
echo ^<ESC^>[4m [4mUnderline[0m
echo ^<ESC^>[7m [7mInverse[0m
echo.
echo [101;93m NORMAL FOREGROUND COLORS [0m
echo ^<ESC^>[30m [30mBlack[0m (black)
echo ^<ESC^>[31m [31mRed[0m
echo ^<ESC^>[32m [32mGreen[0m
echo ^<ESC^>[33m [33mYellow[0m
echo ^<ESC^>[34m [34mBlue[0m
echo ^<ESC^>[35m [35mMagenta[0m
echo ^<ESC^>[36m [36mCyan[0m
echo ^<ESC^>[37m [37mWhite[0m
echo.
echo [101;93m NORMAL BACKGROUND COLORS [0m
echo ^<ESC^>[40m [40mBlack[0m
echo ^<ESC^>[41m [41mRed[0m
echo ^<ESC^>[42m [42mGreen[0m
echo ^<ESC^>[43m [43mYellow[0m
echo ^<ESC^>[44m [44mBlue[0m
echo ^<ESC^>[45m [45mMagenta[0m
echo ^<ESC^>[46m [46mCyan[0m
echo ^<ESC^>[47m [47mWhite[0m (white)
echo.
echo [101;93m STRONG FOREGROUND COLORS [0m
echo ^<ESC^>[90m [90mWhite[0m
echo ^<ESC^>[91m [91mRed[0m
echo ^<ESC^>[92m [92mGreen[0m
echo ^<ESC^>[93m [93mYellow[0m
echo ^<ESC^>[94m [94mBlue[0m
echo ^<ESC^>[95m [95mMagenta[0m
echo ^<ESC^>[96m [96mCyan[0m
echo ^<ESC^>[97m [97mWhite[0m
echo.
echo [101;93m STRONG BACKGROUND COLORS [0m
echo ^<ESC^>[100m [100mBlack[0m
echo ^<ESC^>[101m [101mRed[0m
echo ^<ESC^>[102m [102mGreen[0m
echo ^<ESC^>[103m [103mYellow[0m
echo ^<ESC^>[104m [104mBlue[0m
echo ^<ESC^>[105m [105mMagenta[0m
echo ^<ESC^>[106m [106mCyan[0m
echo ^<ESC^>[107m [107mWhite[0m
echo.
echo [101;93m COMBINATIONS [0m
echo ^<ESC^>[31m                     [31mred foreground color[0m
echo ^<ESC^>[7m                      [7minverse foreground ^<-^> background[0m
echo ^<ESC^>[7;31m                   [7;31minverse red foreground color[0m
echo ^<ESC^>[7m and nested ^<ESC^>[31m [7mbefore [31mnested[0m
echo ^<ESC^>[31m and nested ^<ESC^>[7m [31mbefore [7mnested[0m

— जेन्स ए कोच
स्रोत

11

@ जेंस ए कोच - यह मेरी खिड़कियों में काम नहीं कर रहा है 10 कंसोल (cmd)

— user3057544

40

ठीक। प्रतिक्रिया के लिए धन्यवाद। .cmdया .bat- दोनों को काम करना चाहिए। लेकिन, मुझे लगता है कि मुझे पता है कि यह काम क्यों नहीं करता है: ऐसा लगता है कि स्टैकऑवरफ्लो में पोस्ट करते समय भागने का प्रतीक हटा दिया गया है। कृपया मेरे उत्तर की सामग्री को कॉपी न करें, इसके बजाय यहां से सामग्री का उपयोग करें: gist.githubusercontent.com/mlocati/…

— Jens A. Koch

28

मुझे पहले कभी ESCनोटपैड ++ में जनरेट नहीं करना पड़ा था ... आप L-ALT027

— एएलपी

3

Btw, जैसा कि कोई है जो ज्यादातर दिनों में बहुत सारे बैच बनाता है और उपयोग करता है, इस जवाब ने मेरे समग्र टूलसेट को सौंदर्यवादी तरीके से बढ़ाया है! VB का उपयोग? बिलकुल नहीं। यह जाने का रास्ता है!

— kayleeFrye_onDeck

4

आप ESCइस तरह एक बैच फ़ाइल में एक चरित्र उत्पन्न कर सकते हैं :for /F %%a in ('echo prompt $E ^| cmd') do set "ESC=%%a"

— Aacini

56

यह एक स्व-संकलित बल्ला / .net हाइब्रिड है (इसे इस तरह बचाया जाना चाहिए .BAT) जो किसी भी सिस्टम पर स्थापित किया जा सकता है। नेट फ्रेमवर्क (यह सबसे पुरानी XP / 2003 के लिए भी .NET फ्रेमवर्क के बिना एक विंडो देखने के लिए एक दुर्लभ बात है) स्थापना)। यह मौजूदा लाइन के लिए अलग पृष्ठभूमि / अग्रभूमि रंग के साथ तार मुद्रित करने में सक्षम एक exe बनाने के लिए jscript.net संकलक का उपयोग करता है।

@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal

for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
   set "jsc=%%v"
)

if not exist "%~n0.exe" (
    "%jsc%" /nologo /out:"%~n0.exe" "%~dpsfnx0"
)

%~n0.exe %*

endlocal & exit /b %errorlevel%

*/

import System;

var arguments:String[] = Environment.GetCommandLineArgs();

var newLine = false;
var output = "";
var foregroundColor = Console.ForegroundColor;
var backgroundColor = Console.BackgroundColor;
var evaluate = false;
var currentBackground=Console.BackgroundColor;
var currentForeground=Console.ForegroundColor;


//http://stackoverflow.com/a/24294348/388389
var jsEscapes = {
  'n': '\n',
  'r': '\r',
  't': '\t',
  'f': '\f',
  'v': '\v',
  'b': '\b'
};

function decodeJsEscape(_, hex0, hex1, octal, other) {
  var hex = hex0 || hex1;
  if (hex) { return String.fromCharCode(parseInt(hex, 16)); }
  if (octal) { return String.fromCharCode(parseInt(octal, 8)); }
  return jsEscapes[other] || other;
}

function decodeJsString(s) {
  return s.replace(
      // Matches an escape sequence with UTF-16 in group 1, single byte hex in group 2,
      // octal in group 3, and arbitrary other single-character escapes in group 4.
      /\\(?:u([0-9A-Fa-f]{4})|x([0-9A-Fa-f]{2})|([0-3][0-7]{0,2}|[4-7][0-7]?)|(.))/g,
      decodeJsEscape);
}


function printHelp( ) {
   print( arguments[0] + "  -s string [-f foreground] [-b background] [-n] [-e]" );
   print( " " );
   print( " string          String to be printed" );
   print( " foreground      Foreground color - a " );
   print( "                 number between 0 and 15." );
   print( " background      Background color - a " );
   print( "                 number between 0 and 15." );
   print( " -n              Indicates if a new line should" );
   print( "                 be written at the end of the ");
   print( "                 string(by default - no)." );
   print( " -e              Evaluates special character " );
   print( "                 sequences like \\n\\b\\r and etc ");
   print( "" );
   print( "Colors :" );
   for ( var c = 0 ; c < 16 ; c++ ) {
        
        Console.BackgroundColor = c;
        Console.Write( " " );
        Console.BackgroundColor=currentBackground;
        Console.Write( "-"+c );
        Console.WriteLine( "" );
   }
   Console.BackgroundColor=currentBackground;
   
   

}

function errorChecker( e:Error ) {
        if ( e.message == "Input string was not in a correct format." ) {
            print( "the color parameters should be numbers between 0 and 15" );
            Environment.Exit( 1 );
        } else if (e.message == "Index was outside the bounds of the array.") {
            print( "invalid arguments" );
            Environment.Exit( 2 );
        } else {
            print ( "Error Message: " + e.message );
            print ( "Error Code: " + ( e.number & 0xFFFF ) );
            print ( "Error Name: " + e.name );
            Environment.Exit( 666 );
        }
}

function numberChecker( i:Int32 ){
    if( i > 15 || i < 0 ) {
        print("the color parameters should be numbers between 0 and 15");
        Environment.Exit(1);
    }
}


if ( arguments.length == 1 || arguments[1].toLowerCase() == "-help" || arguments[1].toLowerCase() == "-help"   ) {
    printHelp();
    Environment.Exit(0);
}

for (var arg = 1; arg <= arguments.length-1; arg++ ) {
    if ( arguments[arg].toLowerCase() == "-n" ) {
        newLine=true;
    }
    
    if ( arguments[arg].toLowerCase() == "-e" ) {
        evaluate=true;
    }
    
    if ( arguments[arg].toLowerCase() == "-s" ) {
        output=arguments[arg+1];
    }
    
    
    if ( arguments[arg].toLowerCase() == "-b" ) {
        
        try {
            backgroundColor=Int32.Parse( arguments[arg+1] );
        } catch(e) {
            errorChecker(e);
        }
    }
    
    if ( arguments[arg].toLowerCase() == "-f" ) {
        try {
            foregroundColor=Int32.Parse(arguments[arg+1]);
        } catch(e) {
            errorChecker(e);
        }
    }
}

Console.BackgroundColor = backgroundColor ;
Console.ForegroundColor = foregroundColor ;

if ( evaluate ) {
    output=decodeJsString(output);
}

if ( newLine ) {
    Console.WriteLine(output);  
} else {
    Console.Write(output);
    
}

Console.BackgroundColor = currentBackground;
Console.ForegroundColor = currentForeground;

यहाँ मदद संदेश है:

उदाहरण :

coloroutput.bat -s "aa\nbb\n\u0025cc" -b 10 -f 3 -n -e

इस स्क्रिप्ट को आप यहां देख सकते हैं ।

आप कार्लो का रंग समारोह भी देख सकते हैं -> http://www.dostips.com/forum/viewtopic.php?f=3&t=4453

— npocmaka
स्रोत

13

कितना मजेदार था वो। एक बैट फाइल जो कि इसमें मौजूद jscript को संकलित करती है और केवल तभी जब इसे ज़रूरत होती है - मैं अच्छी तरह से प्रभावित होता हूँ। यह भी नहीं पता था कि एक जावास्क्रिप्ट कंपाइलर था जिसका उपयोग करने के इंतजार में बस वहीं बैठा रहता था। आपको महीने के लिए मेरा "भयानक पुरस्कार" मिलता है। आपको यह उल्लेख करना चाहिए कि इसका पहला उपयोग धीमा होगा (संकलन के कारण)।

— ग्राहम

4

मुझे इस चरम पर जाने के लिए बुरी तरह से रंग की आवश्यकता नहीं है, लेकिन तकनीक वास्तव में प्रभावशाली है और मैं खुद को उस जगह का उपयोग करके देख सकता हूं।

— EM0

47

यह एक महान जवाब नहीं है, लेकिन अगर आपको पता है कि लक्ष्य वर्कस्टेशन में पॉवर्सशेल है तो आप ऐसा कुछ कर सकते हैं (BAT / CMD स्क्रिप्ट मानकर):

CALL:ECHORED "Print me in red!"

:ECHORED
%Windir%\System32\WindowsPowerShell\v1.0\Powershell.exe write-host -foregroundcolor Red %1
goto:eof

संपादित करें: _{^{(अब सरल!)}}

यह एक पुराना उत्तर है, लेकिन मुझे लगा कि मैं स्पष्ट करूँगा और थोड़ा सरल करूँगा

PowerShell अब 7. के बाद से विंडोज के सभी संस्करणों में शामिल है । इसलिए इस उत्तर के लिए सिंटैक्स को सरल रूप में छोटा किया जा सकता है:

पथ के बाद से यह वातावरण चर में पहले से ही किया जाना चाहिए निर्दिष्ट करने की आवश्यकता नहीं है।
असंदिग्ध आज्ञाओं को संक्षिप्त किया जा सकता है । उदाहरण के लिए आप कर सकते हैं:
- के -foreबजाय का उपयोग करें-foregroundcolor
- के -backबजाय का उपयोग करें-backgroundcolor
कमांड को मूल रूप से ' इनलाइन ' के स्थान पर इस्तेमाल किया जा सकता है echo
(ऊपर के रूप में एक अलग बैच फ़ाइल बनाने के बजाय)।

उदाहरण:

powershell write-host -fore Cyan This is Cyan text
powershell write-host -back Red This is Red background

अधिक जानकारी:

रंगों की पूरी सूची और अधिक जानकारी
- के लिए PowerShell प्रलेखन में उपलब्ध हैWrite-Host

— इयान
स्रोत

1

blogs.technet.com/b/heyscriptingguy/archive/2012/10/11/…

— CMCDragonkai

14

ग्रेटे, यह मेरे लिए काम करता है, लेकिन यह बहुत धीमा है।

— पत्नी

4

मुझे पता है कि यह एक समाधान प्रदान करने वाला उत्तर है, लेकिन शक्तियां? ओह।

— SgtPooki

2

इसलिए मैंने "यह एक महान जवाब नहीं है" के साथ शुरुआत की। मुझे पॉवरशेल काफी पसंद है लेकिन यह इसके लिए ओवरकिल है। ANSICON बेहतर है यदि आप इसे लक्ष्य मशीनों में तैनात करने के साथ सामना कर सकते हैं।

— इयान

इस उत्तर के लिए धन्यवाद। मैंने Powershell में एक बैच फ़ाइल से रंगीन आउटपुट को प्रतिध्वनित करने के तरीके के लिए उच्च और निम्न देखा है और यह केवल एक ही था। यह निश्चित नहीं है कि वास्तव में इसे प्रिंट करने में इतना समय क्यों लगता है (प्रत्येक कॉल के साथ 1 सेकंड प्रतीक्षा की तरह है) लेकिन कम से कम मैं यह कर सकता हूं। धन्यवाद!

— पीज़ाफ़िल्म्स

29

विंडोज 10 - टीएच 2 और ऊपर:

(उर्फ संस्करण १५११, १०५ ,६ का निर्माण, २०१५-११-१० रिलीज़)

कमांड प्रॉम्प्ट पर:

echo ^[[32m HI ^[[0m

वास्तविक कुंजियों का उपयोग करना: इको Ctrl+ [[32m HI Ctrl+[[0mEnter

आपको इसके नीचे एक हरे रंग का "HI" देखना चाहिए।

कोड नंबर यहां मिल सकते हैं:

https://en.wikipedia.org/wiki/ANSI_escape_code#Colors

नोटपैड:

नोटपैड में इसे बचाने के लिए, आप ईएससी का उपयोग करके इसे टाइप कर सकते हैं: Alt+ अंश के 027साथ, फिर [32mभाग। एक और चाल जब मैं लैपटॉप पर था, आरंभ करने के लिए एक फ़ाइल में ऊपर की रेखा को पुनर्निर्देशित करें, फिर कट और पेस्ट करें:

echo echo ^[[32m HI ^[[0m >> batch_file.cmd

— ग्रिंगो सुवे
स्रोत

3

Alt + 027 बिल्कुल वही था जिसकी मुझे ज़रूरत थी!

— अलेक्जेंडर स्टेलमैकज़ोनक

1

Alt + 027 ने ग्रहण / जावा में काम नहीं किया .. कोशिश भी की \033लेकिन नहीं ... मैं जावा में यह कैसे कर सकता हूं?

— derHugo

विंडोज़ 10 और इसके बाद के संस्करण पर, यह डॉस और नोटपैड ++ संपादक में काम करता है। धन्यवाद!

— जूनियर मेहे

17

आप केवल प्रिंट करने के लिए शब्द के नाम के साथ फाइल बना सकते हैं, मेज़ का उपयोग कर सकते हैं जो रंग में प्रिंट कर सकता है, और फिर फ़ाइल को मिटा देता है। इस उदाहरण का प्रयास करें:

@echo off
SETLOCAL EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (
  set "DEL=%%a"
)

call :ColorText 0a "green"
call :ColorText 0C "red"
call :ColorText 0b "cyan"
echo(
call :ColorText 19 "blue"
call :ColorText 2F "white"
call :ColorText 4e "yellow"

goto :eof

:ColorText
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1
goto :eof

Daud color /? रंग की एक सूची प्राप्त करने।

— Tutankhamen
स्रोत

3

यह विंडोज़ कमांड लाइन में रंग सेट करता है। क्या आप बता सकते हैं कि यह क्या करता है?

— फीचरच्रीप जूल

2

ठीक है, यह केवल प्रिंट करने के लिए शब्द के नाम के साथ फाइल बनाता है, म्यान का उपयोग करता है जो रंग में प्रिंट कर सकता है, और फिर फ़ाइल को मिटा देता है।

— फ़ीचरक्रीप जूल

2

यह प्रभावशाली है! ध्यान दें कि रंग कोड गलत हैं। भागो "रंग /?" वास्तविक रंग कोड देखने के लिए।

— योयो

3

ध्यान दें कि खोज केवल फ़ाइल नाम को कोलियोरिज़ कर सकती है , जिसका अर्थ है कि आप इस चाल का उपयोग अवैध पथ वर्णों के लिए नहीं कर सकते हैं।

— योयो

3

नोट के अलावा, यह उसी निर्देशिका में फ़ाइलों को अधिलेखित कर देगा यदि वे उस नाम को साझा करते हैं जिसे आप प्रिंट करने की कोशिश कर रहे हैं ... जो बिल्कुल भी अच्छा नहीं है।

— BrainSlugs83

14

आप Windows के पुराने संस्करणों में ANSI टर्मिनल कोड को सक्षम करने के लिए ANSICON का उपयोग कर सकते हैं । 32 और 64 बिट संस्करण हैं जो मैंने विंडोज एक्सपी और विंडोज 7 में उपयोग किए हैं।

— ब्रायन ऐश
स्रोत

यह विंडोज 8.1 पर काम करने के लिए नहीं मिल सकता है। मैं कोशिश और स्थापित हर दुर्घटनाग्रस्त।

— एहर्मन

@ ईमैन शायद इस सवाल से मदद करेगा।

— ब्रायन ऐश

विन 10. के बाद के संस्करणों में ANSICON की आवश्यकता नहीं है। वहां इसका उपयोग करने का प्रयास न करें।

— ग्रिंगो सुवे

6

मुझे cmd में भी उचित रंग की कमी से गुस्सा था, इसलिए मैंने आगे जाकर cmdcolor बनाया । यह सिर्फ एक स्टडआउट प्रॉक्सी है, जो एएनएसआई / वीटी 100 नियंत्रण अनुक्रमों के सीमित सेट की तलाश में है (दूसरे शब्दों में, जैसे बैश में), यानीecho \033[31m RED \033[0m DEFAULT | cmdcolor.exe ।

उपयोग और डाउनलोड ।

— एलेक मेव
स्रोत

यह अच्छा है, और मैंने इसे अपने काम पर एक विशाल बिल्ड स्क्रिप्ट के मेनू सिस्टम में डाल दिया है। केवल मेरे पास गोमांस है जो आप उस पृष्ठ पर उपलब्ध बाइनरी 64-बिट को लक्षित करते हैं, इसलिए यह हमारे 32-बिट बिल्ड मशीन पर काम नहीं करेगा। लेकिन यह सिर्फ स्रोत को हथियाने और खुद को संकलित करने में कोई समस्या नहीं थी।

— धान

लेकिन यह 32-बिट है :) यहाँ GNU फ़ाइल का आउटपुट है:cmdcolor.exe; PE32 executable for MS Windows (console) Intel 80386 32-bit

— एलेक मेव

यह अजीब है ... XP प्रो ने इसे चलाने से इनकार कर दिया, लेकिन यह मेरे Win7 64 बॉक्स पर ठीक चला। मैंने विजुअल C ++ का संकलन किया, Win32 को लक्ष्य करके, और यह ठीक था।

— धान

हुंह ... शायद इस वजह से upx। क्या आप मुझे ई-मेल के माध्यम से संपर्क कर सकते हैं, कृपया

— एलेक मेव

6

मैंने इस पर ध्यान दिया क्योंकि मैं कुछ सरल पाठ रंगों को Win7 बैच फ़ाइल में पेश करना चाहता था। मैंने ये ढूंढ निकाला। आपकी सहायता के लिए धन्यवाद।

@echo off
cls && color 08

rem .... the following line creates a [DEL] [ASCII 8] [Backspace] character to use later
rem .... All this to remove [:]
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do rem"') do (set "DEL=%%a")

echo.

<nul set /p="("
call :PainText 09 "BLUE is cold"    && <nul set /p=")  ("
call :PainText 02 "GREEN is earth"  && <nul set /p=")  ("
call :PainText F0 "BLACK is night"  && <nul set /p=")"
echo.
<nul set /p="("
call :PainText 04 "RED is blood"    && <nul set /p=")  ("
call :PainText 0e "YELLOW is pee"   && <nul set /p=")  ("
call :PainText 0F "WHITE all colors"&& <nul set /p=")"

goto :end

:PainText
<nul set /p "=%DEL%" > "%~2"
findstr /v /a:%1 /R "+" "%~2" nul
del "%~2" > nul
goto :eof

:end
echo.
pause

— निक-एन-शिकागो
स्रोत

5

पहले से ही 250 से अधिक उत्थान के साथ एक स्वीकृत उत्तर है। मैं अभी भी जो योगदान दे रहा हूं, वह हैescape गूंज के लिए आवश्यक चरित्र को कई संपादकों (मैं उपयोग कर रहा हूं, जैसे, एमएस कोड) द्वारा स्वीकार नहीं किया जाता है और अन्य सभी समाधानों के लिए सॉफ्टवेयर के कुछ तृतीय-पक्ष (गैर-विंडोज-डिफ़ॉल्ट) टुकड़ों की आवश्यकता होती है।

इसके PROMPTबजाय केवल सादे बैच कमांड का उपयोग करने के साथ काम के आसपास है ECHO। PROMPTआदेश स्वीकार करता है escapeएक के रूप में एक किसी भी संपादक के अनुकूल तरीके से चरित्र $Eचरित्र अनुक्रम। (केवल ASCII एस्केप कोडEsc में बदलें ) ।$E

यहाँ एक डेमो कोड है:

@ECHO OFF

    :: Do not pollute environment with the %prompt.bak% variable
    :: ! forgetting ENDLOCAL at the end of the batch leads to prompt corruption
    SETLOCAL

    :: Old prompt settings backup
    SET prompt.bak=%PROMPT%

    :: Entering the "ECHO"-like section

        :: Forcing prompt to display after every command (see below)
        ECHO ON

        :: Setting the prompt using the ANSI Escape sequence(s)
        :: - Always start with $E[1A, otherwise the text would appear on a next line
        :: - Then the decorated text follows
        :: - And it all ends with $E30;40m, which makes the following command invisible
        ::   - assuming default background color of the screen
        @ PROMPT $E[1A$E[30;42mHELLO$E[30;40m

        :: An "empty" command that forces the prompt to display. 
        :: The word "rem" is displayed along with the prompt text but is made invisible
        rem

        :: Just another text to display
        @ PROMPT $E[1A$E[33;41mWORLD$E[30;40m
        rem

        :: Leaving the "ECHO"-like section
        @ECHO OFF

    :: Or a more readable version utilizing the cursor manipulation ASCII ESC sequences

        :: the initial sequence
        PROMPT $E[1A
        :: formating commands
        PROMPT %PROMPT%$E[32;44m
        :: the text
        PROMPT %PROMPT%This is an "ECHO"ed text...
        :: new line; 2000 is to move to the left "a lot"
        PROMPT %PROMPT%$E[1B$E[2000D
        :: formating commands fro the next line
        PROMPT %PROMPT%$E[33;47m
        :: the text (new line)
        PROMPT %PROMPT%...spreading over two lines
        :: the closing sequence
        PROMPT %PROMPT%$E[30;40m

        :: Looks like this without the intermediate comments:
        :: PROMPT $E[1A
        :: PROMPT %PROMPT%$E[32;44m
        :: PROMPT %PROMPT%This is an "ECHO"ed text...
        :: PROMPT %PROMPT%$E[1B$E[2000D
        :: PROMPT %PROMPT%$E[33;47m
        :: PROMPT %PROMPT%...spreading over two lines
        :: PROMPT %PROMPT%$E[30;40m

        :: show it all at once!
        ECHO ON
        rem
        @ECHO OFF

    :: End of "ECHO"-ing

    :: Setting prompt back to its original value
    :: - We prepend the settings with $E[37;40m in case
    ::   the original prompt settings do not specify color
    ::   (as they don't by default).
    :: - If they do, the $E[37;40m will become overridden, anyway.
    :: ! It is important to write this command 
    ::   as it is with `ENDLOCAL` and in the `&` form.
    ENDLOCAL & PROMPT $E[37;40m%prompt.bak%

EXIT /B 0

नोट: एकमात्र दोष यह है कि यह तकनीक उपयोगकर्ता cmd रंग सेटिंग्स ( colorकमांड या सेटिंग्स) से टकराती है यदि स्पष्ट रूप से ज्ञात नहीं है।

- आशा है कि यह मदद करता है क्योंकि शुरुआत में उल्लिखित कारणों के लिए थि ही मेरे लिए स्वीकार्य एकमात्र समाधान है। -

संपादित करें:

टिप्पणियों के आधार पर, मैं @ जेब से प्रेरित एक और स्निपेट संलग्न कर रहा हूं। यह:

दिखाता है कि "Esc" चरित्र रनटाइम को कैसे प्राप्त करें और उसका उपयोग करें (एक संपादक में प्रवेश करने के बजाय) (जेब का समाधान)
"देशी" ECHOकमांड का उपयोग करता है
इसलिए यह स्थानीय PROMPTमूल्य को प्रभावित नहीं करता है
दर्शाता है कि ECHOआउटपुट को अनिवार्य रूप से रंगना PROMPTरंग को प्रभावित करता है इसलिए रंग को वैसे भी रीसेट किया जाना चाहिए

@ECHO OFF

    :: ! To observe color effects on prompt below in this script
    ::   run the script from a fresh cmd window with no custom
    ::   prompt settings

    :: Only not to pollute the environment with the %\e% variable (see below)
    :: Not needed because of the `PROMPT` variable
    SETLOCAL

        :: Parsing the `escape` character (ASCII 27) to a %\e% variable
        :: Use %\e% in place of `Esc` in the [http://ascii-table.com/ansi-escape-sequences.php]
        FOR /F "delims=#" %%E IN ('"prompt #$E# & FOR %%E IN (1) DO rem"') DO SET "\e=%%E"

        :: Demonstrate that prompt did not get corrupted by the previous FOR
        ECHO ON
        rem : After for
        @ECHO OFF

        :: Some fancy ASCII ESC staff
        ECHO [          ]
        FOR /L %%G IN (1,1,10) DO (
            TIMEOUT /T 1 > NUL
            ECHO %\e%[1A%\e%[%%GC%\e%[31;43m.
            ECHO %\e%[1A%\e%[11C%\e%[37;40m]
        )

        :: ECHO another decorated text
        :: - notice the `%\e%[30C` cursor positioning sequence
        ::   for the sake of the "After ECHO" test below
        ECHO %\e%[1A%\e%[13C%\e%[32;47mHELLO WORLD%\e%[30C

        :: Demonstrate that prompt did not get corrupted by ECHOing
        :: neither does the cursor positioning take effect.
        :: ! But the color settings do.
        ECHO ON
        rem : After ECHO
        @ECHO OFF

    ENDLOCAL

    :: Demonstrate that color settings do not reset
    :: even when out of the SETLOCAL scope
    ECHO ON
    rem : After ENDLOCAL
    @ECHO OFF

    :: Reset the `PROMPT` color
    :: - `PROMPT` itself is untouched so we did not need to backup it.
    :: - Still ECHOING in color apparently collide with user color cmd settings (if any).
    :: ! Resetting `PROMPT` color this way extends the `PROMPT`
    ::   by the initial `$E[37;40m` sequence every time the script runs.
    :: - Better solution then would be to end every (or last) `ECHO` command
    ::   with the `%\e%[37;40m` sequence and avoid setting `PROMPT` altogether.
    ::   which makes this technique preferable to the previous one (before EDIT)
    :: - I am keeping it this way only to be able to
    ::   demonstrate the `ECHO` color effects on the `PROMPT` above.
    PROMPT $E[37;40m%PROMPT%

    ECHO ON
    rem : After PROMPT color reset
    @ECHO OFF

EXIT /B 0

— PavDub
स्रोत

बहुत ही रोचक तकनीक। मैं देखूंगा कि क्या मुझे इसके साथ github.com/VonC/batcolors को अपडेट करने की आवश्यकता है। Upvoted।

— वॉन

@VonC आप केवल एक वैरिएबल बना सकते हैं, जिसमें बची हुई जीवाणुरोधी हो सकती है, बिना इसे संपादक में प्रवेश करने की आवश्यकता के बिना। for /F "delims=#" %%E in ('"prompt #$E# & for %%E in (1) do rem"') do set "\e=%%E"

— जेब

@ जेब क्या आपका मतलब है " बल्लेबाजीecho में इस्तेमाल किए जाने के विपरीत / echo.bat "?

— वॉन

@VonC हाँ, अपने के set ASCII27=←साथ बदलें for /F "delims=#" %%E in ('"prompt #$E# & for %%E in (1) do rem"') do set "ASCII27=%%E"। यह प्रॉम्प्ट कमांड द्वारा बनाए गए एस्केप कैरेक्टर का उपयोग करता है, बिना प्रॉम्प्ट के स्थायी रूप से बदले (क्योंकि promptकमांड को चाइल्ड प्रोसेस में निष्पादित किया जाता है)। Btw। आपकी echos.batकुछ अनुकूलन क्षमता है ...

— jeb

@jeb "आपका echos.bat कुछ अनुकूलन क्षमता है": मुझे यकीन है कि इसके बारे में हूँ :) पुल अनुरोध स्वागत (दोनों ASCII27 और अन्य अनुकूलन के लिए) कर रहे हैं

— VonC

4

मैं ऊपर कुछ टिप्पणियों में नोट किए गए एक मुद्दे को संबोधित करने के लिए एक उत्तर जोड़ रहा हूं: इनलाइन एएनआई रंग कोड एक लूप के अंदर (वास्तव में, कोड के किसी भी कोष्ठक के भीतर) में दुर्व्यवहार कर सकता है। .Bat कोड नीचे प्रदर्शित करता है (1) इनलाइन कलर कोड का उपयोग, (2) रंग विफलता जो इनलाइन रंग कोड का उपयोग लूप में या कोड के एक कोष्ठक के भीतर, और (3) के समाधान के लिए हो सकता है समस्या। जब .bat कोड निष्पादित होता है, तो परीक्षण 2 और 3 कलरकोड विफलता को प्रदर्शित करता है, और परीक्षण 4 में कोई विफलता नहीं दिखाई देती है क्योंकि यह समाधान को लागू करता है।

[संपादित २०२०-०४-०-07-२०१ found: मुझे एक और समाधान मिला जो संभवतः एक सबरूटीन को कॉल करने की तुलना में अधिक कुशल है। निम्न पंक्ति में, कोष्ठक में FINDSTR वाक्यांश संलग्न करें:

   echo success | (findstr /R success)

ENDEDIT]

नोट: मेरे (सीमित) अनुभव में, कोड के ब्लॉक के अंदर FINDSTR में पाइप डालने के बाद ही कलर कोड की समस्या सामने आती है। इस प्रकार निम्नलिखित .bat समस्या को पुन: पेश करता है। यह संभव है कि FINDSTR से पाइप करने के बाद रंग कोड की समस्या अधिक सामान्य हो। अगर कोई व्यक्ति समस्या की प्रकृति की व्याख्या कर सकता है, और यदि इसे हल करने का कोई बेहतर तरीका है, तो मैं इसकी सराहना करूंगा।

@goto :main
:resetANSI
EXIT /B
rem  The resetANSI subroutine is used to fix the colorcode
rem  bug, even though it appears to do nothing.

:main
@echo off
setlocal EnableDelayedExpansion

rem  Define some useful colorcode vars:
for /F "delims=#" %%E in ('"prompt #$E# & for %%E in (1) do rem"') do set "ESCchar=%%E"
set "green=%ESCchar%[92m"
set "yellow=%ESCchar%[93m"
set "magenta=%ESCchar%[95m"
set "cyan=%ESCchar%[96m"
set "white=%ESCchar%[97m"
set "black=%ESCchar%[30m"

echo %white%Test 1 is NOT in a FOR loop nor within parentheses, and color works right.
   echo %yellow%[Test 1] %green%This is Green, %magenta%this is Magenta, and %yellow%this is Yellow.
   echo %Next, the string 'success' will be piped to FINDSTR...
   echo success | findstr /R success
   echo %magenta%This is magenta and FINDSTR found and displayed 'success'.%yellow%
   echo %green%This is green.
echo %cyan%Test 1 completed.

echo %white%Test 2 is within parentheses, and color stops working after the pipe to FINDSTR.
(  echo %yellow%[Test 2] %green%This is Green, %magenta%this is Magenta, and %yellow%this is Yellow.
   echo %Next, the string 'success' will be piped to FINDSTR...
   echo success | findstr /R success
   echo %magenta%This is supposed to be magenta and FINDSTR found and displayed 'success'.
   echo %green%This is supposed to be green.
)
echo %cyan%Test 2 completed.

echo %white%Test 3 is within a FOR loop, and color stops working after the pipe to FINDSTR.
for /L %%G in (3,1,3) do (
   echo %yellow%[Test %%G] %green%This is Green, %magenta%this is Magenta, and %yellow%this is Yellow.
   echo %Next, the string 'success' will be piped to FINDSTR...
   echo success | findstr /R success
   echo %magenta%This is supposed to be magenta and FINDSTR found and displayed 'success'.
   echo %green%This is supposed to be green.
)
echo %cyan%Test 3 completed.

echo %white%Test 4 is in a FOR loop but color works right because subroutine :resetANSI is 
echo called after the pipe to FINDSTR, before the next color code is used.
for /L %%G in (4,1,4) do (
   echo %yellow%[Test %%G] %green%This is Green, %magenta%this is Magenta, and %yellow%this is Yellow.
   echo %Next, the string 'success' will be piped to FINDSTR...
   echo success | findstr /R success
   call :resetANSI
   echo %magenta%This is magenta and FINDSTR found and displayed 'success'.
   echo %green%This is green.
)
echo %cyan%Test 4 completed.%white%

EXIT /B

— डोलोरेस स्टीवंस
स्रोत

2

आप cecho का उपयोग कर सकते हैं .. आप इसे अपनी स्क्रिप्ट में सही एम्बेड करने के लिए भी उपयोग कर सकते हैं ताकि आपको एक .com या exexe साथ नहीं ले जाना पड़े।

http://www.codeproject.com/Articles/17033/Add-Colors-to-Batch-Files

— ब्रायन ग्लीसन
स्रोत

1

मैं सिर्फ विन 7 होम से विन 10 प्रो में परिवर्तित हुआ और उस बैच को बदलना चाहता हूं जिसे मैं अन्य बैचों से कॉल करता हूं जो रंग में जानकारी को प्रतिध्वनित करता है। ऊपर जो चर्चा की गई है उसकी समीक्षा करना मैं निम्नलिखित का उपयोग करता हूं जो सीधे मेरे पिछले बैच को बदल देगा। संदेश के लिए "~" के अतिरिक्त पर ध्यान दें ताकि रिक्त स्थान वाले संदेशों का उपयोग किया जा सके। कोड याद रखने के बजाय मैं अपनी जरूरत के रंगों के लिए अक्षरों का उपयोग करता हूं।

यदि% 2 में रिक्त स्थान हैं, तो "..."% 1 काले रंग पर मजबूत रंग: R = Red G = GREEN Y = YELLOW W = WHITE

ECHO OFF
IF "%1"=="R" ECHO ^[91m%~2[0m
IF "%1"=="G" ECHO ^[92m%~2[0m
IF "%1"=="Y" ECHO ^[93m%~2[0m
IF "%1"=="W" ECHO ^[97m%~2[0m

— ebloch
स्रोत

0

पाठ रंग को बदलने के लिए आपको ANSI एस्केप कोड अनुक्रम इको करने की आवश्यकता होगी: http://en.wikipedia.org/wiki/ANSI_escape_code

इन एस्केप कोड का एक और बहुत अच्छा स्रोत है http://ascii-table.com/ansi-escape-fterences.php

— बर्नहार्ड हॉफमैन
स्रोत

यह वास्तव में आशाजनक लग रहा है लेकिन मैं एस्केप चरित्र - ASCII 27 को प्रतिध्वनि कमांड में कैसे उत्सर्जित करता हूं?

— रुई

10

Windows कंसोल कोई टर्मिनल एमुलेटर नहीं है। एएनएसआई पलायन क्रम बस काम नहीं कर सकता। आप ANSI.SYS लोड करके Windows 9x को ऐसा करने में सहवास कर सकते हैं, लेकिन हम अब तक थोड़ा अतीत में हैं।

— जॉय

0

निम्न पंक्तियों को ColourText.basअपने डेस्कटॉप पर एक फ़ाइल में डालें ।

Imports System
Imports System.IO
Imports System.Runtime.InteropServices
Imports Microsoft.Win32

Public Module MyApplication  
Public Declare Function GetStdHandle Lib "kernel32" Alias "GetStdHandle" (ByVal nStdHandle As Long) As Long
Public Declare Function SetConsoleTextAttribute Lib "kernel32" Alias "SetConsoleTextAttribute" (ByVal hConsoleOutput As Long, ByVal wAttributes As Long) As Long
Public Const STD_ERROR_HANDLE = -12&
Public Const STD_INPUT_HANDLE = -10&
Public Const STD_OUTPUT_HANDLE = -11&

Sub Main()
    Dim hOut as Long
    Dim Ret as Long
    Dim Colour As Long
    Dim Colour1 As Long
    Dim Text As String
    hOut  = GetStdHandle(STD_OUTPUT_HANDLE)
    Colour = CLng("&h" & Split(Command(), " ")(0))
    Colour1 = Clng("&h" & Split(Command(), " ")(1))
    Text = Mid(Command(), 7)
    Ret = SetConsoleTextAttribute(hOut,  Colour)
    Console.Out.WriteLine(text)
    Ret = SetConsoleTextAttribute(hOut, Colour1)
End Sub
End Module

इसे सहेजें और कमांड प्रॉम्प्ट में निम्न टाइप करें।

"C:\Windows\Microsoft.NET\Framework\v4.0.30319\vbc.exe" /target:exe /out:"%userprofile%\desktop\ColourText.exe" "%userprofile%\desktop\ColourText.bas" /verbose

ColourText.exe नामक एक फ़ाइल आपके डेस्कटॉप पर दिखाई देगी। इसे विंडोज फोल्डर में ले जाएं ।

उपयोग करने के लिए आपको रंग सेट करने के लिए दो वर्ण कोड का उपयोग करना चाहिए जैसे कि 01नहीं 1।

ColourText ColourOfText ColourOfTextWhenFinished Text

ईजी किसी भी पाठ को पारित नहीं करके सफेद पर नीला सेट करने के लिए, फिर सफेद पाठ पर लाल, ग्रे पर नीले रंग के साथ परिष्करण।

ColourText F1 F1
ColourText F2 71 This is green on white

या

ColourText F1 F1
cls
ColourText F4 F4
Echo Hello
Echo Hello today
ColourText F1 F1

साथ ही CLSकमांड रोचक हो जाती है। Colorपैरामीटर के बिना कमांड सभी रंगों को स्टार्टअप रंगों में रीसेट करता है।

रंग कोड प्राप्त करने के लिए निम्नलिखित संख्याओं को एक साथ जोड़ें। प्रोग्रामर मोड में कैलकुलेटर का उपयोग करें। ये हेक्स संख्या हैं। उन्हें एक साथ जोड़ा जा सकता है जैसे रेड + ब्लू + एफजी इंटेंसिटी = 13 = डी। जैसा कि 10+ का उपयोग नहीं किया गया था, पृष्ठभूमि काली होगी। रंग कोड दो वर्ण होना चाहिए, उदाहरण के लिए 08नहीं 8।

FOREGROUND_RED = &H4     '  text color contains red.
FOREGROUND_INTENSITY = &H8     '  text color is intensified.
FOREGROUND_GREEN = &H2     '  text color contains green.
FOREGROUND_BLUE = &H1     '  text color contains blue.
BACKGROUND_BLUE = &H10    '  background color contains blue.
BACKGROUND_GREEN = &H20    '  background color contains green.
BACKGROUND_INTENSITY = &H80    '  background color is intensified.
BACKGROUND_RED = &H40    '  background color contains red.

2

जबकि दिलचस्प है, हर किसी को एसडीके स्थापित नहीं होगा, वास्तव में, बहुत कम लोग, मुझे लगता है।

— हाबिल

0

विंडोज 10 पर यह काम करने के लिए, आप इस ध्वज को सक्षम कर सकते हैं ENABLE_VIRTUAL_TERMINAL_PROCESSING:।

इस रजिस्ट्री कुंजी के साथ आप इसे डिफ़ॉल्ट रूप से सेट कर सकते हैं

[HKCU\Console] VirtualTerminalLevel dword 0x1

— मिशेल डी ग्रूट
स्रोत

0

एक विकल्प NodeJS का उपयोग करना है ।

यहाँ एक उदाहरण है:

const os = require('os');
const colors = require('colors');

console.log("Operative System:".green,os.type(),os.release());
console.log("Uptime:".blue,os.uptime());

और यह परिणाम है:

— Josem
स्रोत

0

जैसा कि ग्लेन स्लेडेन ने इस उत्तर में कहा , आप cmd को "अधिक रंगीन" बनाने के लिए रजिस्ट्री में उचित मूल्य जोड़ सकते हैं।

सौभाग्य से, वैश्विक डिफ़ॉल्ट को ऑप्ट-इन से ऑप्ट-आउट में बदला जा सकता है। HKEY_CURRENT_USER \ Console \ VirtualTerminalLevel पर रजिस्ट्री कुंजी ANSI एस्केप दृश्यों को संसाधित करने के लिए वैश्विक डिफ़ॉल्ट व्यवहार सेट करती है। एक DWORD कुंजी बनाएं (यदि आवश्यक हो) और इसके मूल्य को 1 से विश्व स्तर पर सक्षम करें (या 0 को अक्षम करने के लिए) डिफ़ॉल्ट रूप से ANSI प्रसंस्करण।

— torswq
स्रोत

0

पावरशेल में लॉग स्टेटमेंट के लिए रंग सेट करना कोई बड़ी बात नहीं है। आप -ForegroundColorपैरामीटर का उपयोग कर सकते हैं ।

एक पुष्टिकरण संदेश लिखने के लिए।

Write-Host "Process executed Successfully...." -ForegroundColor Magenta

त्रुटि संदेश लिखने के लिए।

Write-Host "Sorry an unexpected error occurred.." -ForegroundColor Red

एक प्रगति संदेश लिखने के लिए ।

Write-Host "Working under pocess..." -ForegroundColor Green

— Bug_
स्रोत

0

call :color_echo "blue" "blue txt"
call :color_echo "red" "red txt"
echo "white txt"


REM : https://www.robvanderwoude.com/ansi.php
:color_echo
    @echo off

    set "color=%~1"
    set "txt=%~2"

    set ESC=
    set black=%ESC%[30m
    set red=%ESC%[31m
    set green=%ESC%[32m
    set yellow=%ESC%[33m
    set blue=%ESC%[34m
    set magenta=%ESC%[35m
    set cyan=%ESC%[36m
    set white=%ESC%[37m

    if "%~1" == "black"   set "color=!black!"
    if "%~1" == "red"     set "color=!red!"
    if "%~1" == "green"   set "color=!green!"
    if "%~1" == "yellow"  set "color=!yellow!"
    if "%~1" == "blue"    set "color=!blue!"
    if "%~1" == "magenta" set "color=!magenta!"
    if "%~1" == "cyan"    set "color=!cyan!"
    if "%~1" == "white"   set "color=!white!"

    echo | set /p="!color!!txt!"
    echo.

    REM : return to standard white color
    echo | set /p="!white!"

    REM : exiting the function only
    EXIT /B 0

— जमालेदीन आमिर
स्रोत

%ESC%खाली है, इसलिए यह काम नहीं करेगा। echo !white!सफेद रंग सेट करता है। डिफ़ॉल्ट रंगों पर लौटने के लिए (जो भी उपयोगकर्ता इसके लिए हैं): colorपैरामीटर के बिना कमांड ऐसा करता है।

— स्टीफन

-1

हम एएनएसआई टर्मिनल कोड के साथ ऐसा करते थे । यकीन नहीं है कि वे अभी भी काम करते हैं, लेकिन आप उन्हें आज़मा सकते हैं।

— माइकल जे
स्रोत

1

यह एक अच्छा जवाब हो सकता है अगर यह समझाया जाए कि इन एएनएसआई टर्मिनल कोड का उपयोग कैसे किया जाए ...

— Davor

1

मुझे लगा कि मैंने इसे समझाने के लिए जो लेख जोड़ा है। क्या आपने उसे पढ़ा? BTW: यह कहता है कि वे win32 पर काम नहीं करते हैं।

— माइकल जे।

तिरछे। लेख बताता है कि एएनएसआई टर्मिनल कोड क्या हैं, लेकिन वास्तव में उन्हें cmd के भीतर से कैसे उपयोग किया जाए, इसलिए सवाल का जवाब देने के लिए। (हां ... यह तथ्य कि Win32 कंसोल समर्थित नहीं है, यह सवाल के लिए उन्हें थोड़ा अप्रासंगिक बनाता है।)

— जोसफोविक

1

आप टर्मिनल पर ANSI कोड्स को प्रतिध्वनित करेंगे। उदाहरण के लिए "इको m [6m" टर्मिनल के टेक्स्ट का रंग 6 (लाल) पर सेट करेगा। नोट ")" ASCII 27 (बच) है। आप इसे "ALT" दबाकर और संख्यात्मक कीपैड पर "27" लिखकर टाइप कर सकते हैं। मैंने अभी इसे देखा और पाया कि आप अभी भी "रंग" कमांड का उपयोग एक ही काम करने के लिए कर सकते हैं (हालांकि संख्यात्मक कोड अलग हैं)। "रंग 4" आपको लाल पाठ मिलता है।

— माइकल जे

-6

आप पूरे कंसोल का रंग बदलने के लिए कलर कमांड का उपयोग कर सकते हैं

Color 0F

काला और सफेद है

Color 0A

काला और हरा है

— दान तौरो
स्रोत

20

जानकर अच्छा लगा। दुर्भाग्य से इससे पूरे कंसोल का रंग बदल जाता है और सवाल यह है कि सिंगल लाइन (या इसका एक हिस्सा) कैसे बदला जाए ..

— ल्यूक

6

ओपी ने कहा है कि वह इस आदेश से परिचित है और समस्या यह है कि यह पूरे कंसोल को बदलता है न कि एक विशिष्ट लाइन को।

— रान्डेल फ्लैग

5

हाँ वास्तव में वास्तव में उत्तरदायी नहीं है, लेकिन यह जानना अभी भी उपयोगी है।

— क्यूरियसार्क

विंडोज कमांड लाइन में विभिन्न रंगों से गूंज कैसे करें

संपादित करें: (अब सरल!)

उदाहरण:

अधिक जानकारी:

संपादित करें: _{^{(अब सरल!)}}