सफारी "खोज टैब" कीबोर्ड शॉर्टकट

Question

सफारी 8 का नया "सर्च टैब्स" फीचर काफी अच्छा है। जब "सभी टैब दिखाएं" सक्रिय हो जाता है, तो आप टैब को अपने इच्छित व्यक्ति को फ़िल्टर करने के लिए कुछ पाठ टाइप कर सकते हैं। हालाँकि, एक बार मेरे पास एक टैब दिखाई दे, तो उस टैब को सक्रिय करना बहुत अच्छा होगा । यह टैब के लिए "स्पॉटलाइट" प्रकार की कार्यक्षमता की अनुमति देगा।

हालाँकि, ऐसा नहीं लगता है कि टैब को सक्रिय करने के लिए एक कीबोर्ड शॉर्टकट है जिसे मैंने उसके लिए खोजा है, इसलिए मैं अपने माउस के साथ टैब पर क्लिक करने के लिए मजबूर हूं! यह एक निरीक्षण की तरह लगता है, मुझे विश्वास नहीं हो सकता है कि Apple टैब को फ़िल्टर करने के लिए एक अच्छा तरीका जोड़ देगा, लेकिन किसी एक का चयन करने का कोई तरीका नहीं है!

स्क्रीनशॉट:

Comments

मुझे पता है कि यह पूरी तरह से अनपेक्षित है, लेकिन मुझे विश्वास है कि वे ऐसा करेंगे। : पी विशेष रूप से दिया गया है ... मोटे तौर पर योसेमाइट के कुछ किनारों में सामान्य रूप से हैं।

— ट्यूबडॉग

उस पर कुछ भी नया? कुछ महीने हो गए हैं और यह समस्या अभी भी बनी हुई है :(

— Dvcrn

खोज के साथ यह "सभी टैब दिखाएं" दृश्य अब उन सभी ऐप्स के लिए उपलब्ध है जो हाई सिएरा में देशी टैब का उपयोग करते हैं।

— स्टीव मोजर 14

Answer 1

मैंने बिना किसी प्रभाव के ऐसा करने के प्रयास में निम्नलिखित प्रमुख संयोजनों की कोशिश की है:

• कमांड + रिटर्न ... + स्पेस
• विकल्प + वापसी ... + स्थान
• कंट्रोल + रिटर्न ... + स्पेस
• कमांड + शिफ्ट + \ _ (मेरी मैकबुक पर "सभी टैब दिखाएं" कमांड)

यह मुझे विश्वास दिलाता है कि यह वास्तव में एप्पल के हिस्से पर एक नजर है।

कीचड़: एक माउस क्लिक अनुकरण करने के लिए एक स्वचालित कमांड बनाएँ

मैंने निम्नलिखित AppleScripts.net को एक साथ रखने के लिए https://discussions.apple.com/thread/3708948 पर मिलने वाले कोड का उपयोग किया :

प्रयास 1: क्या मैंने इस कोड को एक स्वचालित सेवा में लिपटे Applescript में "कमांड + शिफ्ट + ऑप्शन + कंट्रोल + स्पेस" के लिए मैप किया, जो संख्या मैं "कमांड + कंट्रोल + शिफ्ट + 4" को दबाने से प्राप्त करता था। क्षेत्र के लिए पता प्राप्त करें (बाएं से 600 पिक्सेल क्षैतिज, ऊपर से 300 पिक्सेल ऊर्ध्वाधर), और यह सामान्य सफारी में काम करेगा (कुंजी संयोजन दबाने से माउस को उस पिक्सेल पते पर क्लिक करना होगा), लेकिन इसका कोई प्रभाव नहीं पड़ा जब वही मुख्य कमांड सफारी में "शो ऑल टैब्स" मोड में चलाया गया था!

on run {input, parameters}
    tell application "System Events"
            tell process "Safari"
                click at {600, 300}
            end tell
        end tell

        return input
    end run

# 2 प्रयास: काम किया, लेकिन संभव नहीं

मुझे एक मुख्य कमांड मिला जो कि निम्नलिखित एप्लायस्क्रिप्ट के साथ काम कर रहा है जो एक ऑटोमेटर सेवा में लिपटा हुआ है, लेकिन इसे पूरा होने में 5.125 सेकंड का समय लगा है: (

    on run {input, parameters}

    set x to 600
    set y to 150

    do shell script "
/usr/bin/python <<END
import sys
import time
from Quartz.CoreGraphics import *
def mouseEvent(type, posx, posy):
          theEvent = CGEventCreateMouseEvent(None, type, (posx,posy), kCGMouseButtonLeft)
          CGEventPost(kCGHIDEventTap, theEvent)
def mousemove(posx,posy):
          mouseEvent(kCGEventMouseMoved, posx,posy);
def mouseclick(posx,posy):
          mouseEvent(kCGEventLeftMouseDown, posx,posy);
          mouseEvent(kCGEventLeftMouseUp, posx,posy);
ourEvent = CGEventCreate(None);
currentpos=CGEventGetLocation(ourEvent);             # Save current mouse position
mouseclick(" & x & "," & y & ");
mousemove(int(currentpos.x),int(currentpos.y));      # Restore mouse position
END"
    return input
end run

Comments

मैं इसे अब तक के सबसे अच्छे उत्तर के रूप में चिह्नित करूंगा, क्योंकि यह इस विषय पर काफी गहन उपचार है, और दिखाता है कि यह बहुत असंभव है। धन्यवाद।

— सामबेरन

टैब का चयन करने के लिए शॉर्टकैट का उपयोग करने के लिए थोड़ा क्लंकी वर्कअराउंड है ।

— एडम लिंडबर्ग

Answer 2

मुझे लगता है कि मुझे आपका जवाब मिल गया। मैंने सारा दिन इसी की तलाश में बिताया। मैं सभी ऐप्पल डिवाइसों में एडिशनल जेस्चर और शॉर्टकट जोड़ने के लिए एक बेहतर फ्री ऐप का उपयोग बेटरटचटूल (ओएस एक्स 10.10 का उपयोग करके) करता हूं, और यह तुरंत काम करता है! विलंब न करें!

मैं आपके द्वारा कॉन्फ़िगर किए जाने वाले प्रत्येक चरण के साथ स्क्रीनशॉट बनाऊंगा। नोट: जब आप सफारी का उपयोग कर रहे हैं, तो यह आपकी पसंद के कीबोर्ड शॉर्टकट के रूप में माउस स्थिति को बाँध देगा। डाउनसाइड्स: आप सफारी की विंडो स्थिति को बदल नहीं सकते हैं, और माउस की स्थिति आपके नोटबुक से मॉनिटर से अलग होगी। समाधान: मैं अनुशंसा करता हूं कि स्क्रीन के साथ पूर्ण स्क्रीन का उपयोग करते हुए माउस स्थिति को आप सबसे अधिक बार उपयोग करें (या बस प्रत्येक स्क्रीन के दो शॉर्टकट मैप करें)

• 1 एप्लिकेशन को डाउनलोड करें http://www.bettertouchtool.net

• 2 ऐप खोलें, कीबोर्ड का चयन करें, शॉर्टकट में सूची के लिए एक ऐप जोड़ें (इस मामले में सफारी में), अपना शॉर्टकट चुनें (मैं इस स्क्रीनशॉट में "विकल्प + 1" मैप कर रहा हूं), फिर, ट्रिगर चयन के अंदर मेनू, " मूव माउस टू पोजीशन " को "अन्य माउज़र क्रियाओं" में चुनें। मैंने स्क्रीनशॉट में गलत विकल्प को चिह्नित किया है, यह ऊपर का विकल्प है। यह "माउस स्थिति सहेजें" नहीं है। क्षमा करें, मैं बहुत थक गया हूँ, यह 3 बजे है और मुझे कल काम करना है

• 3 चुनें कि आप कर्सर कहाँ जाना चाहते हैं (इनपुट बॉक्स में स्थिति पहले परिणाम की जांच करेगी जब UI ~ 3 परिणाम दिखा रहा है)

• 4 एक निम्न ईवेंट जोड़ें: एक बाएँ क्लिक ईवेंट। और बस!

2, 3 .. परिणाम प्राप्त करने के लिए एक अलग माउस स्थिति के साथ भी ऐसा ही करें लेकिन ध्यान रखें कि बड़े परिणाम होने पर यूआई बदल जाएगा, कभी-कभी पहले परिणाम को छिपाते हुए भी।

Comments

मैंने रीमेक shift+command+\ किया है command+d। तो आप बस command+d command+f यहाँ पाठ करते हैं command+d।

— दिज

Answer 3

इससे पहले कि वे इस सुविधा को जोड़ते हैं मैं ऐसा करने के लिए Applescript का उपयोग कर रहा हूं:

http://hea-www.harvard.edu/~fine/OSX/safari-tabs.html

यह एक खोज संवाद को पॉप अप करता है, आप अपनी खोज दर्ज करते हैं, और यह तुरंत एक एकल मिलान टैब को सक्रिय करता है, या आपको मिलान टैब की सूची से चयन करने के लिए एक संवाद देता है। यह विंडो को सामने लाता है और यह विंडो में सक्रिय टैब बनाता है।

(मेरे पास टर्मिनल विंडो खोजने के लिए एक समान स्क्रिप्ट है।)

Comments

बहुत ही शांत; मुझे लगता है कि मैं यह कोशिश करूँगा। अगर मैं इसे समझता हूं, तो ऐसा लगता है कि आपकी स्क्रिप्ट भी सभी खुली खिड़कियों को खोजती है, बजाय केवल वर्तमान के। क्या वो सही है? यह एक ऐसी सुविधा है जो मैं चाहूंगा कि सामान्य खोज में नहीं है।

— krs013

Answer 4

मुझे पार्टी में थोड़ी देर हो गई है, लेकिन मुझे लगता है कि शॉर्टकट आवश्यक कार्यक्षमता का प्रदर्शन करेगा।

अतिरिक्त बोनस के साथ ऐसा है कि इसका उपयोग मेल आदि के साथ किया जा सकता है।

Answer 5

ऑटोमेटर का उपयोग करें और AppleScript को एक कीबोर्ड शॉर्टकट से संलग्न करके पेस्ट करें जैसे कि इसमें वर्णित है:

मैंने अपने द्वारा लिखे गए AppleScript में कीबोर्ड शॉर्टकट कैसे असाइन किया?

set question to display dialog ("Find Safari tab:") default answer ""
set searchpat to text returned of question

tell application "Safari"
    set winlist to every window
    set winmatchlist to {}
    set tabmatchlist to {}
    set tabnamematchlist to {}
    repeat with win in winlist
        set ok to true
        try
            set tablist to every tab of win
        on error errmsg
            --display dialog name of win as string
            set ok to false
        end try
        if ok then
            repeat with t in tablist
                if searchpat is in (name of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                else if searchpat is in (URL of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                end if
            end repeat
        end if
    end repeat
    if (count of tabmatchlist) = 1 then
        --display dialog "one!"
        set w to item 1 of winmatchlist
        set t to item 1 of tabmatchlist
        set current tab of w to t
        set index of w to 1
    else if (count of tabmatchlist) = 0 then
        display dialog "No matches"
    else
        set whichtab to choose from list of tabnamematchlist with prompt "The following tabs match, please select one:"
        set AppleScript's text item delimiters to "."
        if whichtab is not equal to false then
            set tmp to text items of (whichtab as string)
            set w to (item 1 of tmp) as integer
            set t to (item 2 of tmp) as integer
            set current tab of window id w to tab t of window id w
            set index of window id w to 1
        end if
    end if
end tell