मैंने एक छोटा मशाल लोकेटर बनाया, जिसमें बटन-सेल (CR2032) से संचालित ATtiny85 का उपयोग किया गया था। यह इस तरह दिख रहा है:
दूसरा पहलु:
जिसका वर्तमान में वजन 5.9 ग्राम है। बैटरी-धारक का वजन 1.6g है ताकि आप अधिक प्रकाश-भार धारक (शायद इन्सुलेशन के लिए थोड़ा सा प्लास्टिक, और बैटरी को सीधे टांका लगाकर) को बचा सकें। चिप सॉकेट का वजन कम से कम 0.5 ग्राम होता है, जिससे आप प्रोसेसर पिन को टांका लगाकर बचा सकते हैं। तो हम 3.8 जी से नीचे हैं।
ATtiny85 में EEPROM के 512 बाइट्स हैं, जिनका उपयोग आप रीडिंग लॉग करने के लिए कर सकते हैं। अगर आप वजन कम करने की कोशिश कर रहे हैं तो मुझे एक घड़ी के बारे में निश्चित नहीं है, लेकिन अगर आप इसे एक ज्ञात समय पर शुरू करते हैं, तो millis()स्टार्टअप के बाद से मिलिसेकंड खोजने के लिए फ़ंक्शन का उपयोग करके आप समय का उचित अनुमान लगा सकते हैं ।
मैंने कुछ समय पहले एक और बनाया था जो हर दो सेकंड में एक एलईडी फ्लैश करता है:
वह समान है। प्रोसेसर वहाँ है (चिप सॉकेट के नीचे उल्टा) और बैटरी नीचे है। जिसका वजन 6g है। बैटरी कुछ वर्षों तक चली है, और वह प्रत्येक सेकंड में एक एलईडी फ्लैश कर रही है!
एलईडी के बजाय तापमान को पढ़ने के लिए आपके पास एक थर्मिस्टर हो सकता है।
आप इसे हर कुछ घंटों में पढ़ने के लिए प्रोग्राम कर सकते हैं और इसे EEPROM में सहेज सकते हैं। फिर जब निर्देश दिया (उदाहरण के लिए, एक जोड़ी पिन के साथ) यह रीडिंग को दूसरे पिन (सीरियल के माध्यम से) में आउटपुट कर सकता है।
आप SMD (सरफेस माउंटेड) डिवाइसों का उपयोग करके अधिक वजन बचा सकते हैं, और शायद एक छोटे सर्किट बोर्ड का उपयोग करके आप बना सकते हैं।
कोड
मेरे मशाल लोकेटर के लिए कोड नीचे है। ब्याज की तथ्य यह है कि यह ज्यादातर समय सोता है। इसके अलावा यह एडीसी नमूने के दौरान सोता है। हालांकि मेरे मामले में मैं एक LDR (प्रकाश निर्भर अवरोधक) को माप रहा हूं, एक थर्मिस्टर को मापने के लिए कोड समान होगा। आपको पढ़ने को तापमान में बदलने के लिए अंत में कुछ गणनाएँ करने की आवश्यकता है।
// ATtiny85 torch detector
// Author: Nick Gammon
// Date: 25 February 2015
// ATMEL ATTINY 25/45/85 / ARDUINO
// Pin 1 is /RESET
//
// +-\/-+
// Ain0 (D 5) PB5 1| |8 Vcc
// Ain3 (D 3) PB3 2| |7 PB2 (D 2) Ain1
// Ain2 (D 4) PB4 3| |6 PB1 (D 1) pwm1
// GND 4| |5 PB0 (D 0) pwm0
// +----+
/*
Pin 2 (PB3) <-- LDR (GL5539) --> Pin 7 (PB2) <----> 56 k <----> Gnd
Pin 5 (PB0) <---- LED ---> 100 R <-----> Gnd
*/
#include <avr/sleep.h> // Sleep Modes
#include <avr/power.h> // Power management
#include <avr/wdt.h> // Watchdog timer
const byte LED = 0; // pin 5
const byte LDR_ENABLE = 3; // pin 2
const byte LDR_READ = 1; // Ain1 (PB2) pin 7
const int LIGHT_THRESHOLD = 200; // Flash LED when darker than this
// when ADC completed, take an interrupt
EMPTY_INTERRUPT (ADC_vect);
// Take an ADC reading in sleep mode (ADC)
float getReading (byte port)
{
power_adc_enable() ;
ADCSRA = bit (ADEN) | bit (ADIF); // enable ADC, turn off any pending interrupt
// set a2d prescale factor to 128
// 8 MHz / 128 = 62.5 KHz, inside the desired 50-200 KHz range.
ADCSRA |= bit (ADPS0) | bit (ADPS1) | bit (ADPS2);
if (port >= A0)
port -= A0;
#if defined(__AVR_ATtiny85__)
ADMUX = (port & 0x07); // AVcc
#else
ADMUX = bit (REFS0) | (port & 0x07); // AVcc
#endif
noInterrupts ();
set_sleep_mode (SLEEP_MODE_ADC); // sleep during sample
sleep_enable();
// start the conversion
ADCSRA |= bit (ADSC) | bit (ADIE);
interrupts ();
sleep_cpu ();
sleep_disable ();
// reading should be done, but better make sure
// maybe the timer interrupt fired
// ADSC is cleared when the conversion finishes
while (bit_is_set (ADCSRA, ADSC))
{ }
byte low = ADCL;
byte high = ADCH;
ADCSRA = 0; // disable ADC
power_adc_disable();
return (high << 8) | low;
} // end of getReading
// watchdog interrupt
ISR (WDT_vect)
{
wdt_disable(); // disable watchdog
} // end of WDT_vect
#if defined(__AVR_ATtiny85__)
#define watchdogRegister WDTCR
#else
#define watchdogRegister WDTCSR
#endif
void setup ()
{
wdt_reset();
pinMode (LED, OUTPUT);
pinMode (LDR_ENABLE, OUTPUT);
ADCSRA = 0; // turn off ADC
power_all_disable (); // power off ADC, Timer 0 and 1, serial interface
} // end of setup
void loop ()
{
// power up the LDR, take a reading
digitalWrite (LDR_ENABLE, HIGH);
int value = getReading (LDR_READ);
// power off the LDR
digitalWrite (LDR_ENABLE, LOW);
// if it's dark, flash the LED for 2 mS
if (value < LIGHT_THRESHOLD)
{
power_timer0_enable ();
delay (1); // let timer reach a known point
digitalWrite (LED, HIGH);
delay (2);
digitalWrite (LED, LOW);
power_timer0_disable ();
}
goToSleep ();
} // end of loop
void goToSleep ()
{
set_sleep_mode (SLEEP_MODE_PWR_DOWN);
noInterrupts (); // timed sequence coming up
// pat the dog
wdt_reset();
// clear various "reset" flags
MCUSR = 0;
// allow changes, disable reset, clear existing interrupt
watchdogRegister = bit (WDCE) | bit (WDE) | bit (WDIF);
// set interrupt mode and an interval (WDE must be changed from 1 to 0 here)
watchdogRegister = bit (WDIE) | bit (WDP2) | bit (WDP1) | bit (WDP0); // set WDIE, and 2 seconds delay
sleep_enable (); // ready to sleep
interrupts (); // interrupts are required now
sleep_cpu (); // sleep
sleep_disable (); // precaution
} // end of goToSleep
