इसका नाम जाने बिना SQL डिफ़ॉल्ट बाधा कैसे छोड़ें?

Question

Microsoft SQL सर्वर में, मुझे पता है कि अगर एक कॉलम के लिए एक डिफ़ॉल्ट बाधा मौजूद है और एक डिफ़ॉल्ट बाधा को रोकने के लिए क्वेरी की जाँच करें:

IF EXISTS(SELECT * FROM sysconstraints
  WHERE id=OBJECT_ID('SomeTable')
  AND COL_NAME(id,colid)='ColName'
  AND OBJECTPROPERTY(constid, 'IsDefaultCnst')=1)    
ALTER TABLE SomeTable DROP CONSTRAINT DF_SomeTable_ColName

लेकिन डेटाबेस के पिछले संस्करणों में टाइपो के कारण, बाधा का नाम DF_SomeTable_ColNameया हो सकता है DF_SmoeTable_ColName।

बिना किसी SQL त्रुटियों के मैं डिफ़ॉल्ट बाधा कैसे हटा सकता हूं? डिफ़ॉल्ट बाधा नाम INFORMATION_SCHEMA तालिका में दिखाई नहीं देते हैं, जो चीजों को थोड़ा पेचीदा बना देता है।

इसलिए, 'इस तालिका / कॉलम में डिफ़ॉल्ट अवरोध हटाएं', या 'हटाएं DF_SmoeTable_ColName' जैसी कोई चीज , लेकिन इसे गलत मानने पर कोई त्रुटि न दें।

Comments

मैं SQL सर्वर के साथ कुशल नहीं हूं, क्या आपको इसका नाम पता चलने के बाद एक बाधा का नाम बदल सकता है? "ऑल्टर टेबल ओरेकल में कुछ नाम बदलने के लिए बाधा xxx"।

— Juergen Hartelt

Answer 1

मिच गेहूं के कोड पर विस्तार, निम्नलिखित स्क्रिप्ट बाधा को छोड़ने और गतिशील रूप से निष्पादित करने के लिए कमांड उत्पन्न करेगा।

declare @schema_name nvarchar(256)
declare @table_name nvarchar(256)
declare @col_name nvarchar(256)
declare @Command  nvarchar(1000)

set @schema_name = N'MySchema'
set @table_name = N'Department'
set @col_name = N'ModifiedDate'

select @Command = 'ALTER TABLE ' + @schema_name + '.[' + @table_name + '] DROP CONSTRAINT ' + d.name
 from sys.tables t
  join sys.default_constraints d on d.parent_object_id = t.object_id
  join sys.columns c on c.object_id = t.object_id and c.column_id = d.parent_column_id
 where t.name = @table_name
  and t.schema_id = schema_id(@schema_name)
  and c.name = @col_name

--print @Command

execute (@Command)

Comments

एक तालिका के लिए सभी विरोधाभासों को छोड़ने के लिए एक संस्करण देखने के लिए stackoverflow.com/a/15786313/2049986 की जाँच करें

— याकूब वैन लिंगेन

मैं का उपयोग sys.check_constraints , नहीं sys.default_constraints

— Kiquenet

यदि कुछ स्तंभों में कई डिफ़ॉल्ट बाधाएँ या चेक बाधाएँ बनी हों ,तो मान्य नहीं है , केवलक्वेरी में अंतिम बाधाओं के लिए निष्पादित की जाती हैं।

— किकेनेट

यह क्वेरी केवल डिफ़ॉल्ट बाधाओं को संबोधित करती है, जिनमें से प्रति कॉलम केवल एक ही हो सकती है। चेक की कमी से निपटना एक अलग समस्या है।

— फिलिप केली

मैंने इस उत्तर को गैर-डिफ़ॉल्ट स्कीमा नामों के लिए समर्थन जोड़ने के लिए अद्यतन किया है। आशा है कि आप बुरा नहीं मानेंगे, यदि आप चाहें तो मैं एक अलग उत्तर दे सकता हूँ।

— जकूब जानुसज़िविक्ज़

Answer 2

रोब फ़ार्ले के ब्लॉग पोस्ट से मदद मिल सकती है:

• अपना नाम जाने बिना एक डिफ़ॉल्ट बाधा को खोजने / छोड़ने के दो तरीके

कुछ इस तरह:

 declare @table_name nvarchar(256)
 declare @col_name nvarchar(256)
 set @table_name = N'Department'
 set @col_name = N'ModifiedDate'

 select t.name, c.name, d.name, d.definition
 from 
     sys.tables t
     join sys.default_constraints d on d.parent_object_id = t.object_id
     join sys.columns c on c.object_id = t.object_id
                           and c.column_id = d.parent_column_id
 where 
     t.name = @table_name
     and c.name = @col_name

Answer 3

मैंने पाया कि यह काम करता है और बिना किसी जोड़ के उपयोग करता है:

DECLARE @ObjectName NVARCHAR(100)
SELECT @ObjectName = OBJECT_NAME([default_object_id]) FROM SYS.COLUMNS
WHERE [object_id] = OBJECT_ID('[tableSchema].[tableName]') AND [name] = 'columnName';
EXEC('ALTER TABLE [tableSchema].[tableName] DROP CONSTRAINT ' + @ObjectName)

बस यह सुनिश्चित करें कि कॉलमनाम के चारों ओर कोष्ठक नहीं हैं क्योंकि क्वेरी सटीक मिलान की तलाश में है और यदि वह [कॉलमनाम] नहीं है तो कुछ भी नहीं लौटाएगा।

Comments

और यह उत्तर किसी अन्य उत्तर के विपरीत डिफ़ॉल्ट [dbo] के अलावा स्कीमा के साथ काम करता है।

— कंटैंगो

मैंने इसका परीक्षण नहीं किया है, लेकिन आप इसके चारों ओर एक WHILE (@ObjectName IS NOT NULL) जोड़कर कोशिश कर सकते हैं, SELECT (at) ObjectName = OBJECT_Name ([डिफ़ॉल्ट ...) से पहले TOP 1 डालें और केवल EXEC ('ALTER) चलाएं। TA ... अगर (पर) ObjectName NULL नहीं है।

— ScubaSteve

इस स्क्रिप्ट को बनाने के लिए IF @ObjectName IS NOT NULLEXEC कमांड से पहले जोड़ें

— सेवन

CHECK बाधाओं का उपयोग करके मेरे लिए काम नहीं कर रहा । [default_object_id])है 0 । मुझे NULL वैल्यू मिलती है ।

— किनिकेत

मीठा और सरल, लेकिन Microsoft डॉक्स के अनुसार इस तरह से काम करना हमेशा के लिए नहीं होगा। एक चेतावनी है कि यह दर्शाता है कि यह अगले संस्करण में दूर हो जाएगा docs.microsoft.com/en-us/sql/t-sql/statements/…

— Hopeless

Answer 4

कई स्तंभों के लिए बाधा छोड़ने के लिए:

declare @table_name nvarchar(256)

declare @Command nvarchar(max) = ''

set @table_name = N'ATableName'

select @Command = @Command + 'ALTER TABLE ' + @table_name + ' drop constraint ' + d.name + CHAR(10)+ CHAR(13)
from sys.tables t
join sys.default_constraints d on d.parent_object_id = t.object_id
join sys.columns c on c.object_id = t.object_id
     and c.column_id = d.parent_column_id
where t.name = @table_name and c.name in ('column1','column2','column3')

--print @Command

execute (@Command)

Answer 5

विस्तारित समाधान (तालिका स्कीमा को ध्यान में रखता है):

-- Drop default contstraint for SchemaName.TableName.ColumnName
DECLARE @schema_name NVARCHAR(256)
DECLARE @table_name NVARCHAR(256)
DECLARE @col_name NVARCHAR(256)
DECLARE @Command  NVARCHAR(1000)

set @schema_name = N'SchemaName'
set @table_name = N'TableName'
set @col_name = N'ColumnName'

SELECT @Command = 'ALTER TABLE [' + @schema_name + '].[' + @table_name + '] DROP CONSTRAINT ' + d.name
 FROM sys.tables t   
  JOIN sys.default_constraints d       
   ON d.parent_object_id = t.object_id  
  JOIN sys.schemas s
        ON s.schema_id = t.schema_id
  JOIN    sys.columns c      
   ON c.object_id = t.object_id      
    AND c.column_id = d.parent_column_id
 WHERE t.name = @table_name
    AND s.name = @schema_name 
  AND c.name = @col_name

EXECUTE (@Command)

Answer 6

एक डेटाबेस में सभी डिफ़ॉल्ट विरोधाभासों को छोड़ दें - नवरच (अधिकतम) सीमा के लिए सुरक्षित।

/* WARNING: THE SAMPLE BELOW; DROPS ALL THE DEFAULT CONSTRAINTS IN A DATABASE */ 
/* MAY 03, 2013 - BY WISEROOT  */
declare @table_name nvarchar(128)
declare @column_name nvarchar(128)
declare @df_name nvarchar(128)
declare @cmd nvarchar(128) 

declare table_names cursor for 
 SELECT t.name TableName, c.name ColumnName
 FROM sys.columns c INNER JOIN
     sys.tables t ON c.object_id = t.object_id INNER JOIN
     sys.schemas s ON t.schema_id = s.schema_id
     ORDER BY T.name, c.name

     open table_names
fetch next from table_names into @table_name , @column_name
while @@fetch_status = 0
BEGIN

if exists (SELECT top(1) d.name from sys.tables t join sys.default_constraints d on d.parent_object_id = t.object_id join sys.columns c on c.object_id = t.object_id and c.column_id = d.parent_column_id where t.name = @table_name and c.name = @column_name)
BEGIN
    SET @df_name = (SELECT top(1) d.name from sys.tables t join sys.default_constraints d on d.parent_object_id = t.object_id join sys.columns c on c.object_id = t.object_id and c.column_id = d.parent_column_id where t.name = @table_name and c.name = @column_name)
    select @cmd = 'ALTER TABLE [' + @table_name +  '] DROP CONSTRAINT [' +  @df_name + ']'
    print @cmd
    EXEC sp_executeSQL @cmd;
END

  fetch next from table_names into @table_name , @column_name
END

close table_names 
deallocate table_names

Comments

यदि कुछ कॉलमों में कई डिफ़ॉल्ट बाधाएँ या चेक बाधाएँ बनी हों ,तो मान्य नहीं , केवलक्वेरी में शीर्ष 1 बाधाओं के लिए निष्पादित किया गया।

— किनिकेत

Answer 7

सभी बाधाओं को ब्राउज़ करने के लिए इस कमांड को चलाएँ:

exec sp_helpconstraint 'mytable' --and look under constraint_name. 

यह कुछ इस तरह दिखेगा DF__Mytable__Column__[ABC123]:। तब तुम सिर्फ अड़चन छोड़ सकते हो।

Comments

मेरे लिए काम नहीं कर रहा है:exec sp_helpconstraint 'Roles2016.UsersCRM'

— Kiquenet

@Kiquenet केवल तालिका का नाम होना चाहिए: निष्पादित sp_helpconstraint 'Roles2016'

— बेक्ड इनफ़्लेशन

यह सिर्फ विदेशी प्रमुख बाधाओं को दिखा रहा है। डिफॉल्ट वैल्यू कॉन्स्टेंट नहीं

— मोरज

Answer 8

मुझे उम्मीद है कि यह उसी के लिए मददगार हो सकता है जिसके पास समान समस्या है। में ObjectExplorerखिड़की, अपने डेटाबेस का चयन करें => टेबल्स, => अपनी मेज => प्रतिबन्ध। यदि ग्राहक को स्तंभ समय बनाने पर परिभाषित किया गया है, तो आप स्तंभ नाम सहित बाधा का डिफ़ॉल्ट नाम देख सकते हैं। फिर उपयोग करें:

ALTER TABLE  yourTableName DROP CONSTRAINT DF__YourTa__NewCo__47127295;

(बाधा नाम सिर्फ एक उदाहरण है)

Answer 9

निम्नलिखित समाधान तालिका से एक कॉलम के विशिष्ट डिफ़ॉल्ट अवरोध को छोड़ देगा

Declare @Const NVARCHAR(256)

SET @Const = (
              SELECT TOP 1 'ALTER TABLE' + YOUR TABLE NAME +' DROP CONSTRAINT '+name
              FROM Sys.default_constraints A
              JOIN sysconstraints B on A.parent_object_id = B.id
              WHERE id = OBJECT_ID('YOUR TABLE NAME')
              AND COL_NAME(id, colid)='COLUMN NAME'
              AND OBJECTPROPERTY(constid,'IsDefaultCnst')=1
            )
 EXEC (@Const)

Answer 10

मेरे पास कुछ कॉलम थे जिनमें कई डिफ़ॉल्ट बाधाएं थीं, इसलिए मैं निम्नलिखित संग्रहीत कार्यविधि बनाता हूं:

CREATE PROCEDURE [dbo].[RemoveDefaultConstraints] @table_name nvarchar(256), @column_name nvarchar(256)
AS
BEGIN

    DECLARE @ObjectName NVARCHAR(100)

    START: --Start of loop
    SELECT 
        @ObjectName = OBJECT_NAME([default_object_id]) 
    FROM 
        SYS.COLUMNS
    WHERE 
        [object_id] = OBJECT_ID(@table_name) 
        AND [name] = @column_name;

    -- Don't drop the constraint unless it exists
    IF @ObjectName IS NOT NULL
    BEGIN
        EXEC ('ALTER TABLE '+@table_name+' DROP CONSTRAINT ' + @ObjectName)
        GOTO START; --Used to loop in case of multiple default constraints
    END
END
GO

-- How to run the stored proc.  This removes the default constraint(s) for the enabled column on the User table.
EXEC [dbo].[RemoveDefaultConstraints] N'[dbo].[User]', N'enabled'
GO

-- If you hate the proc, just get rid of it
DROP PROCEDURE [dbo].[RemoveDefaultConstraints]
GO

Answer 11

कुछ स्तंभों के लिए उपयोगी जिन्हें कई default constraints or check constraints बनाया गया था:

संशोधित https://stackoverflow.com/a/16359095/206730 स्क्रिप्ट

नोट: यह स्क्रिप्ट sys.check_constraints के लिए है

declare @table_name nvarchar(128)
declare @column_name nvarchar(128)
declare @constraint_name nvarchar(128)
declare @constraint_definition nvarchar(512)

declare @df_name nvarchar(128)
declare @cmd nvarchar(128) 

PRINT 'DROP CONSTRAINT [Roles2016.UsersCRM].Estado'

declare constraints cursor for 
 select t.name TableName, c.name ColumnName, d.name ConstraintName, d.definition ConstraintDefinition
 from sys.tables t   
 join sys.check_constraints d  on d.parent_object_id = t.object_id  
 join sys.columns c  on c.object_id = t.object_id      
 and c.column_id = d.parent_column_id
 where t.name = N'Roles2016.UsersCRM' and c.name = N'Estado'

open constraints
fetch next from constraints into @table_name , @column_name, @constraint_name, @constraint_definition
while @@fetch_status = 0
BEGIN
    print 'CONSTRAINT: ' + @constraint_name
    select @cmd = 'ALTER TABLE [' + @table_name +  '] DROP CONSTRAINT [' +  @constraint_name + ']'
    print @cmd
    EXEC sp_executeSQL @cmd;

  fetch next from constraints into @table_name , @column_name, @constraint_name, @constraint_definition
END

close constraints 
deallocate constraints

Answer 12

आपके द्वारा चलाने से पहले हमेशा स्क्रिप्ट और समीक्षा तैयार करें। स्क्रिप्ट के नीचे

  select 'Alter table dbo.' + t.name + ' drop constraint '+ d.name  
  from sys.tables t
  join sys.default_constraints d on d.parent_object_id = t.object_id
  join sys.columns c on c.object_id = t.object_id
       and c.column_id = d.parent_column_id
  where c.name in ('VersionEffectiveDate','VersionEndDate','VersionReasonDesc')
  order by t.name

Answer 13

declare @table_name nvarchar(100)
declare @col_name nvarchar(100)
declare @constraint nvarchar(100)
set @table_name = N'TableName'
set @col_name = N'ColumnName'

IF EXISTS (select       c.*
    from        sys.columns c 
    inner join  sys.tables t on t.object_id = c.object_id
    where       t.name = @table_name
    and         c.name = @col_name) 
BEGIN

select @constraint=d.name
from 
sys.tables t
join sys.default_constraints d on d.parent_object_id = t.object_id
join sys.columns c on c.object_id = t.object_id
and c.column_id = d.parent_column_id
where 
t.name = @table_name
and c.name = @col_name

    IF LEN(ISNULL(@constraint, '')) <> 0
    BEGIN
        DECLARE @sqlcmd VARCHAR(MAX)
        SET @sqlcmd = 'ALTER TABLE ' + QUOTENAME(@table_name) + ' DROP CONSTRAINT' + 
        QUOTENAME(@constraint);
        EXEC (@sqlcmd);

    END

END
GO

Answer 14

declare @ery nvarchar(max)
declare @tab nvarchar(max) = 'myTable'
declare @qu nvarchar(max) = 'alter table '+@tab+' drop constraint '

select @ery = (select bj.name from sys.tables as tb 
inner join sys.objects as bj 
on tb.object_id = bj.parent_object_id
where tb.name = @tab and bj.type = 'PK')

exec(@qu+@ery)

जरा देखो तो।

Comments

यहां तक ​​कि अगर आपका कोड एक समाधान लाता है, तो यह सबसे अच्छा है कि आप इसे थोड़ा स्पष्टीकरण के चारों ओर लपेटते हैं क्योंकि यह प्रश्न हल करता है।

— फेबियन