ओरेकल में एक मेज पर अनुक्रमित द्वारा खपत की जा रही वास्तविक जगह को कैसे ढूंढें?

Question

मैं oracle 10g में एक टेबल पर अनुक्रमित द्वारा भस्म किए जा रहे वास्तविक स्थान को खोजना चाहता हूं। भविष्य के उपयोग के लिए oracle द्वारा आरक्षित स्थान को शामिल करने का मेरा कोई इरादा नहीं है। (ओरेकल द्वारा ओवरहेड पर विचार नहीं किया जाना चाहिए।) मैं चाहता हूं कि इस्तेमाल किए गए बाइट्स आवंटित बाइट्स न हों।

क्या आप आगे जाने में मेरी मदद कर सकते हैं?

इसके अलावा, एक तालिका में एक लंबे क्षेत्र के वास्तविक आकार को खोजने का एक तरीका है।

पुनश्च: बनाम () और dbms_lob.getlength () काम नहीं करते।

Comments

क्या आप साझा कर सकते हैं कि उन दो तरीकों ने आपके लिए काम क्यों नहीं किया?

— jcolebrand

आपको अपना दूसरा प्रश्न अलग से पूछना चाहिए।

— लेह रिफ़ेल

@ अच्छा मुद्दा। आइए देखें कि क्या उपयोगकर्ता को पता चलता है कि वे माइग्रेट हो चुके हैं और यहां उत्तर पाने के लिए सभी चरणों से गुजरते हैं। उनकी ओर से मेरी उँगलियाँ पार करना।

— jcolebrand

यह भी देखें stackoverflow.com/a/16661034/603516 ।

— वडज़िम

Answer 1

SELECT idx.index_name, SUM(bytes)
  FROM dba_segments seg,
       dba_indexes  idx
 WHERE idx.table_owner = <<owner of table>>
   AND idx.table_name  = <<name of table>>
   AND idx.owner       = seg.owner
   AND idx.index_name  = seg.segment_name
 GROUP BY idx.index_name

आपको प्रत्येक इंडेक्स द्वारा वास्तव में खपत की गई जगह दिखाएगा। मुझे यह स्पष्ट नहीं है कि यह वास्तव में किस तरह का ओवरहेड है जिसे आप खाते में रखने की कोशिश कर रहे हैं और आप एक सूचकांक के संदर्भ में "उपयोग" और "आवंटित" में कैसे भेद कर रहे हैं। यदि आप इंडेक्स में खाली जगह का हिसाब चाहते हैं, तो आप इंडेक्स में कितने आंशिक रूप से खाली ब्लॉक हैं, यह निर्धारित करने के लिए DBMS_SPACE.SPACE_USAGE प्रक्रिया का उपयोग कर सकते हैं ।

Comments

मेरा मानना ​​है कि ओपी यह समझता है कि आपकी क्वेरी (जो {{}} के बाद सिकुड़ती नहीं है ) को आवंटित आकार के delete <<name of table>>विपरीत इस्तेमाल किया गया है जो इंडेक्स में प्रविष्टियों की संख्या के साथ अलग-अलग होगी।

— रेने न्यफेनेगर

यह आदेश डीबीए तालिकाओं तक पहुँचने के बिना संभव है: SELECT idx.index_name, SUM(bytes) FROM user_segments seg, user_indexes idx WHERE idx.table_name = 'EMERGE_REPORTING_DETAIL' AND idx.index_name = seg.segment_name GROUP BY idx.index_name

— रिचर्ड डिंगवाल

@RichardDingwall - यह मानते हुए कि आप उस ओरेकल उपयोगकर्ता के रूप में लॉग इन हैं जो सूचकांक का मालिक है, वह काम करेगा। यदि आप एक डीबीए में रुचि रखते हैं कि अंतरिक्ष का उपयोग कितना किया जा रहा है, हालांकि, आप आम तौर पर तालिका के मालिक के अलावा एक उपयोगकर्ता के रूप में लॉग इन करेंगे।

— जस्टिन केव

Answer 2

इंडेक्स के आबंटित और उपयोग किए गए आकार को मापने के लिए (मेरा मानना ​​है कि आपकी समझ है), मैं शायद उपयोग करूँगा dbms_space

create or replace procedure tq84_index_size_proc 
as

  OBJECT_OWNER_in         varchar2(30) :=  user;
  OBJECT_NAME_in          varchar2(30) := 'TQ84_SIZE_IX';
  OBJECT_TYPE_in          varchar2(30) := 'INDEX';
  SAMPLE_CONTROL_in       number       :=  null;
  SPACE_USED_out          number;
  SPACE_ALLOCATED_out     number;
  CHAIN_PCENT_out         number;

  SUM_SEGMENT             number;

begin

  dbms_space.object_space_usage (
    OBJECT_OWNER           => OBJECT_OWNER_in        ,
    OBJECT_NAME            => OBJECT_NAME_in         ,
    OBJECT_TYPE            => OBJECT_TYPE_in         ,
    SAMPLE_CONTROL         => SAMPLE_CONTROL_in      ,
    SPACE_USED             => SPACE_USED_out         ,
    SPACE_ALLOCATED        => SPACE_ALLOCATED_out    ,
    CHAIN_PCENT            => CHAIN_PCENT_out
  );

  select sum(bytes) into SUM_SEGMENT 
    from user_segments
   where segment_name = OBJECT_NAME_in;


  dbms_output.put_line('Space Used:      ' || SPACE_USED_out);
  dbms_output.put_line('Space Allocated: ' || SPACE_ALLOCATED_out);
  dbms_output.put_line('Segment:         ' || SUM_SEGMENT);

end;
/

यह प्रक्रिया * TQ84_SIZE_IX * नामक एक सूचकांक के आबंटित और प्रयुक्त आकार को मापती है। पूर्णता के लिए, मैंने रिपोर्ट के अनुसार बाइट्स की गिनती भी जोड़ी है user_segments।

अब, यह कार्यविधि देखी जा सकती है:

create table tq84_size (
  col_1 varchar2(40),
  col_2 number
);

create index tq84_size_ix on tq84_size(col_1);

insert into tq84_size values ('*', 0);
commit;
exec tq84_index_size_proc;

सूचकांक में एक प्रविष्टि के साथ, निम्नलिखित आंकड़े वापस आ जाते हैं:

Space Used:      1078
Space Allocated: 65536
Segment:         65536

सूचकांक भर रहा है ...

insert into tq84_size 
select substr(object_name || object_type, 1, 40),
       rownum
  from dba_objects,
       dba_types
 where rownum < 500000;
commit;

... और फिर से आंकड़े मिल रहे हैं ...

exec tq84_index_size_proc;

... रिपोर्ट:

Space Used:      25579796
Space Allocated: 32505856
Segment:         32505856

फिर, यदि सूचकांक "खाली" है:

delete from tq84_size;
commit;
exec tq84_index_size_proc;

यह दिखाता है:

Space Used:      4052714
Space Allocated: 32505856
Segment:         32505856

जो प्रदर्शित करता है कि आवंटित आकार सिकुड़ता नहीं है जबकि प्रयुक्त आकार करता है।

Answer 3

यदि कोई व्यक्ति लंबे क्षेत्र के आकार का पता लगाने के लिए यहां आता है, तो यह करने का एक तरीका है। यदि प्रश्न अलग हो जाता है तो मैं इस उत्तर को हटा दूंगा।

नमूना डेटा...

CREATE TABLE TLONG 
(
  C1 Number(3),
  C2 LONG 
);

INSERT INTO TLONG VALUES (1,'abcd');
INSERT INTO TLONG VALUES (2,'abc');
INSERT INTO TLONG VALUES (3,'ab');
INSERT INTO TLONG VALUES (4,'1234567890');

कार्य करने का कार्य ... (उत्पादन के लिए यह एक पैकेज में होना चाहिए)

CREATE OR REPLACE FUNCTION GetLongLength (pKey Number) RETURN Number Is
   vLong Long;
BEGIN
   SELECT C2 INTO vLong FROM TLONG WHERE C1 = pKey;
   Return Length(vLong);
END;
/

SHOW ERRORS;

फ़ंक्शन का परीक्षण करें ...

SELECT rownum, GetLongLength(rownum) FROM dual CONNECT BY rownum<=4;

ROWNUM                 GETLONGLENGTH(ROWNUM)  
---------------------- ---------------------- 
1                      4                      
2                      3                      
3                      2                      
4                      10                   

Answer 4

मुझे एक स्कीमा में सभी अनुक्रमितों के लिए अंतरिक्ष उपयोग देखने के लिए इसे अधिक सामान्य और आसान बनाने के लिए रेने न्यफेनेगर के उत्तर को संशोधित करना पड़ा।

सोचा था कि संशोधित कोड यहाँ साझा करूँगा, यदि कोई अन्य इसे उपयोगी पाता है:

--==========================================
-- Show space usage by all indexes in schema
--==========================================
-- Required to show output in SQLDeveloper, which would supress it otherwise.
SET SERVEROUTPUT ON;
-- Calculates size for given index
CREATE OR REPLACE PROCEDURE calc_index_size(
    index_name IN VARCHAR2)
AS
  OBJECT_OWNER_in     VARCHAR2(30) := USER;
  OBJECT_NAME_in      VARCHAR2(30) := index_name;
  OBJECT_TYPE_in      VARCHAR2(30) := 'INDEX';
  SAMPLE_CONTROL_in   NUMBER       := NULL;
  SPACE_USED_out      NUMBER;
  SPACE_ALLOCATED_out NUMBER;
  CHAIN_PCENT_out     NUMBER;
  SUM_SEGMENT         NUMBER;
BEGIN
  dbms_space.object_space_usage ( OBJECT_OWNER => OBJECT_OWNER_in , OBJECT_NAME => OBJECT_NAME_in , OBJECT_TYPE => OBJECT_TYPE_in , SAMPLE_CONTROL => SAMPLE_CONTROL_in , SPACE_USED => SPACE_USED_out , SPACE_ALLOCATED => SPACE_ALLOCATED_out , CHAIN_PCENT => CHAIN_PCENT_out );
  SELECT SUM(bytes)
  INTO SUM_SEGMENT
  FROM user_segments
  WHERE segment_name = OBJECT_NAME_in;
  dbms_output.put_line('Space Used:      ' || ROUND(SPACE_USED_out     /1024/1024, 2) || 'MB');
  dbms_output.put_line('Space Allocated: ' || ROUND(SPACE_ALLOCATED_out/1024/1024) || 'MB');
  dbms_output.put_line('Segment:         ' || ROUND(SUM_SEGMENT        /1024/1024) || 'MB');
END;
/
-- Shows index size for all indexes in a schema
DECLARE
BEGIN
  FOR user_indexes_sorted_by_size IN
  (SELECT idx.index_name,
    SUM(bytes)/1024/1024 AS "Size(MB)"
  FROM user_segments seg,
    user_indexes idx
  WHERE idx.index_name = seg.segment_name
  GROUP BY idx.index_name
  ORDER BY "Size(MB)" DESC
  )
  LOOP
    dbms_output.put_line( user_indexes_sorted_by_size.index_name );
    dbms_output.put_line( '-------------------------------------' );
    calc_index_size(user_indexes_sorted_by_size.index_name);
    dbms_output.put_line( '' );
  END LOOP;
END;
--==========================================
--==========================================