अप्लायस्क्रिप्ट: स्ट्रिंग टू डेट

Question

मैं एक वेब पेज से विभिन्न दिनांक प्रारूप निकाल रहा हूं।

जैसे रविवार 10 सितंबर 2017 / 09/10/2017 / सितंबर 10 वीं, 2017।

उदाहरण में तारीख समान है, लेकिन लाइव में, तिथियां पूरी तरह से यादृच्छिक और अलग हैं। यह 01/2/1985 / नवंबर 10 वीं, 2005 हो सकता है

पहले वाले से बहुत ज्यादा फर्क नहीं पड़ता क्योंकि यह वर्तमान तिथि है, जो मैं खुद पैदा कर रहा हूं और मैं इसे बदल सकता हूं:

tell (current date)
    set strMonth to (its month as integer)
    set strDay to (its day as integer)
    set stryear to (its year as integer)
end tell

set myOwnDate to strMonth & "/" & strDay & "/" & stryear as string

जो प्रारूप मुझे चाहिए वह पूर्णांक दिन / माह / वर्ष है इसलिए 10/09/2017।

क्या मैं इस प्रारूप में दो अन्य स्ट्रिंग्स (09/10/2017 / सितंबर 10, 2017) को बदल सकता हूं?

Comments

मुझे यह जिस्म मिला । आपको अपनी आवश्यकताओं को पूरा करने के लिए इसे संशोधित करने में सक्षम होना चाहिए।

— Joonas

आपके प्रश्न में: आप चाहते हैं day/month/year, लेकिन आपकी स्क्रिप्ट एक month/day/yearस्ट्रिंग लौटाती है ।

— jackjr300

Answer 1

आप स्ट्रिंग से पार्सिंग दिनांक के लिए NSDataDetector ( एक कोको विधि ) का उपयोग कर सकते हैं ।

यहाँ स्क्रिप्ट ( macOS सिएरा पर परीक्षण ) है:

चेतावनी: एक स्ट्रिंग पर जिसमें " अंक / अंक / वर्ष " होता है, स्क्रिप्ट " दिन / महीने / वर्ष " प्रारूप में स्ट्रिंग के साथ काम नहीं करती है , स्ट्रिंग को " महीने / दिन / वर्ष " प्रारूप में होना चाहिए

use framework "Foundation"
use scripting additions

(* this script works on these formats: 
"Sunday 10th September 2017", "Sunday 10 September 2017", "Sunday 10 September 17", "September 10th, 2017", "September 10th 2017", "September 10 2017"
 "10th September 2017", "10 September 2017", "10 Sep 17"
 also work with the abbreviation ( e.g. Sep instead of September and Sun instead of Sunday) 
 also work with the localized name of (the month and the day)

"09/10/2017", "09.10.2017", "09-10-2017" : month_day_year only,  or "2016/05/22", "2016-05-22", "2016.05.22" : year_month_day only 
( month and days could be one or two digits)
*)

set myString to "Nov 5th, 2005"
set dateString to my stringToDate(myString) --> "05/11/2005"

on stringToDate(thisString) -- 
    tell current application
        -- **  finds all the matches for a date, the result is a NSArray ** 
        set m to its ((NSDataDetector's dataDetectorWithTypes:(its NSTextCheckingTypeDate) |error|:(missing value))'s matchesInString:thisString options:0 range:{0, length of thisString})
        if (count m) > 0 then
            set d to (item 1 of m)'s |date|() -- get the NSDate of the first item 
            set df to its NSDateFormatter's new() -- create a NSDateFormatter 
            df's setDateFormat:"dd/MM/yyyy" -- a specified output format: "day/month/year" (day and month = two digits, year = 4 digits)
            return (df's stringFromDate:d) as text
        end if
    end tell
    return "" -- no match in this string
end stringToDate

Comments

मैं गलत हो सकता हूं, हालांकि, मैं यहां एक मुद्दा देखता हूं। यदि, उदाहरण के लिए, वेबपेज से निकाली गई तारीख के प्रारूप में एक स्ट्रिंग है 09/10/2016, तो वह यूएस के आधार पर 10 सितंबर 2016 या अक्टूबर 09 2016 तक हो सकती है जो उपयोग करने वाले MDYया कई अन्य स्थानों पर उपयोग करता है DMY, और स्वयं बिना अन्य संदर्भ के। विश्वास न करें कि यह निर्धारित करने का एक तरीका है कि यह वास्तव में कौन सा है। इसलिए, अगर मैं पारित 09/10/2016अपने हैंडलर के लिए, यह रिटर्न "10/09/2016", हां, तो आप कृपया समझा सकता है कि कैसे एक या नहीं, किसी अन्य संदर्भ के बिना इस स्ट्रिंग जानता है, 09/10/2016, के रूप में शुरू कर दिया MDYया DMY?

— user3439894

इस प्रकार, " अंक / अंक / वर्ष " टाइप करने के लिए यह जानना असंभव है , इस प्रकार के लिए, मेरी स्क्रिप्ट यह मान लेगी कि इसमें MDY दिनांक शामिल है। कोई स्क्रिप्ट या कोड उसे नहीं मिल सकता है। केवल उपयोगकर्ता को पता होगा कि कुछ वेब पेज पर, तिथियां डी / एम / वाई प्रारूप या एम / डी / वाई में होंगी, इसलिए कुछ पेज के लिए, स्क्रिप्ट को किसी फ़ंक्शन की आवश्यकता नहीं होगी क्योंकि स्ट्रिंग (तिथि) पहले से ही है सही प्रारूप में

— jackjr300