171 बाइट्स 1
Wooohoooo! इसमें आधा दिन लगा, लेकिन यह मजेदार था ...
तो, यहाँ यह है। मुझे लगता है कि यह ऐनक के अनुरूप है (सेल पॉइंटर का रैपराउंड, इनपुट पर वर्णों की प्रतिध्वनि, चार द्वारा चार का पाठ, इनपुट चार की गूंज ...), और यह वास्तव में काम करने लगता है (ठीक है, मैंने कई कार्यक्रमों की कोशिश नहीं की। , लेकिन भाषा की सरलता को देखते हुए, कवरेज उतना बुरा नहीं है, मुझे लगता है)।
सीमाएं
एक महत्वपूर्ण बात: यदि आपके ब्रेनफक प्रोग्राम में 8 ब्रेनफक निर्देशों की तुलना में अन्य वर्ण हैं, या यदि []वे अच्छी तरह से संतुलित नहीं हैं, तो यह आप पर दुर्घटना करेगा, मौहहा!
इसके अलावा, ब्रेनफक प्रोग्राम 512 बाइट्स (एक सेक्टर) से अधिक नहीं हो सकता है। लेकिन जब से आप कहते हैं कि "निष्पादन योग्य ब्रेनफैक दूसरे डिस्क क्षेत्र में स्थित है", यह अनुरूप है। ।
अंतिम विवरण: मैंने स्पष्ट रूप से कोशिकाओं को शून्य से प्रारंभ नहीं किया था। Qemu मेरे लिए ऐसा लगता है, और मैं इस पर भरोसा कर रहा हूं, लेकिन मुझे नहीं पता कि एक वास्तविक कंप्यूटर पर एक वास्तविक BIOS यह करेगा (आरंभीकरण बस कुछ बाइट्स और अधिक ले जाएगा, वैसे भी)।
कोड
(आपके खाके के आधार पर, और वैसे भी, इसके लिए धन्यवाद, मैंने कभी इसके बिना कोशिश नहीं की होगी):
[BITS 16]
[ORG 0x7C00]
%define cellcount 30000 ; you can't actually increase this value much beyond this point...
; first sector:
boot:
; initialize segment registers
xor ax, ax
mov ss, ax
mov ds, ax
mov es, ax
jmp 0x0000:$+5
; initialize stack
mov sp, 0x7bfe
; load brainfuck code into 0x8000
; no error checking is used
mov ah, 2 ; read
mov al, 1 ; one sector
mov ch, 0 ; cylinder & 0xff
mov cl, 2 ; sector | ((cylinder >> 2) & 0xc0)
mov dh, 0 ; head
; dl is already the drive number
mov bx, 0x8000 ; read buffer (es:bx)
int 0x13 ; read sectors
; initialize SI (instruction pointer)
mov si, bx ; 0x8000
; initialize DI (data pointer)
mov bh, 0x82
mov di, bx ; 0x8200
decode:
lodsb ; fetch brainfuck instruction character
.theend:
test al, al ; endless loop on 0x00
jz .theend
and ax, 0x0013 ; otherwise, bit shuffling to get opcode id
shl ax, 4
shl al, 2
shr ax, 1
add ax, getchar ; and compute instruction implementation address
jmp ax
align 32, db 0
getchar:
xor ah, ah
int 0x16
cmp al, 13
jne .normal
mov al, 10 ; "enter" key translated to newline
.normal:
mov byte [di], al
push di
jmp echochar
align 32, db 0
decrementdata:
dec byte [di]
jmp decode
align 32, db 0
putchar:
push di
mov al, byte [di]
echochar:
mov ah, 0x0E
xor bx, bx
cmp al, 10 ; newline needs additional carriage return
jne .normal
mov al, 13
int 0x10
mov al, 10
.normal:
int 0x10
pop di
jmp decode
align 32, db 0
incrementdata:
inc byte [di]
jmp decode
align 32, db 0
decrementptr:
dec di
cmp di, 0x8200 ; pointer wraparound check (really, was that necessary?)
jge decode
add di, cellcount
jmp decode
align 32, db 0
jumpback:
pop si
jmp jumpforward
align 32, db 0
incrementptr:
inc di
cmp di, 0x8200+cellcount ; pointer wraparound check
jl decode
sub di, cellcount
jmp decode
align 32, db 0
jumpforward:
cmp byte [di], 0
jz .skip
push si
jmp decode
.skip:
xor bx, bx ; bx contains the count of [ ] imbrication
.loop:
lodsb
cmp al, '['
je .inc
cmp al, ']'
jne .loop
test bx, bx
jz decode
dec bx
jmp .loop
.inc:
inc bx
jmp .loop
; fill sector
times (0x1FE)-($-$$) db 0
; boot signature
db 0x55, 0xAA
; second sector contains the actual brainfuck program
; currently: "Hello world" followed by a stdin->stdout cat loop
db '++++++++[>++++[>++>+++>+++>+<<<<-]>+>+>->>+[<]<-]>>.>---.+++++++..+++.>>.<-.<.+++.------.--------.>>+.>++.,[.,]'
times 0x400-($-$$) db 0
ट्रिक्स का इस्तेमाल किया
ठीक है, मैंने थोड़ा धोखा दिया। चूंकि आपने कहा था "एक बूटलोडर होने के कारण, प्रोग्राम का आकार संकलित कोड में गैर-शून्य बाइट्स में गिना जाता है" , मैंने आठ ब्रेनफॉक ऑपकोड के कार्यान्वयन के बीच "छेद" की अनुमति देकर कोड को छोटा कर दिया। इस तरह, मुझे परीक्षणों के एक बड़े अनुक्रम की आवश्यकता नहीं है, एक जंप टेबल, या कुछ भी: मैं सिर्फ ब्रेनफॉक "ओपोड आईडी" (0 से 8 तक) को 32 से गुणा करता हूं जो ब्रेनफैक निर्देश को निष्पादित करने के लिए गुणा करता है (ध्यान दें) इसका मतलब है कि निर्देशों का कार्यान्वयन 32 से अधिक बाइट्स नहीं ले सकता है)।
इसके अलावा, इस "opcode आईडी" को प्राप्त करने के लिए ब्रेनफक प्रोग्राम वर्ण से प्राप्त किया, मैंने देखा कि बस थोड़ा सा फेरबदल आवश्यक था। वास्तव में, यदि हम केवल बिट्स 0, 1 और 4 के ओपकोड चरित्र पर विचार करते हैं, तो हम 8 अद्वितीय संयोजनों को समाप्त करते हैं:
X XX
00101100 0x2C , Accept one byte of input, storing its value in the byte at the pointer.
00101101 0x2D - Decrement (decrease by one) the byte at the pointer.
00101110 0x2E . Output the value of the byte at the pointer.
00101011 0x2B + Increment (increase by one) the byte at the pointer.
00111100 0x3C < Decrement the pointer (to point to the next cell to the left).
01011101 0x5D ] Jump back after the corresp [ if data at pointer is nonzero.
00111110 0x3E > Increment the pointer (to point to the next cell to the right).
01011011 0x5B [ Jump forward after the corresp ] if data at pointer is zero.
और, मेरे लिए भाग्यशाली है, वास्तव में एक ओपकोड है जिसे लागू करने के लिए 32 से अधिक बाइट्स की आवश्यकता होती है, लेकिन यह आखिरी है (आगे कूदो [)। के बाद और अधिक कमरा है, सब कुछ ठीक है।
अन्य चाल: मुझे नहीं पता कि एक विशिष्ट ब्रेनफैक दुभाषिया कैसे काम करता है, लेकिन, चीजों को बहुत छोटा करने के लिए, मैंने वास्तव ]में "इसी के बाद वापस कूदें [यदि सूचक पर डेटा नॉनजेरो है " के रूप में लागू नहीं किया । इसके बजाय, मैं हमेशा संबंधित पर वापस जाता हूं [, और, यहां से, विशिष्ट [कार्यान्वयन को फिर से लागू करता हूं (जो तब, अंततः, ]यदि आवश्यक हो तो फिर से आगे बढ़ता है )। इसके लिए, हर बार [जब मैं एक एनकाउंटर करता हूं, तो मैं आंतरिक निर्देशों को निष्पादित करने से पहले स्टैक पर वर्तमान "ब्रेनफक इंस्ट्रक्शन पॉइंटर" डालता हूं, और जब मैं एक मुठभेड़ करता हूं], मैं निर्देश सूचक वापस पॉप। बहुत सुंदर के रूप में अगर यह एक समारोह के लिए एक कॉल था। इसलिए आप सैद्धांतिक रूप से स्टैक को कई imbricated छोरों को बनाकर ओवरफ्लो कर सकते हैं, लेकिन ब्रेनफक कोड के वर्तमान 512-बाइट्स सीमा के साथ, वैसे भी नहीं।
1. शून्य बाइट्स को शामिल करना जो स्वयं कोड का हिस्सा थे, लेकिन उन नहीं जो कुछ पैडिंग का हिस्सा थे
Input must be redमुझे पूरा यकीन है कि अधिकांश बूटलोडर्स मूल रूप से रंग का समर्थन नहीं करते हैं।