x86 32-बिट मशीन-कोड फ़ंक्शन, 42 41 बाइट्स
वर्तमान में सबसे छोटा गैर-गोल्फिंग-भाषा उत्तर, 1B @ स्ट्रीटस्टर q / kdb + से छोटा है ।
सत्य के लिए 0 और झूठे के लिए गैर-शून्य: 41 40 बाइट्स। (सामान्य तौर पर, 32-बिट के लिए 1 बाइट, 64-बिट के लिए 2 बाइट्स बचाता है)।
अंतर्निहित लंबाई के तार के साथ (सी-शैली 0-समाप्त): 45 44 बाइट्स
x86-64 मशीन-कोड (32-बिट पॉइंटर्स के साथ, जैसे x32 ABI): 44 43 बाइट्स ।
x86-64 अंतर्निहित लंबाई के तार के साथ, अभी भी 46 बाइट्स (शिफ्ट / मास्क बिटमैप रणनीति अभी भी ब्रेक है)।
यह C सिग्नेचर वाला एक फंक्शन है _Bool dennis_like(size_t ecx, const char *esi)। कॉलिंग सम्मेलन थोड़ा गैर-मानक है, एमएस वेक्टरकॉल / फास्टकॉल के करीब है, लेकिन विभिन्न आर्ग रजिस्टरों के साथ: ईएसआई में स्ट्रिंग और ईसीएक्स में लंबाई है। यह केवल अपने arg-regs और EDX को देखता है। AL, उच्च बाइट्स कचरा रखने के साथ वापसी मूल्य रखता है (जैसा कि SysV x86 और x32 ABIs द्वारा अनुमत है। आईडीके एमएस के एबीआई बूल या संकीर्ण पूर्णांक वापस करते समय उच्च कचरा के बारे में कहते हैं।)
एल्गोरिथ्म की व्याख्या :
इनपुट स्ट्रिंग पर लूप करें, स्टैक पर बूलियन एरे में फ़िल्टरिंग और वर्गीकृत करें: प्रत्येक बाइट के लिए, जांचें कि क्या यह एक अल्फाबेटिक कैरेक्टर है (यदि नहीं, तो अगले चार पर जारी रखें), और इसे 0-25 (AZ) से पूर्णांक में बदलें । स्वर के एक बिटमैप की जाँच करने के लिए उस 0-25 पूर्णांक का उपयोग करें = 0 / व्यंजन = 1। (बिटमैप को 32-बिट तत्काल के रूप में रजिस्टर में लोड किया जाता है)। बिटमैप परिणाम के अनुसार स्टैक पर 0 या 0xFF दबाएं (वास्तव में 32-बिट तत्व के निचले बाइट में, जिसमें शीर्ष 3 बाइट्स में कचरा हो सकता है)।
पहला लूप 0 या 0xFF का एक सरणी (कचरे के साथ गद्देदार तत्वों में) पैदा करता है। एक दूसरे लूप के साथ सामान्य पैलिंड्रोम की जाँच करें जो तब रुकता है जब पॉइंटर्स बीच में पार हो जाते हैं (या जब वे दोनों एक ही तत्व की ओर इशारा करते हैं यदि विषम संख्या में वर्ण होते हैं)। ऊपर की ओर बढ़ने वाला पॉइंटर स्टैक पॉइंटर है, और हम POP का उपयोग लोड + वृद्धि के लिए करते हैं। इस लूप में तुलना / सेटक के बजाय, हम केवल एक ही / अलग का पता लगाने के लिए XOR का उपयोग कर सकते हैं क्योंकि केवल दो संभावित मान हैं। हम (या के साथ) जमा कर सकते हैं चाहे हमें कोई भी गैर-मिलान तत्व मिले, लेकिन XOR द्वारा स्थापित झंडे पर एक प्रारंभिक-आउट शाखा कम से कम उतनी ही अच्छी है।
ध्यान दें कि दूसरा लूप byteऑपरेंड-आकार का उपयोग करता है , इसलिए यह परवाह नहीं करता कि प्रत्येक लूप तत्व के कम बाइट के बाहर पहला लूप क्या कचरा छोड़ता है।
यह सीएफ़ से एएल को सेट करने के लिए अनिच्छुक salcनिर्देश का उपयोग करता है , उसी तरह से जो sbb al,alकरेगा। यह हर इंटेल सीपीयू (64-बिट मोड को छोड़कर) पर समर्थित है, यहां तक कि नाइट लैंडिंग भी! एग्नर फॉग सभी एएमडी सीपीयू (साथ ही रियान सहित) पर इसके लिए समय की सूची देता है , इसलिए यदि x86 विक्रेता 8086 के बाद से ओपकोड स्पेस के उस बाइट को बांधने पर जोर देते हैं, तो हम इसका लाभ उठा सकते हैं।
दिलचस्प ट्रिक्स:
- संयुक्त इलफ़्फ़ा () और टॉपर () के लिए अहस्ताक्षरित तुलना चाल , और शून्य ईईएक्स भरने के लिए बाइट का विस्तार करता है, के लिए सेटिंग:
- के लिए एक रजिस्टर में तत्काल बिटमैप
bt, के लिए कुछ अच्छा संकलक उत्पादन से प्रेरितswitch ।
- एक लूप में धक्का के साथ ढेर पर एक चर-आकार की सरणी बनाना। (Asm के लिए मानक, लेकिन कुछ नहीं आप अंतर्निहित लंबाई स्ट्रिंग संस्करण के लिए C के साथ कर सकते हैं)। यह हर इनपुट चरित्र के लिए स्टैक स्पेस के 4 बाइट्स का उपयोग करता है, लेकिन कम से कम 1 बाइट बनाम इष्टतम गोल्फिंग के आसपास बचाता है
stosb।
- बूलियन सरणी पर cmp / setne के बजाय XOR बूलियन सीधे सत्य मूल्य प्राप्त करने के लिए। (
cmp/ salcएक विकल्प नहीं है, क्योंकि salcकेवल CF के लिए काम करता है, और 0xFF-0 CF सेट नहीं करता है। sete3 बाइट्स हैं, लेकिन inc2 बाइट्स की शुद्ध लागत के लिए लूप से बचना होगा (64-बिट मोड में 1) )) बनाम लूप में xor और इंक के साथ इसे ठीक करना।
; explicit-length version: input string in ESI, byte count in ECX
08048060 <dennis_like>:
8048060: 55 push ebp
8048061: 89 e5 mov ebp,esp ; a stack frame lets us restore esp with LEAVE (1B)
8048063: ba ee be ef 03 mov edx,0x3efbeee ; consonant bitmap
08048068 <dennis_like.filter_loop>:
8048068: ac lods al,BYTE PTR ds:[esi]
8048069: 24 5f and al,0x5f ; uppercase
804806b: 2c 41 sub al,0x41 ; range-shift to 0..25
804806d: 3c 19 cmp al,0x19 ; reject non-letters
804806f: 77 05 ja 8048076 <dennis_like.non_alpha>
8048071: 0f a3 c2 bt edx,eax # AL = 0..25 = position in alphabet
8048074: d6 SALC ; set AL=0 or 0xFF from carry. Undocumented insn, but widely supported
8048075: 50 push eax
08048076 <dennis_like.non_alpha>:
8048076: e2 f0 loop 8048068 <dennis_like.filter_loop> # ecx = remaining string bytes
; end of first loop
8048078: 89 ee mov esi,ebp ; ebp = one-past-the-top of the bool array
0804807a <dennis_like.palindrome_loop>:
804807a: 58 pop eax ; read from the bottom
804807b: 83 ee 04 sub esi,0x4
804807e: 32 06 xor al,BYTE PTR [esi]
8048080: 75 04 jne 8048086 <dennis_like.non_palindrome>
8048082: 39 e6 cmp esi,esp ; until the pointers meet or cross in the middle
8048084: 77 f4 ja 804807a <dennis_like.palindrome_loop>
08048086 <dennis_like.non_palindrome>:
; jump or fall-through to here with al holding an inverted boolean
8048086: 40 inc eax
8048087: c9 leave
8048088: c3 ret
;; 0x89 - 0x60 = 41 bytes
यह शायद सबसे तेज़ जवाबों में से एक है, क्योंकि कोई भी गोल्फिंग वास्तव में बहुत बुरी तरह से दर्द नहीं करता है, कम से कम कुछ हजार वर्णों के तहत तार के लिए जहां 4x मेमोरी का उपयोग बहुत सारे कैश-मिस नहीं करता है। (यह उन उत्तरों को भी खो सकता है जो सभी वर्णों पर लूप करने से पहले गैर-डेनिस-जैसे तारों के लिए एक प्रारंभिक-आउट लेते हैं।) कई सीपीयू (जैसे स्काईलेक पर 3 उफ़ बनाम 1 ) salcकी तुलना में धीमी है setcc, लेकिन एक बिटमैप की जाँच करें bt/salcअभी भी एक स्ट्रिंग-खोज या रेगेक्स-मैच की तुलना में तेज़ है। और कोई स्टार्टअप ओवरहेड नहीं है, इसलिए यह छोटे तारों के लिए बेहद सस्ता है।
फ्लाई पर एक पास में करने का मतलब होगा अप और डाउन दिशाओं के लिए वर्गीकरण कोड को दोहराना। यह तेज़ लेकिन बड़ा कोड-आकार होगा। (बेशक अगर आप उपवास चाहते हैं, तो आप SSE2 या AVX2 के साथ एक बार में 16 या 32 वर्ण कर सकते हैं, फिर भी तुलनात्मक चाल का उपयोग रेंज-शिफ्टिंग द्वारा हस्ताक्षरित सीमा के निचले भाग में कर सकते हैं)।
इस फ़ंक्शन को cmdline arg के साथ कॉल करने के लिए टेस्ट प्रोग्राम (ia32 या x32 Linux के लिए) , और स्थिति = वापसी मान के साथ बाहर निकलें। int80h.orgstrlen से कार्यान्वयन ।
; build with the same %define macros as the source below (so this uses 32-bit regs in 32-bit mode)
global _start
_start:
;%define PTRSIZE 4 ; true for x32 and 32-bit mode.
mov esi, [rsp+4 + 4*1] ; esi = argv[1]
;mov rsi, [rsp+8 + 8*1] ; rsi = argv[1] ; For regular x86-64 (not x32)
%if IMPLICIT_LENGTH == 0
; strlen(esi)
mov rdi, rsi
mov rcx, -1
xor eax, eax
repne scasb ; rcx = -strlen - 2
not rcx
dec rcx
%endif
mov eax, 0xFFFFAEBB ; make sure the function works with garbage in EAX
call dennis_like
;; use the 32-bit ABI _exit syscall, even in x32 code for simplicity
mov ebx, eax
mov eax, 1
int 0x80 ; _exit( dennis_like(argv[1]) )
;; movzx edi, al ; actually mov edi,eax is fine here, too
;; mov eax,231 ; 64-bit ABI exit_group( same thing )
;; syscall
इस फ़ंक्शन का 64-बिट संस्करण उपयोग कर सकता है sbb eax,eax, जो कि 3 के बजाय केवल 2 बाइट्स है setc al। इसके लिए decया notअंत में एक अतिरिक्त बाइट की भी आवश्यकता होगी (क्योंकि केवल 32-बिट में 1-बाइट इंक / डीईसी आर 32 है)। X32 ABI (लॉन्ग मोड में 32-बिट पॉइंटर्स) का उपयोग करके, हम अभी भी REX उपसर्गों से बच सकते हैं, भले ही हम पॉइंटर्स की प्रतिलिपि बनाएँ और तुलना करें।
setc [rdi]सीधे मेमोरी में लिख सकते हैं, लेकिन स्टैक स्पेस के ईसीएक्स बाइट्स को जमा करने से बचत होती है। (और हमें आउटपुट सरणी के माध्यम से आगे बढ़ने की आवश्यकता है। [rdi+rcx]एड्रेसिंग मोड के लिए एक अतिरिक्त बाइट लेता है, लेकिन वास्तव में हमें एक काउंटर की आवश्यकता होती है जो फ़िल्टर्ड वर्णों के लिए अपडेट नहीं करता है, इसलिए यह इससे भी बदतर होने वाला है।)
यह %ifसशर्त के साथ YASM / NASM स्रोत है । इसे -felf32(32-बिट कोड) या -felfx32(x32 एबीआई के साथ 64-बिट कोड), और अंतर्निहित या स्पष्ट लंबाई के साथ बनाया जा सकता है । मैंने सभी 4 संस्करणों का परीक्षण किया है। NASM / YASM स्रोत से एक स्थिर बाइनरी बनाने के लिए एक स्क्रिप्ट के लिए इस उत्तर को देखें ।
X32 ABI के लिए समर्थन के बिना मशीन पर 64-बिट संस्करण का परीक्षण करने के लिए, आप सूचक को 64-बिट में बदल सकते हैं। (फिर बस गिनती से REX.W = 1 उपसर्गों (0x48 बाइट्स) की संख्या घटाएं। इस मामले में, 4 निर्देशों को 64-बिट regs पर काम करने के लिए REX उपसर्गों की आवश्यकता है)। या बस इसे rspऔर 4 जी पता स्थान के कम इनपुट सूचक के साथ कॉल करें ।
%define IMPLICIT_LENGTH 0
; This source can be built as x32, or as plain old 32-bit mode
; x32 needs to push 64-bit regs, and using them in addressing modes avoids address-size prefixes
; 32-bit code needs to use the 32-bit names everywhere
;%if __BITS__ != 32 ; NASM-only
%ifidn __OUTPUT_FORMAT__, elfx32
%define CPUMODE 64
%define STACKWIDTH 8 ; push / pop 8 bytes
%else
%define CPUMODE 32
%define STACKWIDTH 4 ; push / pop 4 bytes
%define rax eax
%define rcx ecx
%define rsi esi
%define rdi edi
%define rbp ebp
%define rsp esp
%endif
; A regular x86-64 version needs 4 REX prefixes to handle 64-bit pointers
; I haven't cluttered the source with that, but I guess stuff like %define ebp rbp would do the trick.
;; Calling convention similar to SysV x32, or to MS vectorcall, but with different arg regs
;; _Bool dennis_like_implicit(const char *esi)
;; _Bool dennis_like_explicit(size_t ecx, const char *esi)
global dennis_like
dennis_like:
; We want to restore esp later, so make a stack frame for LEAVE
push rbp
mov ebp, esp ; enter 0,0 is 4 bytes. Only saves bytes if we had a fixed-size allocation to do.
; ZYXWVUTSRQPONMLKJIHGFEDCBA
mov edx, 11111011111011111011101110b ; consonant/vowel bitmap for use with bt
;;; assume that len >= 1
%if IMPLICIT_LENGTH
lodsb ; pipelining the loop is 1B shorter than jmp .non_alpha
.filter_loop:
%else
.filter_loop:
lodsb
%endif
and al, 0x7F ^ 0x20 ; force ASCII to uppercase.
sub al, 'A' ; range-shift to 'A' = 0
cmp al, 'Z'-'A' ; if al was less than 'A', it will be a large unsigned number
ja .non_alpha
;; AL = position in alphabet (0-25)
bt edx, eax ; 3B
%if CPUMODE == 32
salc ; 1B only sets AL = 0 or 0xFF. Not available in 64-bit mode
%else
sbb eax, eax ; 2B eax = 0 or -1, according to CF.
%endif
push rax
.non_alpha:
%if IMPLICIT_LENGTH
lodsb
test al,al
jnz .filter_loop
%else
loop .filter_loop
%endif
; al = potentially garbage if the last char was non-alpha
; esp = bottom of bool array
mov esi, ebp ; ebp = one-past-the-top of the bool array
.palindrome_loop:
pop rax
sub esi, STACKWIDTH
xor al, [rsi] ; al = (arr[up] != arr[--down]). 8-bit operand-size so flags are set from the non-garbage
jnz .non_palindrome
cmp esi, esp
ja .palindrome_loop
.non_palindrome: ; we jump here with al=1 if we found a difference, or drop out of the loop with al=0 for no diff
inc eax ;; AL transforms 0 -> 1 or 0xFF -> 0.
leave
ret ; return value in AL. high bytes of EAX are allowed to contain garbage.
मैंने DF के साथ गड़बड़ करने की दिशा में देखा (दिशा ध्वज जो lodsd/ scasdऔर इसी तरह नियंत्रित करता है ), लेकिन यह सिर्फ एक जीत नहीं लगती थी। सामान्य ABI को यह आवश्यक है कि फ़ंक्शन प्रविष्टि और निकास पर DF को मंजूरी दे दी जाए। प्रवेश पर मंजूरी दे दी है, लेकिन इसे बाहर निकलने पर सेट छोड़ दिया जाएगा, धोखा दे रही है, IMO। 3-बाइट से बचने के लिए LODSD / SCASD का उपयोग करना अच्छा होगा sub esi, 4, विशेषकर उस स्थिति में जहां कोई उच्च कचरा नहीं है।
वैकल्पिक बिटमैप रणनीति (x86-64 के लिए अंतर्निहित लंबाई के तार)
यह पता चला है कि यह किसी भी बाइट को नहीं बचाता है, क्योंकि bt r32,r32अभी भी बिट-इंडेक्स में उच्च कचरा के साथ काम करता है। यह सिर्फ दस्तावेज नहीं है जिस तरह से shrहै।
bt / sbbबिट के / CF से बाहर निकलने के बजाय , बिटमैप से हम जो बिट चाहते हैं, उसे अलग करने के लिए एक शिफ्ट / मास्क का उपयोग करें।
%if IMPLICIT_LENGTH && CPUMODE == 64
; incompatible with LOOP for explicit-length, both need ECX. In that case, bt/sbb is best
xchg eax, ecx
mov eax, 11111011111011111011101110b ; not hoisted out of the loop
shr eax, cl
and al, 1
%else
bt edx, eax
sbb eax, eax
%endif
push rax
चूंकि यह AL में अंत में (0 / 0xFF के बजाय) 0/1 का उत्पादन करता है, हम फ़ंक्शन के अंत में रिटर्न वैल्यू के आवश्यक उलटा xor al, 1(2 बी) के बजाय dec eax(x86-64 में भी 2 बी) कर सकते हैं। अभी भी एक उचित bool/_Bool वापसी मूल्य का उत्पादन करते हैं ।
यह EAX के उच्च बाइट्स को शून्य करने की आवश्यकता से बचने के साथ, अंतर्निहित लंबाई के तार के साथ x86-64 के लिए 1 बी को बचाने के लिए उपयोग किया जाता है। (मैं and eax, 0x7F ^ 0x203-बाइट के साथ अपर-केस को बल देने और बाकी ईईएक्स को शून्य करने के लिए उपयोग कर रहा था and r32,imm8। लेकिन अब मैं 2-बाइट का उपयोग तत्काल-एएल एन्कोडिंग के साथ कर रहा हूं जो कि सबसे अधिक 8086 निर्देश हैं, जैसे मैं पहले से ही कर रहा था। ( subऔर cmp) के लिए
यह 32-बिट मोड में bt/ को खो देता salcहै, और स्पष्ट लंबाई के तार को गिनती के लिए ECX की आवश्यकता होती है ताकि यह वहां भी काम न करे।
लेकिन तब मुझे एहसास हुआ कि मैं गलत था: bt edx, eaxअभी भी ईगल में उच्च कचरा के साथ काम करता है। यह जाहिरा तौर पर शिफ्ट की गणना करता है उसी तरह से shr r32, clकरता है (केवल कम 5 बिट्स क्ल को देखते हुए)। यह इससे अलग है bt [mem], reg, जो एड्रेसिंग-मोड / साइज द्वारा संदर्भित मेमोरी के बाहर पहुंच सकता है, इसे बिटस्ट्रिंग के रूप में मानता है। (क्रेजी CISC ...)
इंटेल के इनस सेट रेफरी मैनुअल में मास्किंग का दस्तावेज नहीं है, इसलिए हो सकता है कि यह अबाधित व्यवहार है जिसे इंटेल अभी के लिए संरक्षित कर रहा है। (इस तरह की बात असामान्य नहीं है। bsf dst, srcsrc = 0 के साथ हमेशा dst unmodified निकलता है, भले ही यह उस स्थिति में अपरिभाषित मान रखने वाले dst को छोड़ने के लिए प्रलेखित हो। AMD वास्तव में src = 0 व्यवहार का दस्तावेज है।) Skylake और Core2 में परीक्षण किया गया है। और btसंस्करण AL के बाहर EAX में गैर-शून्य कचरा के साथ काम करता है।
xchg eax,ecxसीएल में गिनती प्राप्त करने के लिए यहां एक साफ सुथरी चाल (1 बाइट) का उपयोग किया जाता है। दुर्भाग्य से, BMI2 shrx eax, edx, eax5 बाइट्स है, बनाम केवल 2 बाइट्स के लिए shr eax, cl। का प्रयोग bextrकी जरूरत है 2-बाइट mov ah,1(बिट्स की संख्या के लिए निकालने के लिए), तो यह फिर से 5 + 2 बाइट्स SHRX + और की तरह है।
स्रोत कोड %ifसशर्त जोड़ने के बाद बहुत गड़बड़ हो गया है । यहां एक्स 32 इम्प्लांट-लेंथ स्ट्रिंग्स (बिटमैप के लिए वैकल्पिक रणनीति का उपयोग करके, इसलिए यह अभी भी 46 बाइट्स है) का डिस्सैप्शन है।
स्पष्ट-लंबाई संस्करण से मुख्य अंतर पहले लूप में है। ध्यान दें कि lodsलूप के शीर्ष पर केवल एक के बजाय, इसके पहले और नीचे में कैसे है।
; 64-bit implicit-length version using the alternate bitmap strategy
00400060 <dennis_like>:
400060: 55 push rbp
400061: 89 e5 mov ebp,esp
400063: ac lods al,BYTE PTR ds:[rsi]
00400064 <dennis_like.filter_loop>:
400064: 24 5f and al,0x5f
400066: 2c 41 sub al,0x41
400068: 3c 19 cmp al,0x19
40006a: 77 0b ja 400077 <dennis_like.non_alpha>
40006c: 91 xchg ecx,eax
40006d: b8 ee be ef 03 mov eax,0x3efbeee ; inside the loop since SHR destroys it
400072: d3 e8 shr eax,cl
400074: 24 01 and al,0x1
400076: 50 push rax
00400077 <dennis_like.non_alpha>:
400077: ac lods al,BYTE PTR ds:[rsi]
400078: 84 c0 test al,al
40007a: 75 e8 jne 400064 <dennis_like.filter_loop>
40007c: 89 ee mov esi,ebp
0040007e <dennis_like.palindrome_loop>:
40007e: 58 pop rax
40007f: 83 ee 08 sub esi,0x8
400082: 32 06 xor al,BYTE PTR [rsi]
400084: 75 04 jne 40008a <dennis_like.non_palindrome>
400086: 39 e6 cmp esi,esp
400088: 77 f4 ja 40007e <dennis_like.palindrome_loop>
0040008a <dennis_like.non_palindrome>:
40008a: ff c8 dec eax ; invert the 0 / non-zero status of AL. xor al,1 works too, and produces a proper bool.
40008c: c9 leave
40008d: c3 ret
0x8e - 0x60 = 0x2e = 46 bytes