मुझे अब तक पता चला है कि एक नई Emacs प्रक्रिया को जन्म देना एक समाधान है।
यहाँ मैंने जो किया है।
1. एक बाहरी emacs प्रक्रिया शुरू करने के लिए एक फ़ंक्शन जोड़ें।
init.el
(defvar my/async-emacs-repl-org-babel-init-file "~/.emacs.d/org-babel-async-init" "File to load on executing async babel evaluation.")
(defun my/async-emacs-repl--start (process-name init-file)
"Start a new Emacs process as a REPL server."
(async-shell-command (concat
"TERM=vt200 emacs --batch -nw"
" --eval '(load \"" init-file "\")'"
" --eval '(while t (print (eval (read))))'"
)
process-name))
(defun my/async-emacs-repl--org-babel--start-server ()
"Starts an Emacs process for async org-babel execution."
(my/async-emacs-repl--start "*org-babel-async*" my/async-emacs-repl-org-babel-init-file))
(defun my/async-emacs-repl--org-babel--start-if-not-exists ()
"Starts an Emacs process if the process does not exist."
(if (not (get-buffer-process "*org-babel-async*")) (my/async-emacs-repl--org-babel--start-server)))
(defun my/async-emacs-repl--org-babel--execute--build-command (file-name line-number)
"Build the command for executing `org-babel-execute-src-block'."
(concat
"(progn"
" (find-file \"" file-name "\")"
" (revert-buffer t t)"
" (goto-line " (number-to-string line-number) ")"
" (org-babel-execute-src-block t)"
" (save-buffer)"
")"
"\n"))
(defun my/async-emacs-repl--org-babel--execute (process-name file-name line-number)
"Sends the command to the server to run the code-block the cursor is at."
(process-send-string
process-name
(my/async-emacs-repl--org-babel--execute--build-command file-name line-number)))
(defun my/async-emacs-repl-org-babel-do-execute ()
"Run org babel execution at point."
(my/async-emacs-repl--org-babel--execute "*org-babel-async*" (buffer-file-name) (line-number-at-pos)))
(defun my/async-emacs-repl-org-babel-execute ()
"Run by the user. Executes command. Starts buffer if not exists."
(interactive)
(save-buffer)
(my/async-emacs-repl--org-babel--start-if-not-exists)
(my/async-emacs-repl-org-babel-do-execute))
2. नई emacs प्रक्रिया में लोड करने के लिए एक कॉन्फ़िगर फ़ाइल जोड़ें।
उपरोक्त फ़ंक्शन --batchमोड में emacs शुरू करता है। इस प्रकार सामान्य init.el लोड नहीं किया जाएगा।
इसके बजाय, हम एक छोटी कॉन्फ़िगरेशन फ़ाइल बनाना चाहते हैं (पथ लोड करने के लिए और इसी तरह)।
हमारी नई कॉन्फ़िग फ़ाइल का पथ async-emacs-repl-org-babel-init-fileऊपर के स्निपेट में संग्रहीत है ।
org-कोलाहल-async-init.el
;; 1
(package-initialize)
;; 2
(setq org-confirm-babel-evaluate nil)
;; 3
(let ((my/org-babel-evaluated-languages
'(emacs-lisp
ditaa
python
ruby
C
matlab
clojure
sh
dot
plantuml)))
(org-babel-do-load-languages
'org-babel-load-languages
(mapcar (lambda (lang)
(cons lang t))
my/org-babel-evaluated-languages)))
यहाँ हम ...
- पैकेज पथ जोड़ें।
- कोड ब्लॉक को निष्पादित करने के लिए नहीं पूछें, ऑर्ग-मोड को बताएं।
- Org-babel को बताएं कि कौन सी भाषाएं आवश्यक हैं।
Footnote 1: इस सेटिंग के बिना, मूल्यांकन विफल हो जाएगा "No org-babel-execute function for $lang!"
फुटनोट 2: यदि आप चाहें तो नई इनफाइटल फ़ाइल बनाने के बजाय सामान्य init.el लोड कर सकते हैं। जोड़कर है कि (setq org-babel-async-init-file "~/.emacs.d/init")आपके लिए init.el। लेकिन मुझे लगता है कि इस कार्य के लिए एक कॉन्फ़िगरेशन फ़ाइल बनाना अधिक सरल है।
3. इसके अतिरिक्त ...
Init.el में जोड़ें
;; This will stop the new process buffer from getting focus.
(setq display-buffer-alist (append display-buffer-alist '(("*org-babel-async*" display-buffer-no-window))))
;; This will automatically show the result section.
(global-auto-revert-mode 1)
में जोड़े ऑर्ग-कोलाहल-async-init.el
;; This will skip the "Save anyway?" confirmation of automatically saving the file when you also edited the buffer from Emacs while an asynchronous process is running.
(defun advice:verify-visited-file-modtime (orig-func &rest args) t)
(advice-add 'verify-visited-file-modtime :around 'advice:verify-visited-file-modtime)
;; This will skip the "Select coding system" prompt that appears when the result is inserted. This may vary among environments.
(setq coding-system-for-write 'utf-8)
;; This will skip the "changed on disk; really edit the buffer?" checking.
(defun ask-user-about-supersession-threat (fn) "blatantly ignore files that changed on disk")
में जोड़े ऑर्ग-कोलाहल-async-init.el (यदि आप इन की जरूरत नहीं हो सकती है। ये MATLAB के लिए कर रहे हैं)
;; This will set MATLAB cli path.
(setq-default matlab-shell-command "/Applications/MATLAB_R2016a.app/bin/matlab")
;; The MATLAB cli path can be obtained by running `fullfile(matlabroot, 'bin')` in your MATLAB.
;; This will stop MATLAB from showing the splash (the MATLAB logo) at the beginning.
(setq-default matlab-shell-command-switches '("-nodesktop" "-nosplash"))
में जोड़े ऑर्ग-कोलाहल-async-init.el (यदि आप इन की जरूरत नहीं हो सकती है। ये जूलिया, अनुसंधान और कि उपयोग ईएसएस अन्य भाषाओं के लिए कर रहे हैं।)
;; This will enable :session header in Julia and other languages that use ESS (Emacs speaks statistics).
(load "/path/to/ess-site")
;; This will suppress ESS from prompting for session directory.
(setq ess-ask-for-ess-directory nil)
4. उपयोग
(ऊपर सेटअप के बाद।)
- कर्सर को उस स्निपेट पर ले जाएं, जिसे आप निष्पादित करना चाहते हैं।
- भागो
M-x my/async-emacs-repl-org-babel-execute(करने के बजाय C-c C-c)। यह जरूरत पड़ने पर REPL सर्वर के रूप में एक बाहरी Emacs प्रक्रिया शुरू करेगा, और फिर आपके द्वारा स्रोत ब्लॉक को निष्पादित करेगा।
स्वीकृतियाँ
मैंने इस पोस्ट से org-babel मूल्यांकन के लिए emacs प्रक्रिया शुरू करने का विचार सीखा है । मैं लेखक को धन्यवाद देना चाहता हूं।
अनुकूलन के लिए टिप्पणियाँ
यहाँ विचार सरल है। Elisp के लिए एक REPL के रूप में एक नई emacs प्रक्रिया शुरू करें। एक ही कर्सर बिंदु, रन ,, के find-fileलिए एक ही .org फ़ाइल हम संपादन कर रहे हैं । जब तक उपयोगकर्ता प्रक्रिया बंद नहीं करता तब तक बाहर निकलना बंद करें (अन्यथा, ग्राफ़ दिखाए जाने के तुरंत बाद गायब हो जाएंगे)। कोई स्वाभाविक रूप से इसके बारे में विस्तार से सोच सकता है:goto-lineorg-babel-execute-src-blocksave-buffer
- ओआरजी-मोड का
C-c C-cउपयोग करने के बजाय हाथों से कार्य चलाने / एक नया कीबाइंड सेट करना (जिसे सलाह द्वारा प्राप्त किया जा सकता है)।
- सत्र चर और भाषा के अनुसार प्रक्रिया का नाम स्विचिंग
- सशर्त रूप से भाषा के आधार पर इनिट फ़ाइलों को स्विच करना।
वास्तव में, इस दृष्टिकोण की सफलता मुझे Emacs में async सुविधाओं को विकसित करने का एक सामान्य तरीका दिखा रही है। "कमांड्स" लेयर बनाना, कार्यों को करने के लिए स्क्रिप्ट जोड़ना और ईमैक्स प्रक्रियाओं को शुरू करने और पुन: उपयोग करने के लिए एक रूपरेखा है। जैसे PHP के Symfony ढांचे (PHP में थ्रेड्स नहीं हैं) में कमांड विशेषताएं हैं।
इतिहास संपादित करें
रिफैक्टेड कोड (2016-04-02)। समाधान अब एक Emacs प्रक्रिया (2016-04-02) का पुन: उपयोग करता है। समाधान अब सरलीकृत किया गया है और interactiveचलाने के लिए केवल एक आदेश है (2016-04-02। जोड़ा गया कॉन्फ़िगरेशन (2016-04-12)।