T SQL टेबल वेल्यूड फंक्शन कोमा पर कॉलम को विभाजित करने के लिए

Question

मैंने प्रत्येक मान के लिए अलग-अलग पंक्तियों को थूकने के लिए एक डेटाबेस में अल्पविराम सीमांकित कॉलम लेने के लिए Microsoft SQL Server 2008 में एक टेबल वैल्यूएड फ़ंक्शन लिखा था।

Ex: "एक, दो, तीन, चार" एक नया टेबल लौटाएगा जिसमें केवल एक कॉलम होगा जिसमें निम्नलिखित मान होंगे:

one
two
three
four

क्या यह कोड आप लोगों के लिए त्रुटिपूर्ण है? जब मैं इसके साथ परीक्षण करता हूं

SELECT * FROM utvf_Split('one,two,three,four',',') 

यह बस हमेशा के लिए चलता है और कभी भी कुछ भी नहीं लौटाता है। यह वास्तव में बहुत निराशाजनक है क्योंकि विशेष रूप से MSSQL सर्वर (WHY WHY WHY ?!) पर विभाजित कार्यों में कोई निर्माण क्यों नहीं किया गया है और वेब पर मुझे मिले सभी समान कार्य निरपेक्ष कचरा या बस मैं क्या करने की कोशिश कर रहा हूँ के लिए अप्रासंगिक हैं। ।

यहाँ समारोह है:

USE *myDBname*
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER FUNCTION [dbo].[utvf_SPlit] (@String VARCHAR(MAX), @delimiter CHAR)

RETURNS @SplitValues TABLE
(
    Asset_ID VARCHAR(MAX) NOT NULL
)

AS
BEGIN
            DECLARE @FoundIndex INT
            DECLARE @ReturnValue VARCHAR(MAX)

            SET @FoundIndex = CHARINDEX(@delimiter, @String)

            WHILE (@FoundIndex <> 0)
            BEGIN
                  DECLARE @NextFoundIndex INT
                  SET @NextFoundIndex = CHARINDEX(@delimiter, @String, @FoundIndex+1)
                  SET @ReturnValue = SUBSTRING(@String, @FoundIndex,@NextFoundIndex-@FoundIndex)
                  SET @FoundIndex = CHARINDEX(@delimiter, @String)
                  INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
            END

            RETURN
END

Answer 1

इसे फिर से काम किया ...

DECLARE @FoundIndex INT
DECLARE @ReturnValue VARCHAR(MAX)

SET @FoundIndex = CHARINDEX(@delimiter, @String)

WHILE (@FoundIndex <> 0)
BEGIN
      SET @ReturnValue = SUBSTRING(@String, 0, @FoundIndex)
      INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
      SET @String = SUBSTRING(@String, @FoundIndex + 1, len(@String) - @FoundIndex)
      SET @FoundIndex = CHARINDEX(@delimiter, @String)
END

INSERT @SplitValues (Asset_ID) VALUES (@String)

RETURN

Answer 2

मैं एक पाश के साथ ऐसा नहीं करेगा; बहुत बेहतर विकल्प हैं। अब तक सबसे अच्छा, आप जब है विभाजित करने के लिए, CLR है, और एडम Machanic का दृष्टिकोण सबसे तेजी से मैं परीक्षण किया है है ।

अगला सर्वोत्तम दृष्टिकोण IMHO, यदि आप सीएलआर को लागू नहीं कर सकते हैं, एक संख्या तालिका है:

SET NOCOUNT ON;

DECLARE @UpperLimit INT = 1000000;

WITH n AS
(
    SELECT
        x = ROW_NUMBER() OVER (ORDER BY s1.[object_id])
    FROM       sys.all_objects AS s1
    CROSS JOIN sys.all_objects AS s2
    CROSS JOIN sys.all_objects AS s3
)
SELECT Number = x
  INTO dbo.Numbers
  FROM n
  WHERE x BETWEEN 1 AND @UpperLimit
  OPTION (MAXDOP 1); -- protecting from Paul White's observation

GO
CREATE UNIQUE CLUSTERED INDEX n ON dbo.Numbers(Number) 
    --WITH (DATA_COMPRESSION = PAGE);
GO

... जो इस समारोह की अनुमति देता है:

CREATE FUNCTION dbo.SplitStrings_Numbers
(
   @List       NVARCHAR(MAX),
   @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
WITH SCHEMABINDING
AS
   RETURN
   (
       SELECT Item = SUBSTRING(@List, Number, 
         CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)
       FROM dbo.Numbers
       WHERE Number <= CONVERT(INT, LEN(@List))
         AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
   );
GO

मेरा मानना ​​है कि ये सभी आपके द्वारा किए गए फ़ंक्शन से बेहतर प्रदर्शन करेंगे, जब आप इसे काम कर रहे हैं, खासकर जब से वे मल्टी-स्टेटमेंट के बजाय इनलाइन हैं। मैंने जांच नहीं की है कि आपका काम क्यों नहीं हो रहा है, क्योंकि मुझे नहीं लगता कि यह उस कार्य को प्राप्त करने के लिए लायक है।

लेकिन यह सब कहा ...

चूँकि आप SQL Server 2008 का उपयोग कर रहे हैं, क्या कोई कारण है कि आपको पहली बार विभाजित करने की आवश्यकता है? मैं इसके लिए एक TVP का उपयोग करूंगा:

CREATE TYPE dbo.strings AS TABLE
(
  string NVARCHAR(4000)
);

अब आप इसे अपनी संग्रहीत प्रक्रियाओं के लिए एक पैरामीटर के रूप में स्वीकार कर सकते हैं, और सामग्री का उपयोग उसी तरह कर सकते हैं जैसे आप एक टीवीएफ का उपयोग करेंगे:

CREATE PROCEDURE dbo.foo
  @strings dbo.strings READONLY
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Asset_ID = string FROM @strings;
  -- SELECT Asset_ID FROM dbo.utvf_split(@other_param, ',');
END

और आप डेटाटेबल के रूप में C # आदि से सीधे TVP पास कर सकते हैं। यह ऊपर दिए गए किसी भी समाधान को लगभग निश्चित रूप से बेहतर बनाएगा, खासकर यदि आप अपने ऐप में विशेष रूप से अल्पविराम से अलग किए गए स्ट्रिंग का निर्माण कर रहे हैं ताकि आपकी संग्रहीत प्रक्रिया इसे फिर से विभाजित करने के लिए टीवीपी कह सके। टीवीपी के बारे में अधिक जानकारी के लिए एरलैंड सोमरसकॉग का शानदार लेख देखें ।

हाल ही में, मैंने स्ट्रिंग्स को विभाजित करने पर एक श्रृंखला लिखी है:

• http://sqlperformance.com/2012/07/t-sql-queries/split-strings
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-follow-up
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-now-with-less-t-sql

और यदि आप SQL Server 2016 या नए (या Azure SQL डेटाबेस) का उपयोग कर रहे हैं, तो एक नया STRING_SPLITफ़ंक्शन है , जिसके बारे में मैंने यहां ब्लॉग किया है:

• प्रदर्शन आश्चर्य और मान्यताएं: STRING_SPLIT ()
• SQL Server 2016 में STRING_SPLIT (): फ़ॉलो-अप # 1
• SQL Server 2016 में STRING_SPLIT (): फ़ॉलो-अप # 2

Answer 3

SQL सर्वर 2016 ने STRING_SPLIT () फ़ंक्शन शुरू किया । इसके दो मापदंड हैं - कटा हुआ और विभाजक। आउटपुट एक पंक्ति प्रति मान लौटा है।

दिए गए उदाहरण के लिए

SELECT * FROM string_split('one,two,three,four', ',');

वापस होगा

value
------------------
one
two
three
four

Answer 4

मैं जेफ मोदेन के स्ट्रिंग स्प्लिटर का उपयोग और प्यार करता रहा हूं, क्योंकि यह बाहर आया था।

टैली ओह! एक बेहतर SQL 8K "CSV फाड़नेवाला" समारोह

CREATE FUNCTION [dbo].[DelimitedSplit8K]
--===== Define I/O parameters
        (@pString VARCHAR(8000), @pDelimiter CHAR(1))
--WARNING!!! DO NOT USE MAX DATA-TYPES HERE!  IT WILL KILL PERFORMANCE!
RETURNS TABLE WITH SCHEMABINDING AS
 RETURN
--===== "Inline" CTE Driven "Tally Table" produces values from 1 up to 10,000...
     -- enough to cover VARCHAR(8000)
  WITH E1(N) AS (
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
                ),                          --10E+1 or 10 rows
       E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
       E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
 cteTally(N) AS (--==== This provides the "base" CTE and limits the number of rows right up front
                     -- for both a performance gain and prevention of accidental "overruns"
                 SELECT TOP (ISNULL(DATALENGTH(@pString),0)) ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
                ),
cteStart(N1) AS (--==== This returns N+1 (starting position of each "element" just once for each delimiter)
                 SELECT 1 UNION ALL
                 SELECT t.N+1 FROM cteTally t WHERE SUBSTRING(@pString,t.N,1) = @pDelimiter
                ),
cteLen(N1,L1) AS(--==== Return start and length (for use in substring)
                 SELECT s.N1,
                        ISNULL(NULLIF(CHARINDEX(@pDelimiter,@pString,s.N1),0)-s.N1,8000)
                   FROM cteStart s
                )
--===== Do the actual split. The ISNULL/NULLIF combo handles the length for the final element when no delimiter is found.
 SELECT ItemNumber = ROW_NUMBER() OVER(ORDER BY l.N1),
        Item       = SUBSTRING(@pString, l.N1, l.L1)
   FROM cteLen l
;

Answer 5

CREATE FUNCTION [dbo].[fnSplit]
(

    @sInputList VARCHAR(8000),         -- List of delimited items

    @sDelimiter VARCHAR(8000) = ','    -- delimiter that separates items

)
RETURNS @List TABLE (colData VARCHAR(8000))

BEGIN

DECLARE @sItem VARCHAR(8000)

    WHILE CHARINDEX(@sDelimiter,@sInputList,0) <> 0

    BEGIN

        SELECT @sItem=RTRIM(LTRIM(SUBSTRING(@sInputList,1,CHARINDEX
(@sDelimiter,@sInputList,0)-1))),

        @sInputList=RTRIM(LTRIM(SUBSTRING(@sInputList,CHARINDEX(@sDelimiter,@sInputList,0)
+LEN(@sDelimiter),LEN(@sInputList))))

        IF LEN(@sItem) > 0
            INSERT INTO @List SELECT @sItem
        END

        IF LEN(@sInputList) > 0
            INSERT INTO @List SELECT @sInputList -- Put the last item in
        RETURN
    END

--TEST

--Example 1: select * from fnSplit('1,22,333,444,,5555,666', ',')

--Example 2: select * from fnSplit('1##22#333##444','##')  --note second colData has embedded #

--Example 3: select * from fnSplit('1 22 333 444  5555 666', ' ')