QBasic, 309 बाइट्स
चेतावनी: गोल्फ संस्करण उपयोगकर्ता के अनुकूल नहीं है: इसमें एक अजीब इनपुट विधि है, एक अनंत लूप के रूप में चलती है, और इसमें कोई देरी नहीं है (इस प्रकार, कुछ प्रणालियों पर बहुत तेजी से चलता है)। इसे तभी चलाएं जब आप अपने QBasic वातावरण में किसी प्रोग्राम को समाप्त करना जानते हों। अनगुल्ड संस्करण की सिफारिश की जाती है (नीचे देखें)।
INPUT w,h
SCREEN 9
FOR y=1TO h
FOR x=1TO w
PSET(x,y),VAL(INPUT$(1))
NEXT
NEXT
DO
FOR y=1TO h
FOR x=1TO w
SCREEN,,0
c=POINT(x,y)
d=c
IF c=7THEN d=1
IF c=1THEN d=6
IF c=6THEN
n=0
FOR v=y-1TO y+1
FOR u=x-1TO x+1
n=n-(POINT(u,v)=7)
NEXT
NEXT
d=7+(n=0OR n>2)
END IF
SCREEN,,1,0
PSET(x,y),d
NEXT
NEXT
PCOPY 1,0
LOOP
चलाने के लिए, इनपुट पर निर्दिष्ट करें आपके कॉन्फ़िगरेशन की चौड़ाई wऔर ऊँचाई को संकेत दें h। 1 फिर w*hकोशिकाओं के लिए एकल-अंकीय कोड टाइप करें (बाएं से दाएं, फिर ऊपर से नीचे)
0 = खाली6 = तार7 = संकेत प्रधान1 = सिग्नल टेल
एक बार जब आप सभी कोशिकाओं में प्रवेश कर जाते हैं, तो सिमुलेशन शुरू हो जाएगा (और हमेशा के लिए जारी रहेगा, जब तक आप प्रोग्राम को नहीं मारते)।
Ungolfed
एक अधिक उपयोगकर्ता के अनुकूल संस्करण। लेआउट को संशोधित करने के लिए, DATAअंत में बयानों को संशोधित करें ।
कोड POINTफ़ंक्शन का लाभ उठाता है , जो स्क्रीन से पिक्सेल का रंग मूल्य पढ़ता है। इसका मतलब है कि हमें एक सरणी के रूप में कोशिकाओं को अलग से संग्रहीत करने की आवश्यकता नहीं है। यह सुनिश्चित करने के लिए कि सभी सेल एक साथ अपडेट होते हैं, हम एक दूसरे "पेज" पर अपडेट करते हैं। हम SCREENकथन के एक संस्करण का उपयोग करके सक्रिय पृष्ठ को टॉगल कर सकते हैं , और कथन का उपयोग करके एक पृष्ठ की सामग्री को दूसरे में कॉपी कर सकते हैं PCOPY।
SCREEN 9
EMPTY = 0 ' Black
HEAD = 7 ' Light gray
TAIL = 1 ' Blue
WIRE = 6 ' Brown/orange
' First two data values are the width and height
READ w, h
' The rest are the initial configuration, row by row
' Read them and plot the appropriately colored pixels
FOR y = 1 TO h
FOR x = 1 TO w
READ state$
IF state$ = "" THEN value = EMPTY
IF state$ = "H" THEN value = HEAD
IF state$ = "T" THEN value = TAIL
IF state$ = "W" THEN value = WIRE
PSET (x, y), value
NEXT x
NEXT y
' Loop the simulation until user presses a key
DO UNTIL INKEY$ <> ""
' Store current time for delay purposes
t# = TIMER
FOR y = 1 TO h
FOR x = 1 TO w
' Active page = display page = 0
SCREEN , , 0
' Get the color value of the pixel at x,y
oldVal = POINT(x, y)
IF oldVal = EMPTY THEN
newVal = EMPTY
ELSEIF oldVal = HEAD THEN
newVal = TAIL
ELSEIF oldVal = TAIL THEN
newVal = WIRE
ELSEIF oldVal = WIRE THEN
neighbors = 0
FOR ny = y - 1 TO y + 1
FOR nx = x - 1 TO x + 1
IF POINT(nx, ny) = HEAD THEN neighbors = neighbors + 1
NEXT nx
NEXT ny
IF neighbors = 1 OR neighbors = 2 THEN
newVal = HEAD
ELSE
newVal = WIRE
END IF
END IF
' Active page = 1, display page = 0
SCREEN , , 1, 0
' Plot the new value on page 1
PSET (x, y), newVal
NEXT x
NEXT y
' Copy page 1 to page 0
PCOPY 1, 0
' Delay
WHILE TIMER >= t# AND t# + 0.2 > TIMER
WEND
LOOP
DATA 8,5
DATA T,H,W,W,W,W,W,W
DATA W, , , ,W, , ,
DATA , , ,W,W,W, ,
DATA W, , , ,W, , ,
DATA H,T,W,W, ,W,W,W
1 चौड़ाई और ऊंचाई के लिए अधिकतम मूल्य इस बात पर निर्भर करते हैं कि स्क्रीन मोड का उपयोग किस प्रकार किया जाता है। में SCREEN 9, चौड़ाई 638 तक और ऊँचाई 348 तक हो सकती SCREEN 7है। एक छोटा रिज़ॉल्यूशन (अधिकतम कॉन्फ़िगरेशन आकार 318 198 तक) है, लेकिन पिक्सेल बड़े हैं और इस प्रकार (डॉस QBasic या DOSBox एमुलेटर पर) देखना आसान है - दुर्भाग्य से QB64 एक छोटी सी खिड़की देता है)।
उदाहरण चलाते हैं
पर Ungolfed संस्करण archive.org , स्क्रीन मोड 7 के साथ:
