एक नया दस्तावेज़ बनाने के लिए राइट-क्लिक करें - कैसे?

Question

ओएस एक्स (मेरे मामले में एल कैपिटन) पर कमांड लाइन से नए दस्तावेज़ बनाने के साथ मैं सहज हूं, लेकिन मैं राइट क्लिक पर एक नया दस्तावेज़ बनाने के लिए विंडोज जैसे विकल्प की संभावना तलाशना चाहता था। मुझे नीचे की स्क्रिप्ट मिली है और मुझे पता है कि इसे ऑटोमेकर & gt से चलाने की आवश्यकता है; वर्कफ़्लो & gt; AppleScript चलाएँ:

set doc_list to {"Add new..."}
tell application "Finder"
    if not (exists folder "NewHere" of folder (path to application support from user domain)) then
        display dialog "This is the first time you've run NewHere." & return & return & "Files added to the list are located at" & return & "~/Library/Application Support/NewHere" & return & "Removing a file from this folder removes it from the list."
        make new folder at folder (path to application support from user domain) with properties {name:"NewHere"}
    else
        try
            set doc_list to doc_list & name of every file of folder "NewHere" of folder (path to application support from user domain) as list
        end try
    end if
    set my_file to choose from list doc_list with prompt "Choose a document to place here"
    if result is not false then
        set my_file to item 1 of my_file as string
        if my_file is "Add new..." then
            set new_file to choose file
            duplicate file new_file to folder "NewHere" of folder (path to application support from user domain) with replacing
            set my_name to text returned of (display dialog "Enter a name for the new file." default answer (name of new_file as text))
            my do_it((name of new_file as text), my_name)
        else
            set my_name to text returned of (display dialog "Enter a name for the new file." default answer my_file)
            my do_it(my_file, my_name)
        end if
    end if
end tell

on do_it(my_file, my_name)
    tell application "Finder" to set my_dest to (folder of the front window) as text
    set my_dest to my_dest & my_name as text
    set my_origin to (path to application support from user domain) & "NewHere:" & my_file as text
    do shell script "cp " & quoted form of (POSIX path of my_origin) & " " & quoted form of (POSIX path of my_dest)
    tell application "Finder" to open my_dest as alias
end do_it

यह मुझे एक विंडोज़ के साथ संकेत देता है, जिसमें कहा गया है, "यहां जगह के लिए एक दस्तावेज चुनें"। स्क्रिप्ट के काम करने के लिए मुझे क्या करना चाहिए?

Comments

उस लिपि , AppleScript कोड आपके प्रश्न में, किसी भी तरह से "विंडोज-जैसा विकल्प राइट क्लिक पर एक नया दस्तावेज़ बनाने के लिए" प्रदान नहीं करता है, भले ही एक ऑटोमोटिव सेवा वर्कफ़्लो में लिपटे हों।

— user3439894

मैं कुछ इस तरह की तलाश में था: hints.macworld.com/article.php?story=20100509134904820

— paranza

Answer 1

यहाँ एक है AppleScript मैं एक के रूप में उपयोग करें AppleScript आवेदन इसलिए मैं इसे असाइन कर सकता हूं TextEdit आइकन और इसे अंदर रखें टूलबार का खोजक । फिर यह किसी भी स्थान पर एक नया पाठ दस्तावेज़ बनाने के लिए उपलब्ध है खोजक के लिए सेट है, कि एक को लिखने की अनुमति है। दूसरे शब्दों में, यदि कोई ऐसे स्थान पर एक नया पाठ दस्तावेज़ बनाने की कोशिश करता है जो केवल ईजी के लिए सुलभ लिखता है। root या किसी भी स्थान पर विशिष्ट लिखने की अनुमति नहीं है, तो नए पाठ दस्तावेज़ बनाने की कोशिश करने पर किसी को सूचित किया जाता है।

कोड यह देखने के लिए जाँच करता है कि क्या एक ही नाम की फ़ाइल पहले से मौजूद है और यदि ऐसा है तो सूचित करता है और वापस लाता है के रूप रक्षित करें: संवाद बॉक्स ।

खुला (अप्पलास्क्रिप्ट संपादक और कॉपी और पेस्ट करें कोड नीचे खाली खिड़की में और इसे बचाने के रूप में नई पाठ फ़ाइल बनाएँ Here.app । सुनिश्चित करें कि आप चयन करें आवेदन के लिये फाइल प्रारूप: में के रूप रक्षित करें: संवाद बॉक्स ।

इसे जोड़ने से पहले टूलबार का खोजक , आप इसका आइकन बदलना चाहते हैं, जिसका उपयोग किया जाता है TextEdit । आप खोल सकते हैं जानकारी हो चादर प्रत्येक ऐप के लिए और फिर से कॉपी और पेस्ट करें TextEdit.app में एक करने के लिए नई पाठ फ़ाइल बनाएँ Here.app । ध्यान दें कि यह शीर्ष बाएँ कोने में प्रदर्शित आइकन है जानकारी हो चादर ।

अब जबकि इसमें एक नया आइकन है, नए ऐप को उस स्थान पर खींचें और छोड़ें टूलबार का खोजक आप इसे होना चाहते हैं। ध्यान दें कि OS X / macOS के किस संस्करण के आधार पर आपको प्रेस करने की आवश्यकता हो सकती है आज्ञा ⌘ एप्लिकेशन को खींचते समय कुंजी टूलबार का खोजक ।

उपयोग करने के लिए, बस क्लिक करें नई पाठ फ़ाइल बनाएँ Here.app आइकन में टूलबार का खोजक और आपको एक नाम के लिए संकेत दिया जाएगा और एक नई पाठ दस्तावेज़ फ़ाइल बनाई जाएगी और वर्तमान स्थान से खोली जाएगी खोजक खिड़की ।

---

on run
    my createNewTextFile()
end run


on createNewTextFile()

    tell application "Finder"
        activate
        set the currentFolder to (folder of the front window as alias)
    end tell

    tell me
        activate
        set fileName to ""
        repeat while fileName = ""
            display dialog "Save As:" with title "Create New Text File Here" default answer fileName buttons {"Cancel", "OK"} default button 2
            set fileName to text returned of the result
        end repeat
        if fileName ends with ".txt" then
            set newTextFile to POSIX path of currentFolder & fileName
        else
            set newTextFile to POSIX path of currentFolder & fileName & ".txt"
        end if

    end tell

    tell application "Finder"
        set itExists to (exists newTextFile as POSIX file)
    end tell

    tell me
        activate
        if itExists is false then
            try
                do shell script "touch \"" & newTextFile & "\"; open \"" & newTextFile & "\""
            on error
                display dialog "Cannot create the \"" & newTextFile & "\" file at this location!..." with title "Cannot Create File" buttons {"OK"} default button 1 with icon stop
            end try
        else
            display dialog "The \"" & newTextFile & "\" file already exists!..." with title "File Already Exists" buttons {"OK"} default button 1 giving up after 5
            my createNewTextFile()
        end if
    end tell

end createNewTextFile

---

ध्यान दें कि यह कोड में भी इस्तेमाल किया जा सकता है स्वचालक के लिए सेवा वर्कफ़्लो हालाँकि, मैंने पाया है कि मैं पहले से ही हूँ खोजक जब मैं एक नया टेक्स्ट डॉक्यूमेंट बनाना चाहता हूं और क्लिक करना आसान हो जाता है नई पाठ फ़ाइल बनाएँ Here.app आइकन में टूलबार का खोजक फिर तो दाएँ क्लिक करें और पहले से ही आबादी से चुनें सेवाएं संदर्भ की विकल्प - सूची मेरे पास जो भी है।

इसके अतिरिक्त, यदि आप संशोधित करते हैं कोड एक बार लिपि एक आवेदन के रूप में सहेजा गया है और में रखा गया है टूलबार का खोजक , फिर आपको आइकन को से हटाना होगा टूलबार और फिर नए सहेजे गए को खींचें और छोड़ें नई पाठ फ़ाइल बनाएँ Here.app आदेश में यह ठीक से काम करने के लिए।

Comments

नोट: .app फ़ाइल को खींचते समय कमांड कुंजी दबाकर फाइंडर कार्यों में खींचें और छोड़ें। कम से कम मैकओएस 10.12 में

— Jorj

Answer 2

मेरे पास एक स्क्रिप्ट है जो मैं एक कीबोर्ड शॉर्टकट से फाइंडर में चलाता हूं FastScripts ( ⇧ ^ ⌘ एन ) जो फ़ाइल टेम्प्लेट की पिक-लिस्ट पॉप-अप करता है (एक टेम्पलेट फ़ोल्डर में संग्रहीत)। नए टेम्पलेट जोड़ने के लिए बस उन्हें उस फ़ोल्डर में रखें।

कुछ साल पहले StackExchange पर पोस्ट किया गया: एक फ़ोल्डर में एक पाठ फ़ाइल कैसे बनाएं

-ccs

Answer 3

मैं राइट-क्लिक के माध्यम से नई फ़ाइलें बनाने के लिए मैक ऐप स्टोर से नई फ़ाइल मेनू का उपयोग कर रहा हूं; यह ठीक काम करता है। यह 30 या तो टेम्पलेट्स के साथ आता है, लेकिन आप अपना खुद का भी बना सकते हैं। लगता है यह एक बहुत आसान समाधान है।

आप इसके बारे में जानकारी पा सकते हैं https://langui.net/new-file-menu/ & Amp; पर https://itunes.apple.com/us/app/new-file-menu/id1064959555?mt=12 ।