एक बैच फ़ाइल के अंदर प्रशासक पहुंच का अनुरोध कैसे करें

179

मैं अपने यूएसी मशीनों के साथ यूएसी के साथ चलने के लिए अपने उपयोगकर्ताओं के लिए एक बैच फ़ाइल लिखने की कोशिश कर रहा हूं। फ़ाइल उनके होस्ट फ़ाइल को फिर से लिख रही है, इसलिए इसे व्यवस्थापक अनुमतियों के साथ चलाने की आवश्यकता है। मुझे उन्हें .bat फ़ाइल के लिंक के साथ एक ईमेल भेजने में सक्षम होने की आवश्यकता है। वांछित व्यवहार यह है कि जब वे फ़ाइल पर राइट-क्लिक करते हैं और ओपन कहते हैं, तो उन्हें उन यूएसी संवादों में से एक मिलेगा जो स्क्रीन को अंधेरा कर देता है और उन्हें जवाब देने के लिए मजबूर करता है कि क्या वे प्रशासक के रूप में चलाने के लिए आवेदन की अनुमति देना चाहते हैं। इसके बजाय, वे केवल कमांड लाइन विंडो पर "प्रवेश निषेध" देख रहे हैं।

क्या यह अलग तरीके से संभव है?

— SKB
स्रोत

2

यदि आप इस पार आए और मेरे जैसे, PowerShell का उपयोग करके खुश हैं, तो @-toster-cx से वन-लाइनर को याद न करें। उत्तम!

— माइकल रेपुकि

353

यह स्क्रिप्ट ट्रिक करती है! बस इसे अपने बल्ले फ़ाइल के शीर्ष में चिपकाएँ। यदि आप अपनी स्क्रिप्ट के आउटपुट की समीक्षा करना चाहते हैं, तो अपनी बैच फ़ाइल के नीचे एक "पॉज़" कमांड जोड़ें।

अद्यतन: यह स्क्रिप्ट अब कमांड लाइन तर्क और 64 बिट ओएस का समर्थन करने के लिए थोड़ा संपादित किया गया है।

धन्यवाद Eneerge @ https://sites.google.com/site/eneerge/scripts/batchgotadmin

@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------    
    <YOUR BATCH SCRIPT HERE>

— बेन ग्रिपका
स्रोत

22

मुझे इस गंदे डॉस बैच बकवास करने से नफरत है लेकिन कभी-कभी आपको मजबूर किया जाता है और यह बहुत अच्छा काम करता है। चीयर्स!

— मैट

4

यह विधि तर्क को आगे नहीं बढ़ाती है। क्या आप जानते हैं कि यह कैसे किया जा सकता है? मूल रूप से मैं जो देखता हूं वह यह है कि पहली पंक्ति में% 1 का कुछ मूल्य है और अंतिम पंक्ति% 1 पर शून्य है। मुझे तर्कों को आगे बढ़ाने की जरूरत है।

— इसके कांटे

3

एक FYI के रूप में यह विंडोज 8 एंबेडेड में काम करने के रूप में परीक्षण किया गया है

— रॉबर्ट स्नाइडर

6

यह मेरी मशीन को स्क्रीन पर तिरछे खुलने और बंद होने वाली कमांड विंडो के सर्पिल में फेंक देता है। इसे रोकने का एकमात्र तरीका मूल बैच फ़ाइल को हटाना है। यह बार-बार मेरा बैच फ़ाइल चला रहा है और vbs फ़ाइल लिख रहा है। पहली बार इसने प्राधिकरण के लिए कहा, लेकिन इसके बाद यह सिर्फ लूप्स।

— टॉमडेस्ट्री

2

मैं अनंत लूप और रिटर्न कोड के साथ TomDestry के समान सटीक समस्या में भाग गया। यह विंडोज 8.1 पर था। मुझे पता है कि यह विंडोज 8.0 पर काम करता है, और यह सुनिश्चित करने के लिए नहीं कह सकता है कि यह 8.1 अपडेट था या कुछ और जो इस्स्स्स्स के कारण था। मेरे लिए काम करने वाला समाधान cacls..exe (या icacls) का उपयोग नहीं करना था, बल्कि: शुद्ध सत्र> nul 2> & 1 IF ERRORLEVEL 1 गोटो UACPrompt ...

— crig

55

यहाँ एक लाइनर का उपयोग कर रहा हूँ:

@echo off
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b)

echo main code here
pause

टिप्पणियाँ:

केवल विंडोज 7 और 10 पर परीक्षण किया गया, आपको उद्धरण के साथ गड़बड़ करना पड़ सकता है
अभी के लिए तर्कों के साथ गुजरने का समर्थन नहीं करता है

— toster-CX
स्रोत

1

यदि आप जानते हैं कि कितने परमेंस हो सकते हैं, तो आप पैरामीटर्स को पास करके पास कर सकते हैं, am_admin if not "%1"=="am_admin" (powershell start -verb runas '%0' 'am_admin "%~1" "%~2"' & exit)इसके बाद पैराम्स एक से ऊपर होंगे जहाँ वे थे

— टोनी ब्रिक्स

'am_admin %*'सब कुछ पास करने के लिए उपयोग करना भी संभव है , उद्धरण और रिक्त स्थान के साथ अच्छी तरह से नहीं खेलता है: / आप shiftबैच में उपयोग कर सकते हैं पहला arg पॉप करने के लिए, इस प्रकार सभी args को छोड़कर %0।

— टस्टर-सीएक्स

यह अच्छा जवाब है, लेकिन इसे स्वीकार नहीं किया जाना चाहिए, क्योंकि यह जाँच करता है कि एफआईआरएसटी रन पर यह ADMIN विशेषाधिकार के साथ चलाया गया था या नहीं।

— टोडुआ

वर्किंग डायरेक्टरी को रखने के लिए cd /D %~dp0बाद मेंif not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b)

— पेड्रो

अच्छा उत्तर। बस काम करता है जबकि VB स्क्रिप्ट की बात अनंत लूप बनाता है, यहां तक कि% अस्थायी% के लिए लिखित अनुमति भी।

— Twonky

19

यहाँ मेरा कोड है! यह बड़ा दिखता है, लेकिन यह ज्यादातर टिप्पणी लाइनें (साथ शुरू होने वाली लाइनें: :) है।

विशेषताएं:

पूर्ण तर्क अग्रेषण
काम करने का फोल्डर नहीं बदलता
गलती संभालना
कोष्ठक के साथ पथ स्वीकार करता है (% TEMP% फ़ोल्डर को छोड़कर)
UNC रास्तों का समर्थन करता है
मैप किए गए फ़ोल्डर की जांच (यदि आप एडमिन मैप्ड ड्राइव का उपयोग नहीं कर सकते हैं)
बाहरी पुस्तकालय के रूप में इस्तेमाल किया जा सकता है (इस विषय पर मेरी पोस्ट देखें : https://stackoverflow.com/a/30417025/4968684 )
अपने कोड में कहीं भी जरूरत पड़ने पर बुलाया जा सकता है

इसे अपनी बैच फ़ाइल के अंत में संलग्न करें, या इसे लाइब्रेरी के रूप में सहेजें (ऊपर देखें)

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:RequestAdminElevation FilePath %* || goto:eof
:: 
:: By:   Cyberponk,     v1.5 - 10/06/2016 - Changed the admin rights test method from cacls to fltmc
::          v1.4 - 17/05/2016 - Added instructions for arguments with ! char
::          v1.3 - 01/08/2015 - Fixed not returning to original folder after elevation successful
::          v1.2 - 30/07/2015 - Added error message when running from mapped drive
::          v1.1 - 01/06/2015
:: 
:: Func: opens an admin elevation prompt. If elevated, runs everything after the function call, with elevated rights.
:: Returns: -1 if elevation was requested
::           0 if elevation was successful
::           1 if an error occured
:: 
:: USAGE:
:: If function is copied to a batch file:
::     call :RequestAdminElevation "%~dpf0" %* || goto:eof
::
:: If called as an external library (from a separate batch file):
::     set "_DeleteOnExit=0" on Options
::     (call :RequestAdminElevation "%~dpf0" %* || goto:eof) && CD /D %CD%
::
:: If called from inside another CALL, you must set "_ThisFile=%~dpf0" at the beginning of the file
::     call :RequestAdminElevation "%_ThisFile%" %* || goto:eof
::
:: If you need to use the ! char in the arguments, the calling must be done like this, and afterwards you must use %args% to get the correct arguments:
::      set "args=%* "
::      call :RequestAdminElevation .....   use one of the above but replace the %* with %args:!={a)%
::      set "args=%args:{a)=!%" 
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEDELAYEDEXPANSION & set "_FilePath=%~1"
  if NOT EXIST "!_FilePath!" (echo/Read RequestAdminElevation usage information)
  :: UAC.ShellExecute only works with 8.3 filename, so use %~s1
  set "_FN=_%~ns1" & echo/%TEMP%| findstr /C:"(" >nul && (echo/ERROR: %%TEMP%% path can not contain parenthesis &pause &endlocal &fc;: 2>nul & goto:eof)
  :: Remove parenthesis from the temp filename
  set _FN=%_FN:(=%
  set _vbspath="%temp:~%\%_FN:)=%.vbs" & set "_batpath=%temp:~%\%_FN:)=%.bat"

  :: Test if we gave admin rights
  fltmc >nul 2>&1 || goto :_getElevation

  :: Elevation successful
  (if exist %_vbspath% ( del %_vbspath% )) & (if exist %_batpath% ( del %_batpath% )) 
  :: Set ERRORLEVEL 0, set original folder and exit
  endlocal & CD /D "%~dp1" & ver >nul & goto:eof

  :_getElevation
  echo/Requesting elevation...
  :: Try to create %_vbspath% file. If failed, exit with ERRORLEVEL 1
  echo/Set UAC = CreateObject^("Shell.Application"^) > %_vbspath% || (echo/&echo/Unable to create %_vbspath% & endlocal &md; 2>nul &goto:eof) 
  echo/UAC.ShellExecute "%_batpath%", "", "", "runas", 1 >> %_vbspath% & echo/wscript.Quit(1)>> %_vbspath%
  :: Try to create %_batpath% file. If failed, exit with ERRORLEVEL 1
  echo/@%* > "%_batpath%" || (echo/&echo/Unable to create %_batpath% & endlocal &md; 2>nul &goto:eof)
  echo/@if %%errorlevel%%==9009 (echo/^&echo/Admin user could not read the batch file. If running from a mapped drive or UNC path, check if Admin user can read it.)^&echo/^& @if %%errorlevel%% NEQ 0 pause >> "%_batpath%"

  :: Run %_vbspath%, that calls %_batpath%, that calls the original file
  %_vbspath% && (echo/&echo/Failed to run VBscript %_vbspath% &endlocal &md; 2>nul & goto:eof)

  :: Vbscript has been run, exit with ERRORLEVEL -1
  echo/&echo/Elevation was requested on a new CMD window &endlocal &fc;: 2>nul & goto:eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

इसका उपयोग कैसे करें पर उदाहरण

:EXAMPLE
@echo off

 :: Run this script with elevation
 call :RequestAdminElevation "%~dpfs0" %* || goto:eof

  echo/I now have Admin rights!
  echo/
  echo/Arguments using %%args%%:    %args%
  echo/Arguments using %%*: %*
  echo/%%1= %~1
  echo/%%2= %~2
  echo/%%3= %~3

  echo/
  echo/Current Directory: %CD%
  echo/
  echo/This file: %0
  echo/

pause &goto:eof

[here you paste the RequestAdminElevation function code]

— cyberponk
स्रोत

महान काम करता है लेकिन मुझे इसे काम करने के लिए एक लाइन बदलनी पड़ी। &fc;: 2>nulमें

set "_FN=_%~ns1" & echo/%TEMP%| findstr /C:"(" >nul && (echo/ERROR: %%TEMP%% path can not contain parenthesis &pause &endlocal &fc;: 2>nul & goto:eof)

1. errorlevel की स्थापना की गई थी मुझे लगता है कि थोड़ा हटा दिया और यह सही काम किया। मैं विंडोज 10 होम का उपयोग कर रहा हूं।

— Kainri

क्या आपके% temp% फ़ोल्डर में कोष्ठक पथ है? केवल इस मामले में त्रुटि 1 सेट किया जाना चाहिए।

— साइबरपोन 18

नहीं। क्या इसकी आवश्यकता है fc;:क्योंकि यह चला जाता है: इसके ठीक बाद ईओएफ? मुझे यकीन नहीं है कि इस मुद्दे का थोड़ा सा भी कारण है, क्योंकि इसे निष्पादित किया जाना चाहिए।

— १२:

"fc ;: 2> nul" जानबूझकर त्रुटि को इंगित करने के लिए बाहर निकलने से पहले ERRORLEVEL 1 को सेट करने के लिए है। क्या आप कृपया @echo को हटा सकते हैं और एक रन बना सकते हैं और मुझे एक निजी संदेश में आउटपुट भेज सकते हैं? धन्यवाद!

— साइबरपोंक

वैसे भी, echo/%TEMP%| findstr /C:"(" >nulअगर वहाँ (yout %temp%पर्यावरण चर में एक चर है, और केवल &&सकारात्मक के बाद भाग चलाना चाहिए तो परीक्षण । यह अजीब है कि आपका (परीक्षण सकारात्मक क्यों लौट रहा है।

— साइबरपोंक

7

एक और तरीका है

स्थानीय रूप से एक शॉर्टकट बनाएं और इसे व्यवस्थापन अनुमति के लिए कॉल करें [गुण, उन्नत, व्यवस्थापक के रूप में चलाएँ]

और फिर

अपने उपयोगकर्ताओं को शॉर्टकट [या शॉर्टकट के लिए एक लिंक भेजने के बजाय एक ही बैच फ़ाइल में भेजें]।

डेनिस

[बाद में जोड़ा गया - हां, मैं इस धागे की तारीख को नोटिस करने में विफल रहा।]

— Tryx3
स्रोत

6

बेन ग्रिप्का का समाधान अनंत छोरों का कारण बनता है। उनका बैच इस तरह काम करता है (छद्म कोड):

IF "no admin privileges?"
    "write a VBS that calls this batch with admin privileges"
ELSE
    "execute actual commands that require admin privileges"

जैसा कि आप देख सकते हैं, यह एक अनंत लूप का कारण बनता है, अगर वीबीएस व्यवस्थापक विशेषाधिकारों का अनुरोध करने में विफल रहता है।

हालांकि, अनंत लूप हो सकता है, हालांकि व्यवस्थापक प्राइवेटिलीज़ को सफलतापूर्वक अनुरोध किया गया है।

बेन ग्रिप्का की बैच फ़ाइल में चेक केवल त्रुटि-प्रवण है। मैंने बैच के साथ खेला और देखा कि व्यवस्थापक विशेषाधिकार उपलब्ध हैं, हालांकि चेक विफल रहा। दिलचस्प है, चेक ने अपेक्षा के अनुरूप काम किया, अगर मैंने विंडोज़ एक्सप्लोरर से बैच फ़ाइल शुरू की, लेकिन यह तब नहीं हुआ जब मैंने इसे अपनी आईडीई से शुरू किया था।

इसलिए मैं दो अलग-अलग बैच फ़ाइलों का उपयोग करने का सुझाव देता हूं। पहला VBS उत्पन्न करता है जो दूसरे बैच फ़ाइल को कॉल करता है:

@echo off

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
set params = %*:"=""
echo UAC.ShellExecute "cmd.exe", "/c ""%~dp0\my_commands.bat"" %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"

दूसरा, जिसका नाम "my_commands.bat" है और पहले के समान निर्देशिका में स्थित है, जिसमें आपके वास्तविक आदेश हैं:

pushd "%CD%"
CD /D "%~dp0"
REM Your commands which require admin privileges here

यह कोई अनंत छोरों का कारण बनता है और त्रुटि-प्रवण व्यवस्थापक विशेषाधिकार जांच को भी हटा देता है।

— मछली की हड्डी
स्रोत

आपके लिए काम किया? मेरे लिए दुख की बात है, यह और अन्य सभी यहाँ और दूसरे धागे से एक ही अंतर्निहित मुद्दे के कारण विफल हो जाते हैं। जब भी शेल ऑब्जेक्ट को किसी अन्य प्रोग्राम के अंदर से अप्रत्यक्ष रूप से बनाया जाता है, तो "रनस" परम (या कमांड) विफल हो जाता है । रुचि का धागा यहाँ ।

— लॉरी स्टर्न

मेरे लिए काम किया :)

— श्रीतम जगदेव

6

एक और पॉवरशेल सॉल्यूशन ...

यह प्रति के रूप में बैच स्क्रिप्ट चलाने के बारे में नहीं है, बल्कि यह है कि बैच से दूसरे प्रोग्राम को कैसे बढ़ाया जाए ...

मेरे पास एक exe के लिए एक बैच फ़ाइल "रैपर" है। उनके पास समान "रूट फ़ाइल नाम" है, लेकिन वैकल्पिक एक्सटेंशन। मैं exe को व्यवस्थापक के रूप में लॉन्च करने में सक्षम हूं, और स्क्रिप्ट के युक्त कार्य निर्देशिका को निम्न एक पंक्ति शक्तियों के आमंत्रण के साथ सेट कर सकता हूं :

@powershell "Start-Process -FilePath '%~n0.exe' -WorkingDirectory '%~dp0' -Verb RunAs"

और जानकारी

अतिरिक्त Start-Processविकल्पों की एक पूरी श्रृंखला है, जिसे आप लागू कर सकते हैं! देखें: https://docs.microsoft.com/en-us/powershell/module/microsoft.powershell.management/start-process?view=powershell-6

ध्यान दें कि मैं @उपसर्ग का उपयोग करता हूं । यह @echo offएक पंक्ति के बराबर है । मैं %~n0बैच स्क्रिप्ट का "रूट नाम" प्राप्त करने के लिए यहां उपयोग करता हूं , फिर मैं .exeइसे समीपवर्ती बाइनरी इंगित करने के लिए संक्षिप्त करता हूं। उपयोग %~dp0निर्देशिका को पूरा रास्ता प्रदान करता है जो बैच रहता है। और, बेशक, पैरामीटर ऊंचाई प्रदान करता है ।-Verb RunAs

— BuvinJ
स्रोत

4

मुझे पता है कि यह ओपी के लिए एक समाधान नहीं है, लेकिन जब से मुझे यकीन है कि यहां कई अन्य उपयोग के मामले हैं, तो मुझे लगा कि मैं साझा करूंगा।

मुझे इन उत्तरों में सभी कोड उदाहरणों के साथ समस्या है, लेकिन फिर मैंने पाया: http://www.robotronic.de/runasspcEnn.html

यह न केवल आपको व्यवस्थापक के रूप में चलाने की अनुमति देता है, यह फ़ाइल को यह सुनिश्चित करने के लिए जांचता है कि इसके साथ छेड़छाड़ नहीं की गई है और आवश्यक जानकारी को सुरक्षित रूप से संग्रहीत करता है। मैं मानता हूँ कि यह कैसे उपयोग करने के लिए पता लगाने के लिए सबसे स्पष्ट उपकरण नहीं है, लेकिन हम में से कोड लिखने वाले लोगों के लिए यह काफी सरल होना चाहिए।

— trex005
स्रोत

3

@echo offऔर titleइस कोड से पहले आ सकते हैं:

net session>nul 2>&1
if %errorlevel%==0 goto main
echo CreateObject("Shell.Application").ShellExecute "%~f0", "", "", "runas">"%temp%/elevate.vbs"
"%temp%/elevate.vbs"
del "%temp%/elevate.vbs"
exit

:main
    <code goes here>
exit

यदि आपको निम्नलिखित के बारे में चिंता करने की आवश्यकता नहीं है, तो कई अन्य उत्तर ओवरकिल हैं:

पैरामीटर
कार्य निर्देशिका ( cd %~dp0बैच फ़ाइल युक्त निर्देशिका में बदल जाएगी)

— FluorescentGreen5
स्रोत

3

@echo off 
Net session >nul 2>&1 || (PowerShell start -verb runas '%~0' &exit /b)
Echo Administrative privileges have been got. & pause

उपरोक्त मेरे विंडोज 10 संस्करण 1903 पर काम करता है

— मैथ्यू वाई
स्रोत

1

चूँकि मुझे इस स्क्रिप्ट से परेशानी है, इसलिए एक नई कमांड प्रॉम्प्ट को अपने साथ फिर से चलाने के लिए, अनंत लूप में (विन 7 प्रो का उपयोग करके), मैं आपको एक और दृष्टिकोण आज़माने का सुझाव देता हूं: मैं अपनी बैच फ़ाइल को कैसे बढ़ा सकता हूं, ताकि यह अनुरोध करे यदि आवश्यक हो तो UAC व्यवस्थापक अधिकार?

सावधान रहें, आपको इसे स्क्रिप्ट के अंत में जोड़ना होगा, जैसा कि एक एडिट में कहा गया है, ताकि आप स्क्रिप्ट डायरेक्टरी में वापस आ जाएं क्योंकि विशेषाधिकार बढ़ गए थे: cd / d% ~ dp0

— barbara.post
स्रोत

इस प्रश्न के लिए मेरे उत्तर की जाँच करें। यह इन सभी समस्याओं को संभालता है।

— साइबरबैंक

1

इस पृष्ठ पर टोस्टर-सीएक्स और अन्य रोचक पोस्ट के आधार पर, मुझे अपनी समस्या को कॉन्फ़िगर करने और हल करने के तरीके के बारे में जानकारी मिली। मेरे पास इसी तरह का मुद्दा था जहां मैं चाहता था कि डिस्क क्लीनअप उपयोगिता हर हफ्ते दो बार सोमवार और गुरुवार को दोपहर के भोजन के समय (2 बजे कहें) के दौरान चलती है। हालाँकि, इसके लिए उन्नत अधिकार आवश्यक थे।

बैच फ़ाइल साझा करना जो मेरे जैसे अन्य शुरुआती लोगों की मदद कर सकती है -

@echo off
echo  Welcome to scheduling 'PC Maintenance Activity'
ping localhost -n 3 >nul
echo -- Step - 1 of 3 : Please give 'Admin' rights on next screen
ping localhost -n 5 >nul
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit)
cls
echo -- Step - 2 of 3 : In next screen, select temp areas for cleaning 
during routine scheduled activity
ping localhost -n 3 >nul
C:\Windows\System32\cleanmgr.exe /sageset:112
cls
echo    Now scheduling maintenance activity...
SchTasks /Create /SC WEEKLY /D MON,THU /TN PC_Cleanup /TR 
"C:\Windows\System32\cleanmgr.exe "/sagerun:112 /ST 14:00

cls

echo                         -- Thanks for your co-operation --
echo                    -- Maintenance activity is scheduled for --
echo                       -- Every Monday and Thursday at 2 pm --

ping localhost -n 10 >nul

इस मंच और Rems POST के लिए यहाँ बहुत-बहुत धन्यवाद [ https://www.petri.com/forums/forum/windows-scripting/general-scripting/32313-schtasks-exe-need-to-pass-parameters-to-script ] [1]

कार्य को शेड्यूल करते समय वैकल्पिक तर्क को कॉन्फ़िगर करने में उनकी पोस्ट ने मदद की।

— आनंद
स्रोत

1

वहाँ भी है से fsutil क्वेरी इस पोस्ट जो भी पर जुड़ा हुआ है ss64.com निम्नलिखित कोड है:

@Echo Off
Setlocal
:: First check if we are running As Admin/Elevated
FSUTIL dirty query %SystemDrive% >nul
if %errorlevel% EQU 0 goto START

::Create and run a temporary VBScript to elevate this batch file
   Set _batchFile=%~f0
   Set _Args=%*
   :: double up any quotes
   Set _batchFile=""%_batchFile:"=%""
   Set _Args=%_Args:"=""%

   Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\~ElevateMe.vbs"
   Echo UAC.ShellExecute "cmd", "/c ""%_batchFile% %_Args%""", "", "runas", 1 >> "%temp%\~ElevateMe.vbs"

   cscript "%temp%\~ElevateMe.vbs" 
   Exit /B

:START
:: set the current directory to the batch file location
cd /d %~dp0
:: Place the code which requires Admin/elevation below
Echo We are now running as admin [%1] [%2]
pause

जब तक FSUTIL आसपास है, यह एक विश्वसनीय विकल्प है।

— लॉरी स्टर्न
स्रोत

0

आप बैच फ़ाइल से व्यवस्थापक अधिकारों का अनुरोध नहीं कर सकते, लेकिन आप% temp% में होस्ट स्क्रिप्ट स्क्रिप्ट लिख सकते हैं और चला सकते हैं (और बदले में अपने बैच को व्यवस्थापक के रूप में निष्पादित करते हैं) आप शेल में शेलएक्सक्यूट विधि को कॉल करना चाहते हैं। क्रिया के रूप में "रनस" के साथ अनुप्रयोग ऑब्जेक्ट

— ऐन्डर्स
स्रोत

0

mshtaव्यवस्थापक अधिकारों के लिए संकेत देने के लिए उपयोग करें :

@echo off
net session >nul 2>&1 && goto :admintasks
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
exit /b
:admintasks
rem ADMIN TASKS HERE

या, पॉवरशेल का उपयोग कर:

powershell -c Start-Process "%~nx0" -Verb runas

— HackingAddict1337
स्रोत

-5

रनस कमांड का उपयोग करें। लेकिन, मुझे नहीं लगता कि आप एक .bat फ़ाइल को आसानी से ईमेल कर सकते हैं।

— जोश
स्रोत

6

यह उत्तर गलत है। runasआदेश ऊंचाई भड़काने के लिए इस्तेमाल नहीं किया जा सकता है।

— Bill_Stewart 20