स्मार्ट फ़ोल्डर फ़िल्टर "शामिल नहीं है"

Question

स्मार्ट फ़ोल्डर फ़ोल्डर को बाहर निकालें

अंततः मैं चाहता हूं कि इस खोज का परिणाम एक स्मार्ट फ़ोल्डर हो।

मानदंड इतने जटिल नहीं हैं:

• नाम "README.md" होना चाहिए
• प्रकार फ़ाइल होना चाहिए
• पथ में "node_modules" नहीं होना चाहिए

find /Users/me/Documents -type f -name README.md -not -path "*/node_modules/*"

समस्या यह है कि स्मार्ट फ़ोल्डर मानदंड ऑपरेटर सूची में does not containविकल्प की कमी लगती है ।

उपलब्ध विकल्प हैं:

• माचिस
• शामिल
• साथ शुरू होता है
• इसी के साथ समाप्त होता है
• है
• नहीं है

क्या यह पूरा करना संभव है और यदि ऐसा है तो कैसे?

संपादित करें 1

मैंने पाया कि विकल्प कुंजी को पकड़कर मैं स्मार्ट फ़ोल्डर खोज मानदंड में एक नकार खंड जोड़ने में सक्षम हूं, लेकिन मैं नोड_मॉडल फ़ोल्डर को सफलतापूर्वक बाहर नहीं कर सकता। यह स्पष्ट नहीं है कि किन मानदंडों का उपयोग करना है, लेकिन मैंने जिन लोगों की कोशिश की है उनमें से कोई भी काम नहीं करता है:

• दस्तावेज़ कंटेनर
• युक्त फ़ोल्डर नाम
• फोल्डर का नाम

मैंने निम्नलिखित ऑपरेटरों के साथ इन्हें संयोजित करने की कोशिश की है:

• शामिल
• माचिस

और निम्नलिखित शर्तों के साथ:

• node_modules
• node_modules

यदि यह वाइल्डकार्ड खोजों का समर्थन करता है।

मैंने उपरोक्त फ़िल्टर, ऑपरेटर और शर्तों के सभी संयोजनों की कोशिश की है।

प्रलेखन विषय पर बहुत खराब है।

Comments

क्या आपने हल खोज लिया?

— gota

Answer 1

ऐसा लगता है कि kMDItemPath वह नहीं कर सकता जो आपको चाहिए:

कोई परिणाम में सुर्खियों में खोजें-खिलाफ-kmditempath

कुछ संभावित विकल्पों पर यहां चर्चा की गई है:

कैसे करने के लिए पता लगाने के एक फ़ाइल में सुर्खियों का उपयोग-फ़ोल्डर और फ़ाइल-नाम

Comments

धन्यवाद, लेकिन मेरे पास पहले से ही एक कमांड लाइन फ़ंक्शन है जो उन फ़ाइलों को पुनर्प्राप्त करता है जो मुझे दिलचस्पी है और मैं स्पॉटलाइट सर्च नहीं कर रहा, स्मार्ट फ़ोल्डर बना रहा हूं। मैं mkdItemPath की सीमा में आया हूं।

— किमी

स्पॉटलाइट सर्च और स्मार्ट फोल्डर एक ही आंतरिक तंत्र का उपयोग करते हैं। kMDItemPath इनमें से किसी भी उपयोगकर्ता इंटरफ़ेस में काम नहीं करेगा।

— ग्रेनाइटाइट जुआर

Answer 2

वर्कअराउंड है, लेकिन यह बहुत सुंदर नहीं है। हालाँकि, यह आपके उद्देश्यों की सेवा करेगा यदि आप अपने READMEs को एक फ़ोल्डर में उपयोग करना चाहते हैं (आपके द्वारा निर्दिष्ट मानदंडों का उपयोग करके), और कुछ धारणा है कि वे कहाँ से आते हैं।

विचार सही फ़ाइलों को खोजने के लिए अपनी शेल स्क्रिप्ट का उपयोग करना है, और फिर एक निर्देशिका में प्रत्येक फ़ाइल के लिए उपनाम इकट्ठा करना है। फिर हम उपनामों का नाम बदलकर हमें बताते हैं कि मूल फ़ाइल किस मूल निर्देशिका की है।

ऐसा करने के लिए Applescript नीचे है। यह यहाँ बदसूरत लग रहा है, लेकिन इसे स्क्रिप्ट एडिटर में चिपकाने की कोशिश करें और इसे संकलित करें, और आपको तर्क देखने में सक्षम होना चाहिए।

--- Set up the name of the folder to contain search results
set myFolder to POSIX file "/Users/me/SmartFolder"

--- Clear the folder of contents. Then we will see only the results of an updated search
tell application "Finder"
    display dialog "WARNING. This will delete all files below " & (POSIX path of myFolder) & " . Are you sure you want to continue?"
    delete (every item of folder myFolder)
    --- alternatively, if you want to keep your script in the same folder, replace the line above with
    --- delete ((every item of folder myFolder) whose name does not end with ".scpt")
end tell

--- The shell command that is doing all the searching
set FileList to do shell script "find /Users/me/Documents -type f -name README.md -not -path '*/node_modules/*'"

--- The rest of the script takes each file and makes an alias in our folder containing search results. The aliases are renamed according to "ParentDirectory_filename"
set FileList to paragraphs of FileList
repeat with CurrentFile in FileList
    set ASCurrentFile to POSIX file CurrentFile
    set PathList to words of (ASCurrentFile as string)
    --- Make the new name include the Parent Directory and file name
    set NewName to (item -2 of PathList) & "_" & (item -1 of PathList)
    tell application "Finder"
        make new alias file at myFolder to ASCurrentFile
        --- We need to save the name/location of the new alias file before we can try to rename it
        set NewAlias to result
        set i to 1
        repeat
            try
                --- Try to rename the alias. Won't work if there's already an alias with the new name
                set name of NewAlias to NewName
                exit repeat
            on error
                --- Append a number to the alias. Increase the number for more duplicates
                if i is not equal to 1 then
                    set NewName to text 1 thru -3 of NewName
                end if
                set NewName to NewName & " " & i
                set i to (i + 1)
            end try
        end repeat
    end tell
end repeat

Comments

मुझे नहीं पता कि यह काम करता है या नहीं। इसके साथ आने के लिए भी +1। मैं एक रीडमी फ़ोल्डर बनाने के लिए इसे दूर जाने के लिए तैयार नहीं हूं।

— km6zla