Sub test()
thesentence = InputBox("Type the filename with full extension", "Raw Data File")
Range("A1").Value = thesentence
If Dir("thesentence") <> "" Then
MsgBox "File exists."
Else
MsgBox "File doesn't exist."
End If
End Sub
इसमें जब मैं इनपुट बॉक्स से टेक्स्ट वैल्यू पिक करता हूं, तो यह काम नहीं करता है। यदि फिर भी, यदि निकालें "the sentence"तो से Dir()और कोड में एक वास्तविक नाम के साथ बदलने के लिए, यह काम करता है। क्या कोई मदद कर सकता है?
जवाबों:
नोट आपके कोड में Dir("thesentence")जो होना चाहिए Dir(thesentence)।
इसमें अपना कोड बदलें
Sub test()
thesentence = InputBox("Type the filename with full extension", "Raw Data File")
Range("A1").Value = thesentence
If Dir(thesentence) <> "" Then
MsgBox "File exists."
Else
MsgBox "File doesn't exist."
End If
End Sub
FileDialogउपयोगकर्ता को फ़ाइल सिस्टम से फ़ाइल लेने के लिए Office ऑब्जेक्ट का उपयोग करें । अपने VB प्रोजेक्ट में या VBA संपादक में एक संदर्भ जोड़ें Microsoft Office Libraryऔर मदद देखें। यह लोगों को पूर्ण पथ में प्रवेश करने से बहुत बेहतर है।
यहां msoFileDialogFilePickerउपयोगकर्ता को कई फ़ाइलों को चुनने की अनुमति देने के लिए एक उदाहरण है । आप भी इस्तेमाल कर सकते हैं msoFileDialogOpen।
'Note: this is Excel VBA code
Public Sub LogReader()
Dim Pos As Long
Dim Dialog As Office.FileDialog
Set Dialog = Application.FileDialog(msoFileDialogFilePicker)
With Dialog
.AllowMultiSelect = True
.ButtonName = "C&onvert"
.Filters.Clear
.Filters.Add "Log Files", "*.log", 1
.Title = "Convert Logs to Excel Files"
.InitialFileName = "C:\InitialPath\"
.InitialView = msoFileDialogViewList
If .Show Then
For Pos = 1 To .SelectedItems.Count
LogRead .SelectedItems.Item(Pos) ' process each file
Next
End If
End With
End Sub
बहुत सारे विकल्प हैं, इसलिए आपको उन सभी को समझने के लिए पूर्ण सहायता फ़ाइलों को देखने की आवश्यकता होगी। आप Office 2007 FileDialog ऑब्जेक्ट के साथ शुरू कर सकते हैं (बेशक, आपको उस संस्करण के लिए सही सहायता खोजने की आवश्यकता होगी जो आप उपयोग कर रहे हैं)।
@UberNubIsTrue से fileExists में सुधार:
Function fileExists(s_directory As String, s_fileName As String) As Boolean
Dim obj_fso As Object, obj_dir As Object, obj_file As Object
Dim ret As Boolean
Set obj_fso = CreateObject("Scripting.FileSystemObject")
Set obj_dir = obj_fso.GetFolder(s_directory)
ret = False
For Each obj_file In obj_dir.Files
If obj_fso.fileExists(s_directory & "\" & s_fileName) = True Then
ret = True
Exit For
End If
Next
Set obj_fso = Nothing
Set obj_dir = Nothing
fileExists = ret
End Function
संपादित करें: छोटा संस्करण
' Check if a file exists
Function fileExists(s_directory As String, s_fileName As String) As Boolean
Dim obj_fso As Object
Set obj_fso = CreateObject("Scripting.FileSystemObject")
fileExists = obj_fso.fileExists(s_directory & "\" & s_fileName)
End Function
बस उन भाषण के निशान से छुटकारा पाएं
Sub test()
Dim thesentence As String
thesentence = InputBox("Type the filename with full extension", "Raw Data File")
Range("A1").Value = thesentence
If Dir(thesentence) <> "" Then
MsgBox "File exists."
Else
MsgBox "File doesn't exist."
End If
End Sub
यह वह है जो मुझे पसंद है:
Option Explicit
Enum IsFileOpenStatus
ExistsAndClosedOrReadOnly = 0
ExistsAndOpenSoBlocked = 1
NotExists = 2
End Enum
Function IsFileReadOnlyOpen(FileName As String) As IsFileOpenStatus
With New FileSystemObject
If Not .FileExists(FileName) Then
IsFileReadOnlyOpen = 2 ' NotExists = 2
Exit Function 'Or not - I don't know if you want to create the file or exit in that case.
End If
End With
Dim iFilenum As Long
Dim iErr As Long
On Error Resume Next
iFilenum = FreeFile()
Open FileName For Input Lock Read As #iFilenum
Close iFilenum
iErr = Err
On Error GoTo 0
Select Case iErr
Case 0: IsFileReadOnlyOpen = 0 'ExistsAndClosedOrReadOnly = 0
Case 70: IsFileReadOnlyOpen = 1 'ExistsAndOpenSoBlocked = 1
Case Else: IsFileReadOnlyOpen = 1 'Error iErr
End Select
End Function 'IsFileReadOnlyOpen
Function FileExists(fullFileName As String) As Boolean
FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function
बहुत अच्छी तरह से, लगभग, मेरी साइट पर काम करता है। अगर मैं इसे "" खाली स्ट्रिंग के साथ कहता हूं, तो Dir " connection.odc " देता है !! बहुत अच्छा होगा यदि आप लोग अपना परिणाम साझा कर सकते हैं।
वैसे भी, मुझे यह पसंद है:
Function FileExists(fullFileName As String) As Boolean
If fullFileName = "" Then
FileExists = False
Else
FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End If
End Function
dir("")कि आपको वर्तमान निर्देशिका में पहली फ़ाइल का नाम दिया गया है। आपके मामले में यह एक फाइल थी connection.odc।
Function FileExists(fullFileName As String) As Boolean
FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function
मुझे यकीन नहीं है कि विशेष रूप से आपके कोड में क्या गलत है, लेकिन मैं इस फ़ंक्शन का उपयोग करता हूं जो मैंने पाया ऑनलाइन (टिप्पणियों में URL) अगर कोई फ़ाइल मौजूद है तो जाँच के लिए:
Private Function File_Exists(ByVal sPathName As String, Optional Directory As Boolean) As Boolean
'Code from internet: http://vbadud.blogspot.com/2007/04/vba-function-to-check-file-existence.html
'Returns True if the passed sPathName exist
'Otherwise returns False
On Error Resume Next
If sPathName <> "" Then
If IsMissing(Directory) Or Directory = False Then
File_Exists = (Dir$(sPathName) <> "")
Else
File_Exists = (Dir$(sPathName, vbDirectory) <> "")
End If
End If
End Function
? dir$("C:\Users\Chloe\AppData\Local\Temp\")उस निर्देशिका में पहली फ़ाइल देगा, और यह "" के बराबर नहीं होगा, इसलिए, यह तब भी सही होगा जब आप Directoryतर्क छोड़ देंगे या इसे गलत पर सेट कर देंगे ।
बहुत पुरानी पोस्ट, लेकिन जब से मैंने इसमें कुछ संशोधन किए हैं, तो मुझे लगा कि मैं साझा करूँगा। यदि आप यह देखने के लिए जाँच कर रहे हैं कि कोई निर्देशिका मौजूद है, तो आप vbDirectory तर्क को Dir फ़ंक्शन में जोड़ना चाहते हैं, अन्यथा आप 0हर बार वापस आएँगे । (संपादित करें: यह रॉय के जवाब के जवाब में था, लेकिन मैंने गलती से इसे एक नियमित उत्तर बना दिया था।)
Private Function FileExists(fullFileName As String) As Boolean
FileExists = Len(Dir(fullFileName, vbDirectory)) > 0
End Function
अन्य उत्तरों के आधार पर मैं अपने एक-लाइनर्स को साझा करना चाहूंगा जो डायर और फाइलों के लिए काम करना चाहिए :
Len(Dir(path)) > 0 or Or Len(Dir(path, vbDirectory)) > 0 'version 1 - ... <> "" should be more inefficient generally
Len(Dir(path))निर्देशिका के लिए काम नहीं किया (एक्सेल 2010 / Win7))CreateObject("Scripting.FileSystemObject").FileExists(path) 'version 2 - could be faster sometimes, but only works for files (tested on Excel 2010/Win7)
PathExists(path)समारोह के रूप में :
Public Function PathExists(path As String) As Boolean
PathExists = Len(Dir(path)) > 0 Or Len(Dir(path, vbDirectory)) > 0
End Function