वहाँ एक तरीका है जो SQL Server 2008 में कुछ खरीद की सूची है?
में इस अतः लिंक वहाँ कुछ जवाब लेकिन हैं 6yrs से पहले।
मुझे पता है कि यह आपके नाम और तारीख को लिखने के लिए सबसे अच्छा विकल्प है, और फिर प्रक्रिया बनाना शुरू करें, लेकिन मैं यह नहीं देखता कि मैं कहां काम करता हूं।
यदि ऐसा करने का कोई तरीका नहीं है, तो क्या यह कार्य ट्रिगर के साथ किया जा सकता है?
और एक बोनस सवाल। क्या यह नौकरी है, एक डीबीए की? यह जानने के लिए कि इसे किसने बनाया?
आपका बहुत बहुत धन्यवाद।
जवाबों:
हां वहां एक रास्ता है
ट्रिगर के परिणामों को संग्रहीत करने के लिए तालिका
USE [SOME_DATABASE]
GO
CREATE TABLE [dbo].[ddl_objects_log](
[date] [datetime] NULL DEFAULT (getdate()),
[login_name] [nvarchar](128) NULL,
[nt_user_name] [nvarchar](128) NULL,
[program_name] [nvarchar](128) NULL,
[host_name] [nvarchar](128) NULL,
[text] [xml] NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
GOट्रिगर
USE [SOME_DATABASE]
GO
/****** Object: DdlTrigger [ddl_db_trigger] Script Date: 22/01/2015 13:41:38 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE TRIGGER [ddl_db_trigger]
ON DATABASE
FOR CREATE_FUNCTION,
CREATE_PROCEDURE,
CREATE_TABLE,
CREATE_TRIGGER,
CREATE_VIEW,
ALTER_FUNCTION,
ALTER_PROCEDURE,
ALTER_TABLE,
ALTER_TRIGGER,
ALTER_VIEW,
DROP_FUNCTION,
DROP_PROCEDURE,
DROP_TABLE,
DROP_TRIGGER,
DROP_VIEW,
CREATE_INDEX,
ALTER_INDEX,
DROP_INDEX
AS
BEGIN
set nocount ON
insert into ddl_objects_log(login_name, nt_user_name, program_name, host_name, text)
select login_name, nt_user_name, program_name, host_name, EVENTDATA() from sys.dm_exec_sessions WITH(NOLOCK) where session_id=@@SPID
set nocount OFF
END
GO
ENABLE TRIGGER [ddl_db_trigger] ON DATABASE
GOट्रिगर के परिणामों की ऑडिट करने की क्वेरी
USE [SOME_DATABASE]
GO
SELECT top 10
REPLACE(CONVERT(VARCHAR(250), text.query('data(/EVENT_INSTANCE/PostTime)')),'T', ' ') as modify_datetime,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/EventType)')) as event_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ServerName)')) as server_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/DatabaseName)')) as database_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectType)')) as object_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) as object_name,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/UserName)')) as user_name,
Login_name,
CONVERT(VARCHAR(MAX), text.query('data(/EVENT_INSTANCE/TSQLCommand/CommandText)')) as command_text
FROM [SOME_DATABASE].[dbo].[ddl_objects_log]
where CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) like '%SOME_STORED_PROCEDURE%'
order by date desc
GOएक और डीबीए एक अलग राय हो सकती है, लेकिन मैं इस जानकारी को डीबीए के लिए आसानी से उपलब्ध होने पर विचार करता हूं।
FROM [SOME_DATABASE].[dbo].[ddl_objects_log]... क्या मुझे टेबल बनाना चाहिए?
यदि आपके पास डिफ़ॉल्ट ट्रेस सक्षम है और यह लुढ़का नहीं है, तो आप इसका उपयोग यह पता लगाने के लिए कर सकते हैं कि एसपी किसने बनाया है
/*
Object Altered
Object Created
Object Deleted
*/
SELECT TE.name ,
v.subclass_name ,
DB_NAME(t.DatabaseId) AS DBName ,
T.NTDomainName ,
t.NTUserName ,
t.HostName ,
t.ApplicationName ,
t.LoginName ,
t.Duration ,
t.StartTime ,
t.ObjectName ,
CASE t.ObjectType
WHEN 8259 THEN 'Check Constraint'
WHEN 8260 THEN 'Default (constraint or standalone)'
WHEN 8262 THEN 'Foreign-key Constraint'
WHEN 8272 THEN 'Stored Procedure'
WHEN 8274 THEN 'Rule'
WHEN 8275 THEN 'System Table'
WHEN 8276 THEN 'Trigger on Server'
WHEN 8277 THEN '(User-defined) Table'
WHEN 8278 THEN 'View'
WHEN 8280 THEN 'Extended Stored Procedure'
WHEN 16724 THEN 'CLR Trigger'
WHEN 16964 THEN 'Database'
WHEN 16975 THEN 'Object'
WHEN 17222 THEN 'FullText Catalog'
WHEN 17232 THEN 'CLR Stored Procedure'
WHEN 17235 THEN 'Schema'
WHEN 17475 THEN 'Credential'
WHEN 17491 THEN 'DDL Event'
WHEN 17741 THEN 'Management Event'
WHEN 17747 THEN 'Security Event'
WHEN 17749 THEN 'User Event'
WHEN 17985 THEN 'CLR Aggregate Function'
WHEN 17993 THEN 'Inline Table-valued SQL Function'
WHEN 18000 THEN 'Partition Function'
WHEN 18002 THEN 'Replication Filter Procedure'
WHEN 18004 THEN 'Table-valued SQL Function'
WHEN 18259 THEN 'Server Role'
WHEN 18263 THEN 'Microsoft Windows Group'
WHEN 19265 THEN 'Asymmetric Key'
WHEN 19277 THEN 'Master Key'
WHEN 19280 THEN 'Primary Key'
WHEN 19283 THEN 'ObfusKey'
WHEN 19521 THEN 'Asymmetric Key Login'
WHEN 19523 THEN 'Certificate Login'
WHEN 19538 THEN 'Role'
WHEN 19539 THEN 'SQL Login'
WHEN 19543 THEN 'Windows Login'
WHEN 20034 THEN 'Remote Service Binding'
WHEN 20036 THEN 'Event Notification on Database'
WHEN 20037 THEN 'Event Notification'
WHEN 20038 THEN 'Scalar SQL Function'
WHEN 20047 THEN 'Event Notification on Object'
WHEN 20051 THEN 'Synonym'
WHEN 20549 THEN 'End Point'
WHEN 20801 THEN 'Adhoc Queries which may be cached'
WHEN 20816 THEN 'Prepared Queries which may be cached'
WHEN 20819 THEN 'Service Broker Service Queue'
WHEN 20821 THEN 'Unique Constraint'
WHEN 21057 THEN 'Application Role'
WHEN 21059 THEN 'Certificate'
WHEN 21075 THEN 'Server'
WHEN 21076 THEN 'Transact-SQL Trigger'
WHEN 21313 THEN 'Assembly'
WHEN 21318 THEN 'CLR Scalar Function'
WHEN 21321 THEN 'Inline scalar SQL Function'
WHEN 21328 THEN 'Partition Scheme'
WHEN 21333 THEN 'User'
WHEN 21571 THEN 'Service Broker Service Contract'
WHEN 21572 THEN 'Trigger on Database'
WHEN 21574 THEN 'CLR Table-valued Function'
WHEN 21577
THEN 'Internal Table (For example, XML Node Table, Queue Table.)'
WHEN 21581 THEN 'Service Broker Message Type'
WHEN 21586 THEN 'Service Broker Route'
WHEN 21587 THEN 'Statistics'
WHEN 21825 THEN 'User'
WHEN 21827 THEN 'User'
WHEN 21831 THEN 'User'
WHEN 21843 THEN 'User'
WHEN 21847 THEN 'User'
WHEN 22099 THEN 'Service Broker Service'
WHEN 22601 THEN 'Index'
WHEN 22604 THEN 'Certificate Login'
WHEN 22611 THEN 'XMLSchema'
WHEN 22868 THEN 'Type'
ELSE 'Hmmm???'
END AS ObjectType
FROM [fn_trace_gettable](CONVERT(VARCHAR(150), ( SELECT TOP 1
value
FROM [fn_trace_getinfo](NULL)
WHERE [property] = 2
)), DEFAULT) T
JOIN sys.trace_events TE ON T.EventClass = TE.trace_event_id
JOIN sys.trace_subclass_values v ON v.trace_event_id = TE.trace_event_id
AND v.subclass_value = t.EventSubClass
WHERE TE.name IN ( 'Object:Created', 'Object:Deleted', 'Object:Altered' )
-- filter statistics created by SQL server
AND t.ObjectType NOT IN ( 21587 )
-- filter tempdb objects
AND DatabaseID <> 2
-- get only events in the past 24 hours
AND StartTime > DATEADD(HH, -24, GETDATE())
ORDER BY t.StartTime DESC ;विस्तार करने के लिए यहां क्लिक करें
क्या यह नौकरी है, एक डीबीए की? यह जानने के लिए कि sql के अंदर किसने क्या बनाया?
यह इस बात पर निर्भर करता है कि आप यह जानना चाहते हैं कि क्या वस्तुएं बनी / बदली गई हैं या गिरा दी गई हैं। यदि आप महसूस करते हैं कि वस्तुओं को बनाया गया है या अनधिकृत उपयोगकर्ता द्वारा बदल दिया गया है या बदल दिया गया है, तो आप सूचना अधिसूचना का उपयोग कर सकते हैं । सुनिश्चित करें कि आपके पास उचित फ़िल्टर्स हैं।
इस उत्तर की पूर्णता के लिए, मैं उल्लेख करना चाहता हूं - मुझे SQL सर्वर से डिफ़ॉल्ट रूप से कौन सी घटना की जानकारी मिल सकती है? हारून बर्ट्रेंड से।
DATEADD(HH, -24, GETDATE())यदि आपको २४ घंटे से अधिक के लिए परिणाम प्राप्त करना है तो आपको संशोधित करना होगा।
select * from sys.procedures where type = 'P' order by create_date desc
AND DatabaseID= 'the_Database_I_Want, तो यह DATEADD(HH, -24, GETDATE())टिप्पणी के साथ मुझे कुछ भी नहीं दिखाता है । क्या मुझसे कुछ गलत हो रही है?
मैं देर से आ रहा हूँ, लेकिन मैं "सुरक्षा" और * प्रशासन की बातें करता हूँ।
क्या यह नौकरी है, एक डीबीए की? यह जानने के लिए कि sql के अंदर किसने क्या बनाया?
हाँ । जहां भी संभव हो इन लॉग को बनाना या बनाना महत्वपूर्ण है। हालाँकि, यह आपकी ज़िम्मेदारी भी है, मेरे विचार से, जब तक यह महत्वपूर्ण न हो जाए, तब तक इस बॉक्स को न खोलें। दूसरे शब्दों में - फिर से, मेरे विचार में - डेटा के लिए रेपो प्रदान करना आपका काम है, सुनिश्चित करें कि यह सुरक्षित है, सुनिश्चित करें कि यह ट्यून किया गया है ... और तब तक डेटा से दूर रहें जब तक कि आपको विशेष रूप से बुलाया न जाए इसे देखो या जब तक यह अपने लक्ष्य को पूरा करने के लिए आवश्यक है।
मेरी राय, और मेरा दृष्टिकोण, लेकिन मैंने कई वर्षों के लिए संवेदनशील और गोपनीय डेटा के साथ काम किया है और इसे बहुत कम [1] "बॉक्स को खोलने" का एक बिंदु बनाया है, क्योंकि यह उपयोगकर्ताओं के साथ विश्वास को कम करता है।
अब मुझे एक अलग रास्ता लेना चाहिए : क्या होगा अगर कोई जल्दी से यह पता नहीं लगा सकता है कि प्रक्रिया किनारे के मामलों में कैसे प्रतिक्रिया देती है? आपको या मुझे एक घंटे तक की पहेली में लेखक को कुछ मिनट लग सकते हैं: "आह, ठीक है, यह बात तब विफल होती है जब ..."