Mavericks के तहत Applescript के साथ किसी फ़ाइल पर टैग सेट / जोड़ने का कोई तरीका?

9

Mavericks के तहत अपनी कुछ लिपियों को लेबल से टैग पर ले जाने की कोशिश कर रहा हूं, लेकिन मुझे Applescript के साथ टैग सेट / जोड़ने का कोई तरीका नहीं मिल रहा है।

किसी को पता है कि यह कैसे करना है? जहां तक मैं यह पता लगा सकता हूं कि टैग वास्तव में नए नहीं हैं, अपडेटेड फाइंडर का अधिक केंद्रीय हिस्सा होने के मामले में सिर्फ नया है।

applescript mavericks

— क्रिश्चियन ए। स्ट्रोमैन
स्रोत

7

आप xattr का उपयोग कर सकते हैं। यह फाइल 1 से फाइल 2 तक के टैग को कॉपी करता है:

xattr -wx com.apple.metadata:_kMDItemUserTags "$(xattr -px com.apple.metadata:_kMDItemUserTags file1)" file2
xattr -wx com.apple.FinderInfo "$(xattr -px com.apple.FinderInfo file1)" file2

टैग्स को संपत्ति सूची में स्ट्रिंग्स के एकल सरणी के रूप में संग्रहीत किया जाता है:

$ xattr -p com.apple.metadata:_kMDItemUserTags file3|xxd -r -p|plutil -convert xml1 - -o -
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>aa</string>
    <string>Orange
7</string>
    <string>Yellow
5</string>
    <string>Green
2</string>
    <string>Blue
4</string>
    <string>Purple
3</string>
    <string>Gray
1</string>
</array>
</plist>

रंगों के लिए टैग में मान हैं Red\n6(जहां \nएक लाइनफ़ीड है)।

यदि com.apple.FinderInfo में kColor ध्वज अप्रभावित है, तो फाइंडर फाइलों के बगल में रंगों के लिए सर्कल नहीं दिखाता है। यदि kColor ध्वज नारंगी पर सेट है और फ़ाइल में लाल टैग है, तो खोजक लाल और नारंगी दोनों हलकों को दिखाता है। आप AppleScript के साथ kColor ध्वज सेट कर सकते हैं:

do shell script "xattr -w com.apple.metadata:_kMDItemUserTags '(\"Red\\n6\",\"new tag\")' ~/desktop/file4"
tell application "Finder" to set label index of file "file4" of desktop to item 1 of {2, 1, 3, 6, 4, 5, 7}

'("Red\n6","new tag")' इसके लिए पुरानी शैली का सिंटैक्स है:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>new tag</string>
</array>
</plist>

xattr -p com.apple.FinderInfo file|head -n1|cut -c28-29केलोर ध्वज के लिए प्रयुक्त बिट्स के मूल्य को प्रिंट करता है। रेड सी है, नारंगी ई है, पीला ए है, हरा 4 है, नीला 8 है, मैजेंटा 6 है, और ग्रे 2 है। (मानों में 1 जोड़ने वाला झंडा ओएस एक्स में उपयोग नहीं किया जाता है)

— LRI
स्रोत

"टैग चित्र" .PNGs या रंग-प्रस्तुत ग्राफिक्स हैं? हार्डडिस्क पर "C.png" जैसा कुछ नहीं मिला :)

1

उत्तर को एप्सस्क्रिप्ट उपयोगकर्ता सूची में पोस्ट किया गया है:

http://lists.apple.com/archives/applescript-users/2015/Jan/msg00193.html

शेन स्टेनली द्वारा लिखित पृष्ठ- कोड से उद्धरण

आप इसे AppleScriptObjC के साथ आसानी से कर सकते हैं। टैग को पुनः प्राप्त करने, टैग सेट करने और टैग जोड़ने के लिए यहां हैंडलर हैं:

use scripting additions
use framework "Foundation"

on returnTagsFor:posixPath -- get the tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- because when there are none, it returns missing value
    return theTags as list
end returnTagsFor:

on setTags:tagList forPath:posixPath -- set the tags, replacing any existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

on addTags:tagList forPath:posixPath -- add to existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    -- get existing tags
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags ≠ missing value then -- add new tags
        set tagList to (theTags as list) & tagList
        set tagList to (current application's NSOrderedSet's orderedSetWithArray:tagList)'s allObjects() -- delete any duplicates
    end if
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end addTags:forPath:

यदि आप इसे स्क्रिप्ट लाइब्रेरी में सहेजते हैं, तो आप उन्हें मावेरिक्स से भी उपयोग कर सकते हैं।

- शेन स्टेनली www.macosxautomation.com/applescript/apps/

— brandelune
स्रोत