सभी बैकअप को एक बैकअप फ़ोल्डर में रखें

15

मैं Emacs कैसे सेट कर सकता हूं ताकि सभी बैकअप एक बैकअप फ़ोल्डर में रखे जाएं? जैसे/MyEmacsBackups

backup

ध्यान रखें कि यह आपकी मशीन पर आस-पास की संवेदनशील जानकारी को छोड़ने का अनपेक्षित दुष्परिणाम हो सकता है, यहां तक कि मूल स्थानांतरित होने या हटाए जाने के बाद भी। इस बैकअप फ़ोल्डर को कभी-कभार शुद्ध करना उचित होगा। इन बैकअप फ़ाइलों में मूल की तुलना में अलग-अलग अनुमतियाँ भी हो सकती हैं।

— 22

संबंधित: मैं कैसे नियंत्रित करता हूं कि Emacs बैकअप फाइलें कैसे बनाता है?

— लीजेंड 2k

17

बाहर की जाँच करें backup-directory-alist, जो आपको फ़ाइल regexp द्वारा बैकअप स्थान सेट करने की अनुमति देता है। सब कुछ एक निर्देशिका में जाने के लिए, कुछ इस तरह आज़माएँ:

(setq backup-directory-alist '(("." . "~/MyEmacsBackups")))

वास्तव में पागल (अपने आप की तरह) के लिए, बैकअप-प्रत्येक-सेव भी है , जो (जैसा कि नाम से पता चलता है) आपकी फ़ाइलों को हर बार एक सुविधाजनक स्थान पर सहेजने के लिए बैकअप देता है। यह पारंपरिक संस्करण नियंत्रण पर सुरक्षा की एक अतिरिक्त परत देता है, उदाहरण के लिए उन मामलों के लिए जब आप गलती से अपनी कार्यशील निर्देशिका को बिना किसी जाँच के साफ़ कर देते हैं।

— Shosti
स्रोत

12

निम्नलिखित मेरे से एक त्वरित कोड है .emacs। यह न केवल बैकअप को एक विशिष्ट निर्देशिका में डालता है, बल्कि ऑटो-सेव भी करता है, और ट्रम्प फ़ाइलों के लिए भी ऐसा ही करता है, इसलिए इन्हें रिमोट सिस्टम पर नहीं डाला जाता है।

;; Put backup files neatly away                                                 
(let ((backup-dir "~/tmp/emacs/backups")
      (auto-saves-dir "~/tmp/emacs/auto-saves/"))
  (dolist (dir (list backup-dir auto-saves-dir))
    (when (not (file-directory-p dir))
      (make-directory dir t)))
  (setq backup-directory-alist `(("." . ,backup-dir))
        auto-save-file-name-transforms `((".*" ,auto-saves-dir t))
        auto-save-list-file-prefix (concat auto-saves-dir ".saves-")
        tramp-backup-directory-alist `((".*" . ,backup-dir))
        tramp-auto-save-directory auto-saves-dir))

(setq backup-by-copying t    ; Don't delink hardlinks                           
      delete-old-versions t  ; Clean up the backups                             
      version-control t      ; Use version numbers on backups,                  
      kept-new-versions 5    ; keep some new versions                           
      kept-old-versions 2)   ; and some old ones, too

— जोर्गेन शेफर
स्रोत

1

;; put all backup files into ~/MyEmacsBackups
(setq backup-directory-alist '(("." . "~/MyEmacsBackups")))
(setq backup-by-copying t)

— CyberSnoopy
स्रोत

शोस्टी पर आपके उत्तर का क्या लाभ है?

— गिल्स एसओ- बुराई को रोकें '

@ गिल्स ज्यादा नहीं, gnu.org/software/emacs/manual/html_node/emacs/…

— CyberSnoopy

0

इसे अपनी इनिट फ़ाइल में डालें। अपने चुने हुए बैकअप निर्देशिका के लिए पथ बदलें।

;;backup directory
(setq backup-directory-alist '(("" . "~/.emacs.d/emacs_backup")))

— Nsukami _
स्रोत