ऑर्ग-मोड के एजेंडे में समय के मुक्त ब्लॉक दिखाएं

Question

मैं यह खोजना आसान बनाना चाहूंगा कि मेरे ऑर्ग-मोड एजेंडे में समय के मुक्त ब्लॉक कहां हैं।

उदाहरण के लिए, अगर मेरे पास दो नियुक्तियां हैं एक 9:30 am-10:30 और दूसरा 11:15 am-12:30, मैं एक नज़र में देखना चाहूंगा कि 10:30 am-11:15am ब्लॉक फ्री है।

दूसरे शब्दों में, मैं खाली समय को आसानी से अलग करने में सक्षम होना चाहता हूं क्योंकि यह Google कैलेंडर जैसे ग्राफ़िकल एजेंडे में किया जाता है।

क्या समय के खाली ब्लॉक को देखने का एक तरीका आसान है? शायद खाली ब्लॉकों को रंग देने के लिए जो दिए गए मिनटों की तुलना में लंबे हैं?

Comments

क्या org-agenda-time-gridआपकी जरूरतों के लिए पर्याप्त नहीं है? gnu.org/software/emacs/manual/html_node/org/…

— कानून सूची

ग्रिड पर्याप्त नहीं है, क्योंकि यह व्यस्त होने पर भी अप दिखाता है (जैसे, यदि 9:30 am-10:30 पूर्वाह्न बैठक है, तो 10:00 बजे ग्रिड लाइन होगी)। मैं व्यस्त और गैर-व्यस्त समय को अलग करना आसान होगा।

— स्कारामूचे

मैंने इस कार्यक्षमता के बारे में थोड़ा और सोचा है। मेरा मानना ​​है कि लागू करने के लिए सबसे उपयोगी और सरल समय ब्लॉक का रंग बदलना होगा (केवल समय ब्लॉक का नाम, उदाहरण के लिए, 8: 00-9: 00) उन समय ब्लॉक के लिए जो किसी दिए गए राशि से अधिक है खाली समय (जैसे, 15 मिनट से अधिक)। रंग और न्यूनतम खाली समय दोनों को उपयोगकर्ता को कॉन्फ़िगर करना चाहिए।

— स्कारामूचे

@scaramouche, ऑर्ग-मोड मेलिंग सूची ( orgmode.org/worg/org-mailing-list.html ) पर एक उपयोगकर्ता पूछता है कि क्या आपने कोशिश की है calfw( emacswiki.org/emacs/Calfw )।

— daveloyall

@daveloyall, मेलिंग सूची चर्चा की ओर इशारा करने के लिए बहुत धन्यवाद। मैंने सिर्फ बछड़े की कोशिश की (और यह सुंदर है!), लेकिन ऐसा नहीं लगता है कि मैं चाहता हूं कि फ़ंक्शन (दिन में खुले समय के लिए नेत्रहीन स्पॉट) हो। उन लोगों के लिए जो बछड़ा + ओआरजी (अत्यधिक अनुशंसित) की कोशिश करना चाहते हैं: मेलपा से बछड़ा प्राप्त करें init.el, इसमें शामिल करें (require 'calfw-org), और कैलेंडर को कॉल करें M-x cfw:open-org-calendar।

— स्कारामोचे

Answer 1

अपने स्वयं के इस प्रश्न के कारण मैंने उस फ़ंक्शन को देखा org-agenda-add-time-grid-maybeजो समय ग्रिड बनाता है। वहां तैनात कोड (जो मेरे द्वारा नहीं लिखा गया है) ओपी की टिप्पणी में अनुरोध के अनुसार समय व्यस्त होने पर एक ग्रिड लाइन को हटा देता है।

आपकी तरह, मैं किसी तरह एक विजुअल ब्लॉक बनाना चाहता था। org-agenda-add-time-grid-maybeमाइकल Ekstrand द्वारा पोस्ट किए गए मूल कोड और डिफैडविस को दूसरे धागे में पोस्ट करके मैं निम्नलिखित कोड के साथ आया org-agenda-add-time-grid-maybe। यह एक अलग रंग में ग्रिड लाइनों का उत्पादन करेगा (फिलहाल मैं चेहरे का उपयोग करता हूं org-archived) और समय का पालन एक अलग स्ट्रिंग द्वारा किया जाएगा। दोनों को अपनी पसंद के हिसाब से बदला जा सकता है।

(defun org-agenda-add-time-grid-maybe (list ndays todayp)
  "Add a time-grid for agenda items which need it.

LIST is the list of agenda items formatted by `org-agenda-list'.
NDAYS is the span of the current agenda view.
TODAYP is t when the current agenda view is on today."

  (catch 'exit
   (cond ((not org-agenda-use-time-grid) (throw 'exit list))
         ((and todayp (member 'today (car org-agenda-time-grid))))
         ((and (= ndays 1) (member 'daily (car org-agenda-time-grid))))
         ((member 'weekly (car org-agenda-time-grid)))
         (t (throw 'exit list)))
   (let* ((blocks (mapcar (lambda (x)
                            (let ((start (get-text-property 1 'time-of-day x))
                                  (dur (get-text-property 1 'duration x)))
                              (cond
                               ((and start dur) (cons start
                                                      (org-time-from-minutes
                                                       (truncate
                                                        (+ dur (org-time-to-minutes start))))))
                               (start start)
                               (t nil))))
                          list))
          (have (delq nil (mapcar
                           (lambda (x) (get-text-property 1 'time-of-day x))
                           list)))
          (string (nth 3 org-agenda-time-grid))
          (gridtimes (nth 1 org-agenda-time-grid))
          (req (car org-agenda-time-grid))
          (remove (member 'remove-match req))
          new time)
     (if (and (member 'require-timed req) (not have))
         ;; don't show empty grid
         (throw 'exit list))

     (while (setq time (pop gridtimes))
       (unless (and remove (member time have))
         (let* ((windows (delq nil blocks))
                (hit nil))
           (dolist (busy windows)
             (unless hit
               (when (and (>= time (car busy))
                          (< time (cdr busy)))
                 (setq hit t))))
           (setq time (replace-regexp-in-string " " "0" (format "%04s" time)))
           (if hit
               (progn
                 (push (org-agenda-format-item
                        (concat string " dito") string nil "" nil
                        (concat (substring time 0 -2) ":" (substring time -2)))
                       new)
                 (put-text-property 2 (length (car new)) 'face 'org-archived (car new)))
             (progn
               (push (org-agenda-format-item
                      nil string nil "" nil
                      (concat (substring time 0 -2) ":" (substring time -2)))
                     new)
               (put-text-property 2 (length (car new)) 'face 'org-time-grid (car new))))
           (setq hit nil))))

     (when (and todayp org-agenda-show-current-time-in-grid)
       (push (org-agenda-format-item
              nil org-agenda-current-time-string nil "" nil
              (format-time-string "%H:%M "))
             new)
       (put-text-property
        2 (length (car new)) 'face 'org-agenda-current-time (car new)))

     (if (member 'time-up org-agenda-sorting-strategy-selected)
         (append new list)
       (append list new)))))

(defun org-time-to-minutes (time)
  "Convert an HHMM TIME to minutes."
  (+ (* (/ time 100) 60) (% time 100)))

(defun org-time-from-minutes (minutes)
  "Convert a number of MINUTES to an HHMM time."
  (+ (* (/ minutes 60) 100) (% minutes 60)))

जाहिर है, यह मानहानि का उपयोग करने के लिए अधिक सुरुचिपूर्ण होगा, लेकिन मैं यह पता नहीं लगा सका कि वास्तव में हस्तक्षेप करना कहां है। फ़ंक्शन स्वयं प्रत्येक ग्रिड समय (सेट में org-agenda-time-grid) से गुजरता है और अंतिम ग्रिड के साथ एक नई सूची बनाता है जिसमें चेहरे (नए) शामिल हैं।

Comments

उपयोगी है, लेकिन मैं वास्तव में आशा करता हूं कि कोई व्यक्ति एक समाधान के साथ आता है जिसमें एक समारोह में सीधे ओवरराइड करना शामिल नहीं होता है org-agenda।

— होलोक्रोनवाइवर

मैं पूरी तरह से सहमत हूं! दुर्भाग्य से, काम कर रहे एक चूक के साथ आने के लिए elisp और org- मोड कोड का मेरा ज्ञान पर्याप्त नहीं है। हो सकता है, कोई और यहाँ मदद कर सकता है, संभवतः "मेरे" कोड का उपयोग कर रहा है।

— फेबियन