मैं PIPELINED टेबल फ़ंक्शन का उपयोग करके एक अलग दृष्टिकोण का प्रस्ताव करना चाहूंगा। यह XMLTABLE की तकनीक से कुछ मिलता-जुलता है, सिवाय इसके कि आप चरित्र स्ट्रिंग को विभाजित करने के लिए अपने स्वयं के कस्टम फ़ंक्शन प्रदान कर रहे हैं:
-- Create a collection type to hold the results
CREATE OR REPLACE TYPE typ_str2tbl_nst AS TABLE OF VARCHAR2(30);
/
-- Split the string according to the specified delimiter
CREATE OR REPLACE FUNCTION str2tbl (
p_string VARCHAR2,
p_delimiter CHAR DEFAULT ','
)
RETURN typ_str2tbl_nst PIPELINED
AS
l_tmp VARCHAR2(32000) := p_string || p_delimiter;
l_pos NUMBER;
BEGIN
LOOP
l_pos := INSTR( l_tmp, p_delimiter );
EXIT WHEN NVL( l_pos, 0 ) = 0;
PIPE ROW ( RTRIM( LTRIM( SUBSTR( l_tmp, 1, l_pos-1) ) ) );
l_tmp := SUBSTR( l_tmp, l_pos+1 );
END LOOP;
END str2tbl;
/
-- The problem solution
SELECT name,
project,
TRIM(COLUMN_VALUE) error
FROM t, TABLE(str2tbl(error));
परिणाम:
NAME PROJECT ERROR
---------- ---------- --------------------
108 test Err1
108 test Err2
108 test Err3
109 test2 Err1
इस तरह के दृष्टिकोण के साथ समस्या यह है कि अक्सर ऑप्टिमाइज़र को टेबल फ़ंक्शन की कार्डिनैलिटी का पता नहीं चलेगा और उसे एक अनुमान लगाना होगा। यह आपकी निष्पादन योजनाओं के लिए हानिकारक हो सकता है, इसलिए यह समाधान ऑप्टिमाइज़र के लिए निष्पादन आँकड़े प्रदान करने के लिए बढ़ाया जा सकता है।
आप इस क्वेरी को ऊपर दिए गए प्रश्न पर एक EXPLAIN PLAN चलाकर देख सकते हैं:
Execution Plan
----------------------------------------------------------
Plan hash value: 2402555806
----------------------------------------------------------------------------------------------
| Id | Operation | Name | Rows | Bytes | Cost (%CPU)| Time |
----------------------------------------------------------------------------------------------
| 0 | SELECT STATEMENT | | 16336 | 366K| 59 (0)| 00:00:01 |
| 1 | NESTED LOOPS | | 16336 | 366K| 59 (0)| 00:00:01 |
| 2 | TABLE ACCESS FULL | T | 2 | 42 | 3 (0)| 00:00:01 |
| 3 | COLLECTION ITERATOR PICKLER FETCH| STR2TBL | 8168 | 16336 | 28 (0)| 00:00:01 |
----------------------------------------------------------------------------------------------
भले ही संग्रह में केवल 3 मान हों, लेकिन अनुकूलक ने इसके लिए 8168 पंक्तियों (डिफ़ॉल्ट मान) का अनुमान लगाया है। यह पहली बार में अप्रासंगिक लग सकता है, लेकिन यह ऑप्टिमाइज़र के लिए उप-इष्टतम योजना के लिए निर्णय लेने के लिए पर्याप्त हो सकता है।
समाधान संग्रह के लिए आँकड़े प्रदान करने के लिए अनुकूलक एक्सटेंशन का उपयोग करना है:
-- Create the optimizer interface to the str2tbl function
CREATE OR REPLACE TYPE typ_str2tbl_stats AS OBJECT (
dummy NUMBER,
STATIC FUNCTION ODCIGetInterfaces ( p_interfaces OUT SYS.ODCIObjectList )
RETURN NUMBER,
STATIC FUNCTION ODCIStatsTableFunction ( p_function IN SYS.ODCIFuncInfo,
p_stats OUT SYS.ODCITabFuncStats,
p_args IN SYS.ODCIArgDescList,
p_string IN VARCHAR2,
p_delimiter IN CHAR DEFAULT ',' )
RETURN NUMBER
);
/
-- Optimizer interface implementation
CREATE OR REPLACE TYPE BODY typ_str2tbl_stats
AS
STATIC FUNCTION ODCIGetInterfaces ( p_interfaces OUT SYS.ODCIObjectList )
RETURN NUMBER
AS
BEGIN
p_interfaces := SYS.ODCIObjectList ( SYS.ODCIObject ('SYS', 'ODCISTATS2') );
RETURN ODCIConst.SUCCESS;
END ODCIGetInterfaces;
-- This function is responsible for returning the cardinality estimate
STATIC FUNCTION ODCIStatsTableFunction ( p_function IN SYS.ODCIFuncInfo,
p_stats OUT SYS.ODCITabFuncStats,
p_args IN SYS.ODCIArgDescList,
p_string IN VARCHAR2,
p_delimiter IN CHAR DEFAULT ',' )
RETURN NUMBER
AS
BEGIN
-- I'm using basically half the string lenght as an estimator for its cardinality
p_stats := SYS.ODCITabFuncStats( CEIL( LENGTH( p_string ) / 2 ) );
RETURN ODCIConst.SUCCESS;
END ODCIStatsTableFunction;
END;
/
-- Associate our optimizer extension with the PIPELINED function
ASSOCIATE STATISTICS WITH FUNCTIONS str2tbl USING typ_str2tbl_stats;
परिणामी निष्पादन योजना का परीक्षण:
Execution Plan
----------------------------------------------------------
Plan hash value: 2402555806
----------------------------------------------------------------------------------------------
| Id | Operation | Name | Rows | Bytes | Cost (%CPU)| Time |
----------------------------------------------------------------------------------------------
| 0 | SELECT STATEMENT | | 1 | 23 | 59 (0)| 00:00:01 |
| 1 | NESTED LOOPS | | 1 | 23 | 59 (0)| 00:00:01 |
| 2 | TABLE ACCESS FULL | T | 2 | 42 | 3 (0)| 00:00:01 |
| 3 | COLLECTION ITERATOR PICKLER FETCH| STR2TBL | 1 | 2 | 28 (0)| 00:00:01 |
----------------------------------------------------------------------------------------------
जैसा कि आप देख सकते हैं कि ऊपर की योजना पर कार्डिनैलिटी 8196 अनुमानित मूल्य नहीं है। यह अभी भी सही नहीं है क्योंकि हम एक स्ट्रिंग शाब्दिक के बजाय फ़ंक्शन के लिए एक कॉलम पास कर रहे हैं।
फ़ंक्शन कोड में कुछ बदलाव इस विशेष मामले में एक करीबी अनुमान देने के लिए आवश्यक होगा, लेकिन मुझे लगता है कि समग्र अवधारणा यहां बहुत स्पष्ट है।
इस उत्तर में प्रयुक्त str2tbl फ़ंक्शन मूल रूप से टॉम कायटे द्वारा विकसित किया गया था: https://asktom.oracle.com/pls/asktom/f?p=100:11 विस्तार ::::P11_QUESTION_ID:110634348061
इस प्रकार के लेखों को पढ़कर वस्तुगत प्रकारों के साथ जुड़ने की अवधारणा का पता लगाया जा सकता है:
http://www.oracle-developer.net/display.php?id=427
यहाँ वर्णित तकनीक 10g + में काम करती है।
REGEXP,XMLTABLEऔरMODELक्लॉज का उपयोग करते हुए , Oracle SQL