आईबीएम पीसी डॉस, 8088 विधानसभा, 54 35 बाइट्स
अंतर विधि का उपयोग करके -19 बाइट्स
ac2c 41d0 d8d7 7206 51b1 04d2 e859 240f 2c03 02e0 e2ea 3534 4527 4125 1303 1462 4523 13
unassembled:
; compare dashes and dots in a morse code string
; input:
; I: pointer to input string (default SI)
; IL: length of input string (default CX)
; TBL: pointer to data table (default BX)
; output:
; Sign/OF flags: Dot-heavy: SF == OF (JGE), Dash-heavy: SF != OF (JL)
MORSE_DD MACRO I, IL, TBL
LOCAL LOOP_LETTER, ODD
IFDIFI <I>,<SI> ; skip if S is already SI
MOV SI, I ; load string into SI
ENDIF
IFDIFI <IL>,<CX> ; skip if IL is already CX
MOV CX, IL ; set up loop counter
ENDIF
IFDIFI <TBL>,<BX> ; skip if TBL is already BX
MOV BX, OFFSET TBL ; load letter table into BX
ENDIF
LOOP_LETTER:
LODSB ; load next char from DS:SI into AL, advance SI
;AND AL, 0DFH ; uppercase the input letter (+2 bytes)
SUB AL, 'A' ; convert letter to zero-based index
RCR AL, 1 ; divide index by 2, set CF if odd index
XLAT ; lookup letter in table
JC ODD ; if odd index use low nibble; if even use high nibble
PUSH CX ; save loop counter (since SHR can only take CL on 8088)
MOV CL, 4 ; set up right shift for 4 bits
SHR AL, CL ; shift right
POP CX ; restore loop counter
ODD:
AND AL, 0FH ; mask low nibble
SUB AL, 3 ; unbias dash/dot difference +3 positive
ADD AH, AL ; add letter difference to sum (set result flags)
LOOP LOOP_LETTER
ENDM
TBL DB 035H, 034H, 045H, 027H, 041H, 025H, 013H, 003H, 014H, 062H, 045H, 023H, 013H
व्याख्या
केवल 8088 संगत निर्देशों का उपयोग करते हुए MACRO (मूल रूप से एक फ़ंक्शन) के रूप में Intel / MASM सिंटैक्स में लागू किया गया है। अपरकेस स्ट्रिंग के रूप में इनपुट (या मिश्रित मामले की अनुमति देने के लिए +2 बाइट्स), आउटपुट ट्रू / फल्सी परिणाम SF == OF(उपयोग JGया JLपरीक्षण करने के लिए) है।
अक्षर अंतर तालिका मान बाइनरी निबल्स के रूप में संग्रहीत होते हैं, इसलिए केवल 13 बाइट्स लेती है।
मूल (54 बाइट्स):
; compare dashes and dots in a Morse code string
; input:
; I: pointer to input string (default SI)
; IL: length of input string (default CX)
; TBL: pointer to data table
; output:
; Carry Flag: CF=1 (CY) if dot-heavy, CF=0 (NC) if dash-heavy
MORSE_DD MACRO I, IL, TBL
LOCAL LOOP_LETTER
IFDIFI <I>,<SI> ; skip if S is already SI
MOV SI, I ; load string into SI
ENDIF
IFDIFI <IL>,<CX> ; skip if IL is already CX
MOV CX, IL ; set up loop counter
ENDIF
MOV BX, OFFSET TBL ; load score table into BX
XOR DX, DX ; clear DX to hold total score
LOOP_LETTER:
LODSB ; load next char from DS:SI into AL, advance SI
;AND AL, 0DFH ; uppercase the input letter (+2 bytes)
SUB AL, 'A' ; convert letter to zero-based index
XLAT ; lookup letter in table
MOV AH, AL ; examine dot nibble
AND AH, 0FH ; mask off dash nibble
ADD DH, AH ; add letter dot count to total
PUSH CX ; save loop counter (since SHR can only take CL)
MOV CL, 4 ; set up right shift for 4 bits
SHR AL, CL ; shift right
POP CX ; restore loop counter
ADD DL, AL ; add letter dash count to total
LOOP LOOP_LETTER
CMP DL, DH ; if dot-heavy CF=1, if dash-heavy CF=0
ENDM
; data table A-Z: MSN = count of dash, LSN = count of dot
TBL DB 011H, 013H, 022H, 012H, 001H, 013H, 021H, 004H, 002H
DB 031H, 021H, 013H, 020H, 011H, 030H, 022H, 031H, 012H
DB 003H, 010H, 012H, 013H, 021H, 022H, 031H, 022H
व्याख्या
केवल 8088 संगत निर्देशों का उपयोग करते हुए MACRO (मूल रूप से एक फ़ंक्शन) के रूप में Intel / MASM सिंटैक्स में लागू किया गया है। स्ट्रिंग के रूप में इनपुट, कैरी फ्लैग में आउटपुट ट्रू / फल्सी परिणाम। स्कोर तालिका में प्रति अक्षर डैश और डॉट्स की संख्या समाहित है।
इनपुट ऊपरी मामला है। लोअर या मिक्स्ड केस लेने के लिए 2 बाइट्स जोड़ें।
उदाहरण परीक्षण कार्यक्रम (आईबीएम पीसी डॉस स्टैंडअलोन COM निष्पादन योग्य के रूप में)
SHR SI, 1 ; point SI to DOS PSP
LODSW ; load arg length into AL, advance SI to 82H
MOV CL, AL ; set up loop counter in CH
DEC CX ; remove leading space from letter count
MORSE_DD SI, CX, TBL ; execute above function, result is in CF
MOV DX, OFFSET F ; default output to "Falsy" string
JA DISP_OUT ; if CF=0, result is falsy, skip to output
MOV DX, OFFSET T ; otherwise CF=1, set output to "Truthy" string
DISP_OUT:
MOV AH, 09H ; DOS API display string function
INT 21H
RET
T DB "Truthy$"
F DB "Falsy$"
उदाहरण आउटपुट:
डाउनलोड परीक्षा कार्यक्रम DD.COM
या इसे ऑनलाइन आज़माएं!
मुझे एक ऑनलाइन TIO के बारे में पता नहीं है जो DOS एक्ज़ीक्यूटेबल से सीधे लिंक के लिए है, हालाँकि आप इसे केवल कुछ चरणों के साथ उपयोग कर सकते हैं:
- एक डीडी फ़ाइल के रूप में DD.COM डाउनलोड करें
- Https://virtualconsoles.com/online-emulators/DOS/ पर जाएं
- आपके द्वारा डाउनलोड किया गया ज़िप फ़ाइल अपलोड करें, प्रारंभ पर क्लिक करें
- टाइप करें
DD Helloया DD codeअपने दिल की सामग्री के लिए
