80186 मशीन कोड + डॉस, 91 बाइट्स
पाठ संस्करण:
hm j j PPjzjzjgaAAA JSJJ RU Sq ReAA JdJJJ RfiJElK JEiS GtI And she said But that s his
टैब्स वर्जन, टैब (कोड 9) के साथ 9और रिक्त स्थान (कोड 32) द्वारा प्रतिस्थापित किया गया *:
hm9j9j9PPjzjzjgaAAA9JSJJ9RU9Sq9ReAA9JdJJJ9RfiJElK9JEiS*GtI*And*she*said***But*that*s*his***
Hexdump:
68 6D 09 6A 09 6A 09 50 50 6A 7A 6A 7A 6A 67 61
41 41 41 09 4A 53 4A 4A 09 52 55 09 53 71 09 52
65 41 41 09 4A 64 4A 4A 4A 09 52 66 69 4A 45 6C
4B 09 4A 45 69 53 20 47 74 49 20 41 6E 64 20 73
68 65 20 73 61 69 64 20 20 20 42 75 74 20 74 68
61 74 20 73 20 68 69 73 20 20 20
मशीन कोड एक्सटेंशन वाली फ़ाइल में दिखाई देता है .com। जब मैं इसे चलाता हूं, तो यह आवश्यक संदेश प्रिंट करता है और फिर हैंग हो जाता है (रैंडम डेटा निष्पादित करना)।
यह क्या करता है पर उच्च-स्तरीय व्याख्या:
- निरंतर मूल्यों के साथ रजिस्टरों को शुरू करता है
- आवश्यक विशेष प्रतीकों द्वारा संदेश में स्थान बदलता है (
,'.$)
int 21निर्देश उत्पन्न करने के लिए कोड को पैच करता है , जो संदेश को प्रिंट करता है- डॉस को कॉल करता है
विधानसभा कोड (इसके साथ संकलित किया जा सकता है tasm):
my_bp equ 7ah
my_si equ 7ah
my_di equ 67h
my_msg equ 13bh
.model tiny
.code
.startup
.186
org 100h
push 96dh ; ax (ah = 0; al = don't care, but see below)
push 9 ; cx
push 9 ; dx
push ax ; bx = don't care
push ax ; don't care
push my_bp
push my_si
push my_di
popa
inc cx
inc cx
inc cx
or [bp+si+my_msg-my_bp-my_si+12], cx ; ,
dec dx
dec dx
or [bp+si+my_msg-my_bp-my_si+14], dx ; '
or [bp+di+my_msg-my_bp-my_di+23], dx ; '
or [bp+si+my_msg-my_bp-my_si+30], dx ; '
inc cx
inc cx
or [bp+si+my_msg-my_bp-my_si+29], cx ; .
dec dx
dec dx
dec dx
or [bp+si+my_msg-my_bp-my_si+31], dx ; $
; 0x2049 * 0x4b6c = 0x98301cc
; So this sets cx to 1cc (a temporary constant used to patch code)
imul cx, [bp+si+my_msg-my_bp-my_si-2], 4b6ch
; 0x1cc | 0x2049 = 0x21cd (the instruction which calls DOS int 21)
; Here ah = 9 ("print" mode)
or [bp+si+my_msg-my_bp-my_si-2], cx
; At address 101, there is the constant 96d, which was loaded into ax
; 0x96d * 0x7447 = 0x448013b
; So the following sets dx to 13b (adddress of the message)
imul dx, [bp+di+101h-my_bp-my_di], 7447h
int21:
dw 2049h
db 'And she said But that s his '
end
यह popaसभी रजिस्टरों को पॉप करने के लिए अनुदेश का उपयोग करता है , क्योंकि नियमित रूप से popसभी आवश्यक रजिस्टरों को नहीं भरा जा सकता है (जैसे pop diकि एक निषिद्ध opcode है)।
बाइट्स टू पैच के पते 0x100 ... 0x160 की सीमा में हैं। भाग्य से, उन्हें अनुमत मूल्यों के साथ 3 बाइट्स के योग के रूप में दर्शाया जा सकता है:
- में 0x7a
bp
- 0x7a या 0x67 में
siयाdi
- तत्काल मूल्य
संदेश में बाइट्स का ORपैच 0x20 (स्पेस कैरेक्टर) और एक छोटे से स्थिरांक (4, 7, 12 या 14) पर लॉजिकल काम करता है । छोटा स्थिरांक 9 cxऔर dx(टैब वर्ण) को इनिशियलाइज़ करके और आवश्यकतानुसार INCया प्राप्त किया DECजाता है।
कोड का पैचिंग IMULनिर्देश का उपयोग करता है । मुझे जानवर-बल खोज का उपयोग करने के लिए 16-बिट स्थिरांक की आवश्यकता थी।
अंत में, संदेश का पता (0x13b) गुणन द्वारा प्राप्त किया जाता है। अंतरिक्ष को बचाने के लिए, मैंने निर्देशकों में से एक निर्देश से एक लिया, जिसमें एक तत्काल मूल्य शामिल है 0x96d। यहां 9भाग एक डॉस प्रिंट फ़ंक्शन चुनता है, और यह 6dहिस्सा एक मुफ्त पैरामीटर है। यह पता चला है कि 6dएकमात्र संभावना है जो गुणा के बाद 0x13b दे सकती है।
कोड भाग की गड़बड़ी:
06BA:0100 686D09 PUSH 096D
06BA:0103 6A09 PUSH +09
06BA:0105 6A09 PUSH +09
06BA:0107 50 PUSH AX
06BA:0108 50 PUSH AX
06BA:0109 6A7A PUSH +7A
06BA:010B 6A7A PUSH +7A
06BA:010D 6A67 PUSH +67
06BA:010F 61 POPA
06BA:0110 41 INC CX
06BA:0111 41 INC CX
06BA:0112 41 INC CX
06BA:0113 094A53 OR [BP+SI+53],CX
06BA:0116 4A DEC DX
06BA:0117 4A DEC DX
06BA:0118 095255 OR [BP+SI+55],DX
06BA:011B 095371 OR [BP+DI+71],DX
06BA:011E 095265 OR [BP+SI+65],DX
06BA:0121 41 INC CX
06BA:0122 41 INC CX
06BA:0123 094A64 OR [BP+SI+64],CX
06BA:0126 4A DEC DX
06BA:0127 4A DEC DX
06BA:0128 4A DEC DX
06BA:0129 095266 OR [BP+SI+66],DX
06BA:012C 694A456C4B IMUL CX,[BP+SI+45],4B6C
06BA:0131 094A45 OR [BP+SI+45],CX
06BA:0134 6953204774 IMUL DX,[BP+DI+20],7447
06BA:0139 CD21 INT 21 (after the code patches itself)
मजेदार तथ्य: आम तौर पर, मैं offset messageहार्ड-कोडेड के बजाय उपयोग करूंगा 13bh, लेकिन इस मामले में, क्योंकि उसके पते को पार्स करने के समय अज्ञात है, tasm 16-बिट तत्काल ऑफसेट उत्पन्न करता है, 1 कोड बाइट को बर्बाद कर रहा है:
06BA:0131 098A4600 OR [BP+SI+0046],CX
