VBA सरणी सॉर्ट फ़ंक्शन?

Question 1

मैं VBA में सरणियों के लिए एक सभ्य प्रकार के कार्यान्वयन की तलाश कर रहा हूं। एक क्विकॉर्ट को प्राथमिकता दी जाएगी। या बुलबुला या मर्ज के अलावा किसी अन्य प्रकार के एल्गोरिथ्म पर्याप्त होगा।

कृपया ध्यान दें कि यह एमएस प्रोजेक्ट 2003 के साथ काम करना है, इसलिए एक्सेल के मूल कार्यों और संबंधित किसी भी .net से बचना चाहिए।

Question 2

~~यहाँ एक नज़र रखना :~~
संपादित करें: संदर्भित स्रोत (allexperts.com) तब से बंद है, लेकिन यहां प्रासंगिक लेखक टिप्पणियां हैं:

छँटाई के लिए वेब पर कई एल्गोरिदम उपलब्ध हैं। सबसे बहुमुखी और आमतौर पर सबसे तेज Quicksort एल्गोरिथ्म है । नीचे इसके लिए एक फ़ंक्शन है।

लोअर ऐरे बाउंड्रीरी (आमतौर पर 0) और अपर ऐरे बाउंड्री (यानी UBound(myArray)।) के साथ इसे केवल मानों (स्ट्रिंग या संख्यात्मक; यह कोई फर्क नहीं पड़ता) को पास करके कॉल करें ।

उदाहरण :Call QuickSort(myArray, 0, UBound(myArray))

जब यह पूरा myArrayहो जाएगा , तो इसे सुलझा लिया जाएगा और आप जो चाहें कर सकते हैं।
_{(स्रोत: आर्काइव.ऑर्ग )}

Public Sub QuickSort(vArray As Variant, inLow As Long, inHi As Long)
  Dim pivot   As Variant
  Dim tmpSwap As Variant
  Dim tmpLow  As Long
  Dim tmpHi   As Long

  tmpLow = inLow
  tmpHi = inHi

  pivot = vArray((inLow + inHi) \ 2)

  While (tmpLow <= tmpHi)
     While (vArray(tmpLow) < pivot And tmpLow < inHi)
        tmpLow = tmpLow + 1
     Wend

     While (pivot < vArray(tmpHi) And tmpHi > inLow)
        tmpHi = tmpHi - 1
     Wend

     If (tmpLow <= tmpHi) Then
        tmpSwap = vArray(tmpLow)
        vArray(tmpLow) = vArray(tmpHi)
        vArray(tmpHi) = tmpSwap
        tmpLow = tmpLow + 1
        tmpHi = tmpHi - 1
     End If
  Wend

  If (inLow < tmpHi) Then QuickSort vArray, inLow, tmpHi
  If (tmpLow < inHi) Then QuickSort vArray, tmpLow, inHi
End Sub

ध्यान दें कि यह केवल एकल-आयामी (उर्फ "सामान्य"?) सरणियों के साथ काम करता है । (यहां एक कार्यशील बहु-आयामी सरणी QuickSort है ।)

Question 3

मैंने if फास्ट क्विक सॉर्ट ’एल्गोरिथम को VBA में बदल दिया, अगर कोई और चाहता है।

मैंने इसे Int / Longs की एक सरणी पर चलाने के लिए अनुकूलित किया है, लेकिन इसे सरल रूप से एक में परिवर्तित करना चाहिए जो मनमाने ढंग से तुलनीय तत्वों पर काम करता है।

Private Sub QuickSort(ByRef a() As Long, ByVal l As Long, ByVal r As Long)
    Dim M As Long, i As Long, j As Long, v As Long
    M = 4

    If ((r - l) > M) Then
        i = (r + l) / 2
        If (a(l) > a(i)) Then swap a, l, i '// Tri-Median Methode!'
        If (a(l) > a(r)) Then swap a, l, r
        If (a(i) > a(r)) Then swap a, i, r

        j = r - 1
        swap a, i, j
        i = l
        v = a(j)
        Do
            Do: i = i + 1: Loop While (a(i) < v)
            Do: j = j - 1: Loop While (a(j) > v)
            If (j < i) Then Exit Do
            swap a, i, j
        Loop
        swap a, i, r - 1
        QuickSort a, l, j
        QuickSort a, i + 1, r
    End If
End Sub

Private Sub swap(ByRef a() As Long, ByVal i As Long, ByVal j As Long)
    Dim T As Long
    T = a(i)
    a(i) = a(j)
    a(j) = T
End Sub

Private Sub InsertionSort(ByRef a(), ByVal lo0 As Long, ByVal hi0 As Long)
    Dim i As Long, j As Long, v As Long

    For i = lo0 + 1 To hi0
        v = a(i)
        j = i
        Do While j > lo0
            If Not a(j - 1) > v Then Exit Do
            a(j) = a(j - 1)
            j = j - 1
        Loop
        a(j) = v
    Next i
End Sub

Public Sub sort(ByRef a() As Long)
    QuickSort a, LBound(a), UBound(a)
    InsertionSort a, LBound(a), UBound(a)
End Sub

Question 4

जर्मन में स्पष्टीकरण लेकिन कोड एक अच्छी तरह से परीक्षण में जगह कार्यान्वयन है:

Private Sub QuickSort(ByRef Field() As String, ByVal LB As Long, ByVal UB As Long)
    Dim P1 As Long, P2 As Long, Ref As String, TEMP As String

    P1 = LB
    P2 = UB
    Ref = Field((P1 + P2) / 2)

    Do
        Do While (Field(P1) < Ref)
            P1 = P1 + 1
        Loop

        Do While (Field(P2) > Ref)
            P2 = P2 - 1
        Loop

        If P1 <= P2 Then
            TEMP = Field(P1)
            Field(P1) = Field(P2)
            Field(P2) = TEMP

            P1 = P1 + 1
            P2 = P2 - 1
        End If
    Loop Until (P1 > P2)

    If LB < P2 Then Call QuickSort(Field, LB, P2)
    If P1 < UB Then Call QuickSort(Field, P1, UB)
End Sub

इस तरह आमंत्रित:

Call QuickSort(MyArray, LBound(MyArray), UBound(MyArray))

Question 5

Dim arr As Object
Dim InputArray

'Creating a array list
Set arr = CreateObject("System.Collections.ArrayList")

'String
InputArray = Array("d", "c", "b", "a", "f", "e", "g")

'number
'InputArray = Array(6, 5, 3, 4, 2, 1)

' adding the elements in the array to array_list
For Each element In InputArray
    arr.Add element
Next

'sorting happens
arr.Sort

'Converting ArrayList to an array
'so now a sorted array of elements is stored in the array sorted_array.

sorted_array = arr.toarray

Question 6

प्राकृतिक संख्या (स्ट्रिंग्स) त्वरित क्रमबद्ध

बस विषय पर ढेर करने के लिए। आम तौर पर, यदि आप संख्याओं के साथ तार छाँटते हैं, तो आपको कुछ इस तरह मिलेगा:

    Text1
    Text10
    Text100
    Text11
    Text2
    Text20

लेकिन आप वास्तव में चाहते हैं कि यह संख्यात्मक मानों को पहचानें और जैसे हल किया जाए

    Text1
    Text2
    Text10
    Text11
    Text20
    Text100

यह कैसे करना है ...

ध्यान दें:

मैंने बहुत समय पहले इंटरनेट से क्विक सॉर्ट चुराया था, अब यकीन नहीं होता ...
मैंने तुलनात्मक रूप से फ़ंक्शन का अनुवाद किया जो मूल रूप से इंटरनेट से सी में लिखा गया था।
अन्य क्यू-सॉर्ट्स से अंतर: मैं मानों की अदला-बदली नहीं करता हूं अगर बॉटमटेम्प = टॉपटैम्प

प्राकृतिक संख्या त्वरित क्रमबद्ध

Public Sub QuickSortNaturalNum(strArray() As String, intBottom As Integer, intTop As Integer)
Dim strPivot As String, strTemp As String
Dim intBottomTemp As Integer, intTopTemp As Integer

    intBottomTemp = intBottom
    intTopTemp = intTop

    strPivot = strArray((intBottom + intTop) \ 2)

    Do While (intBottomTemp <= intTopTemp)
        ' < comparison of the values is a descending sort
        Do While (CompareNaturalNum(strArray(intBottomTemp), strPivot) < 0 And intBottomTemp < intTop)
            intBottomTemp = intBottomTemp + 1
        Loop
        Do While (CompareNaturalNum(strPivot, strArray(intTopTemp)) < 0 And intTopTemp > intBottom) '
            intTopTemp = intTopTemp - 1
        Loop
        If intBottomTemp < intTopTemp Then
            strTemp = strArray(intBottomTemp)
            strArray(intBottomTemp) = strArray(intTopTemp)
            strArray(intTopTemp) = strTemp
        End If
        If intBottomTemp <= intTopTemp Then
            intBottomTemp = intBottomTemp + 1
            intTopTemp = intTopTemp - 1
        End If
    Loop

    'the function calls itself until everything is in good order
    If (intBottom < intTopTemp) Then QuickSortNaturalNum strArray, intBottom, intTopTemp
    If (intBottomTemp < intTop) Then QuickSortNaturalNum strArray, intBottomTemp, intTop
End Sub

प्राकृतिक संख्या की तुलना (त्वरित क्रम में प्रयुक्त)

Function CompareNaturalNum(string1 As Variant, string2 As Variant) As Integer
'string1 is less than string2 -1
'string1 is equal to string2 0
'string1 is greater than string2 1
Dim n1 As Long, n2 As Long
Dim iPosOrig1 As Integer, iPosOrig2 As Integer
Dim iPos1 As Integer, iPos2 As Integer
Dim nOffset1 As Integer, nOffset2 As Integer

    If Not (IsNull(string1) Or IsNull(string2)) Then
        iPos1 = 1
        iPos2 = 1
        Do While iPos1 <= Len(string1)
            If iPos2 > Len(string2) Then
                CompareNaturalNum = 1
                Exit Function
            End If
            If isDigit(string1, iPos1) Then
                If Not isDigit(string2, iPos2) Then
                    CompareNaturalNum = -1
                    Exit Function
                End If
                iPosOrig1 = iPos1
                iPosOrig2 = iPos2
                Do While isDigit(string1, iPos1)
                    iPos1 = iPos1 + 1
                Loop

                Do While isDigit(string2, iPos2)
                    iPos2 = iPos2 + 1
                Loop

                nOffset1 = (iPos1 - iPosOrig1)
                nOffset2 = (iPos2 - iPosOrig2)

                n1 = Val(Mid(string1, iPosOrig1, nOffset1))
                n2 = Val(Mid(string2, iPosOrig2, nOffset2))

                If (n1 < n2) Then
                    CompareNaturalNum = -1
                    Exit Function
                ElseIf (n1 > n2) Then
                    CompareNaturalNum = 1
                    Exit Function
                End If

                ' front padded zeros (put 01 before 1)
                If (n1 = n2) Then
                    If (nOffset1 > nOffset2) Then
                        CompareNaturalNum = -1
                        Exit Function
                    ElseIf (nOffset1 < nOffset2) Then
                        CompareNaturalNum = 1
                        Exit Function
                    End If
                End If
            ElseIf isDigit(string2, iPos2) Then
                CompareNaturalNum = 1
                Exit Function
            Else
                If (Mid(string1, iPos1, 1) < Mid(string2, iPos2, 1)) Then
                    CompareNaturalNum = -1
                    Exit Function
                ElseIf (Mid(string1, iPos1, 1) > Mid(string2, iPos2, 1)) Then
                    CompareNaturalNum = 1
                    Exit Function
                End If

                iPos1 = iPos1 + 1
                iPos2 = iPos2 + 1
            End If
        Loop
        ' Everything was the same so far, check if Len(string2) > Len(String1)
        ' If so, then string1 < string2
        If Len(string2) > Len(string1) Then
            CompareNaturalNum = -1
            Exit Function
        End If
    Else
        If IsNull(string1) And Not IsNull(string2) Then
            CompareNaturalNum = -1
            Exit Function
        ElseIf IsNull(string1) And IsNull(string2) Then
            CompareNaturalNum = 0
            Exit Function
        ElseIf Not IsNull(string1) And IsNull(string2) Then
            CompareNaturalNum = 1
            Exit Function
        End If
    End If
End Function

isDigit (तुलनात्मक रूप में प्रयुक्त)

Function isDigit(ByVal str As String, pos As Integer) As Boolean
Dim iCode As Integer
    If pos <= Len(str) Then
        iCode = Asc(Mid(str, pos, 1))
        If iCode >= 48 And iCode <= 57 Then isDigit = True
    End If
End Function

Question 7

मैंने StackOverflow पर संबंधित प्रश्न के उत्तर में कुछ कोड पोस्ट किया है:

VBA में एक बहु-विषयक सरणी को क्रमबद्ध करना

उस धागे में कोड नमूने शामिल हैं:

एक वेक्टर सरणी क्विकॉर्ट;
एक बहु-स्तंभ सरणी क्विकॉर्ट;
एक बबलर्ट।

एलेन का अनुकूलित क्विकॉर्ट बहुत चमकदार है: मैंने सिर्फ एक बुनियादी विभाजन और पुनरावृत्ति किया था, लेकिन ऊपर दिए गए कोड नमूने में एक 'गेटिंग' फ़ंक्शन है जो डुप्लिकेट किए गए मानों के अनावश्यक तुलनाओं में कटौती करता है। दूसरी ओर, मैं एक्सेल के लिए कोड करता हूं, और रक्षात्मक कोडिंग के तरीके में थोड़ा और अधिक है - चेतावनी दी जाए, यदि आपके सरणी में खतरनाक 'खाली ()' वेरिएंट है, तो आपको इसकी आवश्यकता होगी, जो आपके समय को तोड़ देगा .. तुलना ऑपरेटरों को भेजें और अपने कोड को एक अनंत लूप में फंसा लें।

ध्यान दें कि क्विकॉर्ट अल्गर्थ - और किसी भी पुनरावर्ती एल्गोरिदम - स्टैक और क्रैश एक्सेल को भर सकते हैं। यदि आपके सरणी में 1024 से कम सदस्य हैं, तो मैं अल्पविकसित बबलसॉर्ट का उपयोग करूंगा।

सार्वजनिक उप QuickSortArray (वेरिएंट के रूप में ByRef SortArray, _
                                वैकल्पिक lngMin लंबे समय तक = -1, _ 
                                वैकल्पिक lngMax लंबे समय तक = -1, _ 
                                वैकल्पिक lngColumn लंबे समय तक = 0)
त्रुटि को फिर से शुरू 

करें '2-डायमेंशनल एरे को क्रमबद्ध करें

'नमूना उपयोग: कॉलम 3 की सामग्री द्वारा एरियरडैटा को क्रमबद्ध करें
'
'QuickSortArray arrData,,, 3

'
'जिम रेच 10/20/98 Excel.Programming द्वारा पोस्ट 

' संशोधन, निगेल हेफर्नन :

'' पलायन खाली संस्करण के साथ तुलना में विफल रहा
'' रक्षात्मक कोडिंग: इनपुट्स की जाँच करें

डिम आई अस लॉन्ग
डिम जे अस लॉन्ग
वैरिएंट के रूप में मंद varMid
डिम अरर्र्ट टैम्प वैरिएंट के रूप में
लंबे समय के रूप में डिम लैंगकोलटेम्प


 यदि IsEmpty (SortArray) तब
     उप से बाहर निकलें
 अगर अंत

 यदि InStr (TypeName (SortArray), "()") <1 तो 'IsArray () कुछ हद तक टूट गया है: प्रकार नाम में कोष्ठक देखें
     उप से बाहर निकलें
 अगर अंत

 यदि लैंगमिन = -1 फिर
     lngMin = LBound (SortArray, 1)
 अगर अंत
 
 यदि lngMax = -1 है
     lngMax = UBound (SortArray, 1)
 अगर अंत
 
 अगर lngMin> = lngMax तो 'कोई छँटाई की आवश्यकता नहीं है
     उप से बाहर निकलें
 अगर अंत


 i = लिंगमिन
 j = lngMax

 varMid = खाली
 varMid = SortArray ((lngMin + lngMax) \ 2, lngColumn)

 'हम सूची के अंत में' खाली 'और अमान्य डेटा आइटम भेजते हैं:
 यदि IsObject (varMid) इसके बाद 'ध्यान दें कि हम जांच नहीं करते isObject (SortArray (एन)) - varMid सकता ट सदस्य या संपत्ति लेने
     i = lngMax
     j = lngMin
 ElseIf IsEmpty (varMid) तब
     i = lngMax
     j = lngMin
 ElseIf IsNull (varMid) तब
     i = lngMax
     j = lngMin
 ElseIf varMid = "" तब
     i = lngMax
     j = lngMin
 ElseIf varType (varMid) = vbError तब
     i = lngMax
     j = lngMin
 ElseIf varType (varMid)> 17 फिर
     i = lngMax
     j = lngMin
 अंत अगर 


 मैं <= जे

     जबकि SortArray (i, lngColumn) <varMid और i <lngMax
         i = i + 1
     बीतना

     जबकि varMid <SortArray (j, lngColumn) और j> lngMin
         j = j - १
     वेंड 


     इफ आई <= जे तो

         'पंक्तियों को स्वैप करें
         ReDim arrRowTemp (LBound (SortArray, 2) to UBound (SortArray, 2))
         LngColTemp = LBound (SortArray, 2) के लिए UBound (SortArray, 2)
             arrRowTemp (lngColTemp) = SortArray (i, lngColTemp)
             SortArray (i, lngColTemp) = SortArray (j, lngColTemp)
             SortArray (j, lngColTemp) = arrRowTemp (lngColTemp)
         अगला lngColTemp
         बन्दी मिटाएँ

         i = i + 1
         j = j - 1 

     अंत यदि 


 वेंड हो

 यदि (lngMin <j) तो QuickSortArray (SortArray, lngMin, j, lngColumn) पर कॉल करें
 यदि (i <lngMax) तो QuickSortArray को कॉल करें (SortArray, i, lngMax, lngColumn) 

 
अंतिम उप

Question 8

आप एक्सेल-आधारित समाधान नहीं चाहते थे, लेकिन चूंकि मुझे आज भी यही समस्या थी और मैं नीचे दिए गए फ़ंक्शन को लिखने वाले अन्य कार्यालय एप्लिकेशन कार्यों का उपयोग करके परीक्षण करना चाहता था।

सीमाएं:

2-आयामी सरणियों;
सॉर्ट कीज़ के रूप में अधिकतम 3 कॉलम;
एक्सेल पर निर्भर करता है;

Visio 2010 से एक्सेल 2010 का परीक्षण किया गया

Option Base 1


Private Function sort_array_2D_excel(array_2D, array_sortkeys, Optional array_sortorders, Optional tag_header As String = "Guess", Optional tag_matchcase As String = "False")

'   Dependencies: Excel; Tools > References > Microsoft Excel [Version] Object Library

    Dim excel_application As Excel.Application
    Dim excel_workbook As Excel.Workbook
    Dim excel_worksheet As Excel.Worksheet

    Set excel_application = CreateObject("Excel.Application")

    excel_application.Visible = True
    excel_application.ScreenUpdating = False
    excel_application.WindowState = xlNormal

    Set excel_workbook = excel_application.Workbooks.Add
    excel_workbook.Activate

    Set excel_worksheet = excel_workbook.Worksheets.Add
    excel_worksheet.Activate
    excel_worksheet.Visible = xlSheetVisible

    Dim excel_range As Excel.Range
    Set excel_range = excel_worksheet.Range("A1").Resize(UBound(array_2D, 1) - LBound(array_2D, 1) + 1, UBound(array_2D, 2) - LBound(array_2D, 2) + 1)
    excel_range = array_2D


    For i_sortkey = LBound(array_sortkeys) To UBound(array_sortkeys)

        If IsNumeric(array_sortkeys(i_sortkey)) Then
            sortkey_range = Chr(array_sortkeys(i_sortkey) + 65 - 1) & "1"
            Set array_sortkeys(i_sortkey) = excel_worksheet.Range(sortkey_range)

        Else
            MsgBox "Error in sortkey parameter:" & vbLf & "array_sortkeys(" & i_sortkey & ") = " & array_sortkeys(i_sortkey) & vbLf & "Terminating..."
            End

        End If

    Next i_sortkey


    For i_sortorder = LBound(array_sortorders) To UBound(array_sortorders)
        Select Case LCase(array_sortorders(i_sortorder))
            Case "asc"
                array_sortorders(i_sortorder) = XlSortOrder.xlAscending
            Case "desc"
                array_sortorders(i_sortorder) = XlSortOrder.xlDescending
            Case Else
                array_sortorders(i_sortorder) = XlSortOrder.xlAscending
        End Select
    Next i_sortorder

    Select Case LCase(tag_header)
        Case "yes"
            tag_header = Excel.xlYes
        Case "no"
            tag_header = Excel.xlNo
        Case "guess"
            tag_header = Excel.xlGuess
        Case Else
            tag_header = Excel.xlGuess
    End Select

    Select Case LCase(tag_matchcase)
        Case "true"
            tag_matchcase = True
        Case "false"
            tag_matchcase = False
        Case Else
            tag_matchcase = False
    End Select


    Select Case (UBound(array_sortkeys) - LBound(array_sortkeys) + 1)
        Case 1
            Call excel_range.Sort(Key1:=array_sortkeys(1), Order1:=array_sortorders(1), Header:=tag_header, MatchCase:=tag_matchcase)
        Case 2
            Call excel_range.Sort(Key1:=array_sortkeys(1), Order1:=array_sortorders(1), Key2:=array_sortkeys(2), Order2:=array_sortorders(2), Header:=tag_header, MatchCase:=tag_matchcase)
        Case 3
            Call excel_range.Sort(Key1:=array_sortkeys(1), Order1:=array_sortorders(1), Key2:=array_sortkeys(2), Order2:=array_sortorders(2), Key3:=array_sortkeys(3), Order3:=array_sortorders(3), Header:=tag_header, MatchCase:=tag_matchcase)
        Case Else
            MsgBox "Error in sortkey parameter:" & vbLf & "Maximum number of sort columns is 3!" & vbLf & "Currently passed: " & (UBound(array_sortkeys) - LBound(array_sortkeys) + 1)
            End
    End Select


    For i_row = 1 To excel_range.Rows.Count

        For i_column = 1 To excel_range.Columns.Count

            array_2D(i_row, i_column) = excel_range(i_row, i_column)

        Next i_column

    Next i_row


    excel_workbook.Close False
    excel_application.Quit

    Set excel_worksheet = Nothing
    Set excel_workbook = Nothing
    Set excel_application = Nothing


    sort_array_2D_excel = array_2D


End Function

यह फ़ंक्शन का परीक्षण करने के तरीके पर एक उदाहरण है:

Private Sub test_sort()

    array_unsorted = dim_sort_array()

    Call msgbox_array(array_unsorted)

    array_sorted = sort_array_2D_excel(array_unsorted, Array(2, 1, 3), Array("desc", "", "asdas"), "yes", "False")

    Call msgbox_array(array_sorted)

End Sub


Private Function dim_sort_array()

    Dim array_unsorted(1 To 5, 1 To 3) As String

    i_row = 0

    i_row = i_row + 1
    array_unsorted(i_row, 1) = "Column1": array_unsorted(i_row, 2) = "Column2": array_unsorted(i_row, 3) = "Column3"

    i_row = i_row + 1
    array_unsorted(i_row, 1) = "OR": array_unsorted(i_row, 2) = "A": array_unsorted(i_row, 3) = array_unsorted(i_row, 1) & "_" & array_unsorted(i_row, 2)

    i_row = i_row + 1
    array_unsorted(i_row, 1) = "XOR": array_unsorted(i_row, 2) = "A": array_unsorted(i_row, 3) = array_unsorted(i_row, 1) & "_" & array_unsorted(i_row, 2)

    i_row = i_row + 1
    array_unsorted(i_row, 1) = "NOT": array_unsorted(i_row, 2) = "B": array_unsorted(i_row, 3) = array_unsorted(i_row, 1) & "_" & array_unsorted(i_row, 2)

    i_row = i_row + 1
    array_unsorted(i_row, 1) = "AND": array_unsorted(i_row, 2) = "A": array_unsorted(i_row, 3) = array_unsorted(i_row, 1) & "_" & array_unsorted(i_row, 2)

    dim_sort_array = array_unsorted

End Function


Sub msgbox_array(array_2D, Optional string_info As String = "2D array content:")

    msgbox_string = string_info & vbLf

    For i_row = LBound(array_2D, 1) To UBound(array_2D, 1)

        msgbox_string = msgbox_string & vbLf & i_row & vbTab

        For i_column = LBound(array_2D, 2) To UBound(array_2D, 2)

            msgbox_string = msgbox_string & array_2D(i_row, i_column) & vbTab

        Next i_column

    Next i_row

    MsgBox msgbox_string

End Sub

यदि कोई कार्यालय के अन्य संस्करणों का उपयोग करके इसका परीक्षण करता है, तो यदि कोई समस्या हो तो कृपया यहाँ पोस्ट करें।

Question 9

मुझे आश्चर्य है कि आप इस सरणी सॉर्टिंग कोड के बारे में क्या कहेंगे। यह कार्यान्वयन के लिए त्वरित है और काम करता है ... बड़े सरणियों के लिए अभी तक परीक्षण नहीं किया है। यह एक आयामी सरणियों के लिए काम करता है, बहुआयामी अतिरिक्त मूल्यों के लिए फिर से स्थान मैट्रिक्स का निर्माण करना होगा (एक कम आयाम के साथ प्रारंभिक सरणी)।

       For AR1 = LBound(eArray, 1) To UBound(eArray, 1)
            eValue = eArray(AR1)
            For AR2 = LBound(eArray, 1) To UBound(eArray, 1)
                If eArray(AR2) < eValue Then
                    eArray(AR1) = eArray(AR2)
                    eArray(AR2) = eValue
                    eValue = eArray(AR1)
                End If
            Next AR2
        Next AR1

Question 10

मुझे लगता है कि मेरा कोड (परीक्षण) अधिक "शिक्षित" है, सरल को बेहतर मानते हुए ।

Option Base 1

'Function to sort an array decscending
Function SORT(Rango As Range) As Variant
    Dim check As Boolean
    check = True
    If IsNull(Rango) Then
        check = False
    End If
    If check Then
        Application.Volatile
        Dim x() As Variant, n As Double, m As Double, i As Double, j As Double, k As Double
        n = Rango.Rows.Count: m = Rango.Columns.Count: k = n * m
        ReDim x(n, m)
        For i = 1 To n Step 1
            For j = 1 To m Step 1
                x(i, j) = Application.Large(Rango, k)
                k = k - 1
            Next j
        Next i
        SORT = x
    Else
        Exit Function
    End If
End Function

Question 11

यह वह है जो मैं मेमोरी में सॉर्ट करने के लिए उपयोग करता हूं - यह आसानी से एक सरणी सॉर्ट करने के लिए विस्तारित किया जा सकता है।

Sub sortlist()

    Dim xarr As Variant
    Dim yarr As Variant
    Dim zarr As Variant

    xarr = Sheets("sheet").Range("sing col range")
    ReDim yarr(1 To UBound(xarr), 1 To 1)
    ReDim zarr(1 To UBound(xarr), 1 To 1)

    For n = 1 To UBound(xarr)
        zarr(n, 1) = 1
    Next n

    For n = 1 To UBound(xarr) - 1
        y = zarr(n, 1)
        For a = n + 1 To UBound(xarr)
            If xarr(n, 1) > xarr(a, 1) Then
                y = y + 1
            Else
                zarr(a, 1) = zarr(a, 1) + 1
            End If
        Next a
        yarr(y, 1) = xarr(n, 1)
    Next n

    y = zarr(UBound(xarr), 1)
    yarr(y, 1) = xarr(UBound(xarr), 1)

    yrng = "A1:A" & UBound(yarr)
    Sheets("sheet").Range(yrng) = yarr

End Sub

Question 12

हीप्सर्ट कार्यान्वयन। एक ओ (एन लॉग (एन)) (दोनों औसत और सबसे खराब स्थिति), जगह में, अस्थिर छँटाई एल्गोरिथ्म।

के साथ प्रयोग करें: Call HeapSort(A)जहां Aएक वैरिएंट का एक आयामी सरणी है, के साथ Option Base 1।

Sub SiftUp(A() As Variant, I As Long)
    Dim K As Long, P As Long, S As Variant
    K = I
    While K > 1
        P = K \ 2
        If A(K) > A(P) Then
            S = A(P): A(P) = A(K): A(K) = S
            K = P
        Else
            Exit Sub
        End If
    Wend
End Sub

Sub SiftDown(A() As Variant, I As Long)
    Dim K As Long, L As Long, S As Variant
    K = 1
    Do
        L = K + K
        If L > I Then Exit Sub
        If L + 1 <= I Then
            If A(L + 1) > A(L) Then L = L + 1
        End If
        If A(K) < A(L) Then
            S = A(K): A(K) = A(L): A(L) = S
            K = L
        Else
            Exit Sub
        End If
    Loop
End Sub

Sub HeapSort(A() As Variant)
    Dim N As Long, I As Long, S As Variant
    N = UBound(A)
    For I = 2 To N
        Call SiftUp(A, I)
    Next I
    For I = N To 2 Step -1
        S = A(I): A(I) = A(1): A(1) = S
        Call SiftDown(A, I - 1)
    Next
End Sub

Question 13

@ प्रसाद कुमार, यहां प्रसाद की अवधारणाओं के आधार पर पूरी तरह से दिनचर्या है:

Public Sub ArrayListSort(ByRef SortArray As Variant)
    '
    'Uses the sort capabilities of a System.Collections.ArrayList object to sort an array of values of any simple
    'data-type.
    '
    'AUTHOR: Peter Straton
    '
    'CREDIT: Derived from Prasand Kumar's post at: /programming/152319/vba-array-sort-function
    '
    '*************************************************************************************************************

    Static ArrayListObj As Object
    Dim i As Long
    Dim LBnd As Long
    Dim UBnd As Long

    LBnd = LBound(SortArray)
    UBnd = UBound(SortArray)

    'If necessary, create the ArrayList object, to be used to sort the specified array's values

    If ArrayListObj Is Nothing Then
        Set ArrayListObj = CreateObject("System.Collections.ArrayList")
    Else
        ArrayListObj.Clear  'Already allocated so just clear any old contents
    End If

    'Add the ArrayList elements from the array of values to be sorted. (There appears to be no way to do this
    'using a single assignment statement.)

    For i = LBnd To UBnd
        ArrayListObj.Add SortArray(i)
    Next i

    ArrayListObj.Sort   'Do the sort

    'Transfer the sorted ArrayList values back to the original array, which can be done with a single assignment
    'statement.  But the result is always zero-based so then, if necessary, adjust the resulting array to match
    'its original index base.

    SortArray = ArrayListObj.ToArray
    If LBnd <> 0 Then ReDim Preserve SortArray(LBnd To UBnd)
End Sub

Question 14

कुछ हद तक संबंधित है, लेकिन मैं एक उन्नत एक्सेल VBA समाधान की तलाश में था क्योंकि उन्नत डेटा संरचनाएं (शब्दकोश, आदि) मेरे वातावरण में काम नहीं कर रही हैं। VBA में एक द्विआधारी पेड़ के माध्यम से छंटनी निम्नलिखित औजार:

मान लेता है कि सरणी एक के बाद एक आबाद है
डुप्लिकेट निकालता है
एक अलग स्ट्रिंग ( "0|2|3|4|9") लौटाता है जिसे तब विभाजित किया जा सकता है।

मैंने इसे मनमाने ढंग से चुनी गई सीमा के लिए चुनी गई पंक्तियों की कच्ची छँटाई के लिए लौटाया

Private Enum LeafType: tEMPTY: tTree: tValue: End Enum
Private Left As Variant, Right As Variant, Center As Variant
Private LeftType As LeafType, RightType As LeafType, CenterType As LeafType
Public Sub Add(x As Variant)
    If CenterType = tEMPTY Then
        Center = x
        CenterType = tValue
    ElseIf x > Center Then
        If RightType = tEMPTY Then
            Right = x
            RightType = tValue
        ElseIf RightType = tTree Then
            Right.Add x
        ElseIf x <> Right Then
            curLeaf = Right
            Set Right = New TreeList
            Right.Add curLeaf
            Right.Add x
            RightType = tTree
        End If
    ElseIf x < Center Then
        If LeftType = tEMPTY Then
            Left = x
            LeftType = tValue
        ElseIf LeftType = tTree Then
            Left.Add x
        ElseIf x <> Left Then
            curLeaf = Left
            Set Left = New TreeList
            Left.Add curLeaf
            Left.Add x
            LeftType = tTree
        End If
    End If
End Sub
Public Function GetList$()
    Const sep$ = "|"
    If LeftType = tValue Then
        LeftList$ = Left & sep
    ElseIf LeftType = tTree Then
        LeftList = Left.GetList & sep
    End If
    If RightType = tValue Then
        RightList$ = sep & Right
    ElseIf RightType = tTree Then
        RightList = sep & Right.GetList
    End If
    GetList = LeftList & Center & RightList
End Function

'Sample code
Dim Tree As new TreeList
Tree.Add("0")
Tree.Add("2")
Tree.Add("2")
Tree.Add("-1")
Debug.Print Tree.GetList() 'prints "-1|0|2"
sortedList = Split(Tree.GetList(),"|")