मैं कमांड लाइन का उपयोग करके ब्लूटूथ टेथरिंग कैसे शुरू कर सकता हूं?

Question

मुझे अपने iPhone का उपयोग करके टेदरिंग शुरू करने का एक त्वरित तरीका चाहिए, उम्मीद है कि बस कीबोर्ड का उपयोग कर। ब्लूटूथ मेनू का उपयोग करते हुए, मैं अपने डिवाइस के लिए सबमेनू में कनेक्ट टू नेटवर्क विकल्प चुन सकता हूं, लेकिन क्या इसे स्वचालित करना संभव है?

अंततः मैं इसे (बहुत ही भयानक) Alfred.app के शॉर्टकट में असाइन करना चाहता हूं, लेकिन कमांड लाइन या AppleScript का उपयोग करने से कुछ भी काम करेगा।

क्या यह संभव है? धन्यवाद!!

Answer 1

ऐसा नहीं लगता है कि ब्लूटूथ के साथ काम करने के लिए एक सीधा AppleScript डिक्शनरी है।

यद्यपि आप GUI स्क्रिप्टिंग का उपयोग कर सकते हैं, जो मूल रूप से मेनू आइटम, आदि का चयन करने के लिए मैक ओएस की पहुंच सुविधा का उपयोग करता है।

GUI AppleScript के साथ कैसे शुरू किया जाए इस पर एक बेहतरीन राइटअप MacOSAutomation.com पर उपलब्ध है ।

जीयूआई स्वचालन मुश्किल हो सकता है यदि आपके पास लगातार बदलती चीजों की सूची है, लेकिन अगर आपके पास आमतौर पर ब्लूटूथ से जुड़ी वस्तुओं की सूची है जो कि ठीक रहती है, तो आपको वही रहना चाहिए।

आप तब अल्फ्रेड के माध्यम से इस AppleScript को कॉल कर सकते हैं।

Answer 2

http://macscripter.net/viewtopic.php?id=38559

उपरोक्त लिंक में एक बहुत अच्छी स्क्रिप्ट है जिसे मैंने अभी थोड़ा अपडेट किया है। ध्यान दें कि यह ब्लूयूटिल [ गिट रेपो ] [ वेबसाइट / बायनेरी ] का उपयोग करता है ।

ब्लूटूथ सक्षम करें:

-- Enable Bluetooth and Connect to iPhone

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn on bluetooth.
if execBlueutil("status") contains "Status: off" then
    execBlueutil("on")

    connectDevice()

    doGrowl()

end if

on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

-- Connect Device
on connectDevice()
    tell application "System Preferences"
        activate
        set AppleScript's text item delimiters to "."
        set current pane to pane "com.apple.preference.network"
        set winNetwork to "Network"
        set btooth to "Bluetooth"

        tell application "System Events" to tell process "System Preferences"
            set theRow to row 1 of table 1 of scroll area 1 of window winNetwork whose value of static text 1 contains btooth
            select theRow --clicks the bluetooth row
            --If Bluetooth is already connected, the button will say Disconnect, so we don't want to turn it off:
            try
                click (button 1 of group 1 of window winNetwork whose title is "Connect")
            end try
        end tell
        tell application "System Preferences"
            quit
        end tell
    end tell
end connectDevice

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth is On & iPhone Connected" description ¬
                "Bluetooth has been enabled with iPhone tethered." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

ब्लूटूथ अक्षम करें:

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn off Bluetooth.
if execBlueutil("status") contains "Status: on" then
    execBlueutil("off")

    doGrowl()
end if
on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth Off" description ¬
                "Bluetooth has been disabled." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Answer 3

मैं इसके लिए ऑटोमेटर का उपयोग करने की सलाह दूंगा, आप इसे आसान बनाने के लिए अल्फ्रेड से कॉल कर सकते हैं :)

मेरे वर्तमान ऑटोमेटर वर्कफ़्लो ऐसा करता है:

Click the "bluetooth" menu bar item.
Connect to Network

इस पद्धति का उपयोग करके आप एक मिनट के भीतर लगभग कुछ भी स्वचालित कर सकते हैं