चरण 1: सूचनाएं प्राप्त करने के लिए एक सेवा बनाएं और इसके लिए एक कतार बनाएं:
use msdb;
go
create queue dbm_notifications_queue;
create service dbm_notification_service
on queue dbm_notifications_queue
([http://schemas.microsoft.com/SQL/Notifications/PostEventNotification]);
go
create event notification dbm_notifications
on server
for database_mirroring_state_change
to service N'dbm_notification_service', N'current database';
go
ध्यान दें कि मैं उपयोग कर रहा हूं msdb, यह कोई दुर्घटना नहीं है। क्योंकि सर्वर स्तर की ईवेंट सूचनाएँ इससे भेजी जाती msdbहैं, यदि आप विपरीत वार्तालाप समापन बिंदु (लक्ष्य) भी बनाते हैं तो यह बहुत बेहतर है msdb, जिसका अर्थ है कि गंतव्य सेवा और कतार भी तैनात होनी चाहिए msdb।
चरण 2: ईवेंट सूचना प्रसंस्करण प्रक्रिया बनाएँ:
use msdb;
go
create table dbm_notifications_errors (
incident_time datetime not null,
session_id int not null,
has_rolled_back bit not null,
[error_number] int not null,
[error_message] nvarchar(4000) not null,
[message_body] varbinary(max));
create clustered index cdx_dbm_notifications_errors
on dbm_notifications_errors (incident_time);
go
create table mirroring_alerts (
alert_time datetime not null,
start_time datetime not null,
processing_time datetime not null,
database_id smallint not null,
database_name sysname not null,
[state] tinyint not null,
[text_data] nvarchar(max),
event_data xml not null);
create clustered index cdx_mirroring_alerts
on mirroring_alerts (alert_time);
go
create procedure dbm_notifications_procedure
as
begin
declare @dh uniqueidentifier, @mt sysname, @raw_body varbinary(max), @xml_body xml;
begin transaction;
begin try;
receive top(1)
@dh = conversation_handle,
@mt = message_type_name,
@raw_body = message_body
from dbm_notifications_queue;
if N'http://schemas.microsoft.com/SQL/Notifications/EventNotification' = @mt
begin
set @xml_body = cast(@raw_body as xml);
-- shred the XML and process it accordingly
-- IMPORTANT! IMPORTANT!
-- DO NOT LOOK AT sys.database_mirroring
-- The view represents the **CURRENT** state
-- This message reffers to an **EVENT** that had occured
-- the current state may or may no be relevant for this **PAST** event
declare @alert_time datetime
, @start_time datetime
, @processing_time datetime = getutcdate()
, @database_id smallint
, @database_name sysname
, @state tinyint
, @text_data nvarchar(max);
set @alert_time = @xml_body.value (N'(//EVENT_INSTANCE/PostTime)[1]', 'DATETIME');
set @start_time = @xml_body.value (N'(//EVENT_INSTANCE/StartTime)[1]', 'DATETIME');
set @database_id = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseID)[1]', 'SMALLINT');
set @database_name = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseName)[1]', 'SYSNAME');
set @state = @xml_body.value (N'(//EVENT_INSTANCE/State)[1]', 'TINYINT');
set @text_data = @xml_body.value (N'(//EVENT_INSTANCE/TextData)[1]', 'NVARCHAR(MAX)');
insert into mirroring_alerts (
alert_time,
start_time,
processing_time,
database_id,
database_name,
[state],
text_data,
event_data)
values (
@alert_time,
@start_time,
@processing_time,
@database_id,
@database_name,
@state,
@text_data,
@xml_body);
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/Error' = @mt
begin
set @xml_body = cast(@raw_body as xml);
DECLARE @error INT
, @description NVARCHAR(4000);
WITH XMLNAMESPACES ('http://schemas.microsoft.com/SQL/ServiceBroker/Error' AS ssb)
SELECT @error = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Code)[1]', 'INT'),
@description = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Description)[1]', 'NVARCHAR(4000)');
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
0,
@error,
@description,
@raw_body);
end conversation @dh;
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/EndDialog' = @mt
begin
end conversation @dh;
end
commit;
end try
begin catch
declare @xact_state int = xact_state(),
@error_number int = error_number(),
@error_message nvarchar(4000) = error_message(),
@has_rolled_back bit = 0;
if @xact_state = -1
begin
-- Doomed transaction, it must rollback
rollback;
set @has_rolled_back = 1;
end
else if @xact_state = 0
begin
-- transaction was already rolled back (deadlock?)
set @has_rolled_back = 1;
end
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
@has_rolled_back,
@error_number,
@error_message,
@raw_body);
if (@has_rolled_back = 0)
begin
commit;
end
end catch
end
go
सर्विस ब्रोकर प्रक्रिया लिखना आपका रन-ऑफ-द-मिल कोड नहीं है। एक को कुछ मानकों का पालन करना चाहिए और क्विकसैंड क्षेत्र में भटकना बहुत आसान है। यह कोड कुछ अच्छी प्रथाओं को दिखाता है:
- एक लेनदेन में संदेश को हटाने और प्रसंस्करण को लपेटें। कोई ब्रेनर, स्पष्ट नहीं।
- हमेशा प्राप्त संदेश प्रकार की जाँच करें। एक अच्छा सेवा दलाल प्रक्रिया चाहिए संभाल
Errorऔर EndDialogयह की ओर से संवाद समाप्त संदेशों उचित रूप से। हैंडल लीक में ऐसा नहीं करने से ( sys.conversation_endpointsबढ़ता है)
- हमेशा जांचें कि क्या कोई संदेश RECEIVE द्वारा हटा दिया गया था। कुछ नमूने जाँच करने के बाद @@ rowcount
RECEIVE, जो पूरी तरह से ठीक है। यह नमूना कोड संदेश नाम की जाँच पर निर्भर करता है (कोई संदेश NULL संदेश प्रकार के नाम का अर्थ नहीं है) और उस मामले को संक्षेप में संभालता है।
- एक प्रसंस्करण त्रुटि तालिका बनाएँ। SSB सक्रिय प्रक्रियाओं की पृष्ठभूमि प्रकृति यदि संदेशों को केवल w / oa ट्रेस मिटा देती है, तो त्रुटियों का निवारण करना वास्तव में कठिन हो जाता है।
इसके अलावा, यह कोड हाथ में कार्य के संबंध में कुछ अच्छा अभ्यास कोड भी करता है (डीबीएम की निगरानी):
- के बीच अंतर
post_time( जब अधिसूचना भेजी गई थी? ); start_time( जब कार्रवाई शुरू हुई जिसने नोटिफ़िकेशन शुरू किया? ) processing_time( जब अधिसूचना संसाधित हुई थी? )। post_timeऔर start_timeसंभावना समान या बहुत करीब होगी, लेकिन processing_timeसेकंड, घंटे, दिन अलग हो सकते हैं post_time। ऑडिट के लिए दिलचस्प एक आम तौर पर है post_time।
- के बाद से
post_timeऔर processing_timeअलग हैं, यह स्पष्ट होना चाहिए एक डी बी एम एक और भी अधिसूचना में कार्य की निगरानी के सक्रिय कि प्रक्रिया कोई व्यवसाय को देखकर है sys.database_mirroringदृश्य । यह दृश्य प्रसंस्करण की स्थिति में वर्तमान स्थिति को दिखाएगा , जो घटना से संबंधित हो सकता है या नहीं भी हो सकता है। यदि ईवेंट के पोस्ट किए जाने के बाद प्रसंस्करण लंबे समय से होता है (समस्या के अनुसार रखरखाव डाउनटाइम लगता है), लेकिन यह स्पष्ट है कि यह 'स्वस्थ' प्रसंस्करण में भी काम कर सकता है यदि डीबीएम बहुत तेजी से राज्य बदलता है और एक में दो (या अधिक) इवेंट पोस्ट करता है पंक्ति (जो अक्सर होती है): इस स्थिति में प्रसंस्करण, जैसा कि आपके द्वारा पोस्ट किए गए कोड में, घटना को ऑडिट करते हैं जैसे वे होते हैं, लेकिन वर्तमान, अंतिम , स्थिति को रिकॉर्ड करेगा । इस तरह के ऑडिट को पढ़ना बाद में बहुत भ्रामक हो सकता है।
- हमेशा मूल XML इवेंट का ऑडिट करें। इस तरह से आप बाद में इस XML को किसी भी जानकारी के लिए क्वेरी कर सकते हैं जो ऑडिट टेबल में कॉलम में 'कटा हुआ' नहीं थी।
चरण 3: कतार में प्रक्रिया संलग्न करें:
alter queue dbm_notifications_queue
with activation (
status=on,
procedure_name = [dbm_notifications_procedure],
max_queue_readers = 1,
execute as owner);