CMake: बाहरी परियोजनाओं का निर्माण कैसे करें और उनके लक्ष्यों को शामिल करें

Question

मेरे पास एक प्रोजेक्ट ए है जो एक स्थिर पुस्तकालय को लक्ष्य के रूप में निर्यात करता है:

install(TARGETS alib DESTINATION lib EXPORT project_a-targets)
install(EXPORT project_a-targets DESTINATION lib/alib)

अब मैं प्रोजेक्ट A को प्रोजेक्ट B से बाहरी प्रोजेक्ट के रूप में उपयोग करना चाहता हूं और इसके निर्मित लक्ष्य शामिल करता हूं:

ExternalProject_Add(project_a
  URL ...project_a.tar.gz
  PREFIX ${CMAKE_CURRENT_BINARY_DIR}/project_a
  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
)

include(${CMAKE_CURRENT_BINARY_DIR}/lib/project_a/project_a-targets.cmake)

समस्या यह है कि शामिल फ़ाइल अभी तक मौजूद नहीं है जब प्रोजेक्ट B के CMakeLists चलाए जाते हैं।

क्या शामिल किए जाने का एक तरीका बाहरी परियोजना पर निर्भर होना है?

अद्यतन : मैंनेइस और अन्य आम समस्याओं के आधार पर उदाहरण ट्यूटोरियल द्वारा एक छोटा सीएमके लिखा।

Answer 1

मुझे लगता है कि आप यहां दो अलग-अलग प्रतिमानों को मिला रहे हैं।

जैसा कि आपने उल्लेख किया, अत्यधिक लचीला ExternalProjectमॉड्यूल बिल्ड समय पर अपनी कमांड चलाता है, इसलिए आप प्रोजेक्ट ए के आयात फ़ाइल का प्रत्यक्ष उपयोग नहीं कर सकते क्योंकि यह केवल एक बार प्रोजेक्ट ए स्थापित होने के बाद बनाया गया है।

आप चाहते हैं includeप्रोजेक्ट ए के आयात फ़ाइल, आप करेंगे है मैन्युअल रूप से परियोजना बी के CMakeLists.txt लागू करने से पहले परियोजना स्थापित करने के लिए एक - किसी अन्य तीसरे पक्ष के निर्भरता की तरह इस तरह से जोड़ा या के माध्यम से find_file/ find_library/ find_package।

यदि आप इसका उपयोग करना चाहते हैं ExternalProject_Add, तो आपको अपने CMakeLists.txt में निम्नलिखित की तरह कुछ जोड़ना होगा:

ExternalProject_Add(project_a
  URL ...project_a.tar.gz
  PREFIX ${CMAKE_CURRENT_BINARY_DIR}/project_a
  CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
)

include(${CMAKE_CURRENT_BINARY_DIR}/lib/project_a/project_a-targets.cmake)

ExternalProject_Get_Property(project_a install_dir)
include_directories(${install_dir}/include)

add_dependencies(project_b_exe project_a)
target_link_libraries(project_b_exe ${install_dir}/lib/alib.lib)

Comments

आपके उत्तर के लिए धन्यवाद। आप जो सुझाव देते हैं, वह मेरे जैसा पहले था। मैं निर्यात किए गए लक्ष्यों का उपयोग करने के लिए एक रास्ता खोजने की उम्मीद करता था क्योंकि यह मैन्युअल रूप से काम के रास्ते को निर्दिष्ट करने की तुलना में एक अच्छे इंटरफ़ेस की तरह लग रहा था ...

— mirkokiefer

मैं अपने स्रोत के पेड़ में बाहरी परियोजनाओं के स्रोत को शामिल करने से बचना चाहता था। यह बहुत अच्छा होगा अगर ExternalProject_Addसिर्फ व्यवहार किया जाए add_subdirectoryऔर सभी लक्ष्यों को उजागर किया जाए। ऊपर वर्णित समाधान शायद अभी भी सबसे साफ है।

— 1

उन्हें एक्सप्रोप्रोजेक्ट बिल्ड बनाने पर विचार करें, और फिर बी ए पर निर्भर हैं, और फिर प्रोजेक्ट बी के लिए CMakeLists फ़ाइल में प्रोजेक्ट ए से लक्ष्य फ़ाइल शामिल होगी, लेकिन आपके "सुपर बिल्ड" CMakeLists सिर्फ ए और फिर बी दोनों का निर्माण करेंगे, एक्सप्रोजेक्ट के रूप में ...

— DLRdave

@DLRdave - मैंने सुपर बिल्ड समाधान को कुछ बार अनुशंसित देखा है, लेकिन मुझे लगता है कि मुझे यकीन नहीं है कि यह केवल कुछ बाहरी परियोजनाओं सहित क्या लाभ प्रदान करता है ExternalProject। क्या यह स्थिरता है, या अधिक विहित, या कुछ और? मुझे यकीन है कि मैं यहाँ कुछ मौलिक याद कर रहा हूँ।

— फ्रेजर

इस समाधान के साथ समस्याओं में से एक यह है कि हमने लाइब्रेरी नाम (alib.lib) को केवल हार्डकोड किया है, जो बिल्ड सिस्टम को क्रॉस-प्लेटफॉर्म नहीं बनाता है, क्योंकि विभिन्न ओएस साझा पुस्तकालयों के लिए अलग-अलग नामकरण योजनाओं का उपयोग करते हैं, और इन अलग-अलग नामकरणों के लिए उपयोग करते हैं। योजनाएँ CMake की विशेषताओं में से एक है।

— nsg

Answer 2

ये पद का एक उचित उत्तर है:

CMakeLists.txt.in:

cmake_minimum_required(VERSION 2.8.2)

project(googletest-download NONE)

include(ExternalProject)
ExternalProject_Add(googletest
  GIT_REPOSITORY    https://github.com/google/googletest.git
  GIT_TAG           master
  SOURCE_DIR        "${CMAKE_BINARY_DIR}/googletest-src"
  BINARY_DIR        "${CMAKE_BINARY_DIR}/googletest-build"
  CONFIGURE_COMMAND ""
  BUILD_COMMAND     ""
  INSTALL_COMMAND   ""
  TEST_COMMAND      ""
)

CMakeLists.txt:

# Download and unpack googletest at configure time
configure_file(CMakeLists.txt.in
               googletest-download/CMakeLists.txt)
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
  WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/googletest-download )
execute_process(COMMAND ${CMAKE_COMMAND} --build .
  WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/googletest-download )

# Prevent GoogleTest from overriding our compiler/linker options
# when building with Visual Studio
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)

# Add googletest directly to our build. This adds
# the following targets: gtest, gtest_main, gmock
# and gmock_main
add_subdirectory(${CMAKE_BINARY_DIR}/googletest-src
                 ${CMAKE_BINARY_DIR}/googletest-build)

# The gtest/gmock targets carry header search path
# dependencies automatically when using CMake 2.8.11 or
# later. Otherwise we have to add them here ourselves.
if (CMAKE_VERSION VERSION_LESS 2.8.11)
  include_directories("${gtest_SOURCE_DIR}/include"
                      "${gmock_SOURCE_DIR}/include")
endif()

# Now simply link your own targets against gtest, gmock,
# etc. as appropriate

हालाँकि यह काफी हैकिंग लगता है। मैं एक वैकल्पिक समाधान प्रस्तावित करना चाहूंगा - Git सबमॉड्यूल का उपयोग करें।

cd MyProject/dependencies/gtest
git submodule add https://github.com/google/googletest.git
cd googletest
git checkout release-1.8.0
cd ../../..
git add *
git commit -m "Add googletest"

तब MyProject/dependencies/gtest/CMakeList.txtआप कुछ ऐसा कर सकते हैं:

cmake_minimum_required(VERSION 3.3)

if(TARGET gtest) # To avoid diamond dependencies; may not be necessary depending on you project.
    return()
endif()

add_subdirectory("googletest")

मैंने इसे बड़े पैमाने पर अभी तक आज़माया नहीं है लेकिन यह साफ-सुथरा लगता है।

संपादित करें: इस दृष्टिकोण के लिए एक नकारात्मक पहलू है: उपनिर्देशिका install()आज्ञाओं को चला सकती है जो आप नहीं चाहते हैं। इस पोस्ट में उन्हें अक्षम करने के लिए एक दृष्टिकोण है लेकिन यह छोटी गाड़ी थी और मेरे लिए काम नहीं करती थी।

संपादित करें 2: यदि आप इसका उपयोग करते हैं add_subdirectory("googletest" EXCLUDE_FROM_ALL)तो इसका मतलब install()है कि उपनिर्देशिका के कमांड डिफ़ॉल्ट रूप से उपयोग नहीं किए जाते हैं।

Comments

यह शायद सिर्फ मुझे अत्यधिक सावधान किया जा रहा है क्योंकि यह सिर्फ एक उदाहरण है और गाइस्ट शायद बहुत स्थिर है, लेकिन मैं दृढ़ता से हमेशा GIT_TAGक्लोन के दौरान एक विशिष्ट का उपयोग करने की सलाह देता हूं , आप दोहराव का निर्माण कर सकते हैं क्योंकि अब से 2 साल बाद किसी को स्क्रिप्ट बनाने का मौका मिलेगा। आपने जो किया उससे अलग संस्करण। CMake के डॉक्स भी यही सलाह देते हैं।

— जूनियर

Answer 3

संपादित करें: CMake के पास अब इसके लिए बिलिन समर्थन है। नया जवाब देखें ।

तुम भी एक माध्यमिक बनाने की प्रक्रिया में निर्भर लक्ष्य के निर्माण के लिए मजबूर कर सकते हैं

संबंधित विषय पर मेरा उत्तर देखें ।

Answer 4

cmake का ExternalProject_Addवास्तव में उपयोग किया जा सकता है, लेकिन जो मुझे इसके बारे में पसंद नहीं था - वह यह है कि यह बिल्ड, निरंतर पोल आदि के दौरान कुछ करता है ... मैं बिल्ड चरण के दौरान प्रोजेक्ट बनाना पसंद करूंगा, और कुछ नहीं। मैंने ExternalProject_Addकई प्रयासों में ओवरराइड करने की कोशिश की है , दुर्भाग्य से सफलता के बिना।

फिर मैंने git सबमॉडल को जोड़ने की भी कोशिश की है, लेकिन यह पूरी git रिपॉजिटरी को प्रभावित करता है, जबकि कुछ मामलों में मुझे पूरे git रिपॉजिटरी के केवल सबसेट की जरूरत होती है। मैंने क्या जाँच की है - यह वास्तव में विरल चेकआउट प्रदर्शन करने के लिए संभव है, लेकिन इसके लिए अलग फ़ंक्शन की आवश्यकता होती है, जिसे मैंने नीचे लिखा था।

#-----------------------------------------------------------------------------
#
# Performs sparse (partial) git checkout
#
#   into ${checkoutDir} from ${url} of ${branch}
#
# List of folders and files to pull can be specified after that.
#-----------------------------------------------------------------------------
function (SparseGitCheckout checkoutDir url branch)
    if(EXISTS ${checkoutDir})
        return()
    endif()

    message("-------------------------------------------------------------------")
    message("sparse git checkout to ${checkoutDir}...")
    message("-------------------------------------------------------------------")

    file(MAKE_DIRECTORY ${checkoutDir})

    set(cmds "git init")
    set(cmds ${cmds} "git remote add -f origin --no-tags -t master ${url}")
    set(cmds ${cmds} "git config core.sparseCheckout true")

    # This command is executed via file WRITE
    # echo <file or folder> >> .git/info/sparse-checkout")

    set(cmds ${cmds} "git pull --depth=1 origin ${branch}")

    # message("In directory: ${checkoutDir}")

    foreach( cmd ${cmds})
        message("- ${cmd}")
        string(REPLACE " " ";" cmdList ${cmd})

        #message("Outfile: ${outFile}")
        #message("Final command: ${cmdList}")

        if(pull IN_LIST cmdList)
            string (REPLACE ";" "\n" FILES "${ARGN}")
            file(WRITE ${checkoutDir}/.git/info/sparse-checkout ${FILES} )
        endif()

        execute_process(
            COMMAND ${cmdList}
            WORKING_DIRECTORY ${checkoutDir}
            RESULT_VARIABLE ret
        )

        if(NOT ret EQUAL "0")
            message("error: previous command failed, see explanation above")
            file(REMOVE_RECURSE ${checkoutDir})
            break()
        endif()
    endforeach()

endfunction()


SparseGitCheckout(${CMAKE_BINARY_DIR}/catch_197 https://github.com/catchorg/Catch2.git v1.9.7 single_include)
SparseGitCheckout(${CMAKE_BINARY_DIR}/catch_master https://github.com/catchorg/Catch2.git master single_include)

मैंने फ़ंक्शन का उपयोग करने का तरीका बताने के लिए नीचे दो फ़ंक्शन कॉल जोड़े हैं।

कोई व्यक्ति मास्टर / ट्रंक को चेकआउट करना पसंद नहीं कर सकता है, क्योंकि किसी को तोड़ा जा सकता है - फिर विशिष्ट टैग निर्दिष्ट करना हमेशा संभव होता है।

जब तक आप कैश फ़ोल्डर साफ़ नहीं करते तब तक चेकआउट केवल एक बार किया जाएगा।

Answer 5

मैं इसी तरह के समाधान के लिए खोज रहा था। यहाँ उत्तर और शीर्ष पर ट्यूटोरियल जानकारीपूर्ण है। मैंने अपने सफल बनाने के लिए यहाँ पोस्ट / ब्लॉग का अध्ययन किया। मैं पूरा CMakeLists.txt पोस्ट कर रहा हूं मेरे लिए काम किया। मुझे लगता है, यह शुरुआती लोगों के लिए एक बुनियादी टेम्पलेट के रूप में सहायक होगा।

"CMakeLists.txt"

cmake_minimum_required(VERSION 3.10.2)

# Target Project
project (ClientProgram)

# Begin: Including Sources and Headers
include_directories(include)
file (GLOB SOURCES "src/*.c")
# End: Including Sources and Headers


# Begin: Generate executables
add_executable (ClientProgram ${SOURCES})
# End: Generate executables


# This Project Depends on External Project(s) 
include (ExternalProject)

# Begin: External Third Party Library
set (libTLS ThirdPartyTlsLibrary)
ExternalProject_Add (${libTLS}
    PREFIX          ${CMAKE_CURRENT_BINARY_DIR}/${libTLS}
# Begin: Download Archive from Web Server
    URL             http://myproject.com/MyLibrary.tgz
    URL_HASH        SHA1=<expected_sha1sum_of_above_tgz_file>
    DOWNLOAD_NO_PROGRESS ON
# End: Download Archive from Web Server

# Begin: Download Source from GIT Repository
#    GIT_REPOSITORY  https://github.com/<project>.git
#    GIT_TAG         <Refer github.com releases -> Tags>
#    GIT_SHALLOW     ON
# End: Download Source from GIT Repository

# Begin: CMAKE Comamnd Argiments
    CMAKE_ARGS      -DCMAKE_INSTALL_PREFIX:PATH=${CMAKE_CURRENT_BINARY_DIR}/${libTLS}
    CMAKE_ARGS      -DUSE_SHARED_LIBRARY:BOOL=ON
# End: CMAKE Comamnd Argiments    
)

# The above ExternalProject_Add(...) construct wil take care of \
# 1. Downloading sources
# 2. Building Object files
# 3. Install under DCMAKE_INSTALL_PREFIX Directory

# Acquire Installation Directory of 
ExternalProject_Get_Property (${libTLS} install_dir)

# Begin: Importing Headers & Library of Third Party built using ExternalProject_Add(...)
# Include PATH that has headers required by Target Project
include_directories (${install_dir}/include)

# Import librarues from External Project required by Target Project
add_library (lmytls SHARED IMPORTED)
set_target_properties (lmytls PROPERTIES IMPORTED_LOCATION ${install_dir}/lib/libmytls.so)
add_library (lmyxdot509 SHARED IMPORTED)
set_target_properties(lmyxdot509 PROPERTIES IMPORTED_LOCATION ${install_dir}/lib/libmyxdot509.so)

# End: Importing Headers & Library of Third Party built using ExternalProject_Add(...)
# End: External Third Party Library

# Begin: Target Project depends on Third Party Component
add_dependencies(ClientProgram ${libTLS})
# End: Target Project depends on Third Party Component

# Refer libraries added above used by Target Project
target_link_libraries (ClientProgram lmytls lmyxdot509)