मैं कर्सर लूप में उपयोग के लिए कई कॉलम कैसे ला सकता हूं?

Question 1

जब मैं एक कर्सर लूप के अंदर निम्न SQL स्निपेट चलाने की कोशिश करता हूं,

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

मुझे निम्न संदेश मिले,

Msg 15248, स्तर 11, राज्य 1, प्रक्रिया sp_rename, लाइन 213
या तो पैरामीटर @objnameअस्पष्ट है या दावा किया गया है @objtype(COLUMN) गलत है।

क्या गलत है और मैं इसे कैसे ठीक करूं? मैंने कोष्ठक में स्तंभ नाम लपेटने की कोशिश की [], और ""कुछ खोज परिणामों के दोहरे उद्धरणों का सुझाव दिया।

1 संपादित करें -

यहाँ पूरी स्क्रिप्ट है। मैं नाम को तालिका नाम कैसे पास करूं? मुझे यकीन नहीं है कि कैसे करना है क्योंकि कॉलम के नाम कई तालिकाओं में से एक में हैं।

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

संपादन 2 - स्क्रिप्ट को उन स्तंभों के नाम बदलने के लिए डिज़ाइन किया गया है जिनके नाम एक पैटर्न से मेल खाते हैं, इस मामले में "pct" उपसर्ग के साथ। स्तंभ डेटाबेस के भीतर विभिन्न प्रकार की तालिकाओं में होते हैं। सभी तालिका नाम "TestData" के साथ उपसर्ग किए गए हैं।

Question 2

यहाँ थोड़ा संशोधित संस्करण है। परिवर्तनों को कोड कमेंट्री के रूप में नोट किया जाता है।

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION