दो या अधिक कॉलम के लिए सशर्त ऑर्डर कैसे करें

Question

MS SQL Server 2005 में मैं सशर्त सॉर्ट के साथ एक क्वेरी लिख रहा हूं और मेरी समस्या यह है कि मुझे नहीं पता कि मैं दो कॉलम का उपयोग करके सशर्त कैसे सॉर्ट कर सकता हूं?

अगर मैंने इस तरह कोड लिखा तो यह सामान्य रूप से काम कर रहा है

select
    *
from 
    table
order by 
    case @pkr 
           when 'kol' then kol
           when 'nci' then nci
    end

मुझे नहीं पता कि दो या अधिक कॉलम के लिए सशर्त ऑर्डर कैसे करना है

select
    *
from 
    table
order by 
    case @pkr
        when 'KOL-NCI' then kol,nci
        when 'kol-MPCI' then kol,mpci
    end

गतिशील TSQL बनाने और उपयोग करने के लिए एक विचार है sp_executesqlलेकिन मैं अभी भी एक बेहतर विचार की तलाश कर रहा हूं?

Comments

संभावित अभिव्यक्ति के साथ 'रूपांतरण विफल' त्रुटि के

— gbn

आप यह भी देख सकते हैं कि क्या इसका कोई मतलब है .. OR ORER BY में END? । यद्यपि यह प्रश्न पोस्टग्रेसीक्यूएल के संदर्भ में प्रस्तुत किया गया था, लेकिन ज्यादातर टिप्पणियां और विचार WRT गतिशील क्वेरी बनाम CASEइस मामले पर लागू हो सकते हैं।

— जोनलो

Answer 1

मैं मानता हूँ कि ऐसा करने से पहले मुझे कभी ऐसा नहीं करना पड़ा था ताकि सिर खुजाने की जुर्रत हो। सरल उदाहरण तालिका प्रदर्शित करने के लिए:

IF  EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[MyTable]') AND type in (N'U'))
    DROP TABLE [dbo].[MyTable]
GO

CREATE TABLE dbo.MyTable
(
    col1 INT
    , col2 CHAR(1)
)
GO

INSERT dbo.MyTable (col1, col2) VALUES (1, 'A')
INSERT dbo.MyTable (col1, col2) VALUES (1, 'B')
INSERT dbo.MyTable (col1, col2) VALUES (1, 'C')
INSERT dbo.MyTable (col1, col2) VALUES (2, 'A')
INSERT dbo.MyTable (col1, col2) VALUES (2, 'B')
INSERT dbo.MyTable (col1, col2) VALUES (2, 'C')
INSERT dbo.MyTable (col1, col2) VALUES (3, 'A')
INSERT dbo.MyTable (col1, col2) VALUES (3, 'B')
INSERT dbo.MyTable (col1, col2) VALUES (3, 'C')

सॉर्ट ऑर्डर के बीच अंतर करने के लिए एक @SortStyle पैरामीटर का उपयोग करके, @SortStyle = 1 द्वारा सॉर्ट किया जाएगा col1 ASC, col2 DESCऔर @ SortStyle = 2 द्वारा सॉर्ट किया जाएगा col2 DESC, col1 ASC।

DECLARE @SortStyle INT
SET @SortStyle = 1

SELECT
    col1
    , col2
FROM
    dbo.MyTable
ORDER BY
    CASE
        WHEN @SortStyle = 1 THEN col1
    END ASC,
    CASE
        WHEN @SortStyle = 1 THEN col2
    END DESC,
    CASE
        WHEN @SortStyle = 2 THEN col2
    END DESC,
    CASE
        WHEN @SortStyle = 2 THEN col1
    END ASC

SET @SortStyle = 2

SELECT
    col1
    , col2
FROM
    dbo.MyTable
ORDER BY
    CASE
        WHEN @SortStyle = 1 THEN col1
    END ASC,
    CASE
        WHEN @SortStyle = 1 THEN col2
    END DESC,
    CASE
        WHEN @SortStyle = 2 THEN col2
    END DESC,
    CASE
        WHEN @SortStyle = 2 THEN col1
    END ASC

आप एक पैरामीटर द्वारा कैसे आदेश कर सकते हैं सिर्फ 1 कॉलम द्वारा छँटाई के सरल मामले को कवर करता है।

Answer 2

मान लें कि आपके पास और मामले हैं (मैंने एक जोड़ा), और सभी प्रकार संगत हैं,

order by 
    case @pkr
        when 'KOL-NCI' then kol
        when 'kol-MPCI' then kol
        when 'foo-bar' then foo
    end,
    case @pkr
        when 'KOL-NCI' then nci
        when 'kol-MPCI' then mpci
        when 'foo-bar' then bar 
    end

यह एक बहु-स्तंभ प्रकार नहीं है: आपके पास एक प्राथमिक प्रकार है, उसके बाद एक द्वितीयक प्रकार है। एक्सेल में सॉर्ट डायलॉग बॉक्स को देखिए कि मेरा क्या मतलब है।

Answer 3

आपके द्वारा दिए गए उदाहरण से यह सरल है:

select *
from table
order by kol, case @pkr
                when 'KOL-NCI' then nci
                when 'kol-MPCI' then mpci
              end

गतिशील TSQL बनाने और उपयोग करने के लिए एक विचार है sp_executesqlलेकिन मैं अभी भी बेहतर विचार के लिए मज़ाक कर रहा हूं।

जहाँ संभव हो वहाँ गतिशील SQL से बचना हमेशा अच्छा होता है