क्या किसी को संपर्क की परिभाषित राशि के साथ संपर्क सूची बनाने का तरीका पता है? वे डमी प्रविष्टियां हो सकती हैं, लेकिन मुझे केवल> 2000 प्रविष्टियों के साथ एक एड्रेस बुक बनाने की आवश्यकता है। एक ऑटोमेटर स्क्रिप्ट वह है जो मेरे मन में है, लेकिन मुझे यकीन नहीं है कि इस बारे में कैसे जाना है।
अगर यह गलत जगह है तो मैं माफी मांगता हूं। एसयू या एसई पर विचार कर रहा था, लेकिन लगा कि मैं यहां शुरू करूंगा।
जवाबों:
एक Applescript OS X एड्रेस बुक एंट्रीज को बल्क-क्रिएट कर सकती है, जिसे आप अपने iPhone में इम्पोर्ट कर सकते हैं। मैंने आपके लिए एक आधार बनाया है:
-- Change these to your desired data
set firstName to "Test"
set lastName to "User"
set numberOfEntries to "5" as integer
set counter to "1" as integer
tell application "Address Book"
repeat numberOfEntries times
set thePerson to make new person with properties {first name:firstName, last name:lastName & " " & counter}
make new email at end of emails of thePerson with properties {label:"Work", value:"test" & counter & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
set counter to counter + 1
end repeat
save
end tell
AppleScript एडिटर को (अपने Applications/Utilities/फ़ोल्डर में) खोलें और एक नई स्क्रिप्ट में पेस्ट करें। जैसा है, यह आपको 5 गिने हुए संपर्क बना देगा जैसे:
आप अपनी आवश्यकता के अनुसार संख्या में संख्या बदल सकते हैं set numberOfEntries to "5" as integer, और यदि आप चाहें तो डेटा बदल सकते हैं। यदि आपको अन्य क्षेत्रों (जैसे फोन नंबर) की आवश्यकता है, तो पूछें और मैं आपको दिखा सकता हूं कि कैसे।
मैं थोड़ा ओवरबोर्ड गया और एक संस्करण बनाया जो अच्छे नामों के साथ आता है। मैंने 20 सबसे लोकप्रिय पुरुष और महिला नाम, 40 सबसे लोकप्रिय अंतिम नाम, और एक मध्य प्रारंभिक जोड़ा, इसलिए आपको मेरे गणित के बिना डुप्लिकेट (2000 के सेट में 5% से थोड़ा कम) का एक बहुत कम मौका मिलता है नासमझ दिखने गिने संपर्कों।
यह सभी संपर्कों को एक समूह ("टेस्ट ग्रुप") में जोड़ता है ताकि आप सभी डमी को आसानी से उठा सकें यदि आप किसी मौजूदा एड्रेस बुक में जोड़ रहे हैं और बाद में इसे साफ करना चाहते हैं।
संपादित करें: मैंने इसे कितनी वस्तुओं को बनाने के लिए संकेत दिया है, इसलिए कोड को संपादित करना आवश्यक नहीं है।
-- name lists: 20 most popular (US) male and female first names, 40 most popular last names
set firstNameList to {"Mary", "Patricia", "Linda", "Barbara", "Elizabeth", "Jennifer", "Maria", "Susan", "Margaret", "Dorothy", "Lisa", "Nancy", "Karen", "Betty", "Helen", "Sandra", "Donna", "Carol", "Ruth", "Sharon", "James", "John", "Robert", "Michael", "William", "David", "Richard", "Charles", "Joseph", "Thomas", "Christopher", "Daniel", "Paul", "Mark", "Donald", "George", "Kenneth", "Steven", "Edward", "Brian"}
set lastNameList to {"Smith", "Johnson", "Williams", "Jones", "Brown", "Davis", "Miller", "Wilson", "Moore", "Taylor", "Anderson", "Thomas", "Jackson", "White", "Harris", "Martin", "Thompson", "Garcia", "Martinez", "Robinson", "Clark", "Rodriguez", "Lewis", "Lee", "Walker", "Hall", "Allen", "Young", "Hernandez", "King", "Wright", "Lopez", "Hill", "Scott", "Green", "Adams", "Baker", "Gonzalez", "Nelson", "Carter"}
set initialList to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set counter to "1" as integer
-- prompt for how many contacts to create
set dialogText to "Number of contacts to create?"
repeat
display dialog dialogText default answer ""
set numberOfEntries to text returned of result
try
if numberOfEntries = "" then error
set numberOfEntries to numberOfEntries as number
exit repeat
on error
end try
end repeat
-- populate the address book
tell application "Address Book"
set theGroup to make new group with properties {name:"Test Group"}
repeat numberOfEntries times
set firstName to some item of firstNameList
set lastName to some item of lastNameList
set middleInitial to some item of initialList & "."
set thePerson to make new person with properties {first name:firstName, middle name:middleInitial, last name:lastName}
make new email at end of emails of thePerson with properties {label:"Work", value:firstName & middleInitial & lastName & "@example.com"}
make new address at end of addresses of thePerson with properties {label:"Home", city:"Fakeville", street:(counter as string) & " Some St."}
add thePerson to theGroup
set counter to counter + 1
end repeat
save
end tell
यहाँ यह क्या उत्पन्न करता है:
