पासवर्ड-प्रॉम्प्ट डाइलॉग बॉक्स

Question

कभी-कभी, जब कोई प्रोग्राम इंस्टॉल कर रहा होता है, तो एक संवाद बॉक्स इंस्टॉलर को 'परिवर्तन करने' की अनुमति देने के लिए एक प्रशासक का पासवर्ड पूछेगा। यह ठीक लगता है, लेकिन क्या इंस्टॉलर के लिए यह नकली और लेखक (और आईपी आदि) को पासवर्ड भेजना आसान नहीं होगा? क्या यह सुनिश्चित करने का कोई तरीका है कि यह डाइलॉग बॉक्स वास्तव में ओएस से है? (और देखें कि वास्तव में क्या अनुमति दी जा रही है?)

Comments

सदृश

— Max Ried

Answer 1

मैंने इस Apple स्क्रिप्ट को लिखा है कि यदि परीक्षण:

1. SecurityAgent चल रही है।
2. SecurityAgent कुछ प्रदर्शित कर रहा है।
3. SecurityAgent सही स्थान पर रहता है।

4. SecurityAgent अनमॉडिफाइड है, जिसका अर्थ है कि कोड सिग्नेचर अनमैडेड है।

   tell application "System Events"
       set processList to get the name of every process
       set saWindows to {}
       if processList contains "SecurityAgent" then -- does it run?
       set saPath to POSIX path of application file of application process "SecurityAgent"
       if saPath is not "/System/Library/Frameworks/Security.framework/Versions/A/MachServices/SecurityAgent.bundle" then -- assume this location is protected enough to be geniune
           tell application "Finder" to display dialog "There is a SecurityAgent, but it's the wrong one!" with icon stop buttons {"OK"}
           return
       end if
   
       try -- is it signed
           set saSignature to do shell script "codesign -d /System/Library/Frameworks/Security.framework/Versions/A/MachServices/SecurityAgent.bundle/Contents/MacOS/SecurityAgent"
       on error
           tell application "Finder" to display dialog "Signature broken!" with icon stop buttons {"OK"}
           return
       end try
   
       set saWindows to every window of application process "SecurityAgent"
   end if
   
   if saWindows is {} then -- Does it display a dialog?
       tell application "Finder" to display dialog "No official password dialog is opened." buttons {"OK"} with icon stop
       return
   end if
   end tell
   
   display dialog "Seems legit." with icon note buttons {"OK"}