इस पेंचकस की तरह ओवरले कैसे प्रदर्शित करें?

Question

Emacs में निम्नलिखित की तरह ओवरले कैसे बनाया जाए (शायद यह ओवरले नहीं है, मुझे नहीं पता, यह कंपनी-क्यूक इनलाइन-डॉक्स से है):

Answer 1

वास्तव में यह ओवरले का उपयोग करके उस व्यवहार को पूरा करता है। विशेष रूप से- यह 'after-stringदस्तावेज दिखाने के लिए संपत्ति का उपयोग करता है (देखें: ओवरले गुण )।

यदि आप फ़ंक्शन की जांच करते हैं company-coq--show-definition-overlay-at-point(उदाहरण के माध्यम से M-x find-function) तो आप देख सकते हैं कि यह कैसे बनाया गया है:

(setq company-coq-definition-overlay (make-overlay ins-pos ins-pos))
(overlay-put company-coq-definition-overlay 'after-string ins-str)

ओवरले का एक संदर्भ रखा जाता है, company-coq-definition-overlayजिससे बाद में ओवरले को निकालना आसान हो जाए:

(delete-overlay company-coq-definition-overlay)
(setq company-coq-definition-overlay nil)

Comments

के साथ के (overlay-put OVERLAY 'after-string STR)रूप में नहीं है screencast में।

— स्टारडाइवर

@stardiviner क्या आप विशिष्ट वर्णों / रंगों / शैली के बारे में सोच रहे हैं? आप स्ट्रिंग जांच करने के लिए इस्तेमाल कर सकते हैं edebug ins-strमें company-coq--show-definition-overlay-at-point। विशिष्ट चेहरे और स्टाइल उस स्ट्रिंग में पाठ गुणों के रूप में मौजूद होंगे। पाठ गुण: विशेष गुण उन गुणों को डिकोड करने के लिए एक उपयोगी संदर्भ है।

— इबपा

Answer 2

(defvar inline-docs-overlay nil)

(defgroup inline-docs nil
  "Show inline contextual docs in Emacs."
  :group 'docs)

(defcustom inline-docs-border-symbol ?―
  "Specify symbol for inline-docs border."
  :group 'inline-docs)

(defcustom inline-docs-prefix-symbol ?\s
  "Specify symbol for inline-docs prefix."
  :group 'inline-docs)

(defcustom inline-docs-indicator-symbol "➜"
  "Specify symbol for inline-docs indicator."
  :group 'inline-docs)

(defface inline-docs-face
  '((t (:inherit italic)))
  "Face for `inline-docs-mode'."
  :group 'inline-docs)

(defface inline-docs-border-face
  '((t (:inherit font-lock-doc-face)))
  "Face for inline docs border lines."
  :group 'inline-docs)

(defface inline-docs-prefix-face
  '((t (:inherit default)))
  "Face for inline docs prefix."
  :group 'inline-docs)

(defface inline-docs-indicator-face
  '((t (:inherit font-lock-doc-face)))
  "Face for inline docs indicator."
  :group 'inline-docs)

(defun inline-docs--clear-overlay ()
  "Clear inline-docs overlays."
  (when (overlayp inline-docs-overlay)
    (delete-overlay inline-docs-overlay))
  (remove-hook 'post-command-hook 'inline-docs--clear-overlay))

(defun inline-docs--string-display-next-line (string apply-face)
  "Show STRING contents below point line until next command with APPLY-FACE."
  (let* ((border-line (make-string (window-body-width) inline-docs-border-symbol))
         (prefix (make-string
                  (if (= (current-indentation) 0) ; fix (wrong-type-argument wholenump -1) when current indentation is 0 minus 1 will caused wholenump exception.
                      (current-indentation)
                    (- (current-indentation) 1))
                  inline-docs-prefix-symbol))
         (str (concat (propertize border-line
                                  'face 'inline-docs-border-face)
                      "\n"
                      prefix
                      (propertize (concat inline-docs-indicator-symbol " ")
                                  'face 'inline-docs-indicator-face)
                      (copy-sequence string) ; original eldoc string with format.
                      "\n"
                      (propertize border-line
                                  'face 'inline-docs-border-face)
                      "\n"
                      ))
         start-pos end-pos)
    (unwind-protect
        (save-excursion
          (inline-docs--clear-overlay)
          (forward-line)
          (setq start-pos (point))
          (end-of-line)
          (setq end-pos (point))
          (setq inline-docs-overlay (make-overlay start-pos end-pos (current-buffer)))
          ;; change the face
          (if apply-face
              (overlay-put inline-docs-overlay 'face 'inline-docs-face))
          ;; hide full line
          ;; (overlay-put inline-docs-overlay 'display "")
          ;; (overlay-put inline-docs-overlay 'display :height 20)
          ;; pre-pend indentation spaces
          ;; (overlay-put inline-docs-overlay 'line-prefix prefix)
          ;; auto delete overlay
          (overlay-put inline-docs-overlay 'evaporate t)
          ;; display message
          (overlay-put inline-docs-overlay 'before-string str))
      (add-hook 'post-command-hook 'inline-docs--clear-overlay))))

(defun inline-docs-display-docs-momentary (format-string &rest args)
  "Display inline docs FORMAT-STRING under point with extra ARGS."
  (when format-string
    (inline-docs--string-display-next-line
     (apply 'format format-string args)
     t)))

;;;###autoload
(defalias 'inline-docs 'inline-docs-display-docs-momentary)

मैंने इसके लिए एक रेपो बनाया, https://github.com/stardiviner/inline-docs.el और एक मॉड्यूल जो inline-docs.eleldoc के लिए उपयोग करता है। https://github.com/stardiviner/eldoc-overlay-mode ।

Comments

यह अच्छा होगा कि एक सामान्य उद्देश्य मॉड्यूल के रूप में, जैसे कि इसका उपयोग न केवल एल्डोक बल्कि अन्य "मॉडलिन क्विकइन्फो" के लिए भी किया जा सकता है।

— द ओल्डोरिया

मैं देखता हूं, मैं इसके लिए एक सामान्य मोड बनाऊंगा, फिर एल्डॉक के लिए एक अलग मोड बनाऊंगा।

— स्टारडाइनेर