इस तरह एक (सरलीकृत) संग्रहीत प्रक्रिया को देखते हुए:
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
END
यदि Saleतालिका बड़ी है SELECT, तो निष्पादित होने में लंबा समय लग सकता है, जाहिरा तौर पर क्योंकि स्थानीय चर के कारण ऑप्टिमाइज़र अनुकूलन नहीं कर सकता है। हमने SELECTतब चर को कड़ी कोडित तारीखों के साथ चलाने का परीक्षण किया और निष्पादन समय ~ 9 मिनट से ~ 1 सेकंड तक चला गया।
हमारे पास कई संग्रहीत कार्यविधियाँ हैं जो क्वेरी "निश्चित" तिथि सीमाओं (सप्ताह, महीने, 8-सप्ताह आदि) पर आधारित है, इसलिए इनपुट पैरामीटर सिर्फ @endDate है और @startDate प्रक्रिया के अंदर गणना की जाती है।
प्रश्न यह है कि WHERE क्लॉज में वैरिएबल से बचने के लिए सबसे अच्छा अभ्यास क्या है ताकि ऑप्टिमाइज़र से समझौता न किया जाए?
जिन संभावनाओं के साथ हम आए थे, वे नीचे दिखाए गए हैं। क्या इनमें से कोई सबसे अच्छा अभ्यास है, या कोई और तरीका है?
वेरिएबल्स को मापदंडों में बदलने के लिए एक आवरण प्रक्रिया का उपयोग करें।
पैरामीटर ऑप्टिमाइज़र को उसी तरह प्रभावित नहीं करते हैं जिस तरह से स्थानीय चर करते हैं।
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
EXECUTE DateRangeProc @startDate, @endDate
END
CREATE PROCEDURE DateRangeProc(@startDate DATE, @endDate DATE)
AS
BEGIN
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
END
पैरामीटर किए गए डायनामिक SQL का उपयोग करें।
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
DECLARE @sql NVARCHAR(4000) = N'
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
'
DECLARE @param NVARCHAR(4000) = N'@startDate DATE, @endDate DATE'
EXECUTE sp_executesql @sql, @param, @startDate = @startDate, @endDate = @endDate
END
"हार्ड-कोडित" गतिशील एसक्यूएल का उपयोग करें।
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
DECLARE @sql NVARCHAR(4000) = N'
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
'
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NCHAR(10), @endDate, 126))
EXECUTE sp_executesql @sql
END
DATEADD()सीधे फ़ंक्शन का उपयोग करें ।
मैं इस पर उत्सुक नहीं हूं क्योंकि WHERE में कॉलिंग फ़ंक्शन भी प्रदर्शन को प्रभावित करता है।
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN DATEADD(DAY, -6, @endDate) AND @endDate
END
एक वैकल्पिक पैरामीटर का उपयोग करें।
मुझे यकीन नहीं है कि अगर पैरामीटर को असाइन करना वैरिएबल को असाइन करने के समान समस्या होगी, तो यह एक विकल्प नहीं हो सकता है। मैं वास्तव में इस समाधान को पसंद नहीं करता हूं, लेकिन पूर्णता के लिए इसे शामिल करता हूं।
CREATE PROCEDURE WeeklyProc(@endDate DATE, @startDate DATE = NULL)
AS
BEGIN
SET @startDate = DATEADD(DAY, -6, @endDate)
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
END
-- अपडेट करें --
सुझाव और टिप्पणियों के लिए धन्यवाद। उन्हें पढ़ने के बाद मैंने विभिन्न दृष्टिकोणों के साथ कुछ समय परीक्षण चलाए। मैं संदर्भ के रूप में यहां परिणाम जोड़ रहा हूं।
रन 1 एक योजना के बिना है। रन 2 रन 1 के तुरंत बाद समान मापदंडों के साथ है, इसलिए यह रन 1 से योजना का उपयोग करेगा।
NoProc बार एक संग्रहीत कार्यविधि के बाहर SSMS में मैन्युअल रूप से SELECT क्वेरी को चलाने के लिए हैं।
TestProc1-7 मूल प्रश्न से प्रश्न हैं।
TestProcA-B, Mikael Eriksson के सुझाव पर आधारित है । डेटाबेस में कॉलम एक DATE है, इसलिए मैंने DATETIME के रूप में पैरामीटर पास करने की कोशिश की और अंतर्निहित कास्टिंग (टेस्टप्रोक) और स्पष्ट कास्टिंग (टेस्टप्रोक) के साथ चल रहा है।
TestProcC-D केनेथ फिशर के सुझाव पर आधारित हैं । हम पहले से ही अन्य चीजों के लिए एक तारीख खोज तालिका का उपयोग करते हैं, लेकिन हमारे पास प्रत्येक अवधि सीमा के लिए एक विशिष्ट कॉलम नहीं है। मेरे द्वारा अभी भी की गई भिन्नता BETWEEN का उपयोग करती है, लेकिन यह छोटे लुकअप टेबल पर होती है और बड़ी तालिका में मिलती है। मैं आगे की जांच करने जा रहा हूं कि क्या हम विशिष्ट लुकअप तालिकाओं का उपयोग कर सकते हैं, हालांकि हमारी अवधि तय की गई है लेकिन कुछ अलग हैं।
बिक्री तालिका में कुल पंक्तियाँ: 136,424,366
रन 1 (एमएस) रन 2 (एमएस)
प्रक्रिया सीपीयू बीता हुआ सीपीयू बीता हुआ टिप्पणी
NoProc स्थिरांक 6567 62199 2870 719 स्थिरांक के साथ मैनुअल क्वेरी
NoProc चर 9314 62424 3993 998 चर के साथ मैनुअल क्वेरी
testProc1 6801 62919 2871 736 हार्ड कोडित रेंज
testProc2 8955 63190 3915 979 पैरामीटर और चर रेंज
पैरामीटर रेंज के साथ testProc3 8985 63152 3932 987 रैपर प्रक्रिया
टेस्टप्रोक 4 9142 63939 3931 977 डायनामिक एसक्यूएल
testProc5 7269 62933 2933 728 हार्ड कोडित गतिशील एसक्यूएल
testProc6 9266 63421 3915 984 DATEADD पर DATE का उपयोग करें
testProc7 2044 13950 1092 1087 डमी पैरामीटर
testProcA 12120 61493 5491 1875 CAST के बिना DATETIME पर DATEADD का उपयोग करें
testProcB 8612 61949 3932 978 CAST के साथ DATETIME पर DATEADD का उपयोग करें
testProcC 8861 61651 3917 993 लुकअप टेबल का उपयोग करें, बिक्री पहले
testProcD 8625 61740 3994 1031 लुकअप टेबल का उपयोग करें, अंतिम बिक्री
यहाँ परीक्षण कोड है।
------ SETUP ------
IF OBJECT_ID(N'testDimDate', N'U') IS NOT NULL DROP TABLE testDimDate
IF OBJECT_ID(N'testProc1', N'P') IS NOT NULL DROP PROCEDURE testProc1
IF OBJECT_ID(N'testProc2', N'P') IS NOT NULL DROP PROCEDURE testProc2
IF OBJECT_ID(N'testProc3', N'P') IS NOT NULL DROP PROCEDURE testProc3
IF OBJECT_ID(N'testProc3a', N'P') IS NOT NULL DROP PROCEDURE testProc3a
IF OBJECT_ID(N'testProc4', N'P') IS NOT NULL DROP PROCEDURE testProc4
IF OBJECT_ID(N'testProc5', N'P') IS NOT NULL DROP PROCEDURE testProc5
IF OBJECT_ID(N'testProc6', N'P') IS NOT NULL DROP PROCEDURE testProc6
IF OBJECT_ID(N'testProc7', N'P') IS NOT NULL DROP PROCEDURE testProc7
IF OBJECT_ID(N'testProcA', N'P') IS NOT NULL DROP PROCEDURE testProcA
IF OBJECT_ID(N'testProcB', N'P') IS NOT NULL DROP PROCEDURE testProcB
IF OBJECT_ID(N'testProcC', N'P') IS NOT NULL DROP PROCEDURE testProcC
IF OBJECT_ID(N'testProcD', N'P') IS NOT NULL DROP PROCEDURE testProcD
GO
CREATE TABLE testDimDate
(
DateKey DATE NOT NULL,
CONSTRAINT PK_DimDate_DateKey UNIQUE NONCLUSTERED (DateKey ASC)
)
GO
DECLARE @dateTimeStart DATETIME = '2000-01-01'
DECLARE @dateTimeEnd DATETIME = '2100-01-01'
;WITH CTE AS
(
--Anchor member defined
SELECT @dateTimeStart FullDate
UNION ALL
--Recursive member defined referencing CTE
SELECT FullDate + 1 FROM CTE WHERE FullDate + 1 <= @dateTimeEnd
)
SELECT
CAST(FullDate AS DATE) AS DateKey
INTO #DimDate
FROM CTE
OPTION (MAXRECURSION 0)
INSERT INTO testDimDate (DateKey)
SELECT DateKey FROM #DimDate ORDER BY DateKey ASC
DROP TABLE #DimDate
GO
-- Hard coded date range.
CREATE PROCEDURE testProc1 AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
END
GO
-- Parameter and variable date range.
CREATE PROCEDURE testProc2(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Parameter date range.
CREATE PROCEDURE testProc3a(@startDate DATE, @endDate DATE) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Wrapper procedure.
CREATE PROCEDURE testProc3(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
EXEC testProc3a @startDate, @endDate
END
GO
-- Parameterized dynamic SQL.
CREATE PROCEDURE testProc4(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DECLARE @sql NVARCHAR(4000) = N'SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate'
DECLARE @param NVARCHAR(4000) = N'@startDate DATE, @endDate DATE'
EXEC sp_executesql @sql, @param, @startDate = @startDate, @endDate = @endDate
END
GO
-- Hard coded dynamic SQL.
CREATE PROCEDURE testProc5(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DECLARE @sql NVARCHAR(4000) = N'SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN ''@startDate'' AND ''@endDate'''
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NCHAR(10), @endDate, 126))
EXEC sp_executesql @sql
END
GO
-- Explicitly use DATEADD on a DATE.
CREATE PROCEDURE testProc6(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN DATEADD(DAY, -1, @endDate) AND @endDate
END
GO
-- Dummy parameter.
CREATE PROCEDURE testProc7(@endDate DATE, @startDate DATE = NULL) AS
BEGIN
SET NOCOUNT ON
SET @startDate = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Explicitly use DATEADD on a DATETIME with implicit CAST for comparison with SaleDate.
-- Based on the answer from Mikael Eriksson.
CREATE PROCEDURE testProcA(@endDateTime DATETIME) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN DATEADD(DAY, -1, @endDateTime) AND @endDateTime
END
GO
-- Explicitly use DATEADD on a DATETIME but CAST to DATE for comparison with SaleDate.
-- Based on the answer from Mikael Eriksson.
CREATE PROCEDURE testProcB(@endDateTime DATETIME) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN CAST(DATEADD(DAY, -1, @endDateTime) AS DATE) AND CAST(@endDateTime AS DATE)
END
GO
-- Use a date lookup table, Sale first.
-- Based on the answer from Kenneth Fisher.
CREATE PROCEDURE testProcC(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale J INNER JOIN testDimDate D ON D.DateKey = J.SaleDate WHERE D.DateKey BETWEEN @startDate AND @endDate
END
GO
-- Use a date lookup table, Sale last.
-- Based on the answer from Kenneth Fisher.
CREATE PROCEDURE testProcD(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM testDimDate D INNER JOIN Sale J ON J.SaleDate = D.DateKey WHERE D.DateKey BETWEEN @startDate AND @endDate
END
GO
------ TEST ------
SET STATISTICS TIME OFF
DECLARE @endDate DATE = '2012-12-10'
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: NoProc with constants', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
SET STATISTICS TIME OFF
RAISERROR('Run 2: NoProc with constants', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
SET STATISTICS TIME OFF
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: NoProc with variables', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
SET STATISTICS TIME OFF
RAISERROR('Run 2: NoProc with variables', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
SET STATISTICS TIME OFF
DECLARE @sql NVARCHAR(4000)
DECLARE _cursor CURSOR LOCAL FAST_FORWARD FOR
SELECT
procedures.name,
procedures.object_id
FROM sys.procedures
WHERE procedures.name LIKE 'testProc_'
ORDER BY procedures.name ASC
OPEN _cursor
DECLARE @name SYSNAME
DECLARE @object_id INT
FETCH NEXT FROM _cursor INTO @name, @object_id
WHILE @@FETCH_STATUS = 0
BEGIN
SET @sql = CASE (SELECT COUNT(*) FROM sys.parameters WHERE object_id = @object_id)
WHEN 0 THEN @name
WHEN 1 THEN @name + ' ''@endDate'''
WHEN 2 THEN @name + ' ''@startDate'', ''@endDate'''
END
SET @sql = REPLACE(@sql, '@name', @name)
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NVARCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NVARCHAR(10), @endDate, 126))
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: %s', 0, 0, @sql) WITH NOWAIT
SET STATISTICS TIME ON
EXEC sp_executesql @sql
SET STATISTICS TIME OFF
RAISERROR('Run 2: %s', 0, 0, @sql) WITH NOWAIT
SET STATISTICS TIME ON
EXEC sp_executesql @sql
SET STATISTICS TIME OFF
FETCH NEXT FROM _cursor INTO @name, @object_id
END
CLOSE _cursor
DEALLOCATE _cursor