मैं बैच फ़ाइल में एक नई पंक्ति कैसे गूँज सकता हूँ?

Question

आप अपने बैच फ़ाइल आउटपुट से एक नई पंक्ति कैसे डाल सकते हैं?

मैं कुछ ऐसा करना चाहता हूं:

echo hello\nworld

जो उत्पादन होगा:

hello
world

Comments

मेरे लिए उपयोगी है। मुझे इको \ n \ n करना था | my_app.exe एक स्क्रिप्ट में। मैंने किया (गूंज। && गूंज।) | my_app.exe

— विग्नेश

आसान दृष्टिकोण "कोड शुरू होता है:"> इको हेलो और गूंज दुनिया, आपको क्या देगा यू की आवश्यकता

— prudviraj

आप एक अलग लाइन पर एक अदृश्य एससीआई chr (255) डाल सकते हैं जो एक नई लाइन को बल देगा। [Alt] कुंजी दबाए रखें और कीपैड पर 255 दबाएँ। यह chr (255) सम्मिलित करता है जो एक रिक्त वर्ग है। यानी " गूंज (alt + 255) " आप केवल कीपैड का उपयोग कर सकते हैं न कि क्वर्टी कीबोर्ड के शीर्ष पर!

— jwzumwalt

जैसे कंप्यूटर रिपेयरिंग का आधा हिस्सा इसे प्लग इन कर रहा है और इसे सॉफ्टवेयर डेवलप करने का आधा हिस्सा है, जिसे मैं स्पेस इंजीनियरिंग कहता हूं । हमें अपनी खाली लाइनों की जरूरत है।

— बॉब स्टीन

इस बारे में कैसा है ? echo Yes&echo No

— वैज्ञानिक_7

Answer 1

echo hello & echo.world

इसका मतलब है कि आप & echo.एक newline के लिए एक स्थिरांक के रूप में परिभाषित कर सकते हैं \n।

Comments

उदाहरण के लिए एक अवधि की आवश्यकता नहीं है, लेकिन आपको एक खाली खाली पंक्ति को प्रतिध्वनित करने की आवश्यकता है:echo. && echo hello && echo. && echo world

— मैट विल्की

क्या आप इसे एकल प्रतिध्वनि के साथ कर सकते हैं ताकि इसे एक फ़ाइल पर पुनर्निर्देशित किया जा सके?

— शाहबाज़

@ शहबाज -$ (echo Hello && echo World) > ./File.txt

— नाथन जेबी

अवधि "गूंज" में। मुझे कभी नहीं रोकता है। यह बहुत दिनांकित है, और अभी भी मैं हमेशा भूल जाता हूं कि डॉट को कमांड नाम के साथ कड़ाई से समाहित किया जाना चाहिए, जिसमें कोई रिक्त स्थान नहीं है। आपकी पोस्ट में कोई त्रुटि नहीं है, मैं इसे सिर्फ एक अनुस्मारक के रूप में लिख रहा हूं: "गूंज।" ! = "प्रतिध्वनि।" !

— quetzalcoatl

@quetzalcoatl, यह भी अजनबी हो जाता है। डॉट काम के अलावा अन्य किरदार भी। SS64 का कहना है कि बेहतर सिंटैक्स echo(बेहतर प्रदर्शन के लिए है (फिर भी कोई स्पेस माइंड नहीं है)। ईसीएचओ

— मैट विल्की

Answer 2

उपयोग:

echo hello
echo.
echo world

Comments

क्या एकल इको स्टेटमेंट के भीतर एक स्ट्रिंग प्रदान करते हुए यह संभव है?

— ब्रायन आर। बॉन्डी

आपको इसे एको इको स्टेटमेंट के साथ करने की आवश्यकता क्यों है; एक और होने में नुकसान कहाँ है?

— रोब

@ रब, मैं अभी इस समस्या में आया और इनमें से कोई भी काम नहीं किया। आपको मेरे उदाहरण में एक ही कथन में प्रतिध्वनित होने की आवश्यकता है। मैं HTML से कुछ टेक्स फाइल्स जेनरेट कर रहा हूँ और echo "Makefile contents (which has \n)" > Makefileकई इकोस के साथ मेकफाइल जेनरेट कर रहा हूँ , यह काम नहीं करेगा

— शाहबाज़

उन्हें (या &&) एक ही कथन में करने के लिए: उदाहरण के लिए, एक txt फ़ाइल में "hello \ nworld" डालने के लिए:(echo hello & echo world) >> ./test.txt

— नेड मार्टिन

एक फ़ाइल के लिए मल्टी-लाइन आउटपुट के लिए सिर्फ निम्न क्यों नहीं? echo line 1 > Makefileऔर फिर echo line 2 >> Makefile। >>आउटपुट के कारण फ़ाइल में जोड़ा जा सकता है, जो कि इस मामले के लिए आपके द्वारा आवश्यक व्यवहार है।

— dgnuff

Answer 3

यहां आप जाएं, इसमें निम्नलिखित के साथ एक .bat फ़ाइल बनाएं:

@echo off
REM Creating a Newline variable (the two blank lines are required!)
set NLM=^


set NL=^^^%NLM%%NLM%^%NLM%%NLM%
REM Example Usage:
echo There should be a newline%NL%inserted here.

echo.
pause

आपको निम्न की तरह आउटपुट देखना चाहिए:

There should be a newline
inserted here.

Press any key to continue . . .

आपको केवल REM कथनों के बीच कोड की आवश्यकता है, जाहिर है।

Comments

बहुत प्रभावशाली, क्या आप यह समझाने के लिए समय ले सकते हैं कि लाइन NL = ^ ^ ^ ^ ^% NLM %% NLM% ^% NLM %% NLM% कैसे काम करता है? मैं अपने सिर को गोल-गोल नहीं कर सकता

— एंडी मोरिस

@ कैंडी ने एक +8 टिप्पणी को एक वारंट का रूप दिया है: stackoverflow.com/questions/6379619/…

— मैट विल्की

यह दिखाने के लिए एक अद्भुत उदाहरण है कि cmd.exe और विंडोज बैच फाइलें पूरी तरह से पागल हैं!

— mivk 10

आत्म करने के लिए नोट: लाइन "सेट एनएलएम = ^" चाहिए कैरट के बाद कुछ भी नहीं है और करना होगा यह बाद 2 रिक्त लाइनों की है।

— मेनोट्रॉनिक

एक सरल विधि के लिए मेरा जवाब देखें। set nl=^&echo., तो बस echo hello %nl% worldएक ही प्रभाव पैदा करता है।

— कोल्टन

Answer 4

echo:खाली लाइन लिखने के लिए cmd / bat-files में एक मानक सुविधा है, जो आपके cmd- आउटपुट में एक नई लाइन का अनुकरण करती है:

@echo off
@echo line1
@echo:
@echo line2

सेमी-फाइल के ऊपर उद्धृत उद्धृत का आउटपुट:

line1

line2

Comments

वास्तव में, किसी भी UNUSED विशेष चर को काम करना चाहिए। मैं हमेशा / के उपयोग को प्रोत्साहित करता हूं क्योंकि स्लैश कमांड विकल्पों के लिए मानक चार है। इसके अलावा, मैं हमेशा डॉट के उपयोग की आलोचना करता हूं कि Microsoft में कोई व्यक्ति दुर्भाग्य से चुनता है क्योंकि कमांड: echo.com MS-DOS / Windows बैच कमांड प्रोसेसर के संस्करण के आधार पर अलग-अलग परिणाम देता है।

— आकिनी

केवल संस्करण जो हमेशा काम करता है echo(। ऐसा लगता है कि यह समस्याएं पैदा कर सकता है, लेकिन यह वास्तव में पूरी तरह से काम करता है। अन्य सभी रूपों में कम से कम एक स्थिति होती है जहां कमांड वांछित के रूप में प्रदर्शन नहीं करेगा।

— डेबनहम

@naxa - कुछ भी आधिकारिक नहीं, केवल सामूहिक ज्ञान कुछ बैच हैकर्स द्वारा व्युत्पन्न। लक्ष्य सिंटैक्स है जिसका उपयोग किसी भी मूल्य सहित ईसीएचओ के लिए किया जा सकता है, और कभी भी उम्मीद के अलावा कुछ भी प्राप्त करने के बारे में चिंता करने की आवश्यकता नहीं है। मुझे जो सबसे अच्छा सारांश पता है वह dostips.com/forum/viewtopic.php?p=4554#p4554 पर है । यह आपके द्वारा लटके हुए पत्तों की तरह है, लेकिन कोई भी ऐसा परिदृश्य सामने नहीं आया है जहां ECHO(विफल हो।

— डेबनहम

@ स्पेसर - उन सुझावों में से प्रत्येक के लिए विफलता के उदाहरण हैं। ध्यान से पढ़ें dostips.com/forum/viewtopic.php?p=4554#p4554 ।

— डेबनहम

@ स्पेसर एक स्टैंडअलोन प्रश्न के लिए यहां पर्याप्त गूंज चल रहा है। शायद "क्या वर्ण तुरंत अनुसरण कर सकते हैं echo, और उनके प्रभाव क्या हैं?"

— मैट विल्की

Answer 5

केन के उत्तर की तरह, लेकिन विलंबित विस्तार के उपयोग के साथ।

setlocal EnableDelayedExpansion
(set \n=^
%=Do not remove this line=%
)

echo Line1!\n!Line2
echo Works also with quotes "!\n!line2"

पहले एक एकल लाइनफ़ीड वर्ण बनाया जाता है और उसे \ n चर में सौंपा जाता है।
यह लाइन अंत में कार्यवाहक के रूप में काम करता है, अगले चरित्र से बचने की कोशिश करता है, लेकिन यदि यह एक लाइनफीड है तो इसे नजरअंदाज कर दिया जाता है और अगले चरित्र को पढ़ा जाता है और बच जाता है (भले ही यह एक लाइनफीड भी हो)।
तब आपको वर्तमान निर्देश को समाप्त करने के लिए तीसरी लाइनफीड की आवश्यकता होती है, अन्यथा तीसरी लाइन को एलएफ-चर से जोड़ा जाएगा।
यहां तक ​​कि बैच फ़ाइलों में CR / LF के साथ लाइन अंत है केवल LF महत्वपूर्ण हैं, क्योंकि Parser के इस चरण में CR को हटा दिया गया है।

विलंबित विस्तार का उपयोग करने का लाभ यह है, कि इसमें कोई विशेष चरित्र हैंडलिंग नहीं है।
echo Line1%LF%Line2विफल होगा, क्योंकि पार्सर सिंगल लाइनफीड पर पार्स करना बंद कर देता है।

SO पर अधिक स्पष्टीकरण हैं : Vista / DOS बैच (.bat) फ़ाइल में कई लाइनों पर लंबी कमांड विभाजित होती है
SO: विंडोज कमांड इंटरप्रेटर (CMD.EXE) पार्स स्क्रिप्ट कैसे करता है?

संपादित करें: से बचें echo.

यह सवाल का जवाब नहीं देता है, क्योंकि सवाल एकल के बारे में था echoजो कई लाइनों को आउटपुट कर सकता है।

लेकिन अन्य उत्तरों के बावजूद जो echo.एक नई लाइन बनाने का उपयोग करने का सुझाव देता है , यह ध्यान दिया जाना चाहिए कि echo.यह सबसे खराब है, क्योंकि यह बहुत धीमा है और यह पूरी तरह से विफल हो सकता है, क्योंकि cmd.exe नाम की एक फ़ाइल की खोज करता है ECHOऔर इसे शुरू करने का प्रयास करता है।

सिर्फ एक खाली लाइन की छपाई के लिए, आप इनमें से किसी एक का उपयोग कर सकते हैं

echo,
echo;
echo(
echo/
echo+
echo=

लेकिन के उपयोग echo., echo\या echo:, बचा जाना चाहिए के रूप में वे वास्तव में धीमी गति से हो सकता है, स्थान जहां स्क्रिप्ट नेटवर्क डिस्क की तरह, निष्पादित किया जाएगा के आधार पर।

Comments

यदि आप एक बैच सबरूटीन के पैरामीटर के रूप में newlines के साथ स्ट्रिंग पास कर रहे हैं, उदाहरण के लिए call :pause line1!\n!line2, सबरूटीन को setlocal EnableDelayedExpansionइसके साथ शुरू करें और setlocal DisableDelayedExpansionसमय-समय पर व्याख्या की जा रही नई कहानियों को रखने के लिए इसे समाप्त करें ।

— स्टीववे_ एमसीसी

पात्रों echo, echo; echo( echo/ echo+ echo=और बदमाश गैलरी के कलाकारों के लिए +1 echo. echo\ echo:। अब अगर आपको यह समझाने की कोशिश की जाती है कि पवित्र काम क्यों किया जाता है, तो मैं आपको एक मुफ्त बीयर देना चाहता हूँ।

— बॉब स्टीन

Answer 6

echo. पर्याप्त कथन।

यदि आपको एक पंक्ति में इसकी आवश्यकता है, तो इसका उपयोग करें &। उदाहरण के लिए,

echo Line 1 & echo. & echo line 3

के रूप में उत्पादन होगा:

Line 1

line 3

अब, कहते हैं कि तुम कुछ थोड़ा कट्टर चाहते हैं ...

set n=^&echo.
echo hello %n% world

आउटपुट

hello
world

फिर %n%जब भी आप एक इको स्टेटमेंट में एक नई लाइन चाहते हैं तो बस फेंक दें। यह \nविभिन्न भाषाओं में आपके उपयोग के अधिक करीब है ।

टूट - फूट

set n=इसके nबराबर चर सेट करता है:

^ अगले प्रतीक का अनुसरण करने के लिए नल:

&एक ही लाइन पर एक और कमांड करने का मतलब है। हम एररलेवल के बारे में परवाह नहीं करते हैं (इसके ज़ोर से रोने के लिए एक गूंज कथन), इसलिए कोई &&ज़रूरत नहीं है।

echo. इको स्टेटमेंट जारी रखता है।

यह सब काम करता है क्योंकि आप वास्तव में चर बना सकते हैं जो कोड हैं, और अन्य कमांड के अंदर उनका उपयोग करते हैं। यह एक यहूदी बस्ती समारोह की तरह है, क्योंकि बैच वास्तव में शेल स्क्रिप्टिंग भाषाओं का सबसे उन्नत नहीं है। यह केवल इसलिए काम करता है क्योंकि बैचों का खराब उपयोग, प्राकृतिक रूप से किलों, चरों, तैरने, तार आदि के बीच में डिजाइन नहीं करना।

यदि आप चालाक हैं, तो आप अन्य चीजों के साथ काम करने के लिए इसे प्राप्त कर सकते हैं। उदाहरण के लिए, इसका उपयोग टैब को प्रतिध्वनित करने के लिए

set t=^&echo.     ::there are spaces up to the double colon

Comments

उपयोग न करें echo.क्योंकि यह पहले उस नाम से एक फ़ाइल खोजने का प्रयास करता है। अन्य विराम चिह्नों का उपयोग करें, जैसेecho,

— मोनिका

Answer 7

जब किसी फ़ाइल में रीडायरेक्ट करने के लिए कुछ प्रतिध्वनित होता है, तो एकाधिक इको कमांड काम नहीं करेगा। मुझे लगता है कि शायद ">>" पुनर्निर्देशक एक अच्छा विकल्प है:

इको हैलो> अस्थायी
गूंज दुनिया >> अस्थायी

Comments

पहला उदाहरण, ">" का उपयोग करते हुए, एक नई फ़ाइल बनाएगा, दूसरा >> ">>" का उपयोग करके, एक मौजूदा फ़ाइल में संलग्न होगा (या यदि यह पहले से मौजूद नहीं है तो इसे बनाएं)।

— यमन दुर्जन

(echo hello && echo world) > tempनेथन जे। ब्रेयर द्वारा (वर्तमान) स्वीकार किए गए उत्तर कार्यों के लिए एक टिप्पणी में उल्लेख किया है।

— GeroldBroser ने मोनिका

Answer 8

जैसे ग्रिमट्रॉन का सुझाव है - इसे परिभाषित करने के लिए यहां एक त्वरित उदाहरण है:

@echo off
set newline=^& echo.
echo hello %newline%world

उत्पादन

C:\>test.bat
hello
world

Comments

यह वास्तव में "दुनिया" के बाद एक अतिरिक्त न्यूलाइन को प्रतिध्वनित करेगा

— ब्लूराजा - डैनी पफ्लुघोफ्ट

@ लगता है कि अनुगामी न्यूलाइन स्वयं बैच फ़ाइल का कार्य करती है। यदि आप echo hello %newline%worldपंक्ति को दोहराते हैं तो बीच में कोई रिक्त स्थान नहीं हैं।

— मैट विल्की

echo "Hello %newline% world"विफल रहता है क्योंकि यह उद्धरण के अंदर है। क्योंकि यह एक वास्तविक newline नहीं है ।

— जेब

Answer 9

यदि आपको किसी फ़ाइल में परिणाम डालने की आवश्यकता है, तो आप उपयोग कर सकते हैं

(echo a & echo. & echo b) > file_containing_multiple_lines.txt

Answer 10

आप भी ऐसा कर सकते हैं,

(for %i in (a b "c d") do @echo %~i)

उत्पादन होगा,

a
b
c d

ध्यान दें कि जब इसे एक बैच फ़ाइल में रखा जाता है, तो '%' दोगुना हो जाएगा।

(for %%i in (a b "c d") do @echo %%~i)

Comments

यह समाधान भी काम करता है यदि आप एक एम्परसेंड और एक नई पंक्ति के बजाय प्रतिध्वनित करना चाहते हैं।

— parvus

मुझे लगता है कि मैं एक बग पाया: *चार

Answer 11

अगर कोई यहाँ आता है क्योंकि वे MINGW मेकफाइल से एक खाली लाइन को प्रतिध्वनित करना चाहते हैं, तो मैंने उपयोग किया

@cmd /c echo.

बस echo.खूंखार process_begin: CreateProcess(NULL, echo., ...) failed.त्रुटि संदेश का कारण बनता है ।

मुझे आशा है कि यह कम से कम एक अन्य व्यक्ति को वहां से बाहर निकालने में मदद करता है :)

Comments

लेकिन यह सवाल नहीं है। Downvote!

— मेसालकोड

यकीन नहीं तो व्यंग्य या नहीं: पी

— वेन उरोदा

अपने इनबॉक्स में देख कर पता करें: D

— Mesalcode

Answer 12

अगर किसी को स्ट्रिंग में शाब्दिक प्रसिद्ध \ n का उपयोग करने की आवश्यकता होती है जिसे एक चर में पारित किया जा सकता है, तो नीचे दिए गए Hello.bat स्क्रिप्ट की तरह एक कोड लिख सकते हैं:

@echo off
set input=%1
if defined input (
    set answer=Hi!\nWhy did you call me a %input%?
) else (
    set answer=Hi!\nHow are you?\nWe are friends, you know?\nYou can call me by name.
)

setlocal enableDelayedExpansion
set newline=^


rem Two empty lines above are essential
echo %answer:\n=!newline!%

इस तरह से एक जगह पर मल्टीलाइन आउटपुट तैयार किया जा सकता है, यहां तक ​​कि अन्य स्क्रिट या बाहरी फाइल में भी, और दूसरे में प्रिंट किया जा सकता है।

लाइन ब्रेक न्यूलाइन चर में आयोजित किया जाता है। अपने मूल्य प्रतिस्थापित किया जाना चाहिए के बाद गूंज लाइन तो मैं का उपयोग का विस्तार होता है setlocal enableDelayedExpansion विस्मयादिबोधक लक्षण जिन्हें निष्पादन पर चर का विस्तार कर सकें। और निष्पादन के विकल्प \ N के साथ न्यू लाइन सामग्री (कम से वाक्य रचना के लिए देखो मदद सेट )। हम निश्चित रूप से उपयोग कर सकते हैं ! उत्तर सेट करते समय but \ n अधिक सुविधाजनक है। इसे बाहर से पास किया जा सकता है ( Hello R2 \ nD2 आज़माएं ), जहाँ किसी को भी लाइन ब्रेक को पकड़ने वाले चर का नाम नहीं पता है (हाँ, नमस्ते C3! Newline! P0 उसी तरह काम करता है)।

उपर्युक्त उदाहरण का उपयोग उप-समूह या स्टैंडअलोन बैच के लिए किया जा सकता है, जैसे call:mlecho Hi\nI'm your comuter:

:mlecho
setlocal enableDelayedExpansion
set text=%*
set nl=^


echo %text:\n=!nl!%
goto:eof

कृपया ध्यान दें, अतिरिक्त बैकस्लैश स्क्रिप्ट को पार्सिंग \ n सबस्ट्रिंग से नहीं रोकेगा।

Comments

आप मूल रूप से जेब के उत्तर के समान ही काम कर रहे हैं।

— स्क्वाशमैन

मेरे द्वारा पढ़े गए उत्तर बहुत मददगार थे, लेकिन मुझे एक स्क्रिप्ट ओडी सबरूटीन को कॉल करने की आवश्यकता थी, जो कि पार्स करेगा \ n इसलिए मैं हर जगह ट्रिक को लागू करने से बचूँगा। इसे एक समाधान को परिष्कृत करने की आवश्यकता थी और मैंने इस शोधन को साझा किया। आशा है कि इसने किसी भी जानवर को नुकसान नहीं पहुंचाया।

— तोमर

Answer 13

इसने मेरे लिए काम किया, कोई विलंबित विस्तार आवश्यक नहीं:

@echo off
(
echo ^<html^> 
echo ^<body^>
echo Hello
echo ^</body^>
echo ^</html^>
)
pause

यह इस तरह से आउटपुट लिखता है:

<html>
<body>
Hello
</body>
</html>
Press any key to continue . . .

Comments

-1 echo asdf >myfile.txtठीक उसी परिणाम का उत्पादन करेगा। echoस्ट्रिंग के अंत में एक नई लाइन जोड़ता है।

— ब्लूराजा - डैनी पफ्लुगुएफ्ट

महान उत्तर, एकमात्र व्यक्ति होने के नाते जिसने नई लाइनों के लिए कोष्ठक का उपयोग करने के मूल्य को मान्यता दी। मेरा मानना ​​है कि डॉस के निर्माताओं ने आपको इसे करने के लिए कैसे प्रेरित किया।

— दिजांगोफ़न

Answer 14

बैच में एक नई लाइन शुरू करने के लिए, आपको बस "इको [" जोड़ना है, जैसे:

echo Hi!
echo[
echo Hello!

Comments

यह धीमा है और यह तब विफल हो जाता है जब कोई फ़ाइल नाम के साथ मौजूद होती हैecho[.bat

— jeb

क्या? इसे तुरंत काम करना चाहिए, और बस गूंज [.bat फ़ाइल को भी हटाना चाहिए।

— प्रिकोटेक

यह गूंज के रूप में बहुत सटीक एक ही बात है। वाक्य - विन्यास।

— प्रायरोटेक

हाँ और echo.एक बुरा समाधान भी है।

— जेब

जैसा कि पिछले उत्तरों में देखा जा सकता है, यह पहले पथ पर एक फ़ाइल का पता लगाने की कोशिश करेगा, जो इसे इतना धीमा होने का कारण बनता है। उसी के लिए सच है echo.। आपके स्क्रिप्ट के उपयोगकर्ताओं को उनके सिस्टम पर फ़ाइलों को हटाने के लिए सिर्फ इसलिए कि आपकी स्क्रिप्ट को एक नई पंक्ति की आवश्यकता है, मेरे लिए अच्छे डिजाइन की तरह नहीं है।

— हाबिल

Answer 15

केन और जेब समाधान अच्छी तरह से काम करता है।

लेकिन नई लाइनें केवल एक एलएफ चरित्र के साथ उत्पन्न होती हैं और मुझे सीआरएलएफ वर्ण (विंडोज संस्करण) की आवश्यकता होती है।

इसके लिए, स्क्रिप्ट के अंत में, मैंने LF को CRLF में बदल दिया है।

उदाहरण:

TYPE file.txt | FIND "" /V > file_win.txt
del file.txt
rename file_win.txt file.txt

Answer 16

आप @echo(@echo + [space] + [असुरक्षित जगह] का उपयोग कर सकते हैं )

नोट: असुरक्षित स्थान को Alt + 0160 के साथ प्राप्त किया जा सकता है

आशा है ये मदद करेगा :)

[संपादित करें] हम्म तुम सही हो, मुझे मेकफाइल में इसकी आवश्यकता थी, यह पूरी तरह से वहां काम करता है। मुझे लगता है कि मेरा जवाब बैच फ़ाइलों के लिए अनुकूलित नहीं है ... मेरा बुरा।

Comments

मुझे ECHO ist eingeschaltet (ON).खाली लाइन नहीं मिली, मैंने cmd-प्रॉम्प्ट पर कोशिश की

— jeb

वह नॉन-ब्रेकिंग स्पेस है, न्यूलाइन नहीं।

— Ry-

Answer 17

यह समाधान काम करता है (परीक्षण):

type nul | more /e /p

यह पृथक लाइन लाइन को कैरिज रिटर्न लाइन फीड संयोजन में परिवर्तित करता है।

Comments

लेकिन यह कैसे एक पाठ के बीच एक नई रेखा जोड़ता है? सवाल हैecho hello \n world

— जेब

मेरे नीचे से। यह सवाल का जवाब नहीं है

— मेसालकोड

Answer 18

मैं इसे किसी भी सरल से नहीं बना सकता:

echo echo hello^&echo world^&pause>silly.bat                       
call silly.bat