अस्वीकरण / चेतावनी
छिपी हुई फाइलें आमतौर पर एक कारण के लिए छिपी होती हैं। नीचे दी गई स्क्रिप्ट का उपयोग तभी करें जब आप सुनिश्चित करें कि आप जानते हैं कि आप क्या कर रहे हैं। दूसरे शब्दों में: यदि आप छुपी हुई फ़ाइलों को बेतरतीब ढंग से हटाकर अपने सिस्टम को तोड़ते हैं, तो यह आपकी गलती है।
यहाँ स्क्रिप्ट है जो मैं टॉगल शो का उपयोग करता हूं / फाइंडर के अंदर छिपी हुई फ़ाइलों को नहीं दिखाता हूं ।
( ओपन / सेव संवादों में छिपी हुई फाइलों को टॉगल करने के लिए OSX देशी शॉर्टकट पहले से ही Mateusz Szlosek द्वारा उल्लेख किया गया था)
मेरी स्क्रिप्ट और अन्य के बीच का अंतर जो मैंने अब तक देखा है:
खोजक को मारने के बाद अधिकांश स्क्रिप्ट कुछ और नहीं करते हैं। आमतौर पर, इसका मतलब है कि आपको उस फ़ोल्डर में वापस नेविगेट करना होगा जो आप मूल रूप से थे, क्योंकि स्वचालित खोजक पुन: लॉन्च करने से मज़बूती से आपके पिछले सक्रिय फ़ोल्डर को नहीं खोला जाता है।
इसके बजाय नीचे दी गई स्क्रिप्ट फिर से खुल जाती है, और आपके पिछले सक्रिय फ़ोल्डर, यानी उस फ़ोल्डर पर ध्यान केंद्रित करती है, जिसे आप टॉगल का उपयोग करते समय करते थे, लेकिन अब छिपी हुई फ़ाइलों को दिखा रहा है (या नहीं दिखा रहा है)।
मैंने इसे एक शॉर्टकट सौंपा (cmd + Shift +।) और फाइंडर में छिपी फाइलों के साथ काम करना अब बहुत सुविधाजनक है।
Tetsujin को श्रेय जिन्होंने कुछ समय पहले इस साइट पर एक स्क्रिप्ट पोस्ट की थी जिसे मैंने 'reopen last folder' कार्यक्षमता को जोड़ने के लिए अनुकूलित किया था।
on run {input, parameters}
tell application "Finder"
set var1 to POSIX path of (target of window 1 as alias)
end tell
set newHiddenVisiblesState to "YES"
set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
if oldHiddenVisiblesState is in {"1", "YES"} then
set newHiddenVisiblesState to "NO"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState
---- Sleep hack mentioned below. 0.5s minimum, 1-2s safer. Ugly, but (probably) unavoidable.
do shell script "killall Finder; sleep 0.5s"
tell application "Finder"
---- Close other windows if Finder managed to relaunch already
if application "Finder" is running then
close every window
end if
open (var1 as POSIX file)
activate
end tell
end run
स्क्रिप्ट का उपयोग करने के लिए: ऑटोमेकर में एक नया वर्कफ़्लो खोलें, "रन AppleScript" में खींचें, ऊपर दिए गए कोड को कॉपी और पेस्ट करें, और अपने सर्विस फ़ोल्डर के अंदर सहेजें (आमतौर पर, ~ / लाइब्रेरी / सर्विसेज /, afaik)।
किसी स्क्रिप्ट को निष्पादित करने के लिए एक शॉर्टकट संलग्न करना इस साइट पर कहीं और कवर किया जाना चाहिए। मैंने अपने शॉर्टकट के दायरे को अकेले फाइंडर तक सीमित कर दिया।
शैली टिप्पणी:
मुझे मूल फ़ोल्डर खोलने से पहले फाइंडर को मारने के बाद 'स्लीप' का उपयोग करके, एक बदसूरत हैक के एक बिट का सहारा लेना होगा।
अगर मैं इस देरी को बल नहीं देता, तो एक मौका है OSX ने पहले से ही फाइंडर को वापस ले लिया और एक फ़ोल्डर खोला (जरूरी नहीं कि मेरे अनुभव में अंतिम सक्रिय एक)। अपने स्वयं के 'ओपन' कमांड के साथ, इससे दो (अनजाने, यहां तक कि) खोजक प्रक्रियाएं चल रही हैं, और खोजक अब बिल्कुल भी काम नहीं कर सकते हैं। यदि ऐसा होता है, तो लॉग आउट करना और वापस फिर से इसे ठीक करना, लेकिन यह स्पष्ट रूप से समय की बर्बादी है, इसलिए मैं 'नींद' का उपयोग करता हूं।
मेरे लिए 0.5 मिनट की नींद का मूल्य काम करता है, लेकिन सुरक्षित पक्ष पर होने के लिए, आप इसे थोड़ा बढ़ा सकते हैं (फिर प्रक्रिया में अधिक ध्यान देने योग्य देरी जोड़ते हुए)।
अगर किसी को किलर सिग्नल भेजने के बाद फाइंडर को फिर से खोलने और कुछ खिड़की के अविश्वसनीय खोलने का तरीका पता है - या 'नींद' हैक से छुटकारा पाने का कोई और तरीका - मुझे यह सुनकर खुशी होगी!
