VBA का उपयोग कर एक फ़ोल्डर में फ़ाइलों के माध्यम से लूप?

Question

मैं एक निर्देशिका का उपयोग कर फ़ाइलों के माध्यम से पाश करना चाहते हैं VBA 2010 में एक्सेल में।

पाश में, मुझे आवश्यकता होगी:

• फ़ाइल नाम, और
• वह दिनांक जिस पर फ़ाइल स्वरूपित की गई थी।

मैंने निम्नलिखित को कोडित किया है जो ठीक काम करता है यदि फ़ोल्डर में 50 से अधिक फाइलें नहीं हैं, अन्यथा यह हास्यास्पद रूप से धीमा है (मुझे इसकी आवश्यकता> 10000 फ़ाइलों वाले फ़ोल्डर के साथ काम करने के लिए है)। इस कोड की एकमात्र समस्या यह है कि देखने के लिए ऑपरेशन में file.nameबहुत अधिक समय लगता है।

कोड है कि काम करता है, लेकिन बहुत धीमी है (प्रति 100 फ़ाइलों में 15 सेकंड) waaaaaay है:

Sub LoopThroughFiles()
   Dim MyObj As Object, MySource As Object, file As Variant
   Set MySource = MyObj.GetFolder("c:\testfolder\")
   For Each file In MySource.Files
      If InStr(file.name, "test") > 0 Then
         MsgBox "found"
         Exit Sub
      End If
   Next file
End Sub

---

समस्या सुलझ गयी:

1. मेरी समस्या का समाधान Dirएक विशेष तरीके से उपयोग करके नीचे हल किया गया है (15000 फ़ाइलों के लिए 20 सेकंड) और कमांड का उपयोग करके समय टिकट की जांच के लिए FileDateTime।
2. खाते में 20 सेकंड के नीचे से एक और जवाब लेते हुए 1 सेकंड से भी कम हो जाता है।

Comments

आपका प्रारंभिक समय अभी भी VBA के लिए धीमा लगता है। क्या आप Application.ScreenUpdating = false का उपयोग कर रहे हैं?

— मिचेल वैन डेर ब्लोंक

आप लापता हो रहे हैं codeसेट MyObj = नई FileSystemObject

— baldmosher

मुझे यह दु: खद लगता है कि लोग एफएसओ को "धीमा" कहने के लिए जल्दी हैं, लेकिन किसी ने प्रदर्शन के दंड का उल्लेख नहीं किया है जिसके खिलाफ आप देर से बाध्य कॉल के बजाय बस शुरुआती बंधन का उपयोग करके बच सकते हैं Object।

— मैथ्यू गुइंडन

Answer 1

यहाँ एक फंक्शन के रूप में मेरी व्याख्या है:

'#######################################################################
'# LoopThroughFiles
'# Function to Loop through files in current directory and return filenames
'# Usage: LoopThroughFiles ActiveWorkbook.Path, "txt" 'inputDirectoryToScanForFile
'# /programming/10380312/loop-through-files-in-a-folder-using-vba
'#######################################################################
Function LoopThroughFiles(inputDirectoryToScanForFile, filenameCriteria) As String

    Dim StrFile As String
    'Debug.Print "in LoopThroughFiles. inputDirectoryToScanForFile: ", inputDirectoryToScanForFile

    StrFile = Dir(inputDirectoryToScanForFile & "\*" & filenameCriteria)
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir

    Loop

End Function

Comments

क्यों काम करते हैं, जब कुछ भी वापस नहीं किया जाता है? यह brettdj द्वारा दिए गए उत्तर के समान नहीं है, सिवाय इसके कि यह किसी फ़ंक्शन में संलग्न है

— Shafeek

Answer 2

Dirवाइल्ड कार्ड लेता है ताकि आप testसामने वाले के लिए फ़िल्टर जोड़ने और प्रत्येक फ़ाइल के परीक्षण से बचने में बड़ा अंतर कर सकें

Sub LoopThroughFiles()
    Dim StrFile As String
    StrFile = Dir("c:\testfolder\*test*")
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir
    Loop
End Sub

Comments

महान। इसने 20 सेकंड से <1 सेकंड तक रनटाइम में सुधार किया। यह एक बड़ा सुधार है, क्योंकि कोड बहुत बार चलाया जाएगा। धन्यवाद!!

— टाइरेक्स

यह इसलिए हो सकता है क्योंकि डू जबकि ... लूप तब बेहतर है जबकि ... वेंड। अधिक जानकारी यहाँ stackoverflow.com/questions/32728334/…

— Hila DG

मुझे लगता है कि सुधार के स्तर (20 - xxx बार) द्वारा नहीं लगता - मुझे लगता है कि इसके वाइल्डकार्ड को फर्क पड़ता है।

— brettdj

डीआईआर () छिपी हुई फाइलों को वापस नहीं करता है।

— हामिश

@hamish, आप विभिन्न प्रकार की फ़ाइलों (छिपी, सिस्टम, आदि) को वापस करने के लिए अपने तर्क को बदल सकते हैं - MS प्रलेखन देखें: docs.microsoft.com/en-us/office/vba/language/reference/…

— Vincent

Answer 3

डिर बहुत तेज लग रहा है।

Sub LoopThroughFiles()
    Dim MyObj As Object, MySource As Object, file As Variant
   file = Dir("c:\testfolder\")
   While (file <> "")
      If InStr(file, "test") > 0 Then
         MsgBox "found " & file
         Exit Sub
      End If
     file = Dir
  Wend
End Sub

Comments

अापका बहुत - बहुत धन्यवाद। मैं Dir का उपयोग करता हूं, लेकिन मुझे नहीं पता था कि आप इसे इस तरह भी उपयोग कर सकते हैं। कमांड के अलावा FileDateTimeमेरी समस्या हल हो गई है।

— tyrex

फिर भी एक सवाल। मैं गंभीर रूप से गति में सुधार कर सकता हूं यदि डीआईआर सबसे हाल की फाइलों के साथ शुरू होगा। क्या आपको ऐसा करने का कोई तरीका दिखाई देता है?

— टाइरेक्स

मेरे बाद के प्रश्न को brettdj से नीचे टिप्पणी द्वारा निपटाया गया है।

— टाइरेक्स

notहालांकि डिर traverse the whole directory tree। मामले में आवश्यक: analystcave.com/vba-dir-function-how-to-traverse-directories/…

— AnalystCave.com

अन्य डिर कमांड द्वारा डीआर को भी बाधित किया जाएगा, इसलिए यदि आप एक सबरूटिन चलाते हैं जिसमें डीआर होता है, तो यह आपके मूल उप में "रीसेट" कर सकता है। मूल प्रश्न के अनुसार एफएसओ का उपयोग इस मुद्दे को समाप्त करता है। संपादित करें: बस @LimaNightHawk द्वारा पोस्ट को देखा, नीचे एक ही बात

— Baldmosher

Answer 4

डर फ़ंक्शन जाने का तरीका है, लेकिन समस्या यह है कि आप Dirफ़ंक्शन का पुनरावर्ती उपयोग नहीं कर सकते हैं , जैसा कि यहां कहा गया है, नीचे की ओर ।

जिस तरह से मैंने इसे संभाला है Dirवह लक्ष्य फ़ोल्डर के लिए सभी उप-फ़ोल्डरों को प्राप्त करने के लिए फ़ंक्शन का उपयोग करने और उन्हें एक सरणी में लोड करने के लिए है, फिर सरणी को एक फ़ंक्शन में पास करें जो पुनरावृत्ति करता है।

यहाँ एक वर्ग है जो मैंने लिखा है कि यह पूरा करता है, इसमें फ़िल्टर की खोज करने की क्षमता शामिल है। ( आपको हंगेरियन नोटेशन को माफ़ करना होगा, यह तब लिखा गया था जब यह सभी गुस्से में था। )

Private m_asFilters() As String
Private m_asFiles As Variant
Private m_lNext As Long
Private m_lMax As Long

Public Function GetFileList(ByVal ParentDir As String, Optional ByVal sSearch As String, Optional ByVal Deep As Boolean = True) As Variant
    m_lNext = 0
    m_lMax = 0

    ReDim m_asFiles(0)
    If Len(sSearch) Then
        m_asFilters() = Split(sSearch, "|")
    Else
        ReDim m_asFilters(0)
    End If

    If Deep Then
        Call RecursiveAddFiles(ParentDir)
    Else
        Call AddFiles(ParentDir)
    End If

    If m_lNext Then
        ReDim Preserve m_asFiles(m_lNext - 1)
        GetFileList = m_asFiles
    End If

End Function

Private Sub RecursiveAddFiles(ByVal ParentDir As String)
    Dim asDirs() As String
    Dim l As Long
    On Error GoTo ErrRecursiveAddFiles
    'Add the files in 'this' directory!


    Call AddFiles(ParentDir)

    ReDim asDirs(-1 To -1)
    asDirs = GetDirList(ParentDir)
    For l = 0 To UBound(asDirs)
        Call RecursiveAddFiles(asDirs(l))
    Next l
    On Error GoTo 0
Exit Sub
ErrRecursiveAddFiles:
End Sub
Private Function GetDirList(ByVal ParentDir As String) As String()
    Dim sDir As String
    Dim asRet() As String
    Dim l As Long
    Dim lMax As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If
    sDir = Dir(ParentDir, vbDirectory Or vbHidden Or vbSystem)
    Do While Len(sDir)
        If GetAttr(ParentDir & sDir) And vbDirectory Then
            If Not (sDir = "." Or sDir = "..") Then
                If l >= lMax Then
                    lMax = lMax + 10
                    ReDim Preserve asRet(lMax)
                End If
                asRet(l) = ParentDir & sDir
                l = l + 1
            End If
        End If
        sDir = Dir
    Loop
    If l Then
        ReDim Preserve asRet(l - 1)
        GetDirList = asRet()
    End If
End Function
Private Sub AddFiles(ByVal ParentDir As String)
    Dim sFile As String
    Dim l As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If

    For l = 0 To UBound(m_asFilters)
        sFile = Dir(ParentDir & "\" & m_asFilters(l), vbArchive Or vbHidden Or vbNormal Or vbReadOnly Or vbSystem)
        Do While Len(sFile)
            If Not (sFile = "." Or sFile = "..") Then
                If m_lNext >= m_lMax Then
                    m_lMax = m_lMax + 100
                    ReDim Preserve m_asFiles(m_lMax)
                End If
                m_asFiles(m_lNext) = ParentDir & sFile
                m_lNext = m_lNext + 1
            End If
            sFile = Dir
        Loop
    Next l
End Sub

Comments

अगर मैं कॉलम में मिली फाइलों को सूचीबद्ध करना चाहूंगा, तो इस पर अमल क्या हो सकता है?

— जेकविज़

@jechaviz GetFileList पद्धति स्ट्रिंग की एक सरणी लौटाती है। आप संभवतः सरणी पर केवल पुनरावृति करेंगे और आइटम को एक सूची दृश्य में जोड़ देंगे, या ऐसा कुछ। किसी सूची में आइटम दिखाने के तरीके पर विवरण शायद इस पोस्ट के दायरे से परे हैं।

— लीमानाइट हॉक 11

Answer 5

Dir जब मैं अन्य फ़ोल्डर्स से फ़ाइलों को संभालता हूं और प्रोसेस करता हूं, तो फंक्शन आसानी से फोकस खो देता है।

मैंने घटक के साथ बेहतर परिणाम प्राप्त किए हैं FileSystemObject।

पूरा उदाहरण यहाँ दिया गया है:

http://www.xl-central.com/list-files-fso.html

Microsoft स्क्रिप्टिंग रनटाइम को विज़ुअल बेसिक एडिटर में एक संदर्भ सेट करने के लिए मत भूलना (टूल> संदर्भ का उपयोग करके)

कोशिश करो!

Comments

तकनीकी रूप से यह वह विधि है जिसका उपयोग करने वाला पूछ रहा है, उनके पास केवल उनके संदर्भ शामिल नहीं हैं जो इस विधि को धीमा कर रहे हैं।

— मार्सुकिबॉय 2

Answer 6

इसको आजमाओ। ( लिंक )

Private Sub CommandButton3_Click()

Dim FileExtStr As String
Dim FileFormatNum As Long
Dim xWs As Worksheet
Dim xWb As Workbook
Dim FolderName As String
Application.ScreenUpdating = False
Set xWb = Application.ThisWorkbook
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = xWb.Path & "\" & xWb.Name & " " & DateString
MkDir FolderName
For Each xWs In xWb.Worksheets
    xWs.Copy
    If Val(Application.Version) < 12 Then
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        Select Case xWb.FileFormat
            Case 51:
                FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If Application.ActiveWorkbook.HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56:
                FileExtStr = ".xls": FileFormatNum = 56
            Case Else:
                FileExtStr = ".xlsb": FileFormatNum = 50
        End Select
    End If
    xFile = FolderName & "\" & Application.ActiveWorkbook.Sheets(1).Name & FileExtStr
    Application.ActiveWorkbook.SaveAs xFile, FileFormat:=FileFormatNum
    Application.ActiveWorkbook.Close False
Next
MsgBox "You can find the files in " & FolderName
Application.ScreenUpdating = True

End Sub