क्षेत्र और / या पंक्ति को कैसे संरेखित करें?

Question

हम M-x center-regionऔर के साथ पाठ को केंद्र में रख सकते हैं M-o M-s। क्या सही-संरेखण के लिए भी कुछ ऐसा ही है?

पहले उदाहरण:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

उपरांत:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

पाठ को दाएं-संरेखित करने का सबसे आसान तरीका क्या है?

Answer 1

भरने पर मैनुअल नोड के अनुसार , कई फ़ंक्शंस फ़ंक्शन वैकल्पिक वैकल्पिक तर्क लेते हैं जिनका आप उपयोग कर सकते हैं। इसलिए, उदाहरण के लिए, सही औचित्य के साथ एक पैराग्राफ भरने के लिए, आप उपयोग कर सकते हैं (fill-paragraph 'right)।

आप (justify-current-line 'right)सिंगल लाइन के लिए भी इस्तेमाल कर सकते हैं ।

यदि आप इन विकल्पों का भरपूर उपयोग करने की योजना बनाते हैं, तो आप उन्हें निम्न प्रकार के कार्यों में लपेट सकते हैं, और फिर इन कार्यों को अपनी पसंद की कुंजी में बाँध सकते हैं:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

यहाँ एक फ़ंक्शन है जिसे आप एक प्रतिस्थापन के रूप में छोड़ सकते हैं fill-paragraph। विभिन्न उपसर्गों के साथ, यह आपको यह तय करने की अनुमति देता है कि आप जिस अनुच्छेद को भर रहे हैं, उस पर किस तरह का औचित्य है:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

यदि आप सही-संरेखण करते समय भरना नहीं चाहते हैं, तो आप निम्न फ़ंक्शन का उपयोग कर सकते हैं, जो कि center-regionफ़ंक्शन से सीधे एक पंक्ति-परिवर्तन के साथ इसे ठीक से संरेखित करने के लिए क्रैबर्ड है:

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))