फाइंडर - कीबोर्ड शॉर्टकट में एक नई (.txt) फाइल बनाएं

Question

मैं यह जानना चाहता था कि क्या फाइंडर में नई फाइलें बनाने के लिए कीबोर्ड शॉर्टकट सेट करने का कोई तरीका है। उदाहरण के लिए, डिफ़ॉल्ट रूप से, आप CMD+ Shift+ का उपयोग करके एक नया फ़ोल्डर बना सकते हैं N। क्या एक नया पाठ फ़ाइल बनाने के लिए एक कीबोर्ड शॉर्टकट है? मैं एक प्रोग्रामर हूं इसलिए यह बेहद उपयोगी होगा

मुझे कीबोर्ड शॉर्टकट का उपयोग करके अन्य फ़ाइल प्रकार बनाने में भी रुचि होगी।

मैंने ऑटोमेकर का उपयोग करने का प्रयास किया है, लेकिन मैं इसे काफी भ्रमित कर रहा हूं और मुझे यकीन नहीं है कि मैं इसे कीबोर्ड शॉर्टकट कैसे कनेक्ट करूंगा।

Answer 1

ठीक है, यहाँ आप उसके लिए एक AppleScript के साथ जाते हैं।

सबसे पहले, AppleScript बनाएँ:

1. ओपन ऑटोमेटर
2. एक त्वरित कार्रवाई बनाएँ
3. इनपुट को बिना इनपुट पर सेट करें
4. ग्रे स्पेस पर रन AppleScript वर्कफ़्लो तत्व को खींचें और छोड़ें ।
5. नीचे दिए गए कोड को AppleScript में पेस्ट करें
6. नई फ़ाइल बनाएँ के रूप में वर्कफ़्लो सहेजें
   यदि आपके पास iCloud ड्राइव सक्रिय है, तो सुनिश्चित करें कि आप Library/Services/अपने होम फ़ोल्डर में फ़ाइल सहेज रहे हैं ।

---

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

---

इसे शॉर्टकट के रूप में जोड़ने के लिए:

• सिस्टम वरीयताएँ -> कीबोर्ड -> शॉर्टकट -> सेवाओं पर जाएं
• जब तक आपको सेवा नई फ़ाइल न मिल जाए, तब तक नीचे स्क्रॉल करें
• दाईं ओर कोई भी क्लिक करके उस पर एक शॉर्टकट असाइन करें , जो एक में बदल जाता है Add Shortcut।
  बटन पर क्लिक करें और उस शॉर्टकट को टाइप करें जिसे आप उपयोग करना चाहते हैं।
  मैं का उपयोग ⌘ Command+ ⌥ Option+N

Comments

मुझे समझ में नहीं आ रहा है कि इस विशिष्ट लिपि के माध्यम से शॉर्टकट को कैसे सेट किया जाए

— हैरी

मैंने इस स्क्रिप्ट को शॉर्टकट के रूप में जोड़ने के बारे में अधिक विस्तृत तरीका जोड़ा।

— rwenz3l

अब इसे खाली फ़ोल्डरों के साथ भी काम करना चाहिए। कम से कम यह मेरे लिए काम करता है। आप अपनी फ़ाइल को स्क्रिप्ट "filename.txt" के अंदर लिख सकते हैं।

— rwenz3l

यह भी देखें superuser.com/questions/106943/…

— mems

डिफ़ॉल्ट रूप से उनके पास ऐसा कुछ क्यों नहीं है? उनके साथ क्या मामला है?

— जी। रैसोव्स्की

Answer 2

मैंने @ YoshiBotX के एक के समान एक AppleScript बनाया है, लेकिन कुछ सुधारों के साथ।

निम्नलिखित चरणों का उपयोग करके एक ऑटोमेकर वर्कफ़्लो बनाने और इसके लिए एक शॉर्टकट असाइन करने का विचार है:

• ऑटोमेटर खोलें और एक सेवा बनाएं ;
• इनपुट को बिना इनपुट पर सेट करें , और Finder.app के लिए आवेदन करें ;
• ग्रे स्पेस पर रन AppleScript वर्कफ़्लो तत्व को खींचें और छोड़ें ;
• इस AppleScript की सामग्री को टेक्स्टबॉक्स में रखें;
• एक उचित नाम (जैसे नई फ़ाइल ) के साथ वर्कफ़्लो सहेजें ;
• पर जाएं सेटिंग्स -> कीबोर्ड -> शॉर्टकट -> सेवाएं और उसका एक शॉर्टकट आवंटित।

अब, AppleScript दिखाते हैं:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

सुविधा के लिए, मैं इस AppleScript को इस GitHub Gist में डाल रहा हूं ।

Comments

बहुत बढ़िया स्क्रिप्ट, धन्यवाद। केवल एक चीज जो मैं इस राइट-अप में जोड़ूंगा, उसे और अधिक पूर्ण बनाने के लिए जानकारी है जो नए ऑटोमेकर उपयोगकर्ताओं को निर्देश दे रही है कि उनके द्वारा बनाई गई वर्कफ़्लो स्क्रिप्ट को सहेजा जाए ~/Library/Services। (मेरा डिफ़ॉल्ट अंदर था iCloud Drive\Automatorऔर मुझे यह जानने के लिए थोड़ा शोध करना पड़ा कि इसे कहाँ बचाया जाए ताकि यह कीबोर्ड शॉर्टकट में सेवाओं के तहत दिखाई दे।)

— कॉलिन जॉन्सटन

Answer 3

आप स्वयं एक ऑटोमेटर सेवा बना सकते हैं - यह करना सरल है। फिर आप इसे एक कीबोर्ड शॉर्टकट असाइन कर सकते हैं ताकि आपको सेवा मेनू के माध्यम से सेवा को सक्रिय करने की आवश्यकता न हो (जो आप वैसे भी कर सकते हैं)।

ऑटोमेटर खोलें और नए दस्तावेज़ के प्रकार के रूप में सेवा का चयन करें।

Finder.app में कोई इनपुट प्राप्त करने के लिए सेवा सेट करें और वर्कफ़्लो में नया TextEdit दस्तावेज़ क्रिया जोड़ें।

सेवा को सहेजें, फिर सिस्टम प्राथमिकताएँ खोलें → कीबोर्ड → शॉर्टकट्स → ऐसी सेवाएँ जहाँ आपको सामान्य नाम से सूचीबद्ध सेवा मिलेगी, जिसे आपने सेव करते समय सेवा के लिए दिया था।

सेवा का चयन करके सेवा में एक कीबोर्ड शॉर्टकट जोड़ें, फिर 'शॉर्टकट जोड़ें' पर क्लिक करें।

यदि शॉर्टकट का पहले से ही उपयोग किया जाता है तो यहां आपको कुछ समस्याएं हो सकती हैं। इसलिए अपने लिए काम करने के लिए रचनात्मक बनें।

Answer 4

आप इस तरह से एक स्क्रिप्ट को शॉर्टकट भी दे सकते हैं :

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

प्रविष्टि स्थान या तो सामने वाले खोजक विंडो या डेस्कटॉप का लक्ष्य है।

Comments

आपका कोड इतना सरल और उपयोगी है! मैं एक एप्लिकेशन बनाने के लिए ऑटोमेटर का उपयोग करता हूं, जिसमें केवल एक ही कार्रवाई है: अपने कोड के साथ AppleScript चलाएँ। फिर मैंने इस एप्लीकेशन को फाइंडर टाइटलबार में डाला। ठीक है। जब मुझे ज़रूरत होगी, बस क्लिक करें, और वर्तमान फ़ोल्डर में एक नई फ़ाइल बनाई जाएगी।

— फंतासी

Answer 5

खुला टर्मिनल और प्रकार

touch filename

या

> filename

Comments

तुमने मुझे यहाँ खो दिया? वह क्या करता है?

— Ruskes

क्या आप इस पर विस्तार कर सकते हैं कि आप इस कमांड में कीबोर्ड शॉर्टकट कैसे जोड़ेंगे? (@Buscar देखें स्पर्श )

— GRG

यदि आपके पास पाथफाइंडर है - तो यह वास्तव में एक बढ़िया विकल्प है; डी

— rwenz3l

यह बहुत अच्छी तरह से cmd2shell के साथ काम करता है। कोई शॉर्टकट नहीं, लेकिन बस खोजक में cmd2shell बटन पर क्लिक करें और टच कमांड टाइप करें।

— इफलेट

मैं OSX में खोजक के साथ कुछ और संगत की तलाश कर रहा था।

— हैरी

Answer 6

यह उस पोस्ट का रिपॉस्ट है जो मैंने पिछले साल बनाया था। मुझे निम्नलिखित के साथ अच्छा अनुभव रहा है।

दो उपयोगी उपयोगिताओं हैं जिन्हें आप डाउनलोड कर सकते हैं और इंस्टॉल कर सकते हैं जो आपको वर्तमान में खुले फ़ोल्डर में एक नई टेक्स्ट फ़ाइल (या आरटीएफ फ़ाइल) बनाने में सक्षम करेगा जिसे आप खोजक का उपयोग करके देख रहे हैं।

उपयोगिताओं को NewTextFileHere और NewRTFHere कहा जाता है और इससे डाउनलोड किया जा सकता है

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

इनमें से किसी भी ऐप के लिए आइकन तब आपके सभी फाइंडर विंडो पर शामिल किए जा सकते हैं।

Answer 7

बस मैं क्या चाह रहा था, रिचर्ड फूहर। इसके लिए धन्यवाद।

एक नोट: NewTextFileHere के लिए URL का लिंक किसी खाली पृष्ठ पर लोड होता है। लेकिन मैंने एक खोज की और ऐप यहां पाया: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Answer 8

एक विकल्प, यदि आपके पास पहले से ही BetterTouchTools है (यह एक मुफ्त ऐप हुआ करता था, अब इसमें 30-दिन की परीक्षण अवधि के साथ पे- व्हाट-यू-वांट मॉडल है), तो आप उस पर कार्रवाई पा सकते हैं, "Utility Actions > Create New File in Current Folder"जो बिल्कुल ऐसा करता है, पॉप-अप आपको नाम चुनने के लिए। आपको जो शॉर्टकट चाहिए उसे असाइन करें (मैंने विकल्प + शिफ्ट + एन उठाया) और आप जाने के लिए अच्छे हैं।

Answer 9

यदि आप MacVim का उपयोग कर रहे Finder -> Servicesहैं तो एक नया vim बफर बनाने के लिए एक विकल्प है :

मैंने इसे शॉर्ट कट ShiftcmdMमें मैप किया है System Preferences -> Keyboard -> Shortcuts: