जांचें कि क्या सेल वैल्यू कॉलम में मौजूद है, और फिर NEXT सेल का मान प्राप्त करें

Question

यह जाँचने के बाद कि क्या स्तंभ में सेल वैल्यू मौजूद है, मुझे मिलान सेल के आगे सेल का मान प्राप्त करने की आवश्यकता है । उदाहरण के लिए, मैं जाँचता हूँ कि क्या मान cell A1मौजूद है column B, और यह मानकर मेल खाता है B5, तो मुझे मूल्य चाहिए cell C5।

समस्या के पहले आधे हिस्से को हल करने के लिए, मैंने यह किया ...

=IF(ISERROR(MATCH(A1,B:B, 0)), "No Match", "Match")

... और यह काम कर गया। फिर, SO पर पहले के उत्तर के लिए धन्यवाद , मैं मिलान सेल की पंक्ति संख्या भी प्राप्त करने में सक्षम था:

=IF(ISERROR(MATCH(A1,B:B, 0)), "No Match", "Match on Row " & MATCH(A1,B:B, 0))

तो स्वाभाविक रूप से, अगले सेल का मूल्य पाने के लिए, मैंने कोशिश की ...

=IF(ISERROR(MATCH(A1,B:B, 0)), "No Match", C&MATCH(A1,B:B, 0))

... और यह काम नहीं करता है।

मैं क्या खो रहा हूँ? मैं वांछित परिणाम प्राप्त करने के लिए दिए गए पंक्ति संख्या में कॉलम संख्या को कैसे जोड़ सकता हूं?

Answer 1

एक अलग फ़ंक्शन का उपयोग करें, जैसे VLOOKUP:

=IF(ISERROR(MATCH(A1,B:B, 0)), "No Match", VLOOKUP(A1,B:C,2,FALSE))

Comments

धन्यवाद! यह भी काम करता है! और मुझे लगता है कि VLOOKUP(A1, B:C, 2, FALSE)निश्चित सीमा का उपयोग करने के बजाय इसका उपयोग करना बेहतर होगा (ताकि बढ़ती हुई लुक-अप सरणी को समायोजित किया जा सके)?

— SNag

हाँ, बस एक परीक्षण के रूप में इस तय सीमा का इस्तेमाल किया। मेरे जवाब में इसे संपादित किया।

— कस्टमएक्सएक्स

आप IFERRORयहाँ की जरूरत नहीं है। यह इसके बिना ठीक काम करता है, क्योंकि मैच होने पर ही VLOOKUP को निष्पादित किया जाता है।

— 14

ऊप्स! मुझे लगता है कि गलत कॉलम में परीक्षण किया गया है: पी वास्तव में IFERROR के बिना यह पूरी तरह से भी काम करता है: P

— CustomX

यह पुराने से पुराना है, लेकिन मैं सिर्फ यह कहना चाहता था कि मैं वर्षों से इसका उपयोग कर रहा हूं और यह वास्तव में मुझे परेशान करता है कि आपको कभी भी सर्वश्रेष्ठ उत्तर नहीं दिया गया। मुझे लगता है कि यह कई स्तंभों की तुलना करने के लिए तालिका को मापनीय बनाता है।

— डफडफ

Answer 2

T.thielemans के उत्तर के बाद , मैंने बस यही काम किया

=VLOOKUP(A1, B:C, 2, FALSE) 

ठीक काम करता है और वही करता है जो मैं चाहता था, सिवाय इसके कि वह #N/Aगैर मैचों के लिए लौटे ; इसलिए यह उस मामले के लिए उपयुक्त है जहां यह ज्ञात है कि मूल्य निश्चित रूप से लुक-अप कॉलम में मौजूद है।

संपादित करें (t.thielemans की टिप्पणी के आधार पर): गैर-मैचों

से बचने के #N/Aलिए, करें:

=IFERROR(VLOOKUP(A1, B:C, 2, FALSE), "No Match")

Comments

इसकी जगह इसका इस्तेमाल करें IFERROR(VLOOKUP(A1, B:C, 2, FALSE),0)। मैंने इसे अपने उत्तर में भी जोड़ा। 0 जो कुछ भी आप चाहते हैं उसका मूल्य होना :) (कोड में इसका उपयोग करने पर कोई मिलान नहीं होने पर कोई मिलान नहीं होगा);

— CustomX

Answer 3

इस बारे में कैसा है?

=IF(ISERROR(MATCH(A1,B:B, 0)), "No Match", INDIRECT(ADDRESS(MATCH(A1,B:B, 0), 3)))

कॉलम सी के लिए अंत में "3" का मतलब है।

Comments

बहुत खुबस! मैंने बस यही कोशिश की कि ( एक्सेल पर आधारित : पंक्ति और स्तंभ संख्याओं को देखते हुए एक सेल की सामग्री प्राप्त करें ), और मेरे स्वयं के प्रश्न का उत्तर देने वाला था, लेकिन आपने मुझे इसे हरा दिया! धन्यवाद, यह बहुत अच्छा काम करता है!

— एसएनएग