जवाबों:
यदि आप किसी डेटाबेस को किसी उदाहरण से अलग करते हैं, तो आपको फ़ाइल का OS-level हटाना होगा। सुरक्षित दृष्टिकोण इसके बजाय डेटाबेस को छोड़ना है।
आपके द्वारा रीड ओनली मोड में डालने के बाद मैं जो सुझाव देता हूं वह डेटाबेस का अंतिम बैकअप ले रहा है (जैसा कि यह सुनिश्चित करेगा कि बैकअप के दौरान कोई गतिविधि नहीं हो रही है), जिसके बाद इसे ड्रॉप डेटाबेस कमांड के माध्यम से सिस्टम से हटा दें ।
कमांड का पूरा सेट निम्न के जैसा दिखेगा:
-- Use master db to ensure you don't have an active connection to the db you wish to affect
USE [master]
GO
-- This will kill any active transactions, but will force the database into a Read-Only state
ALTER DATABASE [db_name] SET READ_ONLY WITH ROLLBACK IMMEDIATE
GO
BACKUP DATABASE [db_name] -- Fill in more options here or use the UI to take a backup if you chooose
GO
-- This will kick out all connections from the database allowing you to drop it.
ALTER DATABASE [db_name] SET SINGLE_USER WITH ROLLBACK IMMEDIATE
GO
-- Drop the database (which automatically removes the files from the OS)
DROP DATABASE [db_name]
GO
इसके बाद, आप किसी भी ऐसे जॉब्स की तलाश करना चाहते हैं जो डेटाबेस के खिलाफ स्क्रिप्ट चलाता हो। मेरा सुझाव है कि आप बस यह देखने के लिए प्रतीक्षा करें कि क्या विफल रहता है (जिसके बाद आप नौकरी से बाहर कर सकते हैं / हटा सकते हैं) क्योंकि ऐसे कई तरीके हैं जिनसे नौकरी डेटाबेस का संदर्भ ले सकती है (जिनमें से सभी को पहचानना आसान नहीं है)।
अंत में, आप किसी भी उपयोगकर्ता को उस उदाहरण से निकालना चाहेंगे जो केवल इस डेटाबेस तक पहुंच था। इस स्क्रिप्ट को पहचानना चाहिए कि वे उपयोगकर्ता कौन हैं, हालांकि मैक्स का संस्करण बहुत अधिक क्लीनर है (मुझे यह महसूस नहीं हुआ कि जब तक मैंने इसे शामिल करने के लिए अपना जवाब संपादित नहीं किया, तब तक उसने एक दृष्टिकोण पोस्ट नहीं किया):
DECLARE @ExecString NVARCHAR (4000)
-- Create Empty Table in a very lazy manner
SELECT name, principal_id, CAST('' AS NVARCHAR(128)) as database_name
INTO ##tmp_AllDBUsers
FROM sys.server_principals
WHERE 1 = 2
-- Declare Cursor to iterate through all DBs on the instance
DECLARE dbCursor CURSOR
FOR
SELECT name
FROM sys .databases
DECLARE @name NVARCHAR (128)
OPEN dbCursor
FETCH NEXT FROM dbCursor
INTO @name
WHILE @@FETCH_STATUS = 0
BEGIN
SET @ExecString =
'USE [' + @name + '];
INSERT INTO ##tmp_AllDBUsers
SELECT sp.name, sp.principal_id, DB_NAME()
FROM sys.server_principals sp INNER JOIN sys.database_principals dp
ON sp.sid = dp.sid'
EXEC(@ExecString)
FETCH NEXT FROM dbCursor
INTO @name
END
-- Close and deallocate the cursor because you've finished traversing all it's data
CLOSE dbCursor
DEALLOCATE dbCursor
-- Show all logins that do not belong to a server-level role nor have access to any databases
SELECT sp.*
FROM sys.server_principals sp LEFT JOIN ##tmp_AllDBUsers adu
ON sp.principal_id = adu.principal_id
WHERE adu.principal_id IS NULL
AND sp.principal_id NOT IN (SELECT member_principal_id
FROM sys.server_role_members)
AND TYPE IN ('S', 'U', 'G')
-- cleanup
DROP TABLE ##tmp_AllDBUsers
मैंने जॉन के जवाब को गलत ठहराया है; मैं अन्य वस्तुओं के बारे में कुछ विवरण जोड़ना चाहूंगा जिन्हें आप साफ करना चाहते हैं।
SQL सर्वर एजेंट नौकरियों और अलर्ट डेटाबेस को संदर्भित कर सकते हैं। उन्हें साफ करने से अनावश्यक त्रुटियों को रोका जा सकेगा।
डेटाबेस के लिए विशेष रूप से बनाए गए किसी भी लॉगिन को हटा दें। निम्न T-SQL संभावित उम्मीदवार लॉगिन की पहचान करेगा जिसे आप देख सकते हैं कि क्या उनका उपयोग किया जा रहा है। कोड उन लॉगिन की पहचान करता है जो किसी डेटाबेस द्वारा संदर्भित नहीं हैं।
DECLARE @cmd nvarchar(max);
SET @cmd = ' SELECT sp.sid
FROM master.sys.server_principals sp
';
SELECT @cmd = @cmd + ' EXCEPT
SELECT dp.sid
FROM ' + QUOTENAME(d.name) + '.sys.database_principals dp
'
FROM sys.databases d
WHERE d.[state] <> 6; --ignore offline DBs
SET @cmd = 'SELECT spr.*
FROM (
' + @cmd + '
) src
INNER JOIN master.sys.server_principals spr
ON src.sid = spr.sid
WHERE spr.type <> ''R''
AND spr.name NOT LIKE ''%##MS_%''
AND spr.name NOT LIKE ''NT %''
AND NOT EXISTS (
SELECT 1
FROM sys.server_role_members srm
WHERE srm.member_principal_id = spr.principal_id
)
ORDER BY spr.name;
';
EXEC sys.sp_executesql @cmd;
बैकअप डिवाइस उस डेटाबेस के लिए मौजूद हो सकते हैं। उन्हें हटाते समय कड़ाई से आवश्यक नहीं है, यदि उनका उपयोग नहीं किया जा रहा है, तो उन्हें संभावित भविष्य के भ्रम को खत्म करने के लिए जाना चाहिए।
सर्वर-स्तरीय ट्रिगर डेटाबेस को संदर्भित कर सकते हैं।
डेटाबेस को संदर्भित करने वाली रखरखाव योजनाओं की तलाश करें - यदि वे लापता डेटाबेस को निकालने के लिए अद्यतन नहीं किए जाते हैं तो ये विफल हो जाएंगे।
सभी प्रमुख बिंदु पहले से ही कवर किए गए हैं। नीचे मेरे 2 सेंट हैं:
डेटाबेस का पता लगाना कभी भी एक स्थायी समाधान नहीं है क्योंकि इसका उपयोग डेटाबेस फ़ाइलों को सर्वर या किसी अन्य सर्वर पर ले जाने के लिए किया जाता था। जैसा कि ऊपर बताया गया है, SSMS या DROP डेटाबेस कमांड में डिलीट विकल्प द्वारा स्थायी रूप से एक डेटाबेस को हटाया जा सकता है।
आमतौर पर जो डेटाबेस जानबूझकर ऑफलाइन रखे जाते हैं और अलर्ट बनाते रहते हैं वे हैं जिन्हें हम अलग कर देते हैं और तब तक रखते हैं जब तक कि इसे स्थायी रूप से हटाया नहीं जा सकता (हटा दिया गया)।
Pre detach task: sp_helpdb dbnameफाइल लोकेशन जानने के लिए रन करें।
सफाई कार्य:
लॉगिन्स, एजेंट जॉब्स, ट्रिगर के अलावा और मैक्स द्वारा पहले से ही उल्लेख किए गए बिंदु, इन 2 पर भी ध्यान दिया जा सकता है।