मुझे फ़ाइल / फ़ोल्डर नाम में उपयोग के लिए उपयुक्त प्रारूप में विंडोज कमांड लाइन पर वर्तमान दिनांक / समय कैसे मिलता है?

539

अद्यतन: अब जब कि यह २०१६ है, मैं इसके लिए पॉवरशेल का उपयोग करूंगा, जब तक कि इसके लिए वास्तव में सम्मोहक पीछे-संगत कारण न हो, विशेष रूप से क्षेत्रीय सेटिंग्स समस्या के कारण date। @ Npocmaka का https://stackoverflow.com/a/19799236/8479 देखें

विंडोज कमांड लाइन स्टेटमेंट क्या है? मैं वर्तमान डेटाइम को एक प्रारूप में प्राप्त करने के लिए उपयोग कर सकता हूं जिसे मैं फ़ाइल नाम में डाल सकता हूं?

मैं एक .bat फ़ाइल उस नाम का हिस्सा है, उदाहरण के लिए के रूप में वर्तमान दिनांक और समय के साथ एक संग्रह में एक निर्देशिका ऊपर से ज़िप करना चाहते हैं Code_2008-10-14_2257.zip। क्या कोई आसान तरीका है जो मैं यह कर सकता हूं, मशीन की क्षेत्रीय सेटिंग्स से स्वतंत्र?

मैं वास्तव में तारीख प्रारूप के बारे में बुरा नहीं मानता, आदर्श रूप से यह yyyy-mm-dd होगा, लेकिन कुछ भी सरल ठीक है।

अब तक मुझे यह मिल गया है, जो मेरी मशीन पर मुझे देता है Tue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

मैं इसके साथ रह सकता हूं, लेकिन यह थोड़ा भद्दा लगता है। आदर्श रूप से यह ब्रीफ़र होगा और पहले उल्लेखित प्रारूप होगा।

मैं Windows Server 2003 और Windows XP Professional का उपयोग कर रहा हूं। मैं इसे प्राप्त करने के लिए अतिरिक्त उपयोगिताओं को स्थापित नहीं करना चाहता हूं (हालांकि मुझे एहसास है कि कुछ ऐसे हैं जो अच्छी तारीख स्वरूपण करेंगे)।

— रोरी
स्रोत

7

अपने कोड के लिए एक स्वचालित बैकअप बनाना? आपके लिए अच्छा हैं! हमें यह भी करना चाहिए :)

— आंद्रेई रैनिया

24

लोगों का उपयोग करें ...[datetime]::now.tostring("yyyy-MM-dd")

— Nacht - Monica

SQL सर्वर में xp_cmdshell का उपयोग करके बनाई गई तारीख के साथ फाइल लोड करना संभव है? मैंने stackoverflow पर एक प्रश्न पूछा है, कृपया लिंक @ stackoverflow.com/q/32293517/3327081 देखें

— kolunar

667

MMDDYYYY प्रारूप में वर्तमान दिनांक प्राप्त करने के लिए Windows बैच फ़ाइल (.bat) देखें :

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

यदि आप 24 घंटे / सैन्य प्रारूप में समय पसंद करते हैं, तो आप दूसरी पंक्ति को इसके साथ बदल सकते हैं:

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

C:>। \ Date.bat
2008-10-14_0642

यदि आप इस क्षेत्र के दिन / महीने के आदेश के लिए स्वतंत्र रूप से तारीख चाहते हैं, तो आप "WMIC OS GET लोकल डेटाइम" का उपयोग एक स्रोत के रूप में कर सकते हैं, क्योंकि यह आईएसओ क्रम में है:

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

C:> test.cmd
स्थानीय तिथि है [2012-06-19 10: 23: 47.048]

— नीलकंठ
स्रोत

44

ब्रिटेन के लोगों के लिए आप For /f "tokens=1-3 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%b-%%a)दूसरी पंक्ति चाहते हैं ।

— रोरी

17

यह समाधान स्थानीय निर्भर है, रोरी ने अन्य स्थानों के लिए यूके के लिए उदाहरण दिया, जहां तारीख 22-02-2012 आती है, आपको डेलिम्स को बदलने की आवश्यकता है = / delims के साथ = -

— नूनो फर्टाडो

25

मेरे सिस्टम पर% TIME% "0:01:15" और "3:15:12" जैसे मान लौटाता है और उत्तर में %% %% b कोड "001" और "315" जैसे अग्रणी स्थान देता है। चार अंकों के hhmm का उपयोग करने के लिए: For /f "tokens=1-2 delims=/: " %%a in ("%TIME%") do (if %%a LSS 10 (set mytime=0%%a%%b) else (set mytime=%%a%%b))यह "0001" और "0315" जैसे मान लौटाता है, जिसे मैं अपने फ़ाइल नाम में पसंद करता हूं।

— ट्वामले

10

wmicकमांड का अच्छा संस्करण ! अभी तक मैंने केवल देखा है WMIC Path Win32_LocalTime Get Day,Hour,Minute,Month,Second,Year /Format:table। इसी तरह, 20120623-1619मेरे स्थानीय एम्स्टर्डम समय क्षेत्र में, एक लाइन में पाने के लिए:for /f %%a in ('wmic os get LocalDateTime ^| findstr ^[0-9]') do (set ts=%%a) & set datetime=%ts:~0,8%-%ts:~8,4%

— अर्जन

5

मेरे लिए यह कहता है%%a was unexpected at this time.

— स्कॉट zuz22 Blacklock

109

समय-समय पर स्वतंत्र तिथि पार्सिंग

कमांड का %DATE%और आउटपुट आउटपुट dirक्षेत्रीय रूप से निर्भर है और इस प्रकार न तो मजबूत और न ही स्मार्ट है। date.exe ( UnxUtils का हिस्सा ) किसी भी विचारशील प्रारूप में किसी भी तारीख और समय की जानकारी देता है। आप किसी भी फ़ाइल से दिनांक / समय की जानकारी भी निकाल सकते हैं date.exe।

उदाहरण: (cmd- स्क्रिप्ट में% के बजाय %% का उपयोग करें)

date.exe +"%Y-%m-%d"
2009/12/22

date.exe +"%T"
18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
20091222 185503: कोई भी पाठ

date.exe +"Text: %y/%m/%d-any text-%H.%M"
पाठ: 09/12/22-कोई भी पाठ -18.55

Command: date.exe +"%m-%d """%H %M %S """"
07-22 "18:55:03" `

संदर्भ फ़ाइल से दिनांक / समय की जानकारी:
date.exe -r c:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

वर्ष, माह, दिन, समय की जानकारी प्राप्त करने के लिए CMD स्क्रिप्ट में इसका उपयोग करना:

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

किसी भी आवश्यक प्रारूप में टाइमस्टैम्प प्राप्त करने के लिए CMD स्क्रिप्ट में इसका उपयोग करना:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

किसी भी संदर्भ फ़ाइल से दिनांक / समय की जानकारी निकालना।

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

फ़ाइल को उसकी तिथि / समय की जानकारी में जोड़ना:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe नि: शुल्क GNU टूल्स का हिस्सा है, जिन्हें किसी इंस्टॉलेशन की आवश्यकता नहीं है।

नोट: date.exeखोज पथ में है जो किसी भी निर्देशिका में प्रतिलिपि बनाने से अन्य स्क्रिप्ट्स विफल हो सकती हैं जो Windows अंतर्निहित dateकमांड का उपयोग करती हैं ।

— उरी लिबासिंड
स्रोत

4

ऊपर अजीब तरह से अधिक लोकप्रिय समाधान की तुलना में बेहतर है, लेकिन मुझे विंडोज 8.1 पर प्रॉम्प्ट से बचने के लिए / टी जोड़ना पड़ा

— रेनबा

6

बिल्ट-इन विंडोज 8.1 date.exeलोकल डिपेंडेंट लगता है। यह मेरे सिस्टम पर dd / MM / yyyy में तारीख लौटाता है, अगर यह लोकेल-इंडिपेंडेंट होता तो मैं MM / dd / yyyy या yyyy-MM-dd की उम्मीद करता। मुझे नहीं लगता कि यह उत्तर बिल्ट-इन date.exe के बारे में बात कर रहा है, लेकिन इसके कुछ तृतीय-पक्ष संस्करण हैं।

— एसएसएस

1

यह स्थानीय स्वतंत्र है यदि आप इसे कमांड लाइन पर वांछित प्रारूप के साथ प्रदान करते हैं

— terinecold

3

कृपया ध्यान दें कि date.exe (UnxUtils का हिस्सा) बिल्ड-इन डेट कमांड के समान नहीं है। इसलिए यदि आपको विंडोज़ डेट कमांड को जोड़ना / टी करना है तो निष्पादित किया जाता है। यदि date.exe + "% Y-% m-% d" जैसे कुछ काम करता है, तो आपने UnxUtils को सही तरीके से स्थापित किया है। :-)

— just.do.it

SQL सर्वर में xp_cmdshell का उपयोग करके बनाई गई तारीख के साथ फाइल लोड करना संभव है? मैंने "forfiles" कमांड की कोशिश की है, लेकिन कोई फायदा नहीं हुआ। मैंने stackoverflow पर एक प्रश्न पूछा है, कृपया लिंक @ stackoverflow.com/q/32293517/3327081

— kolunar

103

दो और तरीके जो समय सेटिंग्स पर निर्भर नहीं करते हैं (दोनों से लिया गया है : स्थानीयकरण से स्वतंत्र डेटा / समय कैसे प्राप्त करें:) । और दोनों को सप्ताह के दिन भी मिलते हैं और उनमें से किसी को भी व्यवस्थापक अनुमति की आवश्यकता नहीं है! "

MAKECAB - हर विंडोज सिस्टम पर काम करेगा (तेजी से, लेकिन एक छोटी सी टेम्प फाइल बनाता है) (फॉक्सड्राइव स्क्रिप्ट):
```
@echo off
pushd "%temp%"
makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
   set "current-date=%%e-%%b-%%c"
   set "current-time=%%d"
   set "weekday=%%a"
)
del ~.*
popd
echo %weekday% %current-date% %current-time%
pause
```
Get-date फ़ंक्शन के बारे में अधिक जानकारी ।
ROBOCOPY - यह Windows XP और Windows Server 2003 के लिए मूल कमांड नहीं है, लेकिन इसे Microsoft साइट से डाउनलोड किया जा सकता है । लेकिन विंडोज विस्टा और इसके बाद के संस्करण की सभी चीजों में अंतर्निहित है:
```
@echo off
setlocal
for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
 set "dow=%%D"
 set "month=%%E"
 set "day=%%F"
 set "HH=%%G"
 set "MM=%%H"
 set "SS=%%I"
 set "year=%%J"
)

echo Day of the week: %dow%
echo Day of the month : %day%
echo Month : %month%
echo hour : %HH%
echo minutes : %MM%
echo seconds : %SS%
echo year : %year%
endlocal
```
और तीन और तरीके जो अन्य विंडोज स्क्रिप्ट भाषाओं का उपयोग करते हैं। वे आपको अधिक लचीलापन देंगे जैसे कि आप वर्ष के सप्ताह, मिलिसेकंड में समय और इतने पर प्राप्त कर सकते हैं।

JScript / बैच हाइब्रिड (के रूप में सहेजा जाना चाहिए .bat)। JScript विंडोज सिस्टम होस्ट के एक भाग के रूप में NT और उससे अधिक के हर सिस्टम फॉर्म पर उपलब्ध है ( हालाँकि रजिस्ट्री के माध्यम से इसे दुर्लभ मामला माना जा सकता है ):

@if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment

@echo off
cscript //E:JScript //nologo "%~f0"
exit /b 0
*------------------------------------------------------------------------------*/

function GetCurrentDate() {
        // Today date time which will used to set as default date.
        var todayDate = new Date();
        todayDate = todayDate.getFullYear() + "-" +
                       ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                       ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                       ("0" + todayDate.getMinutes()).slice(-2);

        return todayDate;
    }

WScript.Echo(GetCurrentDate());

VSCRIPT / BATCH हाइब्रिड ( क्या यह एक अस्थायी फ़ाइल का उपयोग किए बिना बैच फ़ाइल के भीतर VBScript को एम्बेड और निष्पादित करना संभव है? ) JScript के समान मामला, लेकिन संकरण इतना सही नहीं है:

:sub echo(str) :end sub
echo off
'>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
'& echo current date:
'& cscript /nologo /E:vbscript "%~f0"
'& exit /b

'0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
'1 = vbLongDate - Returns date: weekday, monthname, year
'2 = vbShortDate - Returns date: mm/dd/yy
'3 = vbLongTime - Returns time: hh:mm:ss PM/AM
'4 = vbShortTime - Return time: hh:mm

WScript.echo  Replace(FormatDateTime(Date,1),", ","-")

PowerShell - प्रत्येक मशीन पर स्थापित किया जा सकता है जिसमें .NET है - Microsoft से डाउनलोड करें ( v1 , v2 , v3 (केवल विंडोज 7 और इसके बाद के संस्करण के लिए))। यह विंडोज 7 / विंडोज सर्वर 2008 और इसके बाद के संस्करण की हर चीज पर डिफ़ॉल्ट रूप से स्थापित है:
```
C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
```
बैच फ़ाइल से इसका उपयोग करने के लिए:
```
for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
```

स्व-संकलित jscript.net/batch (बिना .NET के विंडोज मशीन कभी नहीं देखी गई, इसलिए मुझे लगता है कि यह एक बहुत ही पोर्टेबल है):

@if (@X)==(@Y) @end /****** silent line that start JScript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       Compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"

:: Searching the latest installed .NET framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       End of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation

"%~n0.exe"

exit /b 0


****** End of JScript comment ******/
import System;
import System.IO;

var dt=DateTime.Now;
Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));

लोगमैन यह सप्ताह का वर्ष और दिन नहीं मिल सकता है। यह तुलनात्मक रूप से धीमा है और एक अस्थायी फ़ाइल भी बनाता है और यह उस समय के टिकटों पर आधारित है जो लॉगमैन अपनी लॉग फ़ाइलों पर डालता है। यह विंडोज एक्सपी और उससे ऊपर की सभी चीजों पर काम करेगा। यह शायद कभी भी किसी के द्वारा उपयोग नहीं किया जाएगा - मेरे सहित - लेकिन एक और तरीका है ...
```
@echo off
setlocal
del /q /f %temp%\timestampfile_*

Logman.exe stop ts-CPU 1>nul 2>&1
Logman.exe delete ts-CPU 1>nul 2>&1

Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
Logman.exe start ts-CPU 1>nul 2>&1

Logman.exe stop ts-CPU >nul 2>&1
Logman.exe delete ts-CPU >nul 2>&1
for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t

echo %timestamp%
echo MM: %timestamp:~0,2%
echo dd: %timestamp:~2,2%
echo hh: %timestamp:~4,2%
echo mm: %timestamp:~6,2%

endlocal
exit /b 0
```
WMIC के साथ एक और तरीका जो वर्ष के सप्ताह और सप्ताह का दिन भी देता है, लेकिन मिलीसेकंड नहीं (मिलीसेकंड के लिए foxidrive के उत्तर की जांच करें):
```
for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
echo %day%
echo %DayOfWeek%
echo %hour%
echo %minute%
echo %month%
echo %quarter%
echo %second%
echo %weekinmonth%
echo %year%
```

TYPEPERF का उपयोग विभिन्न भाषा सेटिंग्स के साथ तेज और संगत होने के लिए कुछ प्रयासों के साथ और जितनी जल्दी हो सके:

@echo off
setlocal

:: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")

for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
set "mon="
for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
   if not defined mon (
      for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
        set mon=%%a
        set date=%%b
        set year=%%c
        set hour=%%d
        set minute=%%e
        set sec=%%f
        set ms=%%g
      )
   )
)
echo %year%.%mon%.%date%
echo %hour%:%minute%:%sec%.%ms%
endlocal

MSHTA ऊपर # 3 में प्रदर्शित JScript विधि के समान जावास्क्रिप्ट विधियों को कॉल करने की अनुमति देता है। इस बात को ध्यान में रखें कि जावास्क्रिप्ट वैल्यू ऑब्जेक्ट में महीने के मान शामिल होते हैं, जिनकी संख्या 0 से 11 तक होती है, न कि 1 से 12. इसलिए 9 का मान अक्टूबर का मतलब है।

<!-- : Batch portion

@echo off
setlocal

for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"

rem Display all variables beginning with "now."
set now.

goto :EOF

end batch / begin HTA -->

<script>
    resizeTo(0,0)
    var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
        now = new Date(),
        props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
            'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
            'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
            'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
            'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
        output = [];

    for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
    close(fso.Write(output.join('\n')));
</script>

— npocmaka
स्रोत

2

शक्तियां C: \> के लिए / f %% में i ('शक्तियां प्राप्त करें-दिनांक -रूपात "{yyyyMMdd_HHmmss" ") सेट डेटाइम = %% i C: \> गूंज% डेटाइम%

— सैमुअल

1

makecab: यह नामक एक फाइल बनाकर काम करता है ~.rpt, और stringइसके अंदर खोज करता है makecab, जिसके साथ शुरुआत होती है , जो एक लाइन है MakeCAB Report: Tue Sep 02 22:15:57 2014। मेरे लिए यह आदेश स्थानीय नहीं है यह स्थानीय स्वतंत्र है। यह ट्रिक उसी पर निर्भर है। चलो आशा करते हैं कि यह कभी नहीं होगा, अन्यथा सावधान रहें!

— n611x007

10

मैं शुरुआती पाठ "दो और ..." का आनंद लेता हूं और इसके बाद 8 समाधान करता हूं।

— एडम स्मिथ

1

क्या, कोई mshtaसंकर नहीं ? :) मन अगर मैं आपके जवाब को संपादित करने और एक जोड़? यह गूढ़ समाधानों का सबसे अच्छा संग्रह प्रतीत होता है, और ऐसा लगता है कि mshtaयहां से संबंधित है।

— रोजो

1

स्वीकृत समाधान मेरे लिए काम नहीं करेगा चाहे मैंने कोई भी कोशिश की हो। इनमें से कई समाधानों ने मेरे लिए काम किया। (बैच और पॉवरशेल)।

— ब्रेट वेट

44

यहाँ alt.msdos.batch.nt का एक संस्करण है जो स्थानीय-स्वतंत्र रूप से काम करता है।

इसे टेक्स्ट फाइल में रखें, जैसे getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

काम करने के लिए कोड पाने के लिए sans error msg's to stderr, मुझे वेरिएबल असाइनमेंट को %% a, %% b और %% c के लिए सिंगल कोट्स में जोड़ना था। मेरा स्थान (पीटी) लूपिंग / पार्सिंग में एक चरण में त्रुटियां पैदा कर रहा था जहां "सेट = 20" जैसे सामान को निष्पादित किया जा रहा था। असाइनमेंट स्टेटमेंट के बाएं हिस्से के लिए उद्धरण एक टोकन (खाली जगह) देते हैं।

नकारात्मक पक्ष गन्दा स्थानीय चर नाम है: 'yy', 'mm' और 'dd'। लेकिन हे, कौन परवाह करता है!

— VMAX
स्रोत

3

यह एकदम सही है और सबसे सरल और सबसे सुंदर दृष्टिकोण है जिसे मैंने आज तक देखा है।

— डग

2

यह भी देखें कि जेरेन के संवर्द्धन की जरूरत है, क्योंकि सभी स्थानों में तार का उपयोग नहीं किया जाता है dd, mmऔर yyआउटपुट में echo:^|date।

— अर्जन

सभी स्थानों पर काम नहीं करता है। (जर्मन में dateदेता है Geben Sie das neue Datum ein: (TT-MM-JJ), जहां JJआपकी स्क्रिप्ट को तोड़ता है (उम्मीद करता है YY))

— स्टीफन

35

मैं इसका उपयोग करता हूं (फिर से स्वतंत्र नहीं (यूके)

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%

— नीला सा
स्रोत

देखें बृहदान्त्र और टिल्ड साथ Cmd.exe पर्यावरण चर इस छोटे से जाना जाता है लेकिन बहुत ही कुशल तकनीक पर। (Microsoft आधिकारिक संदर्भ के लिए एक सूचक की सराहना की जाएगी।)

— डेविड आरआर

यहाँ Windows XP के लिए Microsoft का बैच फ़ाइल संदर्भ है । उस संदर्भ में बैच मापदंडों का उपयोग करना शामिल है । दुर्भाग्य से, 'स्लाइसिंग' तकनीक की कोई चर्चा नहीं हुई।

— डेविड आरआर

यह मेरे लिए काफी काम नहीं करता है। शायद यह क्षेत्रीय सेटिंग्स के साथ कुछ करना है? मुझे "/ 15 / - 1-We_1009" का आउटपुट मिलता है जब इसे बुधवार, 15 अक्टूबर 2014 को चलाते हैं।

— जोएल बी

26

इस कोड की पहली चार पंक्तियाँ आपको Windows XP प्रोफेशनल और उच्चतर में विश्वसनीय YY DD MM YYYY HH मिन सेक चर प्रदान करेंगी।

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

— foxidrive
स्रोत

बिल्कुल सही, यह मेरे लिए सबसे अच्छा समाधान है क्योंकि पीएस को कॉल करने से सीएमडी पाठ की उपस्थिति के परिणामस्वरूप अजीब लग रही होगी।

— Ste

25

दुर्भाग्य से यह क्षेत्रीय सेटिंग्स के लिए प्रतिरक्षा नहीं है, लेकिन यह वही करता है जो आप चाहते हैं।

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

कमाल का सामान आप विकिपीडिया पर पा सकते हैं ।

— मार्क रैनसम
स्रोत

1

मार्क - कोलोन और टिल्ड के साथ Cmd.exe पर्यावरण चर पाया गया, जो आपके उत्तर में प्रदर्शित चर 'स्लाइसिंग' तकनीक का वर्णन करता है। विकिपीडिया लेख में अब वह जानकारी नहीं मिल रही है। Microsoft से एक आधिकारिक संदर्भ खोजना चाहेंगे।

— डेविड आरआर

1

यहाँ Windows XP के लिए Microsoft का बैच फ़ाइल संदर्भ है । उस संदर्भ में बैच मापदंडों का उपयोग करना शामिल है । दुर्भाग्य से, 'स्लाइसिंग' तकनीक की कोई चर्चा नहीं हुई।

— डेविड आरआर

18

कमांड लाइन में वर्तमान दिन प्राप्त करने के लिए कृपया निम्न स्क्रिप्ट का उपयोग करें:

echo %Date:~0,3%day

— सुडिप्टो रो
स्रोत

8

इसके साथ थोड़ा इधर-उधर खेला, यह मुझे दिनांक और समय मिलने वाला सबसे छोटा समय है: इको% तारीख%% समय%%

— loomi

15

दूसरा तरीका ( क्रेडिट ):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

ध्यान दें कि मेरे दोनों उत्तर यहां अभी भी क्षेत्रीय सेटिंग्स द्वारा निर्धारित दिन और महीने के क्रम पर निर्भर हैं - यह सुनिश्चित नहीं है कि इसके आसपास कैसे काम करें।

— जे सी
स्रोत

14

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

— DigiP
स्रोत

http://www.dotnetperls.com/7-zip-examplesकुछ अच्छे अंक भविष्य में किसी एक के लिए उपयोगी हो सकते हैं।

— सरवनन

13

यह वास्तव में दुखद नहीं है, लेकिन अधिक लचीला तरीका ( क्रेडिट ) हो सकता है :

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

— जे सी
स्रोत

10

यहां एक पंक्ति में दिनांक समय प्राप्त करने का एक तरीका है:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

अमेरिका में यह "yyyy-mm-dd hhmm" का उत्पादन करेगा। विभिन्न क्षेत्रीय सेटिंग्स का परिणाम अलग-अलग% दिनांक% आउटपुट में होगा, लेकिन आप टोकन ऑर्डर को संशोधित कर सकते हैं।

यदि आप एक अलग प्रारूप चाहते हैं, तो टोकन को पुन: व्यवस्थित करके या अलग (या नहीं) विभाजकों का उपयोग करके इको स्टेटमेंट को संशोधित करें।

— मैथ्यू जॉनसन
स्रोत

क्या 12 घंटे के प्रारूप में समय प्राप्त करने और एएम या पीएम की जानकारी प्रदर्शित करने का भी कोई तरीका है?

— सांगली

9

बस इस लाइन का उपयोग करें:

PowerShell -Command "get-date"

— gdelfino
स्रोत

9

संक्षिप्त जवाब :

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result

लंबा जवाब

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

— यॉर्डन जॉर्जिएव
स्रोत

:: cmd में / f% i के लिए ('PowerShell -Command "get-date" -format "yyyMMdd"')) yyyMMdd =% i सेट करें: / f% i ('PowerShell -Command) के लिए cmd स्क्रिप्ट में "get-date" -फॉर्मेट "yyyyMMdd" ') do yyyMMdd = %% मैं निर्धारित करता हूं

— Yordan Georgiev

8

मैथ्यू जॉनसन का वन- लाइनर दिनांक और समय प्राप्त करने का वन-लाइनर समाधान वाक्पटु और उपयोगी है।

हालांकि इसे एक बैच फ़ाइल के भीतर से काम करने के लिए एक सरल संशोधन की आवश्यकता होती है:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

— जॉन लैंगस्टाफ
स्रोत

1

सीएमडी में काम नहीं करता है (%% इस समय अप्रत्याशित था) या विंडोज 8.1 पर

— पावरशेल

3

रेनबा, ठीक यही त्रुटि आपको तब होती है जब उस कमांड को सीएमडी लाइन से जारी किया जाता है । हालांकि, " एक बैच फ़ाइल के भीतर " से , कमांड "2014-01-30 1324" देता है।

— जॉन लैंगस्टैफ

1

या बहुत सरल लूप के लिए बिना होगाecho %date:/=-%%time::=-%

— गेरहार्ड बरनार्ड

7

और यहाँ समय भाग के लिए एक समान बैच-फ़ाइल है।

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen

— जीरो वेर्ट प्ल्यूमर
स्रोत

नमस्ते, मैं नीचे एक कमांड का उपयोग करके संशोधित तिथि के अनुसार फ़ाइलों को लोड करने में सक्षम था, z: & forfiles /m *.jpg /s /d 07/16/2015 /c “cmd /c echo @fdate @ftime @path” लेकिन मुझे पता है कि क्रिएटेड तिथि के अनुसार फ़ाइलों को कैसे लोड करना है। किसी भी मदद को बहुत सराहा जाएगा। स्टैकओवरफ़्लो पर एक प्रश्न पूछा गया है, लेकिन अभी तक कोई जवाब नहीं है। कृपया जानकारी के लिए लिंक पर एक नज़र डालें stackoverflow.com/q/32293517/3327081

— kolunar

1

उस बारे में एक नया प्रश्न पूछें। मैंने कभी उपयोग नहीं किया forfiles।

— जीरोन विर्ट प्लिमर्स

7

मैंने vMax से बैच फ़ाइल के साथ उत्तर को बदल दिया है इसलिए यह डच भाषा के साथ भी काम करता है। डच - लगातार हम कर रहे हैं के रूप में - में कुछ परिवर्तन किया है , और
%date%date/tdate है कि ब्रेक मूल बैच फ़ाइल।

यह अच्छा होगा अगर कुछ लोग इसे अन्य विंडोज स्थानों के खिलाफ भी जांच सकते हैं, और परिणाम वापस कर सकते हैं।
यदि बैच-फ़ाइल आपके स्थान पर विफल रहती है, तो कमांड प्रॉम्प्ट पर इन दो कथनों के आउटपुट को शामिल करें:
echo:^|date
date/t

यह आउटपुट का एक नमूना है जिसे आपको बैच-फ़ाइल से प्राप्त करना चाहिए:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

यहाँ टिप्पणियों के साथ संशोधित कोड क्यों है:

:: /programming/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen

— जीरो वेर्ट प्ल्यूमर
स्रोत

2

कुछ पहले वर्षों का उपयोग करते हैं, या अग्रणी शून्य का अभाव करते हैं; देश द्वारा विकिपीडिया का दिनांक प्रारूप देखें । फ्रेंच पत्रिकाओं, mois, annee के लिए उपयोग कर सकते हैं jj-mm-aaaa? शायद gg/mm/aaaagiorno, mese, anno के लिए इटालियंस ? tt.mm.jjjjटैग, मोनाट, जहर के लिए जर्मन ? लेकिन फिर: मेरा अनुमान है कि अधिकांश देशों में केवल कुछ भाषाओं का उपयोग किया जाता है। जैसे नीदरलैंड में वास्तव में विंडोज अक्सर अंग्रेजी या डच होगा, बहुत अधिक नहीं। मेरे लिए काफी अच्छा।

— अर्जन

2

एक तरफ के रूप में: विंडोज बैच फ़ाइलों की छिपी सुविधाओं में एक और संस्करण कम परिपूर्ण है (डच के लिए फिक्स की आवश्यकता है jj, और 4 अंक वर्ष लागू नहीं करता है), लेकिन shiftदिन को त्यागने के लिए उपयोग करता है Monया जैसे ma। बिल्कुल अलग।

— अर्जन

4

यह एक जर्मन प्रणाली पर टूटता है। वर्ष और महीने का काम, लेकिन दिन विफल रहता है क्योंकि "दिन" जर्मन में "टी" से शुरू होता है ("टैग"), "डी" नहीं। प्रॉम्प्ट में प्रारूप स्ट्रिंग है (TT-MM-JJ), date/tआउटपुट है 23.06.2012। / cc @ अर्जन

— बेल्फा

2

एक और: एक आदेश भी मिल सकता है रजिस्ट्री से , का उपयोग कर reg query "HKCU\Control Panel\International" /vShortDate। जबकि परीक्षण सावधान: शीघ्र एक खुला आदेश के लिए, बदल रहा है कि नियंत्रण कक्ष भी स्थापित करने में परिवर्तन की तारीख को प्रदर्शित करने के लिए प्रयोग किया जाता प्रारूप (दोनों के लिए dateऔर date /tऔर echo %date%), लेकिन विंडोज 7 पर नई तारीख के लिए स्वरूप बदल नहीं करता है! मेरी छोटी तारीख के प्रारूप को बदलने की तरह YY/MM/dd, मुझे हो जाता है The current date is: 12/06/23 Enter the new date: (mm-dd-yy):। एक नया कमांड प्रॉम्प्ट खोलना ठीक करता है।

— अर्जन

2

@ अर्जन यह होना चाहिए reg query "HKCU\Control Panel\International" /v sShortDate।

— त्रिकसेव

6

यह वही है जो मैंने उपयोग किया है:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

यदि आप 7-ज़िप अभिलेखागार में बैकअप को स्वचालित करने के लिए और विचार चाहते हैं, तो मेरे पास एक मुफ्त / खुली परियोजना है जिसका उपयोग आप विचारों के लिए कर सकते हैं या समीक्षा कर सकते हैं: http://wittman.org/ziparcy/

— micahwittman
स्रोत

मेरे सिस्टम पर%%% में "Tue 10/14/2008" है। तो, आपको अभी भी "Tue" और अंतरिक्ष चरित्र को काट देना होगा (या अन्यथा निपटना होगा)।

— बोल्टबिट

हाय @micahwittman। SQL सर्वर में xp_cmdshell का उपयोग करके बनाई गई तारीख के साथ फाइल लोड करना संभव है? मैंने "forfiles" कमांड की कोशिश की है, लेकिन कोई फायदा नहीं हुआ। मैंने stackoverflow पर एक प्रश्न पूछा है, कृपया लिंक @ stackoverflow.com/q/32293517/3327081 देखें

— kolunar

5

मुझे भी ऐसी ही समस्या का समाधान करना पड़ा था। मैं एक एन्क्रिप्टेड फ़ाइल के एफ़टीपी सर्वर से एक स्वचालित दैनिक डाउनलोड करता हूं। मैं gpg का उपयोग करके फ़ाइल को डिक्रिप्ट करना चाहता था, फ़ाइल को वर्तमान तिथि (YYYYMMDD प्रारूप) में बदल देना और सही विभाग के लिए डिक्रिप्ट की गई फ़ाइल को फ़ोल्डर में छोड़ देना।

मैं तारीख के अनुसार फ़ाइल का नाम बदलने के लिए कई सुझावों के माध्यम से चला गया और जब तक मैं इस सरल समाधान पर ठोकर खाई, तब तक कोई भाग्य नहीं था।

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

यह पूरी तरह से काम करता है (यानी, फ़ाइल नाम "2011-06-14.txt" के रूप में सामने आता है)।

(स्रोत)

— KChiki
स्रोत

5

एक फ़ंक्शन जो पर आधारित है wmic:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

अपसाइड: क्षेत्र स्वतंत्र। डाउनसाइड: केवल सिस्टम एडमिनिस्ट्रेटर wmic.exe चला सकते हैं।

उपयोग:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

यह इस तरह एक स्ट्रिंग है:

2014-01-22 12:51:53

ध्यान दें कि फ़ंक्शन पैरामीटर आउट-पैरामीटर्स हैं - अर्थात, आपको मानों के बजाय चर नामों की आपूर्ति करनी चाहिए।

सभी पैरामीटर वैकल्पिक हैं, इसलिए call:Now Y Mएक वैध कॉल है यदि आप केवल वर्ष और महीने प्राप्त करना चाहते हैं।

— Tomalak
स्रोत

4

http://sourceforge.net/projects/unxutils/files/

"Date.exe" नामक किसी चीज़ के लिए ज़िप फ़ाइल के अंदर देखें और इसे "DateFormat.exe" नाम दें (संघर्षों से बचने के लिए)।

इसे अपने विंडोज सिस्टम 32 फोल्डर में रखें।

इसमें बहुत सारे "डेट आउटपुट" विकल्प हैं।

मदद के लिए, का उपयोग करें DateFormat.exe --h

मुझे यकीन नहीं है कि आप इसके आउटपुट को पर्यावरण चर में कैसे डालेंगे ... SET का उपयोग करते हुए।

— विप्लव
स्रोत

1

धन्यवाद, हालांकि यह प्रश्न विशेष रूप से अतिरिक्त टूल डाउनलोड किए बिना इसे करने के लिए है।

— रॉरी

3

आईएसओ तिथि प्रारूप तैयार करने वाला क्षेत्रीय स्वतंत्र समाधान:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

अभी भी क्या अनुकूलित किया जा सकता है: यदि संशोधित किया गया है तो छोटी अवधि में तारीख प्रारूप का उपयोग करते हुए अन्य प्रक्रियाएं भ्रमित हो सकती हैं। इसलिए मौजूदा प्रारूप स्ट्रिंग के अनुसार आउटपुट को पार्स करना 'सुरक्षित' हो सकता है - लेकिन अधिक जटिल होगा

— V15I0N
स्रोत

आप क्वेरी iDate ( Technet.microsoft.com/en-us/library/cc978637.aspx ) प्राप्त कर सकते हैं और सशर्त रूप से आगे बढ़ सकते हैं (तकनीकी के अनुसार 3 संभावित मान) - हालाँकि मैंने अभी तक इसकी कोशिश नहीं की है।

— विंसेंट डी स्मेट

2

:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 adolfo.dimare@gmail.com
:: - http://stackoverflow.com/questions/203090
@echo off

set _isotime=
set _now=

:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_

if not (%1)==() goto _help
SetLocal EnableDelayedExpansion

:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    IF "%%~L"=="" goto  _WMIC_done_
        set _yyyy=%%L
        set _mm=00%%J
        set _dd=00%%G
        set _hour=00%%H
        set _minute=00%%I
        set _second=00%%K
)
:_WMIC_done_

::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017

:: Remove excess leading zeroes
        set _mm=%_mm:~-2%
        set _dd=%_dd:~-2%
        set _hour=%_hour:~-2%
        set _minute=%_minute:~-2%
        set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%

:: Set date/time in ISO 8601 format:
        Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format

if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
    set /a _hour=1%_hour%-12
    set _hour=%_hour:~-2%
    set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
    :: -> https://ss64.com/nt/if.html
    :: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
    :: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_

EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out

:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"

:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.

:_out
:: EOF: GetDate.cmd

— एडोल्फो
स्रोत

0

कार्यात्मक रूप में संदर्भ के लिए एक ज्ञात इलाके को देखते हुए। ECHOTIMESTAMPकॉल से पता चलता है कि कैसे एक चर में टाइमस्टैम्प प्राप्त करने के लिए ( DTSइस उदाहरण में।)

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

और फाइल को सेव किया, टाइमस्टैम्प.बैट, यहाँ आउटपुट है:

— bvj
स्रोत

ऐसा लगता है कि यह क्षेत्रीय मुद्दे के साथ आता है - यह सभी अंग्रेजी मशीनों में काम नहीं करता है।

चौंक गए ना, @SteveFest। यदि स्थानीय रूप से अस्थायी रूप से सेट करना संभव था, तो यह एक वैश्विक समाधान प्रदान करने में मदद कर सकता है, लेकिन यह पहले से ही इस क्षेत्र को जानना आवश्यक है। क्या आपका लोकेल एन-यूएस या एन-कहीं है?

— bvj

@SteveFest मुझे लगता है कि उन स्थानों की सूची बनाना संभव होगा जहां प्रत्येक में मान्य करने के लिए नमूने के साथ दिनांक / समय के भाव शामिल हैं। मैं सुपर व्यस्त हूं, लेकिन मैं उदाहरण देने के लिए अपने उत्तर को अपडेट करने की कोशिश करूंगा। क्या आप मुझे एचके समय / दिनांक आउटपुट के नमूने दिखा सकते हैं? मैं मूर्खतापूर्ण रूप से निश्चित ऑफसेट पर zh-HK प्रिंट्स अंकों को मान सकता हूं।

— bvj

zh-HK: (yy)yy年m月d日 hh:mm- कोई अग्रणी शून्य नहीं है। (yy) को अनदेखा किया जा सकता है क्योंकि हमारे पास 2 अंक वर्ष, या 4 अंक वर्ष है। लेकिन कृपया एक बात पर ध्यान दें: तिथि समय प्रारूप को प्रति मशीन बदला जा सकता है।

धन्यवाद @SteveFest, मैं कुछ हफ्तों के भीतर पालन करूंगा। भागो systeminfoCLI पर और मुझे पता है कि आप क्या देखते हैं System Locale। कार्यक्रम को चलने में समय लगता है, लेकिन शायद स्थानीय परिणाम को कैश किया जा सकता है और बाद में टाइमस्टैम्प प्रारूप को अनुक्रमित करने के लिए उपयोग किया जाता है।

— bjj

0

विंडोज 7 के साथ, यह कोड मेरे लिए काम करता है:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%

— Frizz1977
स्रोत

और फिर। यह अच्छा है कि यह आपकी मशीन पर काम करता है, लेकिन आप इस बिंदु से चूक गएindependent of the regional settings of the machine

— jeb

-1

मैं ध्यान देता हूं कि ओ / पी नहीं था एक क्षेत्र-स्वतंत्र समाधान के लिए कहा । मेरा समाधान हालांकि यूके के लिए है।

यह एक बैच फ़ाइल में उपयोग के लिए सबसे सरल संभव समाधान, 1-लाइन समाधान है:

FOR /F "tokens=1-3 delims=/" %%A IN ("%date%") DO (SET today=%%C-%%B-%%A)
echo %today%

— Ed999
स्रोत

2

उन्होंने एक क्षेत्र के स्वतंत्र समाधान का उल्लेख किया ...particularly because of the regional settings issue with using date। Btw। आपका समाधान बीस अन्य उत्तरों के समान है।

— जेब

हाँ, लेकिन मेरा वास्तव में (वैकल्पिक रूप से) कमांड लाइन पर इस्तेमाल किया जा सकता था। कोड की 35 लाइनों को पोस्ट करने में योग्यता क्या है, अगर कोड की एक पंक्ति एक ही समाधान प्रदान करेगी?

— एड .999

मैं के पुराने उत्तर देने के लिए किसी भी प्रासंगिक अंतर नहीं देख सकता @Matthew जॉनसन, 2010 या @KChiki, 2011

— जेब

हालांकि यह उत्तर गलत है, वास्तविक उत्तर पर टिप्पणी करने के लिए, एक लूप के लिए यहाँ आवश्यक नहीं है जब आप बस कर सकते थेecho %date:/=-%

— गेरहार्ड बरनार्ड

यदि आप लूप को छोड़ देते हैं, तो कोई चर नहीं बनाया जा सकता है, और जिस तारीख को आपने निकालने के लिए परेशानी उठाई है, वह अभी भी बेकार है। फ़ोर लूप के साथ, लूप द्वारा बनाए गए चर स्क्रिप्ट के अन्य भागों में उपयोग करने के लिए उपलब्ध हैं। मैं लूप बनाने के लिए कोड की दर्जनों लाइनों का उपयोग करते हुए दृढ़ता से चित्रित करता हूं, जब केवल 1 लाइन की आवश्यकता होती है। और मैं दृढ़ता से गैर-कमांड लाइन समाधान पोस्ट कर रहा हूं, जहां ओ / पी ने विशेष रूप से कमांड लाइन पर उपयोग के लिए एक-लाइन समाधान के लिए कहा है।

— एड999

-3

मुझे पता है कि पहले से ही कई तरीके बताए गए हैं। लेकिन यहाँ यह समझने का तरीका है कि इसे कैसे किया जाए। उम्मीद है, यह उन लोगों के लिए सहायक है जो कदम से कदम विधि को पसंद करते हैं।

:: Check your local date format
echo %date%

    :: Output is Mon 08/15/2016

:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
    :: output is Mon 

:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
    :: output is 08

:: get date 
set mydate=%DATE:~7,2% 
echo %mydate%
    :: output is 15

:: get year
set myyear=%DATE:~10,4%
echo %myyear%
    :: output is 2016

— Gifcrazy
स्रोत

3

आप बिंदु से चूक गएindependent of the regional settings of the machine

— jeb