IF EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[vGetVisits]') AND type in (N'U'))
DROP TABLE [dbo].[vGetVisits]
GO
CREATE TABLE [dbo].[vGetVisits](
[id] [int] NOT NULL,
[mydate] [datetime] NOT NULL,
CONSTRAINT [PK_vGetVisits] PRIMARY KEY CLUSTERED
(
[id] ASC
)
)
GO
INSERT INTO [dbo].[vGetVisits]([id], [mydate])
VALUES
(1, '2014-01-01 11:00'),
(2, '2014-01-03 10:00'),
(3, '2014-01-04 09:30'),
(4, '2014-04-01 10:00'),
(5, '2014-05-01 11:00'),
(6, '2014-07-01 09:00'),
(7, '2014-07-31 08:00');
GO
-- Clean up
IF OBJECT_ID (N'dbo.udfLastHitRecursive', N'FN') IS NOT NULL
DROP FUNCTION udfLastHitRecursive;
GO
-- Actual Function
CREATE FUNCTION dbo.udfLastHitRecursive
( @MyDate datetime)
RETURNS TINYINT
AS
BEGIN
-- Your returned value 1 or 0
DECLARE @Returned_Value TINYINT;
SET @Returned_Value=0;
-- Prepare gaps table to be used.
WITH gaps AS
(
-- Select Date and MaxDiff from the original table
SELECT
CONVERT(Date,mydate) AS [date]
, DATEDIFF(day,ISNULL(LAG(mydate, 1) OVER (ORDER BY mydate), mydate) , mydate) AS [MaxDiff]
FROM dbo.vGetVisits
)
SELECT @Returned_Value=
(SELECT DISTINCT -- DISTINCT in case we have same date but different time
CASE WHEN
(
-- It is a first entry
[date]=(SELECT MIN(CONVERT(Date,mydate)) FROM dbo.vGetVisits))
OR
/*
--Gap between last qualifying date and entered is greater than 90
Calculate Running sum upto and including required date
and find a remainder of division by 91.
*/
((SELECT SUM(t1.MaxDiff)
FROM (SELECT [MaxDiff] FROM gaps WHERE [date]<=t2.[date]
) t1
)%91 -
/*
ISNULL added to include first value that always returns NULL
Calculate Running sum upto and NOT including required date
and find a remainder of division by 91
*/
ISNULL((SELECT SUM(t1.MaxDiff)
FROM (SELECT [MaxDiff] FROM gaps WHERE [date]<t2.[date]
) t1
)%91, 0) -- End ISNULL
<0 )
/* End Running sum upto and including required date */
OR
-- Gap between two nearest dates is greater than 90
((SELECT SUM(t1.MaxDiff)
FROM (SELECT [MaxDiff] FROM gaps WHERE [date]<=t2.[date]
) t1
) - ISNULL((SELECT SUM(t1.MaxDiff)
FROM (SELECT [MaxDiff] FROM gaps WHERE [date]<t2.[date]
) t1
), 0) > 90)
THEN 1
ELSE 0
END
AS [Qualifying]
FROM gaps t2
WHERE [date]=CONVERT(Date,@MyDate))
-- What is neccesary to return when entered date is not in dbo.vGetVisits?
RETURN @Returned_Value
END
GO
SELECT
dbo.udfLastHitRecursive(mydate) AS [Qualifying]
, [id]
, mydate
FROM dbo.vGetVisits
ORDER BY mydate
परिणाम
SQL सर्वर में रनिंग कुल की गणना करने के तरीके पर भी एक नज़र डालें
अद्यतन: कृपया प्रदर्शन परीक्षण के परिणाम नीचे देखें।
"90 दिनों के गैप" को खोजने के लिए इस्तेमाल किए जाने वाले अलग-अलग लॉजिक के कारण ypercube का और मेरे समाधानों को छोड़ दिया जाए तो पॉल व्हाइट के समाधान के अलग-अलग परिणाम लौट सकते हैं। इस के उपयोग की वजह से है DateDiff और DATEADD क्रमशः कार्य करता है।
उदाहरण के लिए:
SELECT DATEADD(DAY, 90, '2014-01-01 00:00:00.000')
रिटर्न '2014-04-01 00: 00: 00.000' का अर्थ है कि '2014-04-01 01: 00: 00.000' 90 दिनों के अंतराल से परे है
परंतु
SELECT DATEDIFF(DAY, '2014-01-01 00:00:00.000', '2014-04-01 01:00:00.000')
रिटर्न '90' का अर्थ है कि यह अभी भी अंतराल के भीतर है।
एक रिटेलर के उदाहरण पर विचार करें। इस मामले में एक खराब होने वाला उत्पाद बेचना जो '2014-01-01' तक '2014-01-01 23: 59: 59: 999' पर बिकता है, ठीक है। तो इस मामले में DatedIFF (DAY, ...) का मूल्य ठीक है।
एक और उदाहरण एक मरीज को देखा जा सकता है। किसी के लिए जो '2014-01-01 00: 00: 00: 000' पर आता है और '2014-01-01 23: 59: 59: 999' पर छोड़ता है, यह 0 (शून्य) दिन है यदि डेटेडिफ़ का उपयोग किया जाता है, भले ही वास्तविक प्रतीक्षा लगभग 24 घंटे की थी। फिर से रोगी जो '2014-01-01 23:59:59' पर आता है और '2014-01-02 00:00:01' पर चलता है, अगर एक दिन के लिए इंतजार किया जाता है, तो DatedIFF का उपयोग किया जाता है।
लेकिन मैं पीछे हटा।
मैंने दिनांकित समाधान छोड़ दिया और यहां तक कि प्रदर्शन ने उन लोगों का परीक्षण किया लेकिन उन्हें वास्तव में अपनी लीग में होना चाहिए।
यह भी ध्यान दिया गया कि बड़े डेटासेट के लिए उसी दिन मूल्यों से बचना असंभव है। इसलिए यदि हमने 13 मिलियन रिकॉर्ड को 2 साल के डेटा के रूप में कहा है तो हम कुछ दिनों के लिए एक से अधिक रिकॉर्ड बनाएंगे। उन रिकॉर्डों को मेरे और यपरक्यूब के डेटेडिफिक सॉल्यूशन में सबसे पहले मौका दिया गया है। आशा है कि ypercube को यह बुरा नहीं लगता।
निम्न तालिका पर समाधान का परीक्षण किया गया
CREATE TABLE [dbo].[vGetVisits](
[id] [int] NOT NULL,
[mydate] [datetime] NOT NULL,
)
दो अलग-अलग क्लस्टर इंडेक्स (इस मामले में mydate) के साथ:
CREATE CLUSTERED INDEX CI_mydate on vGetVisits(mydate)
GO
टेबल को निम्न तरीके से आबाद किया गया था
SET NOCOUNT ON
GO
INSERT INTO dbo.vGetVisits(id, mydate)
VALUES (1, '01/01/1800')
GO
DECLARE @i bigint
SET @i=2
DECLARE @MaxRows bigint
SET @MaxRows=13001
WHILE @i<@MaxRows
BEGIN
INSERT INTO dbo.vGetVisits(id, mydate)
VALUES (@i, DATEADD(day,FLOOR(RAND()*(3)),(SELECT MAX(mydate) FROM dbo.vGetVisits)))
SET @i=@i+1
END
मल्टीमिलियन पंक्ति केस के लिए INSERT को इस तरह से बदल दिया गया था कि 0-20 मिनट की प्रविष्टियाँ बेतरतीब ढंग से जोड़ी गईं।
सभी समाधान निम्नलिखित कोड में सावधानीपूर्वक लपेटे गए थे
SET NOCOUNT ON
GO
DECLARE @StartDate DATETIME
SET @StartDate = GETDATE()
--- Code goes here
PRINT 'Total milliseconds: ' + CONVERT(varchar, DATEDIFF(ms, @StartDate, GETDATE()))
परीक्षण किए गए वास्तविक कोड (किसी विशेष क्रम में नहीं):
Ypercube के दिनांकित समाधान ( YPC, DatedIFF )
DECLARE @cd TABLE
( TheDate datetime PRIMARY KEY,
Qualify INT NOT NULL
);
DECLARE
@TheDate DATETIME,
@Qualify INT = 0,
@PreviousCheckDate DATETIME = '1799-01-01 00:00:00'
DECLARE c CURSOR
LOCAL STATIC FORWARD_ONLY READ_ONLY
FOR
SELECT
mydate
FROM
(SELECT
RowNum = ROW_NUMBER() OVER(PARTITION BY cast(mydate as date) ORDER BY mydate)
, mydate
FROM
dbo.vGetVisits) Actions
WHERE
RowNum = 1
ORDER BY
mydate;
OPEN c ;
FETCH NEXT FROM c INTO @TheDate ;
WHILE @@FETCH_STATUS = 0
BEGIN
SET @Qualify = CASE WHEN DATEDIFF(day, @PreviousCheckDate, @Thedate) > 90 THEN 1 ELSE 0 END ;
IF @Qualify=1
BEGIN
INSERT @cd (TheDate, Qualify)
SELECT @TheDate, @Qualify ;
SET @PreviousCheckDate=@TheDate
END
FETCH NEXT FROM c INTO @TheDate ;
END
CLOSE c;
DEALLOCATE c;
SELECT TheDate
FROM @cd
ORDER BY TheDate ;
Ypercube का DATEADD समाधान ( YPC, DATEADD )
DECLARE @cd TABLE
( TheDate datetime PRIMARY KEY,
Qualify INT NOT NULL
);
DECLARE
@TheDate DATETIME,
@Next_Date DATETIME,
@Interesting_Date DATETIME,
@Qualify INT = 0
DECLARE c CURSOR
LOCAL STATIC FORWARD_ONLY READ_ONLY
FOR
SELECT
[mydate]
FROM [test].[dbo].[vGetVisits]
ORDER BY mydate
;
OPEN c ;
FETCH NEXT FROM c INTO @TheDate ;
SET @Interesting_Date=@TheDate
INSERT @cd (TheDate, Qualify)
SELECT @TheDate, @Qualify ;
WHILE @@FETCH_STATUS = 0
BEGIN
IF @TheDate>DATEADD(DAY, 90, @Interesting_Date)
BEGIN
INSERT @cd (TheDate, Qualify)
SELECT @TheDate, @Qualify ;
SET @Interesting_Date=@TheDate;
END
FETCH NEXT FROM c INTO @TheDate;
END
CLOSE c;
DEALLOCATE c;
SELECT TheDate
FROM @cd
ORDER BY TheDate ;
पॉल व्हाइट का समाधान ( पीडब्लू )
;WITH CTE AS
(
SELECT TOP (1)
T.[mydate]
FROM dbo.vGetVisits AS T
ORDER BY
T.[mydate]
UNION ALL
SELECT
SQ1.[mydate]
FROM
(
SELECT
T.[mydate],
rn = ROW_NUMBER() OVER (
ORDER BY T.[mydate])
FROM CTE
JOIN dbo.vGetVisits AS T
ON T.[mydate] > DATEADD(DAY, 90, CTE.[mydate])
) AS SQ1
WHERE
SQ1.rn = 1
)
SELECT
CTE.[mydate]
FROM CTE
OPTION (MAXRECURSION 0);
मेरा DATEADD समाधान ( PN, DATEADD )
DECLARE @cd TABLE
( TheDate datetime PRIMARY KEY
);
DECLARE @TheDate DATETIME
SET @TheDate=(SELECT MIN(mydate) as mydate FROM [dbo].[vGetVisits])
WHILE (@TheDate IS NOT NULL)
BEGIN
INSERT @cd (TheDate) SELECT @TheDate;
SET @TheDate=(
SELECT MIN(mydate) as mydate
FROM [dbo].[vGetVisits]
WHERE mydate>DATEADD(DAY, 90, @TheDate)
)
END
SELECT TheDate
FROM @cd
ORDER BY TheDate ;
मेरा दिनांकित समाधान ( PN, DatedIFF )
DECLARE @MinDate DATETIME;
SET @MinDate=(SELECT MIN(mydate) FROM dbo.vGetVisits);
;WITH gaps AS
(
SELECT
t1.[date]
, t1.[MaxDiff]
, SUM(t1.[MaxDiff]) OVER (ORDER BY t1.[date]) AS [Running Total]
FROM
(
SELECT
mydate AS [date]
, DATEDIFF(day,LAG(mydate, 1, mydate) OVER (ORDER BY mydate) , mydate) AS [MaxDiff]
FROM
(SELECT
RowNum = ROW_NUMBER() OVER(PARTITION BY cast(mydate as date) ORDER BY mydate)
, mydate
FROM dbo.vGetVisits
) Actions
WHERE RowNum = 1
) t1
)
SELECT [date]
FROM gaps t2
WHERE
( ([Running Total])%91 - ([Running Total]- [MaxDiff])%91 <0 )
OR
( [MaxDiff] > 90)
OR
([date]=@MinDate)
ORDER BY [date]
मैं SQL Server 2012 का उपयोग कर रहा हूं, इसलिए मिकेल एरिकसन से माफी मांगता हूं, लेकिन उनके कोड का परीक्षण यहां नहीं किया जाएगा। मैं अभी भी DATADIFF और DATEADD के साथ कुछ डेटासेट पर विभिन्न मूल्यों को वापस करने के लिए उनके समाधान की उम्मीद करूंगा।
और वास्तविक परिणाम हैं:
