x86 32-बिट मशीन कोड फ़ंक्शन, 21 बाइट्स
x86-64 मशीन कोड फ़ंक्शन, 22 बाइट्स
32-बिट मोड में 1 बी सेविंग के लिए विभाजक = भराव -1, जैसे fill=0और का उपयोग करने की आवश्यकता होती है sep=/। 22-बाइट संस्करण विभाजक और भराव का एक मनमाना विकल्प का उपयोग कर सकता है।
यह इनपुट-विभाजक = \n(0xa), आउटपुट-भराव = 0, आउटपुट-विभाजक = /= भराव -1 के साथ 21-बाइट संस्करण है । इन स्थिरांक को आसानी से बदला जा सकता है।
; see the source for more comments
; RDI points to the output buffer, RSI points to the src string
; EDX holds the base
; This is the 32-bit version.
; The 64-bit version is the same, but the DEC is one byte longer (or we can just mov al,output_separator)
08048080 <str_exp>:
8048080: 6a 01 push 0x1
8048082: 59 pop ecx ; ecx = 1 = base**0
8048083: ac lods al,BYTE PTR ds:[esi] ; skip the first char so we don't do too many multiplies
; read an input row and accumulate base**n as we go.
08048084 <str_exp.read_bar>:
8048084: 0f af ca imul ecx,edx ; accumulate the exponential
8048087: ac lods al,BYTE PTR ds:[esi]
8048088: 3c 0a cmp al,0xa ; input_separator = newline
804808a: 77 f8 ja 8048084 <str_exp.read_bar>
; AL = separator or terminator
; flags = below (CF=1) or equal (ZF=1). Equal also implies CF=0 in this case.
; store the output row
804808c: b0 30 mov al,0x30 ; output_filler
804808e: f3 aa rep stos BYTE PTR es:[edi],al ; ecx bytes of filler
8048090: 48 dec eax ; mov al,output_separator
8048091: aa stos BYTE PTR es:[edi],al ;append delim
; CF still set from the inner loop, even after DEC clobbers the other flags
8048092: 73 ec jnc 8048080 <str_exp> ; new row if this is a separator, not terminator
8048094: c3 ret
08048095 <end_of_function>
; 0x95 - 0x80 = 0x15 = 21 bytes
2-बाइट डीईसी या ए का उपयोग करके 64-बिट संस्करण 1 बाइट लंबा है mov al, output_separator। उसके अलावा, मशीन-कोड दोनों संस्करणों के लिए ही है, लेकिन कुछ रजिस्टर नाम परिवर्तन (जैसे rcxके बजाय ecxमें pop)।
परीक्षण कार्यक्रम चलाने से नमूना आउटपुट (आधार 3):
$ ./string-exponential $'.\n..\n...\n....' $(seq 3);echo
000/000000000/000000000000000000000000000/000000000000000000000000000000000000000000000000000000000000000000000000000000000/
एल्गोरिथम :
इनपुट पर लूप करें, exp *= baseहर फिलर चार के लिए कर रहे हैं। सीमांकक और समाप्ति शून्य बाइट पर, expभराव के बाइट्स और फिर आउटपुट स्ट्रिंग के लिए एक विभाजक संलग्न करें और इसे रीसेट करें exp=1। यह बहुत सुविधाजनक है कि इनपुट को गारंटी दी जाती है कि वह एक नई रेखा और एक टर्मिनेटर दोनों के साथ समाप्त न हो।
इनपुट पर, विभाजक (अहस्ताक्षरित तुलना) के ऊपर किसी भी बाइट मान को भराव के रूप में माना जाता है, और विभाजक के नीचे किसी भी बाइट मूल्य को एंड-ऑफ-स्ट्रिंग मार्कर के रूप में माना जाता है। (शून्य-बाइट के लिए स्पष्ट रूप से जाँच करना test al,alआंतरिक लूप द्वारा सेट किए गए झंडे पर एक अतिरिक्त बनाम शाखाकरण होगा )।
नियम केवल एक अनुगामी विभाजक को अनुमति देता है जब वह अनुगामी न्यूलाइन होता है। मेरा कार्यान्वयन हमेशा विभाजक को जोड़ता है। 32-बिट मोड में 1 बी बचत प्राप्त करने के लिए, उस नियम के लिए विभाजक = 0xa ( '\n'ASCII LF = लाइनफीड), भराव = 0xb ( '\v'ASCII VT = ऊर्ध्वाधर टैब) की आवश्यकता होती है। यह बहुत मानव-अनुकूल नहीं है, लेकिन कानून के पत्र को संतुष्ट करता है। (आप
tr $'\v' xयह सत्यापित करने के लिए आउटपुट या हेक्सडंप या आउटपुट कर सकते हैं या निरंतर बदल सकते हैं कि आउटपुट सेपरेटर और भरण मुद्रण योग्य हैं। मैंने यह भी देखा कि नियमों की आवश्यकता है कि यह उसी फिल / सेप के साथ इनपुट को स्वीकार कर सकता है जो आउटपुट के लिए उपयोग करता है। , लेकिन मुझे उस नियम को तोड़ने से कुछ हासिल नहीं होता।)
NASM / YASM स्रोत। 32 या 64-बिट कोड के रूप में बनाएँ, %ifपरीक्षण कार्यक्रम के साथ शामिल सामान का उपयोग कर या बस आरएक्सएक्स को एक्सएक्सएक्स में बदलें।
input_separator equ 0xa ; `\n` in NASM syntax, but YASM doesn't do C-style escapes
output_filler equ '0' ; For strict rules-compliance, needs to be input_separator+1
output_separator equ output_filler-1 ; saves 1B in 32-bit vs. an arbitrary choice
;; Using output_filler+1 is also possible, but isn't compatible with using the same filler and separator for input and output.
global str_exp
str_exp: ; void str_exp(char *out /*rdi*/, const char *src /*rsi*/,
; unsigned base /*edx*/);
.new_row:
push 1
pop rcx ; ecx=1 = base**0
lodsb ; Skip the first char, since we multiply for the separator
.read_bar:
imul ecx, edx ; accumulate the exponential
lodsb
cmp al, input_separator
ja .read_bar ; anything > separator is treated as filler
; AL = separator or terminator
; flags = below (CF=1) or equal (ZF=1). Equal also implies CF=0, since x-x doesn't produce carry.
mov al, output_filler
rep stosb ; append ecx bytes of filler to the output string
%if output_separator == output_filler-1
dec eax ; saves 1B in the 32-bit version. Use dec even in 64-bit for easier testing
%else
mov al, output_separator
%endif
stosb ; append the delimiter
; CF is still set from the .read_bar loop, even if DEC clobbered the other flags
; JNC/JNB here is equivalent to JE on the original flags, because we can only be here if the char was below-or-equal the separator
jnc .new_row ; separator means more rows, else it's a terminator
; (f+s)+f+ full-match guarantees that the input doesn't end with separator + terminator
ret
फ़ंक्शन x86-64 SystemV ABI का अनुसरण करता है, हस्ताक्षर के साथ
void str_exp(char *out /*rdi*/, const char *src /*rsi*/, unsigned base /*edx*/);
यह केवल आउटपुट स्ट्रिंग की लंबाई के कॉलर को सूचित करता है कि इसमें एक-एक-पिछले-सूचक को छोड़ कर rdi, इसलिए आप इसे गैर में वापसी मान मान सकते हैं -स्टैंडिंग कॉलिंग कन्वेंशन।
xchg eax,ediबाज या रैक्स में अंत-सूचक को वापस करने के लिए 1 या 2 बाइट्स ( ) का खर्च आएगा। (यदि x32 ABI का उपयोग किया जाता है, तो पॉइंटर्स केवल 32 बिट्स होने की गारंटी दी जाती है, अन्यथा हमें xchg rax,rdiकॉल करने की स्थिति में उपयोग करना पड़ता है क्योंकि कॉलर कम 32 बिट्स के बाहर एक बफर को पॉइंटर पास करता है।) मैंने इसे संस्करण में शामिल नहीं किया है। पोस्टिंग क्योंकि वर्कअराउंड हैं, जिससे कॉलर बिना मूल्य प्राप्त किए उपयोग rdiकर सकता है, इसलिए आप इसे C से बिना किसी रैपर के कॉल कर सकते हैं।
हम आउटपुट स्ट्रिंग या कुछ भी शून्य-समाप्त नहीं करते हैं, इसलिए यह केवल न्यूलाइन-टर्मिनेटेड है। इसे ठीक करने में 2 बाइट्स लगेंगे: xchg eax,ecx / stosb (rcx इससे शून्य है rep stosb)
आउटपुट-स्ट्रिंग लंबाई का पता लगाने के तरीके हैं:
- वापसी पर स्ट्रिंग के एक-अतीत-अंत तक आरडी अंक (इसलिए कॉल करने वाला लेन = अंत-प्रारंभ कर सकता है)
- फोन करने वाले को पता चल सकता है कि इनपुट में कितनी पंक्तियाँ थीं और नई सूचियाँ गिनना
- कॉलर एक बड़े शून्य बफर और
strlen()उसके बाद का उपयोग कर सकता है ।
वे सुंदर या कुशल नहीं हैं (एक asm कॉलर से RDI वापसी मान का उपयोग करने के लिए छोड़कर), लेकिन अगर आप चाहते हैं कि तब सी से पीए गोल्फ फ़ंक्शन को कॉल न करें: P
आकार / सीमाएँ
अधिकतम आउटपुट स्ट्रिंग आकार केवल वर्चुअल मेमोरी एड्रेस-स्पेस लिमिटेशन द्वारा सीमित है। (मुख्य रूप से वर्तमान x86-64 हार्डवेयर केवल आभासी पते में 48 महत्वपूर्ण बिट्स का समर्थन करता है, आधे में विभाजित होता है क्योंकि वे शून्य-विस्तार के बजाय साइन-एक्सटेंशन करते हैं। लिंक किए गए उत्तर में आरेख देखें ।)
प्रत्येक पंक्ति में अधिकतम 2 ** 32 - 1 भराव बाइट्स हो सकते हैं, क्योंकि मैं 32-बिट रजिस्टर में घातांक जमा करता हूं।
फ़ंक्शन 0 से 2 ** 32 तक के लिए सही ढंग से काम करता है - 1. (आधार के लिए सही 0 0 ^ x = 0 है, यानी बिना भराव बाइट्स के साथ सिर्फ खाली लाइनें। आधार 1 के लिए सही 1 ^ x = 1 है, इसलिए हमेशा प्रति पंक्ति 1 भराव।)
यह इंटेल इवीब्रिज पर भी धधकते हुए तेज है और बाद में, विशेष रूप से बड़ी पंक्तियों के लिए स्मृति को संरेखित करने के लिए लिखा जा रहा है। ERMSB सुविधा के साथ सीपीयू पर संरेखित बिंदुओं के साथ बड़े काउंट rep stosbके memset()लिए एक इष्टतम कार्यान्वयन है । उदा। 180 ** 4 0.97GB है, और मेरे i7-6700k स्काइलेक (~ 256k सॉफ्ट पेज-फॉल्ट्स) पर /27 / null लिखने के लिए 0.27 सेकंड लगते हैं। (लिनक्स पर / dev / null के लिए डिवाइस-ड्राइवर डेटा को कहीं भी कॉपी नहीं करता है, यह बस वापस आ जाता है। इसलिए सभी समय rep stosbउस सॉफ्ट पेज-दोष में होता है जो पहली बार मेमोरी को छूने पर ट्रिगर होता है। यह पहली बार है। दुर्भाग्य से BSS में सरणी के लिए पारदर्शी विशालताओं का उपयोग नहीं किया गया। संभवत: एक madvise()सिस्टम कॉल इसे गति देगा।)
परीक्षण कार्यक्रम :
स्थैतिक बाइनरी बनाएँ और ./string-exponential $'#\n##\n###' $(seq 2)आधार 2 के लिए चलाएं। ए को लागू करने से बचने के लिए atoi, यह उपयोग करता है base = argc-2। (कमांड-लाइन की लंबाई सीमाएं हास्यास्पद रूप से बड़े ठिकानों के परीक्षण को रोकती हैं।)
यह आवरण 1 जीबी तक आउटपुट स्ट्रिंग्स के लिए काम करता है। (यह केवल विशाल स्ट्रिंग्स के लिए एक सिंगल राइट () सिस्टम कॉल करता है, लेकिन लिनक्स पाइप को लिखने के लिए भी इसका समर्थन करता है)। वर्णों की गिनती के लिए, या तो पाइप को लिखने के लिए arg को देखने के लिए wc -cउपयोग strace ./foo ... > /dev/nullकरें।
यह आरडीआई रिटर्न-वैल्यू का फायदा उठाता है ताकि स्ट्रिंग लंबाई की गणना एक आर्ग के रूप में की जा सके write()।
;;; Test program that calls it
;;; Assembles correctly for either x86-64 or i386, using the following %if stuff.
;;; This block of macro-stuff also lets us build the function itself as 32 or 64-bit with no source changes.
%ifidn __OUTPUT_FORMAT__, elf64
%define CPUMODE 64
%define STACKWIDTH 8 ; push / pop 8 bytes
%define PTRWIDTH 8
%elifidn __OUTPUT_FORMAT__, elfx32
%define CPUMODE 64
%define STACKWIDTH 8 ; push / pop 8 bytes
%define PTRWIDTH 4
%else
%define CPUMODE 32
%define STACKWIDTH 4 ; push / pop 4 bytes
%define PTRWIDTH 4
%define rcx ecx ; Use the 32-bit names everywhere, even in addressing modes and push/pop, for 32-bit code
%define rsi esi
%define rdi edi
%define rsp esp
%endif
global _start
_start:
mov rsi, [rsp+PTRWIDTH + PTRWIDTH*1] ; rsi = argv[1]
mov edx, [rsp] ; base = argc
sub edx, 2 ; base = argc-2 (so it's possible to test base=0 and base=1, and so ./foo $'xxx\nxx\nx' $(seq 2) has the actual base in the arg to seq)
mov edi, outbuf ; output buffer. static data is in the low 2G of address space, so 32-bit mov is fine. This part isn't golfed, though
call str_exp ; str_exp(outbuf, argv[1], argc-2)
; leaves RDI pointing to one-past-the-end of the string
mov esi, outbuf
mov edx, edi
sub edx, esi ; length = end - start
%if CPUMODE == 64 ; use the x86-64 ABI
mov edi, 1 ; fd=1 (stdout)
mov eax, 1 ; SYS_write (Linux x86-64 ABI, from /usr/include/asm/unistd_64.h)
syscall ; write(1, outbuf, length);
xor edi,edi
mov eax,231 ; exit_group(0)
syscall
%else ; Use the i386 32-bit ABI (with legacy int 0x80 instead of sysenter for convenience)
mov ebx, 1
mov eax, 4 ; SYS_write (Linux i386 ABI, from /usr/include/asm/unistd_32.h)
mov ecx, esi ; outbuf
; 3rd arg goes in edx for both ABIs, conveniently enough
int 0x80 ; write(1, outbuf, length)
xor ebx,ebx
mov eax, 1
int 0x80 ; 32-bit ABI _exit(0)
%endif
section .bss
align 2*1024*1024 ; hugepage alignment (32-bit uses 4M hugepages, but whatever)
outbuf: resb 1024*1024*1024 * 1
; 2GB of code+data is the limit for the default 64-bit code model.
; But with -m32, a 2GB bss doesn't get mapped, so we segfault. 1GB is plenty anyway.
यह एक मजेदार चुनौती थी जिसने खुद को बहुत अच्छी तरह से asm, विशेष रूप से x86 स्ट्रिंग ऑप्स के लिए उधार दिया । नियमों को अच्छी तरह से एक नई रेखा और फिर इनपुट स्ट्रिंग के अंत में एक टर्मिनेटर को संभालने से बचने के लिए डिज़ाइन किया गया है।
दोहराया गुणा के साथ एक घातांक बार-बार जोड़ के साथ गुणा करने की तरह है, और मुझे वैसे भी प्रत्येक इनपुट पंक्ति में वर्णों को गिनने के लिए लूप की आवश्यकता थी।
मैंने वन-ऑपरेंड mulया imulलंबे समय के बजाय imul r,rइसका उपयोग करने पर विचार किया , लेकिन EAX के इसके निहित उपयोग ने LODSB के साथ संघर्ष किया।
मैंने लोड और तुलना के बजाय SCASB की भी कोशिश की , लेकिन मुझे xchg esi,ediआंतरिक लूप से पहले और बाद की आवश्यकता थी , क्योंकि SCASB और STOSB दोनों ईडीआई का उपयोग करते हैं। (तो 64-बिट संस्करण 64-बिट पॉइंटर्स को छोटा करने से बचने के लिए x32 ABI का उपयोग करना है)।
STOSB से बचना कोई विकल्प नहीं है; कहीं और कुछ भी छोटा नहीं है। और SCASB का उपयोग करने का आधा लाभ यह है कि आंतरिक लूप छोड़ने के बाद AL = भराव है, इसलिए हमें REP STBB के लिए किसी भी सेटअप की आवश्यकता नहीं है।
SCASB दूसरी दिशा में तुलना करता है कि मैं क्या कर रहा था, इसलिए मुझे तुलनाओं को उलटने की जरूरत थी।
Xchg और scasb के साथ मेरा सबसे अच्छा प्रयास। काम करता है, लेकिन कम नहीं है। ( 32-बिट कोड, विभाजक में भराव को बदलने के लिए inc/ decचाल का उपयोग करके )।
; SCASB version, 24 bytes. Also experimenting with a different loop structure for the inner loop, but all these ideas are break-even at best
; Using separator = filler+1 instead of filler-1 was necessary to distinguish separator from terminator from just CF.
input_filler equ '.' ; bytes below this -> terminator. Bytes above this -> separator
output_filler equ input_filler ; implicit
output_separator equ input_filler+1 ; ('/') implicit
8048080: 89 d1 mov ecx,edx ; ecx=base**1
8048082: b0 2e mov al,0x2e ; input_filler= .
8048084: 87 fe xchg esi,edi
8048086: ae scas al,BYTE PTR es:[edi]
08048087 <str_exp.read_bar>:
8048087: ae scas al,BYTE PTR es:[edi]
8048088: 75 05 jne 804808f <str_exp.bar_end>
804808a: 0f af ca imul ecx,edx ; exit the loop before multiplying for non-filler
804808d: eb f8 jmp 8048087 <str_exp.read_bar> ; The other loop structure (ending with the conditional) would work with SCASB, too. Just showing this for variety.
0804808f <str_exp.bar_end>:
; flags = below if CF=1 (filler<separator), above if CF=0 (filler<terminator)
; (CF=0 is the AE condition, but we can't be here on equal)
; So CF is enough info to distinguish separator from terminator if we clobber ZF with INC
; AL = input_filler = output_filler
804808f: 87 fe xchg esi,edi
8048091: f3 aa rep stos BYTE PTR es:[edi],al
8048093: 40 inc eax ; output_separator
8048094: aa stos BYTE PTR es:[edi],al
8048095: 72 e9 jc 8048080 <str_exp> ; CF is still set from the inner loop
8048097: c3 ret
के इनपुट के लिए ../.../., उत्पादन करता है ..../......../../। मैं विभाजक = newline के साथ संस्करण का एक हेक्सडंप दिखाने के लिए परेशान करने वाला नहीं हूं।
"" <> "#"~Table~#3 बाइट्स से कम है"#"~StringRepeat~#, शायद गोल्फ के रूप में भी आगे।